data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58 .float kh_previous_owner_playerid;
  59
  60 string kh_sound_capture = "sound/kh/capture.wav";
  61 string kh_sound_destroy = "sound/kh/destroy.wav";
  62 string kh_sound_drop = "sound/kh/drop.wav";
  63 string kh_sound_collect = "sound/kh/collect.wav";
  64 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  65
  66 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  67 float kh_key_dropped, kh_key_carried;
  68
  69 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  70 {
  71         if(t == e)           return kh_sprite_friend;
  72         if(t == COLOR_TEAM1) return kh_sprite_red;
  73         if(t == COLOR_TEAM2) return kh_sprite_blue;
  74         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  75         if(t == COLOR_TEAM4) return kh_sprite_pink;
  76         return 0;
  77 }
  78
  79 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  80 {
  81         kh_Controller_Thinkfunc = func;
  82         kh_controller.cnt = t;
  83         if(kh_Controller_Waitmsg != "")
  84                 strunzone(kh_Controller_Waitmsg);
  85         if(msg == "")
  86                 kh_Controller_Waitmsg = "";
  87         else
  88                 kh_Controller_Waitmsg = strzone(msg);
  89         if(t == 0)
  90                 kh_controller.nextthink = time; // force
  91 }
  92
  93 void kh_Controller_Think()  // called a lot
  94 {
  95         entity e;
  96         if(intermission_running)
  97                 return;
  98         if(self.cnt > 0)
  99         {
 100                 if(kh_Controller_Waitmsg != "")
 101                 {
 102                         string s;
 103                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 104                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 105                         else
 106                                 s = kh_Controller_Waitmsg;
 107
 108                         //dprint(s, "\n");
 109
 110                         FOR_EACH_PLAYER(e)
 111                                 if(clienttype(e) == CLIENTTYPE_REAL)
 112                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 113                 }
 114                 self.cnt -= 1;
 115         }
 116         else if(self.cnt == 0)
 117         {
 118                 self.cnt -= 1;
 119                 kh_Controller_Thinkfunc();
 120         }
 121         self.nextthink = time + 1;
 122 }
 123
 124 // frags f: take from cvar * f
 125 // frags 0: no frags
 126 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 127 {
 128         string s;
 129         if(intermission_running)
 130                 return;
 131         if(frags_player)
 132                 UpdateFrags(player, frags_player);
 133         if(key && key.owner && frags_owner)
 134                 UpdateFrags(key.owner, frags_owner);
 135         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 136                 return;
 137         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 138         s = strcat(s, ":", ftos(frags_player));
 139         if(key && key.owner)
 140                 s = strcat(s, ":", ftos(key.owner.playerid));
 141         else
 142                 s = strcat(s, ":0");
 143         s = strcat(s, ":", ftos(frags_owner), ":");
 144         if(key)
 145                 s = strcat(s, key.netname);
 146         GameLogEcho(s);
 147 }
 148
 149 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 150 {
 151         if(e.tag_entity)
 152         {
 153                 makevectors(e.tag_entity.angles);
 154                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 155         }
 156         else
 157                 return e.origin;
 158 }
 159
 160 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 161 {
 162 #ifdef KH_PLAYER_USE_ATTACHMENT
 163         entity first;
 164         first = key.owner.kh_next;
 165         if(key == first)
 166         {
 167                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 168                 if(key.kh_next)
 169                 {
 170                         setattachment(key.kh_next, key, "");
 171                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 173                         key.kh_next.angles = '0 0 0';
 174                 }
 175                 else
 176                         setorigin(key, KH_PLAYER_ATTACHMENT);
 177                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 178         }
 179         else
 180         {
 181                 setattachment(key, key.kh_prev, "");
 182                 if(key.kh_next)
 183                         setattachment(key.kh_next, key, "");
 184                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 185                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 186                 key.angles = '0 0 0';
 187         }
 188 #else
 189         setattachment(key, key.owner, "");
 190         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 191         key.angles_y -= key.owner.angles_y;
 192 #endif
 193         key.flags = 0;
 194         key.solid = SOLID_NOT;
 195         key.movetype = MOVETYPE_NONE;
 196         key.team = key.owner.team;
 197         key.nextthink = time;
 198         key.damageforcescale = 0;
 199         key.modelindex = kh_key_carried;
 200 }
 201
 202 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 203 {
 204         float i;
 205         i = test[key.owner.playerid];
 206                 if(key.netname == "^1red key")
 207                         i -= 1;
 208                 if(key.netname == "^4blue key")
 209                         i -= 2;
 210                 if(key.netname == "^3yellow key")
 211                         i -= 4;
 212                 if(key.netname == "^6pink key")
 213                         i -= 8;
 214         test[key.owner.playerid] = i;
 215
 216         kh_show_temp();
 217         if(key.owner)
 218                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 219         //key.owner.kh_state += test[key.owner.playerid];
 220
 221 #ifdef KH_PLAYER_USE_ATTACHMENT
 222         entity first;
 223         first = key.owner.kh_next;
 224         if(key == first)
 225         {
 226                 if(key.kh_next)
 227                 {
 228                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 229                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 230                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231                 }
 232         }
 233         else
 234         {
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key.kh_prev, "");
 237                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 238         }
 239         // in any case:
 240         setattachment(key, world, "");
 241         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 242         key.angles = key.owner.angles;
 243 #else
 244         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 245         setattachment(key, world, "");
 246         key.angles_y += key.owner.angles_y;
 247 #endif
 248         key.flags = FL_ITEM;
 249         key.solid = SOLID_TRIGGER;
 250         key.movetype = MOVETYPE_TOSS;
 251         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 252         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 253         // let key.team stay
 254         key.modelindex = kh_key_dropped;
 255         key.kh_previous_owner = key.owner;
 256         key.kh_previous_owner_playerid = key.owner.playerid;
 257 }
 258
 259 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 260 {
 261         if(key.owner == player)
 262                 return;
 263
 264         if(key.owner)
 265         {
 266                 kh_Key_Detach(key);
 267
 268                 // remove from linked list
 269                 if(key.kh_next)
 270                         key.kh_next.kh_prev = key.kh_prev;
 271                 key.kh_prev.kh_next = key.kh_next;
 272                 key.kh_next = world;
 273                 key.kh_prev = world;
 274
 275                 if(key.owner.kh_next == world)
 276                 {
 277                         // No longer a key carrier
 278                         WaypointSprite_DetachCarrier(key.owner);
 279                 }
 280         }
 281
 282         key.owner = player;
 283
 284         if(player)
 285         {
 286                 // insert into linked list
 287                 key.kh_next = player.kh_next;
 288                 key.kh_prev = player;
 289                 player.kh_next = key;
 290                 if(key.kh_next)
 291                         key.kh_next.kh_prev = key;
 292
 293                 float i;
 294                 i = test[key.owner.playerid];
 295                         if(key.netname == "^1red key")
 296                                 i += 1;
 297                         if(key.netname == "^4blue key")
 298                                 i += 2;
 299                         if(key.netname == "^3yellow key")
 300                                 i += 4;
 301                         if(key.netname == "^6pink key")
 302                                 i += 8;
 303                 test[key.owner.playerid] = i;
 304
 305                 kh_Key_Attach(key);
 306
 307                 if(key.kh_next == world)
 308                 {
 309                         // player is now a key carrier
 310                         WaypointSprite_AttachCarrier("", player);
 311                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 312                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 313                         if(player.team == COLOR_TEAM1)
 314                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "");
 315                         else if(player.team == COLOR_TEAM2)
 316                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "");
 317                         else if(player.team == COLOR_TEAM3)
 318                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "");
 319                         else if(player.team == COLOR_TEAM4)
 320                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "");
 321                 }
 322         }
 323
 324         // moved that here, also update if there's no player
 325         kh_show_temp();
 326         if(key.owner)
 327                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 328
 329         key.pusher = world;
 330 }
 331
 332 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 333 {
 334         if(self.owner)
 335                 return;
 336         if(vlen(force) <= 0)
 337                 return;
 338         if(time > self.pushltime)
 339                 if(attacker.classname == "player")
 340                         self.team = attacker.team;
 341 }
 342
 343 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 344 {
 345         entity key;
 346         key = spawn();
 347         key.classname = STR_ITEM_KH_KEY;
 348         key.touch = kh_Key_Touch;
 349         key.think = kh_Key_Think;
 350         key.nextthink = time;
 351         key.items = IT_KEY1 | IT_KEY2;
 352         key.cnt = angle;
 353         key.angles = '0 360 0' * random();
 354         key.event_damage = kh_Key_Damage;
 355         key.takedamage = DAMAGE_YES;
 356         key.modelindex = kh_key_dropped;
 357         key.model = "key";
 358         key.kh_dropperteam = 0;
 359         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 360         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 361         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 362
 363         switch(initial_owner.team)
 364         {
 365                 case COLOR_TEAM1:
 366                         key.netname = "^1red key";
 367                         break;
 368                 case COLOR_TEAM2:
 369                         key.netname = "^4blue key";
 370                         break;
 371                 case COLOR_TEAM3:
 372                         key.netname = "^3yellow key";
 373                         break;
 374                 case COLOR_TEAM4:
 375                         key.netname = "^6pink key";
 376                         break;
 377                 default:
 378                         key.netname = "NETGIER key";
 379                         break;
 380         }
 381
 382         // link into key list
 383         key.kh_worldkeynext = kh_worldkeylist;
 384         kh_worldkeylist = key;
 385
 386         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 387
 388         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 389         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 390
 391         kh_Key_AssignTo(key, initial_owner);
 392 }
 393
 394 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 395 {
 396         entity o;
 397         o = key.owner;
 398         kh_Key_AssignTo(key, world);
 399         if(o) // it was attached
 400                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 401         else // it was dropped
 402                 WaypointSprite_DetachCarrier(key);
 403
 404         // remove key from key list
 405         if (kh_worldkeylist == key)
 406                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 407         else
 408         {
 409                 o = kh_worldkeylist;
 410                 while (o)
 411                 {
 412                         if (o.kh_worldkeynext == key)
 413                         {
 414                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 415                                 break;
 416                         }
 417                         o = o.kh_worldkeynext;
 418                 }
 419         }
 420
 421         remove(key);
 422 }
 423
 424 // -1 when no team completely owns all keys yet
 425 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 426 {
 427         entity key;
 428         float teem;
 429
 430         teem = -1;
 431         FOR_EACH_KH_KEY(key)
 432         {
 433                 if(!key.owner)
 434                         return -1;
 435                 if(teem == -1)
 436                         teem = key.team;
 437                 else if(teem != key.team)
 438                         return -1;
 439         }
 440         return teem;
 441 }
 442
 443 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 444 {
 445         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 446
 447         if(key.kh_dropperteam != player.team)
 448         {
 449                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 450                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 451         }
 452         key.kh_dropperteam = 0;
 453         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 454
 455         kh_Key_AssignTo(key, player); // this also updates .kh_state
 456
 457         if(kh_Key_AllOwnedByWhichTeam() != -1)
 458         {
 459                 kh_interferemsg_time = time + 0.2;
 460                 kh_interferemsg_team = player.team;
 461
 462                 // audit all key carrier sprites, update them to RUN HERE
 463         }
 464 }
 465
 466 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 467 {
 468         entity key;
 469         entity mypusher;
 470         if(player.kh_next)
 471         {
 472                 mypusher = world;
 473                 if(player.pusher)
 474                         if(time < player.pushltime)
 475                                 mypusher = player.pusher;
 476                 while((key = player.kh_next))
 477                 {
 478                         kh_Scores_Event(player, key, "losekey", 0, 0);
 479                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 480                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 481                         kh_Key_AssignTo(key, world);
 482                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 483                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 484                         key.pusher = mypusher;
 485                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 486                         if(suicide)
 487                                 key.kh_dropperteam = player.team;
 488                 }
 489                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 490         }
 491 }
 492
 493 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 494 {
 495         if(intermission_running)
 496                 return;
 497
 498         if(self.owner) // already carried
 499                 return;
 500         if(other.classname != "player")
 501                 return;
 502         if(other.deadflag != DEAD_NO)
 503                 return;
 504         if(other == self.enemy)
 505                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 506                         return;  // you just dropped it!
 507         kh_Key_Collect(self, other);
 508 }
 509
 510 void kh_Key_Think()  // runs all the time
 511 {
 512         entity head;
 513         //entity player;  // needed by FOR_EACH_PLAYER
 514
 515         if(intermission_running)
 516                 return;
 517         /*
 518         if(time > self.stuff_time)
 519         {
 520                 FOR_EACH_PLAYER(player)
 521                         player.kh_state = test[0]*256 + (player.kh_state&255);
 522
 523                 self.stuff_time = time + 1;  // repeat in 1 second
 524         }
 525         */
 526
 527 #ifdef KH_KEY_ATTACHMENT_DEBUG
 528         if(self.kh_prev == self.owner)
 529         {
 530                 if(cvar_string("_angles") != "")
 531                 {
 532                         self.angles = stov(cvar_string("_angles"));
 533                         self.origin = stov(cvar_string("_origin"));
 534                 }
 535         }
 536 #endif
 537
 538         if(self.owner)
 539         {
 540 #ifndef KH_PLAYER_USE_ATTACHMENT
 541                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 542                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 543 #endif
 544
 545                 if(self.owner.BUTTON_USE)
 546                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 547                 {
 548                         self.owner.kh_droptime = time;
 549                         self.kh_droptime = time;  // prevent collecting this one for some time
 550                         self.enemy = self.owner;
 551                         self.pusher = world;
 552                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 553                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 554                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 555                         makevectors(self.owner.v_angle);
 556                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 557                         kh_Key_AssignTo(self, world);
 558                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 559                         self.kh_dropperteam = self.team;
 560                 }
 561         }
 562
 563         // if in nodrop or time over, end the round
 564         if(!self.owner)
 565                 if(time > self.pain_finished)
 566                         kh_LoserTeam(self.team, self);
 567
 568         if(self.owner)
 569         if(kh_Key_AllOwnedByWhichTeam() != -1)
 570         {
 571                 if(self.siren_time < time)
 572                 {
 573                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 574                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 575                 }
 576
 577                 entity key;
 578                 vector p;
 579                 p = self.owner.origin;
 580                 FOR_EACH_KH_KEY(key)
 581                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 582                                 goto not_winning;
 583                 kh_WinnerTeam(self.team);
 584 :not_winning
 585         }
 586
 587         if(kh_interferemsg_time && time > kh_interferemsg_time)
 588         {
 589                 kh_interferemsg_time = 0;
 590                 FOR_EACH_PLAYER(head)
 591                 {
 592                         if(head.team == kh_interferemsg_team)
 593                                 if(head.kh_next)
 594                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 595                                 else
 596                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 597                         else
 598                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 599                 }
 600         }
 601
 602         self.nextthink = time + 0.05;
 603 }
 604
 605 void kh_WinnerTeam(float teem)  // runs when a team wins
 606 {
 607         // all key carriers get some points
 608         vector firstorigin, lastorigin, midpoint;
 609         float first;
 610         entity key;
 611         float score;
 612         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 613         DistributeEvenly_Init(score, kh_teams);
 614         // twice the score for 3 team games, three times the score for 4 team games!
 615         // note: for a win by destroying the key, this should NOT be applied
 616         FOR_EACH_KH_KEY(key)
 617         {
 618                 float f;
 619                 f = DistributeEvenly_Get(1);
 620                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 621                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 622         }
 623
 624         first = TRUE;
 625         FOR_EACH_KH_KEY(key)
 626                 if(key.owner.kh_next == key)
 627                 {
 628                         if(!first)
 629                                 bprint("^7, ");
 630                         bprint(key.owner.netname);
 631                         first = FALSE;
 632                 }
 633         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 634
 635         first = TRUE;
 636         midpoint = '0 0 0';
 637         FOR_EACH_KH_KEY(key)
 638         {
 639                 vector thisorigin;
 640
 641                 thisorigin = kh_AttachedOrigin(key);
 642                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 643                 midpoint += thisorigin;
 644
 645                 if(!first)
 646                         te_lightning2(world, lastorigin, thisorigin);
 647                 lastorigin = thisorigin;
 648                 if(first)
 649                         firstorigin = thisorigin;
 650                 first = FALSE;
 651         }
 652         if(kh_teams > 2)
 653         {
 654                 te_lightning2(world, lastorigin, firstorigin);
 655         }
 656         midpoint = midpoint * (1 / kh_teams);
 657         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 658
 659         play2all(kh_sound_capture);
 660         kh_FinishRound();
 661 }
 662
 663 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 664 {
 665         entity player, key, attacker;
 666         float players;
 667         float keys;
 668         float f;
 669
 670         attacker = world;
 671         if(lostkey.pusher)
 672                 if(lostkey.pusher.team != teem)
 673                         if(lostkey.pusher.classname == "player")
 674                                 attacker = lostkey.pusher;
 675
 676         players = keys = 0;
 677
 678         if(attacker)
 679         {
 680                 if(lostkey.kh_previous_owner)
 681                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 682                         // don't actually GIVE him the -nn points, just log
 683                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 684                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 685                 centerprint(attacker, "Your push is the best!\n\n\n");
 686                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 687         }
 688         else
 689         {
 690                 float of, fragsleft, i, j, thisteam;
 691                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 692
 693                 FOR_EACH_PLAYER(player)
 694                         if(player.team != teem)
 695                                 ++players;
 696
 697                 FOR_EACH_KH_KEY(key)
 698                         if(key.owner && key.team != teem)
 699                                 ++keys;
 700
 701                 if(lostkey.kh_previous_owner)
 702                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 703                         // don't actually GIVE him the -nn points, just log
 704
 705                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 706                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 707
 708                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 709
 710                 FOR_EACH_KH_KEY(key)
 711                         if(key.owner && key.team != teem)
 712                         {
 713                                 f = DistributeEvenly_Get(of);
 714                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 715                         }
 716
 717                 fragsleft = DistributeEvenly_Get(players);
 718
 719                 // Now distribute these among all other teams...
 720                 j = kh_teams - 1;
 721                 for(i = 0; i < kh_teams; ++i)
 722                 {
 723                         thisteam = kh_Team_ByID(i);
 724                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 725                                 continue;
 726
 727                         players = 0;
 728                         FOR_EACH_PLAYER(player)
 729                                 if(player.team == thisteam)
 730                                         ++players;
 731
 732                         DistributeEvenly_Init(fragsleft, j);
 733                         fragsleft = DistributeEvenly_Get(j - 1);
 734                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 735
 736                         FOR_EACH_PLAYER(player)
 737                                 if(player.team == thisteam)
 738                                 {
 739                                         f = DistributeEvenly_Get(1);
 740                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 741                                 }
 742
 743                         --j;
 744                 }
 745
 746                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 747         }
 748         play2all(kh_sound_destroy);
 749         te_tarexplosion(lostkey.origin);
 750
 751         kh_FinishRound();
 752 }
 753
 754 void kh_FinishRound()  // runs when a team captures the keys
 755 {
 756         // prepare next round
 757         kh_interferemsg_time = 0;
 758         entity key;
 759         FOR_EACH_KH_KEY(key)
 760                 kh_Key_Remove(key);
 761
 762         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 763 }
 764
 765 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 766 {
 767         float i, players, teem;
 768         entity player;
 769         string result;
 770         result = "";
 771
 772         // find a random player per team
 773         for(i = 0; i < kh_teams; ++i)
 774         {
 775                 teem = kh_Team_ByID(i);
 776                 players = 0;
 777                 FOR_EACH_PLAYER(player)
 778                         if(player.deadflag == DEAD_NO)
 779                                 if(!player.BUTTON_CHAT)
 780                                         if(player.team == teem)
 781                                                 ++players;
 782                 if(players == 0)
 783                 {
 784                         if(result != "")
 785                                 result = strcat(result, ", ");
 786                         result = strcat(result, ColoredTeamName(teem));
 787                 }
 788         }
 789         return result;
 790 }
 791
 792 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 793 {
 794         string teams_missing;
 795         teams_missing = kh_CheckEnoughPlayers();
 796         if(teams_missing == "")
 797                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 798         else
 799                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 800 }
 801
 802 void kh_StartRound()  // runs at the start of each round
 803 {
 804         string teams_missing;
 805         float i, players, teem;
 806         entity player;
 807
 808         teams_missing = kh_CheckEnoughPlayers();
 809         if(teams_missing != "")
 810         {
 811                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 812                 return;
 813         }
 814
 815         FOR_EACH_PLAYER(player)
 816                 if(clienttype(player) == CLIENTTYPE_REAL)
 817                         centerprint_expire(player, CENTERPRIO_SPAM);
 818
 819         for(i = 0; i < kh_teams; ++i)
 820         {
 821                 teem = kh_Team_ByID(i);
 822                 players = 0;
 823                 entity my_player;
 824                 FOR_EACH_PLAYER(player)
 825                         if(player.deadflag == DEAD_NO)
 826                                 if(!player.BUTTON_CHAT)
 827                                         if(player.team == teem)
 828                                         {
 829                                                 ++players;
 830                                                 if(random() * players <= 1)
 831                                                         my_player = player;
 832                                         }
 833                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 834                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 835                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 836         }
 837
 838         kh_tracking_enabled = FALSE;
 839         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 840 }
 841
 842 void kh_setstatus()  // runs all the time
 843 {
 844         if(kh_teams)
 845         {
 846                 float kh_KEY;
 847                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 848                 if(self.kh_next)
 849                         self.items = self.items | kh_KEY;
 850                 else
 851                         self.items = self.items - (self.items & kh_KEY);
 852         }
 853 }
 854
 855 void kh_EnableTrackingDevice()  // runs after each round
 856 {
 857         entity player;
 858
 859         FOR_EACH_PLAYER(player)
 860                 if(clienttype(player) == CLIENTTYPE_REAL)
 861                         centerprint_expire(player, CENTERPRIO_SPAM);
 862
 863         kh_tracking_enabled = TRUE;
 864 }
 865
 866 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 867 {
 868         if(!kh_tracking_enabled)
 869                 return FALSE;
 870         if(!self.owner)
 871                 return TRUE;
 872         if(!self.owner.owner)
 873                 return TRUE;
 874         return FALSE;  // draw only when key is not owned
 875 }
 876
 877 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 878 {
 879         if(e.classname != "player" || self.team != e.team)
 880                 if(!kh_tracking_enabled)
 881                         return FALSE;
 882
 883         return TRUE;
 884 }
 885
 886 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 887 {
 888         if(attacker == targ)
 889                 return f;
 890
 891         if(targ.kh_next)
 892         {
 893                 if(attacker.team == targ.team)
 894                 {
 895                         entity k;
 896                         float nk;
 897                         nk = 0;
 898                         for(k = targ.kh_next; k != world; k = k.kh_next)
 899                                 ++nk;
 900                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 901                 }
 902                 else
 903                 {
 904                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 905                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 906                         // the frag gets added later
 907                 }
 908         }
 909
 910         return f;
 911 }
 912
 913 void kh_init()  // sets up th KH environment
 914 {
 915         precache_sound(kh_sound_capture);
 916         precache_sound(kh_sound_destroy);
 917         precache_sound(kh_sound_drop);
 918         precache_sound(kh_sound_collect);
 919         precache_sound(kh_sound_alarm);  // the new siren
 920
 921         precache_model("models/sprites/key-dropped.sp2");
 922         precache_model("models/sprites/keycarrier-finish.sp2");
 923         precache_model("models/sprites/keycarrier-friend.sp2");
 924         precache_model("models/sprites/keycarrier-red.sp2");
 925         precache_model("models/sprites/keycarrier-blue.sp2");
 926         precache_model("models/sprites/keycarrier-yellow.sp2");
 927         precache_model("models/sprites/keycarrier-pink.sp2");
 928 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 929         precache_model("models/keyhunt/key-carried.md3");
 930 #endif
 931         precache_model("models/keyhunt/key.md3");
 932
 933         // setup variables
 934         kh_teams = cvar("g_keyhunt_teams_override");
 935         if(kh_teams < 2)
 936                 kh_teams = cvar("g_keyhunt_teams");
 937         kh_teams = bound(2, kh_teams, 4);
 938
 939         // make a KH entity for controlling the game
 940         kh_controller = spawn();
 941         kh_controller.think = kh_Controller_Think;
 942         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 943
 944         setmodel(kh_controller, "models/keyhunt/key.md3");
 945         kh_key_dropped = kh_controller.modelindex;
 946         /*
 947         dprint(vtos(kh_controller.mins));
 948         dprint(vtos(kh_controller.maxs));
 949         dprint("\n");
 950         */
 951 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 952         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 953         kh_key_carried = kh_controller.modelindex;
 954 #else
 955         kh_key_carried = kh_key_dropped;
 956 #endif
 957         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 958         kh_sprite_dropped = kh_controller.modelindex;
 959         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 960         kh_sprite_finish = kh_controller.modelindex;
 961         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 962         kh_sprite_friend = kh_controller.modelindex;
 963         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 964         kh_sprite_red = kh_controller.modelindex;
 965         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 966         kh_sprite_blue = kh_controller.modelindex;
 967         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 968         kh_sprite_pink = kh_controller.modelindex;
 969         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 970         kh_sprite_yellow = kh_controller.modelindex;
 971         setmodel(kh_controller, "");
 972
 973         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 974
 975         ScoreRules_kh(kh_teams);
 976 }
 977
 978 void kh_finalize()
 979 {
 980         // to be called before intermission
 981         kh_FinishRound();
 982         remove(kh_controller);
 983         kh_controller = world;
 984 }
 985
 986 /**
 987  * kh_show_temp originally by victim.
 988  * changed it to use the kh_state stat var
 989  * Updates the general key stat bits for each player
 990  */
 991 void kh_show_temp()
 992 {
 993         entity player;
 994         float i, j;
 995
 996         j = 0;  // reset/blank j
 997         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
 998                 j += test[i];
 999
1000         test[0] = j;
1001
1002         j *= 256;
1003         FOR_EACH_PLAYER(player)
1004                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1005 }