data/qcsrc/warpzonelib/common.qc

   1 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
   2 {
   3         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
   4         e.warpzone_origin = my_org;
   5         e.warpzone_targetorigin = other_org;
   6         e.warpzone_angles = my_ang;
   7         e.warpzone_targetangles = other_ang;
   8         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
   9         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  10 }
  11
  12 .entity enemy;
  13
  14 vector WarpZoneLib_BoxTouchesBrush_mins;
  15 vector WarpZoneLib_BoxTouchesBrush_maxs;
  16 entity WarpZoneLib_BoxTouchesBrush_ent;
  17 entity WarpZoneLib_BoxTouchesBrush_ignore;
  18 float WarpZoneLib_BoxTouchesBrush_Recurse()
  19 {
  20         float s;
  21         entity se;
  22         float f;
  23
  24         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
  25 #ifdef CSQC
  26         if (trace_networkentity)
  27         {
  28                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
  29                 // we cannot continue, as a player blocks us...
  30                 // so, abort
  31                 return 0;
  32         }
  33 #endif
  34         if not(trace_ent)
  35                 return 0;
  36         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
  37                 return 1;
  38
  39
  40
  41         se = trace_ent;
  42         s = se.solid;
  43         se.solid = SOLID_NOT;
  44         f = WarpZoneLib_BoxTouchesBrush_Recurse();
  45         se.solid = s;
  46
  47         return f;
  48 }
  49
  50 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
  51 {
  52     float f, s;
  53
  54     if not(e.modelindex)
  55         return 1;
  56
  57     s = e.solid;
  58     e.solid = SOLID_BSP;
  59     WarpZoneLib_BoxTouchesBrush_mins = mi;
  60     WarpZoneLib_BoxTouchesBrush_maxs = ma;
  61     WarpZoneLib_BoxTouchesBrush_ent = e;
  62     WarpZoneLib_BoxTouchesBrush_ignore = ig;
  63     f = WarpZoneLib_BoxTouchesBrush_Recurse();
  64     e.solid = s;
  65
  66     return f;
  67 }
  68
  69 entity WarpZone_Find(vector mi, vector ma)
  70 {
  71         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
  72         entity e;
  73         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
  74                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
  75                         return e;
  76         return world;
  77 }
  78
  79 void WarpZone_MakeAllSolid()
  80 {
  81         entity e;
  82         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
  83                 e.solid = SOLID_BSP;
  84 }
  85
  86 void WarpZone_MakeAllOther()
  87 {
  88         entity e;
  89         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
  90                 e.solid = SOLID_TRIGGER;
  91 }
  92
  93 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
  94 {
  95         float frac, sol;
  96         vector o0, e0;
  97         vector vf, vr, vu;
  98         vf = v_forward;
  99         vr = v_right;
 100         vu = v_up;
 101         WarpZone_MakeAllSolid();
 102         o0 = org;
 103         e0 = end;
 104         sol = -1;
 105         frac = 0;
 106         for(;;)
 107         {
 108                 tracebox(org, mi, ma, end, nomonsters, forent);
 109                 if(WarpZone_trace_callback)
 110                         WarpZone_trace_callback();
 111                 if(sol < 0)
 112                         sol = trace_startsolid;
 113                 if(trace_fraction >= 1)
 114                         break;
 115                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 116                 if(trace_ent.classname != "trigger_warpzone")
 117                         break;
 118                 // we hit a warpzone... so, let's perform the trace after the warp again
 119                 org = WarpZone_TransformOrigin(trace_ent, trace_endpos);
 120                 end = WarpZone_TransformOrigin(trace_ent, end);
 121                 WarpZone_trace_velocity = WarpZone_TransformVelocity(trace_ent, WarpZone_trace_velocity);
 122                 WarpZone_trace_angles = WarpZone_TransformAngles(trace_ent, WarpZone_trace_angles);
 123                 WarpZone_trace_v_angle = WarpZone_TransformVAngles(trace_ent, WarpZone_trace_v_angle);
 124         }
 125         WarpZone_MakeAllOther();
 126         trace_startsolid = sol;
 127         WarpZone_trace_endpos = o0 + (e0 - o0) * trace_fraction;
 128         v_forward = vf;
 129         v_right = vr;
 130         v_up = vu;
 131 }
 132
 133 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 134 {
 135         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 136 }
 137
 138 void WarpZone_TraceToss(entity e, entity forent)
 139 {
 140         float g, dt;
 141         vector vf, vr, vu, v0, o0;
 142         vf = v_forward;
 143         vr = v_right;
 144         vu = v_up;
 145         WarpZone_MakeAllSolid();
 146         g = cvar("sv_gravity") * e.gravity;
 147         WarpZone_tracetoss_time = 0;
 148         v0 = e.velocity;
 149         o0 = e.origin;
 150         for(;;)
 151         {
 152                 tracetoss(e, forent);
 153                 if(WarpZone_trace_callback)
 154                         WarpZone_trace_callback();
 155                 e.origin = trace_endpos;
 156                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 157                 WarpZone_tracetoss_time += dt;
 158                 e.velocity_z -= WarpZone_tracetoss_time * g;
 159                 if(trace_fraction >= 1)
 160                         break;
 161                 if(trace_ent.classname != "trigger_warpzone")
 162                         break;
 163                 // we hit a warpzone... so, let's perform the trace after the warp again
 164                 e.origin = WarpZone_TransformOrigin(trace_ent, e.origin);
 165                 e.velocity = WarpZone_TransformVelocity(trace_ent, e.velocity);
 166         }
 167         WarpZone_MakeAllOther();
 168         v_forward = vf;
 169         v_right = vr;
 170         v_up = vu;
 171         WarpZone_tracetoss_velocity = e.velocity;
 172         e.velocity = v0;
 173         e.origin = o0;
 174         WarpZone_trace_endpos = e.origin + e.velocity * WarpZone_tracetoss_time;
 175         WarpZone_trace_endpos_z -= 0.5 * g * WarpZone_tracetoss_time * WarpZone_tracetoss_time;
 176 }
 177
 178 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 179 {
 180         float frac;
 181         vector vf, vr, vu;
 182         vf = v_forward;
 183         vr = v_right;
 184         vu = v_up;
 185         WarpZone_MakeAllSolid();
 186         frac = 0;
 187         for(;;)
 188         {
 189                 traceline(org, end, MOVE_NOMONSTERS, world);
 190                 //print(vtos(org), " to ", vtos(trace_endpos), "\n");
 191                 trailparticles(own, eff, org, trace_endpos);
 192                 if(trace_fraction >= 1)
 193                         break;
 194                 if(trace_ent.classname != "trigger_warpzone")
 195                         break;
 196                 // we hit a warpzone... so, let's perform the trace after the warp again
 197                 org = WarpZone_TransformOrigin(trace_ent, trace_endpos);
 198                 end = WarpZone_TransformOrigin(trace_ent, end);
 199         }
 200         WarpZone_MakeAllOther();
 201         v_forward = vf;
 202         v_right = vr;
 203         v_up = vu;
 204 }
 205
 206 float WarpZone_PlaneDist(entity wz, vector v)
 207 {
 208         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 209 }
 210
 211 float WarpZone_TargetPlaneDist(entity wz, vector v)
 212 {
 213         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 214 }
 215
 216 vector WarpZone_TransformOrigin(entity wz, vector v)
 217 {
 218         return wz.enemy.warpzone_origin + AnglesTransform_Apply(wz.warpzone_transform, v - wz.warpzone_origin);
 219 }
 220
 221 vector WarpZone_TransformVelocity(entity wz, vector v)
 222 {
 223         return AnglesTransform_Apply(wz.warpzone_transform, v);
 224 }
 225
 226 vector WarpZone_TransformAngles(entity wz, vector v)
 227 {
 228         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 229 }
 230
 231 vector WarpZone_TransformVAngles(entity wz, vector ang)
 232 {
 233         float roll;
 234
 235         roll = ang_z;
 236         ang_z = 0;
 237
 238         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 239         ang = AnglesTransform_Normalize(ang, TRUE);
 240         ang = AnglesTransform_CancelRoll(ang);
 241
 242         ang_z = roll;
 243         return ang;
 244 }