data/qcsrc/server/t_teleporters.qc

   1 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   2 {
   3         entity head;
   4         vector deathmin;
   5         vector deathmax;
   6         float deathradius;
   7         deathmin = player.absmin;
   8         deathmax = player.absmax;
   9         if(telefragmin != telefragmax)
  10         {
  11                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  12                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  13                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  14                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  15                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  16                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  17         }
  18         deathradius = max(vlen(deathmin), vlen(deathmax));
  19         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  20                 if(head != player)
  21                         if(head.takedamage)
  22                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  23                                 {
  24                                         if ((player.classname == "player") && (player.health >= 1))
  25                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  26                                         else if (telefragger.health < 1) // corpses gib
  27                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  28                                         else // dead bodies and monsters gib themselves instead of telefragging
  29                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  30                                 }
  31 }
  32
  33 void spawn_tdeath(vector v0, entity e, vector v)
  34 {
  35         tdeath(e, e, e, '0 0 0', '0 0 0');
  36 }
  37
  38 .entity pusher;
  39 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  40 {
  41         entity oldself;
  42         entity telefragger;
  43         vector from;
  44
  45         if(teleporter.owner)
  46                 telefragger = teleporter.owner;
  47         else
  48                 telefragger = player;
  49
  50         makevectors (to_angles);
  51
  52         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  53         {
  54                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  55                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  56                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  57                 self.pushltime = time + 0.2;
  58         }
  59
  60         // Relocate the player
  61         // assuming to allows PL_MIN to PL_MAX box and some more
  62         from = player.origin;
  63         setorigin (player, to);
  64         player.angles = to_angles;
  65         player.fixangle = TRUE;
  66         player.velocity = to_velocity;
  67
  68         if(player.classname == "player")
  69         {
  70                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  71                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  72
  73                 // hide myself a tic
  74                 player.effects = player.effects | EF_NODRAW;
  75                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  76                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  77                 player.teleport_time = time + cvar("sys_ticrate");
  78
  79                 // player no longer is on ground
  80                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  81
  82                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  83                 player.oldvelocity = player.velocity;
  84
  85                 // reset tracking of who pushed you into a hazard (for kill credit)
  86                 if(teleporter.owner)
  87                 {
  88                         player.pusher = teleporter.owner;
  89                         player.pushltime = time + cvar("g_maxpushtime");
  90                 }
  91                 else
  92                 {
  93                         player.pushltime = 0;
  94                 }
  95
  96                 // stop player name display
  97                 {
  98                         oldself = self;
  99                         self = player;
 100                         ClearSelectedPlayer();
 101                         self = oldself;
 102                 }
 103         }
 104 }
 105
 106 void Teleport_Touch (void)
 107 {
 108         entity oldself;
 109
 110         if (other.health < 1)
 111                 return;
 112         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 113                 return;
 114
 115         EXACTTRIGGER_TOUCH;
 116
 117         makevectors(self.enemy.mangle);
 118
 119         if(other.classname == "player")
 120                 RemoveGrapplingHook(other);
 121
 122         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 123
 124         if(self.enemy.target)
 125         {
 126                 oldself = self;
 127                 activator = other;
 128                 self = self.enemy;
 129                 SUB_UseTargets();
 130                 self = oldself;
 131         }
 132 }
 133
 134 void spawnfunc_info_teleport_destination (void)
 135 {
 136         self.mangle = self.angles;
 137         self.angles = '0 0 0';
 138
 139         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 140         setorigin (self, self.origin);
 141
 142         IFTARGETED
 143         {
 144         }
 145         else
 146                 objerror ("Teleport destination without a targetname");
 147 }
 148
 149 void spawnfunc_misc_teleporter_dest (void)
 150 {
 151         spawnfunc_info_teleport_destination();
 152 }
 153
 154 void spawnfunc_target_teleporter (void)
 155 {
 156         spawnfunc_info_teleport_destination();
 157 }
 158
 159 void teleport_findtarget (void)
 160 {
 161         // now enable touch
 162         self.touch = Teleport_Touch;
 163
 164         self.enemy = find (world, targetname, self.target);
 165         if (!self.enemy)
 166         {
 167                 objerror ("Teleporter with nonexistant target");
 168                 return;
 169         }
 170
 171         self.dest = self.enemy.origin;
 172         waypoint_spawnforteleporter(self, self.dest, 0);
 173 }
 174
 175 void spawnfunc_trigger_teleport (void)
 176 {
 177         self.angles = '0 0 0';
 178
 179         EXACTTRIGGER_INIT;
 180
 181         // this must be called to spawn the teleport waypoints for bots
 182         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 183
 184         if (!self.target)
 185         {
 186                 objerror ("Teleporter with no target");
 187                 return;
 188         }
 189 }