data/qcsrc/server/t_teleporters.qc

   1 .entity pusher;
   2 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
   3 {
   4         entity head;
   5         entity oldself;
   6         entity telefragger;
   7
   8         if(teleporter.owner)
   9                 telefragger = teleporter.owner;
  10         else
  11                 telefragger = player;
  12
  13         sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  14         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  15
  16         makevectors (to_angles);
  17         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  18
  19         // Relocate the player
  20         // assuming to allows PL_MIN to PL_MAX box and some more
  21         setorigin (player, to + '0 0 1' * (1 - player.mins_z - 24));
  22         player.angles = to_angles;
  23         player.fixangle = TRUE;
  24         player.velocity = to_velocity;
  25
  26         if(player.classname == "player")
  27         {
  28                 RemoveGrapplingHook(player);
  29
  30                 // Kill anyone else in the teleporter box (NO MORE TDEATH)
  31                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  32                 {
  33                         vector deathmin;
  34                         vector deathmax;
  35                         float deathradius;
  36                         deathmin = player.absmin;
  37                         deathmax = player.absmax;
  38                         if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  39                         if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  40                         if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  41                         if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  42                         if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  43                         if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  44                         deathradius = max(vlen(deathmin), vlen(deathmax));
  45                         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  46                                 if(head != player)
  47                                         if(head.takedamage)
  48                                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  49                                                 {
  50                                                         if ((player.classname == "player") && (player.health >= 1))
  51                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  52                                                         else if (telefragger.health < 1) // corpses gib
  53                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  54                                                         else // dead bodies and monsters gib themselves instead of telefragging
  55                                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  56                                                 }
  57                 }
  58
  59                 // hide myself a tic
  60                 player.effects = player.effects | EF_NODRAW;
  61                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  62                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  63                 player.teleport_time = time + cvar("sys_ticrate");
  64
  65                 // player no longer is on ground
  66                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  67
  68                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  69                 player.oldvelocity = player.velocity;
  70
  71                 // reset tracking of who pushed you into a hazard (for kill credit)
  72                 if(teleporter.owner)
  73                 {
  74                         player.pusher = teleporter.owner;
  75                         player.pushltime = time + cvar("g_maxpushtime");
  76                 }
  77                 else
  78                 {
  79                         player.pushltime = 0;
  80                 }
  81
  82                 // stop player name display
  83                 {
  84                         oldself = self;
  85                         self = player;
  86                         ClearSelectedPlayer();
  87                         self = oldself;
  88                 }
  89         }
  90 }
  91
  92 void Teleport_Touch (void)
  93 {
  94         entity oldself;
  95
  96         if (other.health < 1)
  97                 return;
  98         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
  99                 return;
 100
 101         EXACTTRIGGER_TOUCH;
 102
 103         makevectors(self.enemy.mangle);
 104         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 105
 106         if(self.enemy.target)
 107         {
 108                 oldself = self;
 109                 activator = other;
 110                 self = self.enemy;
 111                 SUB_UseTargets();
 112                 self = oldself;
 113         }
 114 }
 115
 116 void spawnfunc_info_teleport_destination (void)
 117 {
 118         self.mangle = self.angles;
 119         self.angles = '0 0 0';
 120
 121         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 122         setorigin (self, self.origin);
 123
 124         IFTARGETED
 125         {
 126         }
 127         else
 128                 objerror ("Teleport destination without a targetname");
 129 }
 130
 131 void spawnfunc_misc_teleporter_dest (void)
 132 {
 133         spawnfunc_info_teleport_destination();
 134 }
 135
 136 void spawnfunc_target_teleporter (void)
 137 {
 138         spawnfunc_info_teleport_destination();
 139 }
 140
 141 void teleport_findtarget (void)
 142 {
 143         // now enable touch
 144         self.touch = Teleport_Touch;
 145
 146         self.enemy = find (world, targetname, self.target);
 147         if (!self.enemy)
 148         {
 149                 objerror ("Teleporter with nonexistant target");
 150                 remove(self);
 151                 return;
 152         }
 153
 154         self.dest = self.enemy.origin;
 155         waypoint_spawnforteleporter(self, self.dest, 0);
 156 }
 157
 158 void spawnfunc_trigger_teleport (void)
 159 {
 160         self.angles = '0 0 0';
 161
 162         EXACTTRIGGER_INIT;
 163
 164         // this must be called to spawn the teleport waypoints for bots
 165         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 166
 167         if (!self.target)
 168                 objerror ("Teleporter with no target");
 169 }