qcsrc/server/cl_weapons.qc

   1
   2 // generic weapons table
   3 // add new weapons here
   4 float(float wpn, float wrequest) weapon_action =
   5 {
   6         if (wpn == WEP_LASER)
   7                 return w_laser(wrequest);
   8         else if (wpn == WEP_SHOTGUN)
   9                 return w_shotgun(wrequest);
  10         else if (wpn == WEP_UZI)
  11                 return w_uzi(wrequest);
  12         else if (wpn == WEP_GRENADE_LAUNCHER)
  13                 return w_glauncher(wrequest);
  14         else if (wpn == WEP_ELECTRO)
  15                 return w_electro(wrequest);
  16         else if (wpn == WEP_CRYLINK)
  17                 return w_crylink(wrequest);
  18         else if (wpn == WEP_NEX)
  19                 return w_nex(wrequest);
  20         else if (wpn == WEP_HAGAR)
  21                 return w_hagar(wrequest);
  22         else if (wpn == WEP_ROCKET_LAUNCHER)
  23                 return w_rlauncher(wrequest);
  24         return FALSE;
  25 };
  26
  27 // think function for tossed weapons
  28 void() thrown_wep_think
  29 {
  30         self.solid = SOLID_TRIGGER;
  31         self.owner = world;
  32         SUB_SetFade(self, time + 20, 1);
  33         setorigin(self, self.origin);
  34 };
  35
  36 // toss current weapon
  37 void() W_ThrowWeapon
  38 {
  39         local float w, ammo;
  40         local entity wep, e;
  41
  42         e = self;
  43         wep = spawn();
  44         self = wep;
  45         w = e.weapon;
  46         setorigin(wep, e.origin);
  47         makevectors(e.angles);
  48         wep.classname = "droppedweapon";
  49         wep.velocity = e.velocity * 0.5 + v_forward * 750;
  50         SUB_SetFade(wep, time + 20, 1);
  51
  52         if(w == WEP_SHOTGUN)
  53         {
  54                 w = IT_SHOTGUN;
  55                 if(!(e.items & w))
  56                 {
  57                         remove(wep);
  58                         return;
  59                 }
  60                 weapon_shotgun();
  61                 ammo = min(e.ammo_shells, wep.ammo_shells);
  62                 wep.ammo_shells = ammo;
  63                 e.ammo_shells -= ammo;
  64         }
  65         else if(w == WEP_UZI)
  66         {
  67                 w = IT_UZI;
  68                 if(!(e.items & w))
  69                 {
  70                         remove(wep);
  71                         return;
  72                 }
  73                 weapon_uzi();
  74                 ammo = min(e.ammo_nails, wep.ammo_nails);
  75                 wep.ammo_nails = ammo;
  76                 e.ammo_nails -= ammo;
  77         }
  78         else if(w == WEP_GRENADE_LAUNCHER)
  79         {
  80                 w = IT_GRENADE_LAUNCHER;
  81                 if(!(e.items & w))
  82                 {
  83                         remove(wep);
  84                         return;
  85                 }
  86                 weapon_grenadelauncher();
  87                 ammo = min(e.ammo_rockets, wep.ammo_rockets);
  88                 wep.ammo_rockets = ammo;
  89                 e.ammo_rockets -= ammo;
  90         }
  91         else if(w == WEP_ELECTRO)
  92         {
  93                 w = IT_ELECTRO;
  94                 if(!(e.items & w))
  95                 {
  96                         remove(wep);
  97                         return;
  98                 }
  99                 weapon_electro();
 100                 ammo = min(e.ammo_cells, wep.ammo_cells);
 101                 wep.ammo_cells = ammo;
 102                 e.ammo_cells -= ammo;
 103         }
 104         else if(w == WEP_CRYLINK)
 105         {
 106                 w = IT_CRYLINK;
 107                 if(!(e.items & w))
 108                 {
 109                         remove(wep);
 110                         return;
 111                 }
 112                 weapon_crylink();
 113                 ammo = min(e.ammo_cells, wep.ammo_cells);
 114                 wep.ammo_cells = ammo;
 115                 e.ammo_cells -= ammo;
 116         }
 117         else if(w == WEP_NEX)
 118         {
 119                 w = IT_NEX;
 120                 if(!(e.items & w))
 121                 {
 122                         remove(wep);
 123                         return;
 124                 }
 125                 weapon_nex();
 126                 ammo = min(e.ammo_cells, wep.ammo_cells);
 127                 wep.ammo_cells = ammo;
 128                 e.ammo_cells -= ammo;
 129         }
 130         else if(w == WEP_HAGAR)
 131         {
 132                 w = IT_HAGAR;
 133                 if(!(e.items & w))
 134                 {
 135                         remove(wep);
 136                         return;
 137                 }
 138                 weapon_hagar();
 139                 ammo = min(e.ammo_rockets, wep.ammo_rockets);
 140                 wep.ammo_rockets = ammo;
 141                 e.ammo_rockets -= ammo;
 142         }
 143         else if(w == WEP_ROCKET_LAUNCHER)
 144         {
 145                 w = IT_ROCKET_LAUNCHER;
 146                 if(!(e.items & w))
 147                 {
 148                         remove(wep);
 149                         return;
 150                 }
 151                 weapon_rocketlauncher();
 152                 ammo = min(e.ammo_rockets, wep.ammo_rockets);
 153                 wep.ammo_rockets = ammo;
 154                 e.ammo_rockets -= ammo;
 155         }
 156
 157         if(e.items & w)
 158                 sprint(e, strcat("You dropped the ^2", wep.netname, "\n"));
 159         wep.owner = e;
 160         setorigin(wep, wep.origin);
 161         wep.nextthink = time + 0.5;
 162         wep.think = thrown_wep_think;
 163         wep.classname = "droppedweapon";
 164         e.items = e.items - (e.items & w);
 165         e.switchweapon = w_getbestweapon(e);
 166         wep.colormap = e.colormap;
 167         if (e.switchweapon != e.weapon)
 168                 e.cnt = e.weapon;
 169         self = e;
 170 };
 171
 172 // switch between weapons
 173 void(float imp) W_SwitchWeapon
 174 {
 175         if (self.weapon != imp)
 176         if (client_hasweapon(self, imp, TRUE, TRUE))
 177         {
 178                 self.cnt = self.weapon;
 179                 self.switchweapon = imp;
 180         }
 181 };
 182
 183 // next weapon
 184 void() W_NextWeapon =
 185 {
 186         local float weaponwant, maxtries;
 187
 188         maxtries = WEP_LAST;
 189
 190         weaponwant = self.switchweapon + 1;
 191         if (weaponwant < WEP_FIRST)
 192                 weaponwant = WEP_LAST;
 193         if (weaponwant > WEP_LAST)
 194                 weaponwant = WEP_FIRST;
 195         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 196         {
 197                 if(!maxtries)
 198                         return;
 199
 200                 maxtries -= 1;
 201                 weaponwant = weaponwant + 1;
 202                 if (weaponwant < WEP_FIRST)
 203                         weaponwant = WEP_LAST;
 204                 if (weaponwant > WEP_LAST)
 205                         weaponwant = WEP_FIRST;
 206         }
 207         self.cnt = self.weapon;
 208         self.switchweapon = weaponwant;
 209 };
 210
 211 // prev weapon
 212 void() W_PreviousWeapon =
 213 {
 214         local float weaponwant, maxtries;
 215
 216         maxtries = WEP_LAST;
 217
 218         weaponwant = self.switchweapon - 1;
 219         if (weaponwant < WEP_FIRST)
 220                 weaponwant = WEP_LAST;
 221         if (weaponwant > WEP_LAST)
 222                 weaponwant = WEP_FIRST;
 223         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 224         {
 225                 if(!maxtries)
 226                         return;
 227
 228                 maxtries -= 1;
 229                 weaponwant = weaponwant - 1;
 230                 if (weaponwant < WEP_FIRST)
 231                         weaponwant = WEP_LAST;
 232                 if (weaponwant > WEP_LAST)
 233                         weaponwant = WEP_FIRST;
 234         }
 235         self.cnt = self.weapon;
 236         self.switchweapon = weaponwant;
 237 };
 238
 239 // Bringed back weapon frame
 240 void() W_WeaponFrame =
 241 {
 242         if(arena_roundbased)
 243         if(time < self.arena_warmup_end)
 244                 return;
 245
 246         if (!self.weaponentity || self.health < 1)
 247                 return; // Dead player can't use weapons and injure impulse commands
 248
 249         if(!self.switchweapon)
 250         {
 251                 self.weapon = 0;
 252                 self.weaponentity.state = WS_CLEAR;
 253                 return;
 254         }
 255
 256         makevectors(self.v_angle);
 257
 258         // Change weapon
 259         if (self.weapon != self.switchweapon)
 260         {
 261                 if (self.weaponentity.state == WS_CLEAR)
 262                 {
 263                         self.weaponentity.state = WS_RAISE;
 264                         weapon_action(self.switchweapon, WR_SETUP);
 265                         // VorteX: add player model weapon select frame here
 266                         // setcustomframe(PlayerWeaponRaise);
 267                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 268                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 269                 }
 270                 else if (self.weaponentity.state == WS_READY)
 271                 {
 272                         sound (self, CHAN_WEAPON, "weapons/weapon_switch.ogg", 1, ATTN_NORM);
 273                         self.weaponentity.state = WS_DROP;
 274                         // set up weapon switch think in the future, and start drop anim
 275                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 276                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 277                 }
 278         }
 279
 280         // call the think code which may fire the weapon
 281         weapon_action(self.weapon, WR_THINK);
 282
 283         // update currentammo incase it has changed
 284         if (self.items & IT_CELLS)
 285                 self.currentammo = self.ammo_cells;
 286         else if (self.items & IT_ROCKETS)
 287                 self.currentammo = self.ammo_rockets;
 288         else if (self.items & IT_NAILS)
 289                 self.currentammo = self.ammo_nails;
 290         else if (self.items & IT_SHELLS)
 291                 self.currentammo = self.ammo_shells;
 292         else
 293                 self.currentammo = 1;
 294
 295         // do weapon think
 296         if (time >= self.weapon_nextthink)
 297                 if (self.weapon_nextthink > 0)
 298                         self.weapon_think();
 299 };
 300
 301 float nixnex_weapon;
 302 float nixnex_nextchange;
 303 float nixnex_nextweapon;
 304 .float nixnex_lastchange_id;
 305 .float nixnex_lastinfotime;
 306 .float nixnex_nextincr;
 307
 308 void Nixnex_ChooseNextWeapon()
 309 {
 310         float numberof, id;
 311         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 312         if(cvar("g_nixnex_with_laser"))
 313                 numberof = numberof - 1;
 314         id = WEP_FIRST + ceil(random() * numberof) - 1;
 315
 316         if(cvar("g_nixnex_with_laser")) // skip the laser if needed
 317                 id = id + 1;
 318
 319         if(id >= nixnex_weapon) // skip the current weapon
 320                 id = id + 1;
 321
 322         if(id < WEP_FIRST) // can't happen, but to be sure...
 323         {
 324                 dprint("Won't happen (id < WEP_FIRST)\n");
 325                 id = WEP_FIRST;
 326         }
 327         if(id > WEP_LAST) // either
 328         {
 329                 dprint("Won't happen (id > WEP_LAST)\n");
 330                 id = WEP_LAST;
 331         }
 332
 333         nixnex_nextweapon = id;
 334 }
 335
 336 string W_Name(float weaponid)
 337 {
 338         if(weaponid == WEP_LASER)             return "Laser";
 339         if(weaponid == WEP_UZI)               return "Machine Gun";
 340         if(weaponid == WEP_SHOTGUN)           return "Shotgun";
 341         if(weaponid == WEP_GRENADE_LAUNCHER)  return "Mortar";
 342         if(weaponid == WEP_ELECTRO)           return "Electro";
 343         if(weaponid == WEP_NEX)               return "Nex";
 344         if(weaponid == WEP_HAGAR)             return "Hagar";
 345         if(weaponid == WEP_ROCKET_LAUNCHER)   return "Rocket Launcher";
 346         if(weaponid == WEP_CRYLINK)           return "Crylink";
 347         return "@!#%'n Tuba";
 348 }
 349
 350 void Nixnex_GiveCurrentWeapon()
 351 {
 352         float dt;
 353         if(cvar("g_nixnex"))
 354         {
 355                 if(!nixnex_nextweapon)
 356                         Nixnex_ChooseNextWeapon();
 357
 358                 dt = ceil(nixnex_nextchange - time);
 359
 360                 if(dt <= 0)
 361                 {
 362                         nixnex_weapon = nixnex_nextweapon;
 363                         nixnex_nextweapon = 0;
 364                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 365                 }
 366
 367                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 368                 {
 369                         self.nixnex_lastchange_id = nixnex_nextchange;
 370                         if (cvar("g_use_ammunition"))
 371                         {
 372                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 373                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 374                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 375                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 376                         }
 377                         else
 378                         {
 379                                 self.ammo_shells = 999;
 380                                 self.ammo_nails = 999;
 381                                 self.ammo_rockets = 999;
 382                                 self.ammo_cells = 999;
 383                         }
 384                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 385                         if(dt >= 1 && dt <= 5)
 386                                 self.nixnex_lastinfotime = -42;
 387                         else
 388                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 389                 }
 390                 if(self.nixnex_lastinfotime != dt)
 391                 {
 392                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 393                         if(dt >= 1 && dt <= 5)
 394                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 395                 }
 396
 397                 if(cvar("g_use_ammunition") && time > self.nixnex_nextincr)
 398                 {
 399                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 400                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 401                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 402                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 403                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 404                 }
 405
 406                 self.items = self.items - (self.items & (IT_LASER | IT_SHOTGUN | IT_UZI | IT_GRENADE_LAUNCHER | IT_ELECTRO | IT_CRYLINK | IT_NEX | IT_HAGAR | IT_ROCKET_LAUNCHER));
 407                 if(cvar("g_nixnex_with_laser"))
 408                         self.items = self.items + IT_LASER;
 409                 self.items = self.items - (self.items & weapon_translateindextoflag(nixnex_weapon)) + weapon_translateindextoflag(nixnex_weapon);
 410
 411                 if(self.switchweapon != nixnex_weapon)
 412                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 413                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 414                                         W_SwitchWeapon(nixnex_weapon);
 415         }
 416 }
 417