configure.ac

   1 # -*- mode: shell-script -*-
   2
   3 define([D2X_MAJOR],0)
   4 define([D2X_MINOR],2)
   5 define([D2X_MICRO],0)
   6
   7 AC_INIT(d2x,[D2X_MAJOR.D2X_MINOR.D2X_MICRO],[descent-source@warpcore.org])
   8 AC_PREREQ(2.52)
   9
  10 AC_CANONICAL_BUILD
  11 AC_CANONICAL_HOST
  12 AC_CANONICAL_TARGET
  13
  14 AM_INIT_AUTOMAKE([1.6])
  15
  16 AM_CONFIG_HEADER(conf.h)
  17
  18 AC_DEFINE_UNQUOTED(D2XMAJOR,D2X_MAJOR,[d2x major version])
  19 AC_DEFINE_UNQUOTED(D2XMINOR,D2X_MINOR,[d2x minor version])
  20 AC_DEFINE_UNQUOTED(D2XMICRO,D2X_MICRO,[d2x micro version])
  21
  22 AM_MAINTAINER_MODE
  23
  24 #kludge to keep autoconf from adding -g -O2
  25 CFLAGS=" $CFLAGS"
  26
  27 AC_PROG_INSTALL
  28 AC_PROG_MAKE_SET
  29 AC_ISC_POSIX
  30 AC_CHECK_TOOL(CC, gcc, :)
  31 AC_CHECK_TOOL(RANLIB, ranlib, :)
  32 AC_CHECK_TOOL(STRIP, strip, :)
  33 AC_CHECK_TOOL(AR, ar, :)
  34 AC_PROG_CC
  35 AC_PROG_CXX
  36 AC_STDC_HEADERS
  37 AC_PATH_PROGS(NASM, nasm nasmw, no)
  38 AC_C_BIGENDIAN
  39
  40 case $host_cpu in
  41         sparc)
  42                 AC_DEFINE(WORDS_NEED_ALIGNMENT,,[Define if your processor needs data to be word-aligned])
  43         ;;
  44 esac
  45
  46 case $host_os in
  47     cygwin)
  48         AC_MSG_WARN([Cygwin found, setting -mno-cygwin])
  49         CFLAGS="-mno-cygwin $CFLAGS"
  50         MINGW32=yes
  51         ;;
  52     mingw*)
  53         MINGW32=yes
  54         ;;
  55     darwin*)
  56         MACOSX=yes
  57         ;;
  58     msdos*)
  59         MSDOS=yes
  60         ;;
  61 esac
  62
  63 AM_CONDITIONAL(MINGW32, test x$MINGW32 = xyes)
  64 if test x$MINGW32 = xyes; then
  65     GL_LIBS="opengl32 glu32"
  66 elif test x$MACOSX = xyes; then
  67     GL_LIBS=""
  68 else
  69     GL_LIBS="GL GLU"
  70 fi
  71
  72 if test x$MACOSX = xyes; then
  73     AC_DEFINE(__MACOSX__,,[Define if building on MAC OS X])
  74 fi
  75 AM_CONDITIONAL(MACOSX, test x$MACOSX = xyes)
  76
  77 dnl Set $prefix and $exec_prefix to $ac_default_prefix if they are not set
  78 test "x$prefix" = "xNONE" && prefix=$ac_default_prefix
  79 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
  80
  81 dnl Set default locations to find data files.
  82 default_sharepath="$datadir/games/$PACKAGE"
  83
  84 CFLAGS="-Wall $CFLAGS"
  85
  86 dnl Enable editor build?
  87 AC_ARG_ENABLE(editor,
  88     [  --enable-editor         Build editor? (not functional)],,)
  89 if test x$enable_editor = xyes; then
  90     AC_DEFINE(EDITOR,,[Define if you want to build the editor])
  91     D2X_MAIN_SUBDIRS=editor
  92 fi
  93 AM_CONDITIONAL(EDITOR, test x$enable_editor = xyes)
  94
  95 dnl Enable macdata build?
  96 AC_ARG_ENABLE(macdata,
  97     [  --enable-macdata        Build for mac datafiles],,)
  98 if test x$enable_macdata = xyes; then
  99     AC_DEFINE(MACDATA,,[Define if you want to build for mac datafiles])
 100     D2X_FEATURES="macdata ${D2X_FEATURES}"
 101 fi
 102 AM_CONDITIONAL(MACDATA, test x$enable_macdata = xyes)
 103
 104 dnl Build with NDEBUG?
 105 AC_ARG_ENABLE(debug,
 106     [  --disable-debug         Take out debug symbols, Asserts, Int3, etc ],,)
 107 if test x$enable_debug = xno; then
 108     AC_DEFINE(NDEBUG,,[Define to disable asserts, int3, etc.])
 109     CFLAGS="-O2 $CFLAGS"
 110 else
 111     CFLAGS="-g $CFLAGS"
 112     D2X_FEATURES="debug ${D2X_FEATURES}"
 113 fi
 114
 115 dnl Build with RELEASE?
 116 AC_ARG_ENABLE(release,
 117     [  --enable-release        Release build.  Removes debug/editor things ],,)
 118 if test x$enable_release = xyes; then
 119     AC_DEFINE(RELEASE,,[Define for a "release" build])
 120     D2X_FEATURES="release ${D2X_FEATURES}"
 121 fi
 122
 123 dnl Build without using sdl-joystick ?
 124 AC_ARG_ENABLE(linuxjoy,
 125     [  --enable-linuxjoy       do not use the SDL Joystick. (eg for MS Sidewinder)],,)
 126 if test x$enable_linuxjoy = xyes; then
 127     AC_DEFINE(USE_LINUX_JOY,,[define to not use the SDL_Joystick routines.])
 128 fi
 129 AM_CONDITIONAL(USE_LINUX_JOY, test x$enable_linuxjoy = xyes)
 130
 131 dnl Build with FAST_FILE_IO?
 132 AC_ARG_ENABLE(fastfileio,
 133     [  --disable-fastfileio    Disable fast file i/o. ],,)
 134 if test x$enable_fastfileio != xno; then
 135         if test x$ac_cv_c_bigendian = xyes; then
 136                 AC_MSG_WARN([big-endian cpu detected.  disabling fastfileio])
 137                 enable_fastfileio="no";
 138         fi
 139 fi
 140 if test x$enable_fastfileio != xno; then
 141     AC_DEFINE(FAST_FILE_IO,,[Define for faster i/o on little-endian cpus])
 142     D2X_FEATURES="fastfileio ${D2X_FEATURES}"
 143 fi
 144
 145 dnl Build with CONSOLE?
 146 AC_ARG_ENABLE(console,
 147     [  --enable-console         Enable console (very experimental) ],,)
 148 if test x$enable_console = xyes; then
 149     AC_DEFINE(CONSOLE,,[Define to enable console])
 150     D2X_FEATURES="console ${D2X_FEATURES}"
 151 fi
 152
 153 AC_ARG_WITH(sharepath,
 154     [[  --with-sharepath=DIR    Use DIR for shared game data (unix only) [DATADIR/games/d2x]]],
 155     sharepath=$withval, sharepath="auto")
 156 if test "x$sharepath" = "xauto" -o "x$sharepath" = "xyes" -o "x$sharepath" = "x"; then
 157     sharepath="$default_sharepath"
 158 fi
 159 AC_SUBST(sharepath)
 160 eval sharepath=$sharepath
 161 AC_DEFINE_UNQUOTED(SHAREPATH, "$sharepath",[Define this to be the shared game directory root])
 162
 163 # Test for MSDOS
 164 if test x$MSDOS = xyes; then
 165     CFLAGS="-I \$(top_srcdir)/arch/dos/include $CFLAGS"
 166     TARGETS=d2x
 167     D2X_ARCH_SUBDIRS=dos
 168 else
 169
 170     CFLAGS="-pipe $CFLAGS"
 171
 172     dnl Check for SDL
 173     AM_PATH_SDL(1.1.0,
 174         :,
 175         AC_MSG_ERROR(SDL not found. Make sure sdl-config is in your PATH, or specify with --with-sdl-prefix)
 176     )
 177     CFLAGS="$SDL_CFLAGS $CFLAGS"
 178     LIBS="$SDL_LIBS $LIBS"
 179
 180     TARGETS=d2x-sdl
 181     D2X_ARCH_SUBDIRS=sdl
 182
 183     AC_CHECK_HEADERS(netipx/ipx.h)
 184
 185   # Check for OpenGL
 186     AC_ARG_WITH(opengl,
 187         [  --with-opengl           Build OpenGL support ],,)
 188     if test x$with_opengl = xyes; then
 189         for lib in $GL_LIBS; do
 190             AC_CHECK_LIB($lib, main,
 191                 OGL_LIBS="${OGL_LIBS} -l$lib",
 192                 [AC_MSG_ERROR([$lib not found, --with-opengl cannot be used])
 193                     opengl=false],
 194                 ${OGL_LIBS}
 195             )
 196         done
 197         AC_DEFINE(OGL,,[Define if you want an OpenGL build])
 198         TARGETS=d2x-gl
 199         D2X_ARCH_SUBDIRS="ogl ${D2X_ARCH_SUBDIRS}"
 200     fi
 201     AC_SUBST(OGL_LIBS)
 202     AM_CONDITIONAL(USE_OPENGL, test x$with_opengl = xyes)
 203
 204   # Check for GGI
 205     AC_ARG_WITH(ggi,
 206         [  --with-ggi              Build GGI support ],,)
 207     if test x$with_ggi = xyes; then
 208         AC_CHECK_LIB(ggi, ggiInit,
 209             GGI_LIBS="-lggi",
 210             [AC_MSG_ERROR([GGI not found, GGI version cannot be built]); ggi=false])
 211         AC_CHECK_LIB(gii, giiInit,
 212             GGI_LIBS="${GGI_LIBS} -lgii",
 213             [AC_MSG_ERROR([GII not found, GGI version cannot be built]); ggi=false])
 214         AC_DEFINE(GGI,,[Define if you want a GGI build])
 215         TARGETS=d2x-ggi
 216         D2X_ARCH_SUBDIRS="ggi ${D2X_ARCH_SUBDIRS}"
 217     fi
 218     AC_SUBST(GGI_LIBS)
 219     AM_CONDITIONAL(USE_GGI, test x$with_ggi = xyes)
 220
 221   # Check for SVGALib
 222     AC_ARG_WITH(svga,
 223         [  --with-svga             Build SVGALib support ],,)
 224     if test x$with_svga = xyes; then
 225         AC_CHECK_LIB(vga,vga_getmousetype,
 226             SVGA_LIBS="-lvga",
 227             [AC_MSG_ERROR([vga not found, SVGALib cannot be built])
 228                 svga=false],
 229         )
 230         AC_CHECK_LIB(vgagl,gl_getcontext,
 231             SVGA_LIBS="${SVGA_LIBS} -lvgagl",
 232             [AC_MSG_ERROR([vgagl not found, SVGALib cannot be built])
 233                 svga=false],
 234             -lvga)
 235         AC_DEFINE(SVGA,,[Define if you want an SVGALib build])
 236         TARGETS=d2x-svga
 237         D2X_ARCH_SUBDIRS="svgalib ${D2X_ARCH_SUBDIRS}"
 238     fi
 239     AC_SUBST(SVGA_LIBS)
 240     AM_CONDITIONAL(USE_SVGALIB, test x$with_svga = xyes)
 241
 242     if test x$MINGW32 = xyes; then
 243         D2X_ARCH_SUBDIRS="win32 ${D2X_ARCH_SUBDIRS}"
 244     else
 245         CFLAGS="-I \$(top_srcdir)/arch/linux/include $CFLAGS"
 246         D2X_ARCH_SUBDIRS="linux ${D2X_ARCH_SUBDIRS}"
 247     fi
 248 fi
 249
 250 dnl Check for network
 251 AC_ARG_ENABLE(network,
 252     [  --disable-network       Do not build network/serial support ],,)
 253 if test x$enable_network != xno; then
 254         if test x$MACOSX = xyes; then
 255                 AC_MSG_WARN([OS X detected.  disabling network])
 256                 enable_network="no";
 257         fi
 258 #       if test x$MINGW32 = xyes; then
 259 #               AC_MSG_WARN([MINGW detected.  disabling network])
 260 #               enable_network="no";
 261 #       fi
 262 fi
 263 if test x$enable_network != xno; then
 264     AC_DEFINE(NETWORK,,[Define if you want a network build])
 265     D2X_FEATURES="network ${D2X_FEATURES}"
 266 fi
 267 AM_CONDITIONAL(USE_NETWORK, test x$enable_network != xno)
 268
 269 dnl Check for assembler
 270 AC_ARG_ENABLE(assembler,
 271     [  --disable-assembler     Do not use assembler optimization ],,)
 272 if test x$enable_assembler != xno; then
 273     if test x$NASM = xno; then
 274         AC_MSG_WARN([nasm not found. disabling assembler])
 275         enable_assembler="no"
 276     else
 277         NASMFLAGS="-i\$(srcdir)/ $NASMFLAGS"
 278         case $host_os in
 279             cygwin* | mingw*)
 280                 NASMFLAGS="-f win32 $NASMFLAGS"
 281                 ;;
 282             msdos*)
 283                 NASMFLAGS="-f coff $NASMFLAGS"
 284                 ;;
 285             linux*)
 286                 NASMFLAGS="-f elf -d__linux__ $NASMFLAGS"
 287                 ;;
 288             *)
 289                 AC_MSG_WARN([nasm not supported for this OS. disabling assembler])
 290                 enable_assembler="no"
 291                 ;;
 292         esac
 293     fi
 294 fi
 295 if test x$enable_assembler = xno; then
 296     AC_DEFINE(NO_ASM,,[Define if you want an assembler free build])
 297     D2X_FEATURES="no_asm ${D2X_FEATURES}"
 298 fi
 299 AM_CONDITIONAL(USE_ASM, test x$enable_assembler != xno)
 300
 301 AH_BOTTOM([
 302         /* General defines */
 303 #define VERSION_NAME PACKAGE_STRING
 304 #define NMONO 1
 305 #define PIGGY_USE_PAGING 1
 306 #define NEWDEMO 1
 307
 308 #ifdef __MACOSX__
 309 #define __unix__
 310 #endif
 311
 312 #ifdef __unix__
 313 # ifdef GGI
 314 #  define GII_INPUT 1
 315 #  define GGI_VIDEO 1
 316 # else
 317 #  ifdef SVGA
 318 #   define SVGALIB_INPUT 1
 319 #   define SVGALIB_VIDEO 1
 320 #  else
 321 #   define SDL_INPUT 1
 322 #   ifdef OGL
 323 #    define SDL_GL_VIDEO 1
 324 #   else
 325 #    define SDL_VIDEO 1
 326 #   endif
 327 #  endif
 328 # endif
 329 #endif
 330
 331 #ifdef __MINGW32__
 332 # define SDL_INPUT 1
 333 # ifdef OGL
 334 #  define SDL_GL_VIDEO 1
 335 # else
 336 #  define SDL_VIDEO 1
 337 # endif
 338 #endif
 339         ])
 340
 341 AM_PROG_AS
 342
 343 AC_SUBST(D2X_ARCH_SUBDIRS)
 344
 345 AC_SUBST(D2X_MAIN_SUBDIRS)
 346
 347 AC_SUBST(TARGETS)
 348
 349 AC_SUBST(NASMFLAGS)
 350
 351 AC_SUBST(CFLAGS)
 352
 353 AC_OUTPUT(
 354     Makefile
 355     2d/Makefile
 356     3d/Makefile
 357     arch/Makefile
 358     arch/dos/Makefile
 359     arch/ggi/Makefile
 360     arch/linux/Makefile
 361     arch/ogl/Makefile
 362     arch/sdl/Makefile
 363     arch/svgalib/Makefile
 364     arch/win32/Makefile
 365     cfile/Makefile
 366     iff/Makefile
 367     libmve/Makefile
 368     main/Makefile
 369     main/editor/Makefile
 370     maths/Makefile
 371     mem/Makefile
 372     misc/Makefile
 373     texmap/Makefile
 374     utilities/Makefile
 375     debian/changelog
 376     rpm/d2x.spec
 377 )
 378
 379 AC_MSG_RESULT([
 380         d2x has been configured successfully.
 381
 382         Platform(s): $D2X_ARCH_SUBDIRS
 383         Features   : $D2X_FEATURES $D2X_MAIN_SUBDIRS
 384
 385         Shared game data directory (unix only): $sharepath
 386         ])