data/qcsrc/server/t_teleporters.qc

   1 .entity pusher;
   2 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles)
   3 {
   4         entity head;
   5         entity oldself;
   6
   7         sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
   8         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
   9
  10         makevectors (to_angles);
  11         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  12
  13         // Relocate the player
  14         // assuming to allows PL_MIN to PL_MAX box and some more
  15         setorigin (player, to + '0 0 1' * (1 - player.mins_z - 24));
  16         player.angles = to_angles;
  17         player.fixangle = TRUE;
  18         player.velocity = v_forward * vlen(player.velocity);
  19         RemoveGrapplingHook(player);
  20
  21         // Kill anyone else in the teleporter box (NO MORE TDEATH)
  22         if(player.takedamage && !g_race)
  23         {
  24                 vector deathmin;
  25                 vector deathmax;
  26                 float deathradius;
  27                 deathmin = player.absmin;
  28                 deathmax = player.absmax;
  29                 deathradius = max(vlen(deathmin), vlen(deathmax));
  30                 for(head = findradius(player.origin, deathradius); head; head = head.chain)
  31                         if(head != player)
  32                                 if(head.takedamage)
  33                                         if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  34                                         {
  35                                                 if ((player.classname == "player") && (player.health >= 1))
  36                                                         Damage (head, teleporter, player, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  37                                                 else if (player.health < 1) // corpses gib
  38                                                         Damage (head, teleporter, player, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  39                                                 else // dead bodies and monsters gib themselves instead of telefragging
  40                                                         Damage (player, teleporter, player, 10000, DEATH_TELEFRAG, player.origin, '0 0 0');
  41                                         }
  42         }
  43
  44         // hide myself a tic
  45         player.effects = player.effects | EF_NODRAW;
  46         if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  47                 player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  48         player.teleport_time = time + cvar("sys_ticrate");
  49
  50         // player no longer is on ground
  51         player.flags = player.flags - (player.flags & FL_ONGROUND);
  52
  53         // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  54         player.oldvelocity = player.velocity;
  55
  56         // reset tracking of who pushed you into a hazard (for kill credit)
  57         if(teleporter.owner)
  58         {
  59                 player.pusher = teleporter.owner;
  60                 player.pushltime = time + cvar("g_maxpushtime");
  61         }
  62         else
  63         {
  64                 player.pushltime = 0;
  65         }
  66
  67         // stop player name display
  68         {
  69                 oldself = self;
  70                 self = player;
  71                 ClearSelectedPlayer();
  72                 self = oldself;
  73         }
  74 }
  75
  76 void Teleport_Touch (void)
  77 {
  78         entity oldself;
  79
  80         if (other.health < 1)
  81                 return;
  82         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
  83                 return;
  84
  85         EXACTTRIGGER_TOUCH;
  86
  87         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle);
  88
  89         if(self.enemy.target)
  90         {
  91                 oldself = self;
  92                 activator = other;
  93                 self = self.enemy;
  94                 SUB_UseTargets();
  95                 self = oldself;
  96         }
  97 }
  98
  99 void spawnfunc_info_teleport_destination (void)
 100 {
 101         self.mangle = self.angles;
 102         self.angles = '0 0 0';
 103
 104         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 105         setorigin (self, self.origin);
 106
 107         IFTARGETED
 108         {
 109         }
 110         else
 111                 objerror ("Teleport destination without a targetname");
 112 }
 113
 114 void spawnfunc_misc_teleporter_dest (void)
 115 {
 116         spawnfunc_info_teleport_destination();
 117 }
 118
 119 void spawnfunc_target_teleporter (void)
 120 {
 121         spawnfunc_info_teleport_destination();
 122 }
 123
 124 void teleport_findtarget (void)
 125 {
 126         // now enable touch
 127         self.touch = Teleport_Touch;
 128
 129         self.enemy = find (world, targetname, self.target);
 130         if (!self.enemy)
 131         {
 132                 objerror ("Teleporter with nonexistant target");
 133                 remove(self);
 134                 return;
 135         }
 136
 137         self.dest = self.enemy.origin;
 138         waypoint_spawnforteleporter(self, self.dest, 0);
 139 }
 140
 141 void spawnfunc_trigger_teleport (void)
 142 {
 143         self.angles = '0 0 0';
 144
 145         EXACTTRIGGER_INIT;
 146
 147         // this must be called to spawn the teleport waypoints for bots
 148         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 149
 150         if (!self.target)
 151                 objerror ("Teleporter with no target");
 152 }