data/qcsrc/server/w_uzi.qc

   1
   2 // leilei's fancy muzzleflash stuff
   3 void W_Uzi_Flash_Go() {
   4         if (self.frame > 10){
   5                 SUB_Remove();
   6                 return;
   7         }
   8         self.frame = self.frame + 2;
   9         self.alpha = self.alpha - 0.2;
  10         self.think = W_Uzi_Flash_Go;
  11         self.nextthink = time + 0.02;
  12 };
  13
  14 .float uzi_bulletcounter;
  15 void W_Uzi_Attack (float deathtype)
  16 {
  17         local entity flash, flash2;
  18
  19         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  20         {
  21                 if (self.uzi_bulletcounter == 1)
  22                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  23                 else
  24                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  25         }
  26         W_SetupShot (self, '23 8 -9.5', TRUE, 0, "weapons/uzi_fire.wav");
  27         if (!g_norecoil)
  28         {
  29                 self.punchangle_x = random () - 0.5;
  30                 self.punchangle_y = random () - 0.5;
  31         }
  32
  33         // this attack_finished just enforces a cooldown at the end of a burst
  34         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
  35
  36         if (self.uzi_bulletcounter == 1)
  37                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_first_damage"), 0, cvar("g_balance_uzi_first_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  38         else
  39                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_sustained_damage"), 0, cvar("g_balance_uzi_sustained_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  40
  41         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  42
  43         // muzzle flash for 1st person view
  44         flash = spawn();
  45         setorigin(flash, '5 0 0');
  46         setmodel(flash, "models/uziflash.md3"); // precision set below
  47         setattachment(flash, self.weaponentity, "bone02");
  48         flash.owner = self;
  49         flash.viewmodelforclient = self;
  50         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
  51         //SUB_SetFade(flash, time + 0.06, 0);
  52         flash.think = W_Uzi_Flash_Go;
  53         flash.nextthink = time + 0.02;
  54         flash.frame = 2;
  55
  56         // muzzle flash for 3rd person view
  57         flash2 = spawn();
  58         setorigin(flash2, '43 1 8');
  59         setmodel(flash2, "models/uziflash.md3"); // precision set below
  60         setattachment(flash2, self.exteriorweaponentity, "");
  61         //SUB_SetFade(flash2, time + 0.06, 0);
  62         flash2.think = W_Uzi_Flash_Go;
  63         flash2.nextthink = time + 0.02;
  64         flash2.frame = 2;
  65         // common properties
  66         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  67         flash.alpha = flash2.alpha = 1;
  68         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  69
  70         // casing code
  71         if (cvar("g_casings") >= 2)
  72                 SpawnCasing (w_shotorg - v_forward * 10, ((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  73 }
  74
  75 // weapon frames
  76 void uzi_fire1_02()
  77 {
  78         if(self.weapon != self.switchweapon) // abort immediately if switching
  79         {
  80                 w_ready();
  81                 return;
  82         }
  83         if (self.BUTTON_ATCK)
  84         {
  85                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  86                 {
  87                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  88                         w_ready();
  89                         return;
  90                 }
  91                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  92                 W_Uzi_Attack(WEP_UZI);
  93                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  94         }
  95         else
  96                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
  97 };
  98
  99 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
 100
 101 float w_uzi(float req)
 102 {
 103         if (req == WR_AIM)
 104                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 105                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 106                 else
 107                 {
 108                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 109                 }
 110         else if (req == WR_THINK)
 111         {
 112                 if (self.BUTTON_ATCK)
 113                 if (weapon_prepareattack(0, 0))
 114                 {
 115                         self.uzi_bulletcounter = 1;
 116                         W_Uzi_Attack(WEP_UZI); // sets attack_finished
 117                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 118                 }
 119                 if (self.BUTTON_ATCK2)
 120                 if (weapon_prepareattack(1, 0))
 121                 {
 122                         self.uzi_bulletcounter = 1;
 123                         W_Uzi_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 124                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_uzi_first_refire"), w_ready);
 125                 }
 126         }
 127         else if (req == WR_PRECACHE)
 128         {
 129                 precache_model ("models/uziflash.md3");
 130                 precache_model ("models/weapons/g_uzi.md3");
 131                 precache_model ("models/weapons/v_uzi.md3");
 132                 precache_model ("models/weapons/w_uzi.dpm");
 133                 precache_sound ("weapons/uzi_fire.wav");
 134         }
 135         else if (req == WR_SETUP)
 136         {
 137                 weapon_setup(WEP_UZI);
 138         }
 139         else if (req == WR_CHECKAMMO1)
 140                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 141         else if (req == WR_CHECKAMMO2)
 142                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 143         else if (req == WR_SUICIDEMESSAGE)
 144                 w_deathtypestring = "did the impossible";
 145         else if (req == WR_KILLMESSAGE)
 146         {
 147                 if(w_deathtype & HITTYPE_SECONDARY)
 148                         w_deathtypestring = "was sniped by";
 149                 else
 150                         w_deathtypestring = "was riddled full of holes by";
 151         }
 152         return TRUE;
 153 };