data/qcsrc/server/w_uzi.qc

   1
   2 // leilei's fancy muzzleflash stuff
   3 void W_Uzi_Flash_Go() {
   4         if (self.frame > 10){
   5                 SUB_Remove();
   6                 return;
   7         }
   8         self.frame = self.frame + 2;
   9         self.alpha = self.alpha - 0.2;
  10         self.think = W_Uzi_Flash_Go;
  11         self.nextthink = time + 0.02;
  12 };
  13
  14 .float uzi_bulletcounter;
  15 void W_Uzi_Attack (float deathtype)
  16 {
  17         local entity flash, flash2;
  18
  19         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  20         {
  21                 if (self.uzi_bulletcounter == 1)
  22                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  23                 else
  24                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  25         }
  26         W_SetupShot (self, '23 8 -9.5', TRUE, 0, "weapons/uzi_fire.wav");
  27         if (!g_norecoil)
  28         {
  29                 self.punchangle_x = random () - 0.5;
  30                 self.punchangle_y = random () - 0.5;
  31         }
  32
  33         // this attack_finished just enforces a cooldown at the end of a burst
  34         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
  35
  36         if (self.uzi_bulletcounter == 1)
  37                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_first_damage"), 0, cvar("g_balance_uzi_first_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  38         else
  39                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_sustained_damage"), 0, cvar("g_balance_uzi_sustained_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  40
  41         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  42
  43         // muzzle flash for 1st person view
  44         flash = spawn();
  45         setorigin(flash, '5 0 0');
  46         setmodel(flash, "models/uziflash.md3"); // precision set below
  47         if (gettagindex(self.weaponentity, "shot"))
  48                 setattachment(flash, self.weaponentity, "shot");
  49         else if (gettagindex(self.weaponentity, "bone02"))
  50                 setattachment(flash, self.weaponentity, "bone02");
  51         else
  52         {
  53                 setorigin(flash, '48 0 5');
  54                 setattachment(flash, self.weaponentity, "");
  55         }
  56         flash.owner = self;
  57         flash.viewmodelforclient = self;
  58         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
  59         //SUB_SetFade(flash, time + 0.06, 0);
  60         flash.think = W_Uzi_Flash_Go;
  61         flash.nextthink = time + 0.02;
  62         flash.frame = 2;
  63
  64         // muzzle flash for 3rd person view
  65         flash2 = spawn();
  66         setorigin(flash2, '43 1 8');
  67         setmodel(flash2, "models/uziflash.md3"); // precision set below
  68         setattachment(flash2, self.exteriorweaponentity, "");
  69         //SUB_SetFade(flash2, time + 0.06, 0);
  70         flash2.think = W_Uzi_Flash_Go;
  71         flash2.nextthink = time + 0.02;
  72         flash2.frame = 2;
  73         // common properties
  74         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  75         flash.alpha = flash2.alpha = 1;
  76         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  77
  78         // casing code
  79         if (cvar("g_casings") >= 2)
  80                 SpawnCasing (w_shotorg - v_forward * 10, ((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  81 }
  82
  83 // weapon frames
  84 void uzi_fire1_02()
  85 {
  86         if(self.weapon != self.switchweapon) // abort immediately if switching
  87         {
  88                 w_ready();
  89                 return;
  90         }
  91         if (self.BUTTON_ATCK)
  92         {
  93                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  94                 {
  95                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  96                         w_ready();
  97                         return;
  98                 }
  99                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
 100                 W_Uzi_Attack(WEP_UZI);
 101                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 102         }
 103         else
 104                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
 105 };
 106
 107 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
 108
 109 float w_uzi(float req)
 110 {
 111         if (req == WR_AIM)
 112                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 113                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 114                 else
 115                 {
 116                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 117                 }
 118         else if (req == WR_THINK)
 119         {
 120                 if (self.BUTTON_ATCK)
 121                 if (weapon_prepareattack(0, 0))
 122                 {
 123                         self.uzi_bulletcounter = 1;
 124                         W_Uzi_Attack(WEP_UZI); // sets attack_finished
 125                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 126                 }
 127                 if (self.BUTTON_ATCK2)
 128                 if (weapon_prepareattack(1, 0))
 129                 {
 130                         self.uzi_bulletcounter = 1;
 131                         W_Uzi_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 132                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_uzi_first_refire"), w_ready);
 133                 }
 134         }
 135         else if (req == WR_PRECACHE)
 136         {
 137                 precache_model ("models/uziflash.md3");
 138                 precache_model ("models/weapons/g_uzi.md3");
 139                 precache_model ("models/weapons/v_uzi.md3");
 140                 precache_model ("models/weapons/w_uzi.dpm");
 141                 precache_sound ("weapons/uzi_fire.wav");
 142         }
 143         else if (req == WR_SETUP)
 144         {
 145                 weapon_setup(WEP_UZI);
 146         }
 147         else if (req == WR_CHECKAMMO1)
 148                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 149         else if (req == WR_CHECKAMMO2)
 150                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 151         else if (req == WR_SUICIDEMESSAGE)
 152                 w_deathtypestring = "did the impossible";
 153         else if (req == WR_KILLMESSAGE)
 154         {
 155                 if(w_deathtype & HITTYPE_SECONDARY)
 156                         w_deathtypestring = "was sniped by";
 157                 else
 158                         w_deathtypestring = "was riddled full of holes by";
 159         }
 160         return TRUE;
 161 };