data/qcsrc/server/gamec/w_rocketlauncher.c

   1 void() rlauncher_ready_01;
   2 void() rlauncher_fire1_01;
   3 void() rlauncher_deselect_01;
   4 void() rlauncher_select_01;
   5
   6 float() rlauncher_check =
   7 {
   8         if ((self.attack_finished > time && self.weapon == WEP_ROCKET_LAUNCHER)  // don't switch while guiding a missile
   9                 || self.ammo_rockets >= cvar("g_balance_rocketlauncher_ammo"))
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 void(float req) w_rlauncher =
  15 {
  16         if (req == WR_IDLE)
  17                 rlauncher_ready_01();
  18         else if (req == WR_FIRE1)
  19                 weapon_prepareattack(rlauncher_check, rlauncher_check, rlauncher_fire1_01, cvar("g_balance_rocketlauncher_refire"));
  20         else if (req == WR_FIRE2)
  21         {
  22                 sound (self, CHAN_BODY, "weapons/rocket_det.ogg", 0.5, ATTN_NORM);
  23                 if(cvar("g_laserguided_missile"))
  24                 if(self.exteriorweaponentity.attack_finished < time)
  25                 {
  26                         self.exteriorweaponentity.attack_finished = time + 0.4;
  27                         self.laser_on = !self.laser_on;
  28                         sound (self, CHAN_AUTO, "weapons/tink1.ogg", 1, ATTN_NORM);
  29                 }
  30         }
  31         else if (req == WR_RAISE)
  32                 rlauncher_select_01();
  33         else if (req == WR_UPDATECOUNTS)
  34                 self.currentammo = self.ammo_rockets;
  35         else if (req == WR_DROP)
  36                 rlauncher_deselect_01();
  37         else if (req == WR_SETUP)
  38                 weapon_setup(WEP_ROCKET_LAUNCHER, "w_rl.zym", IT_ROCKETS);
  39         else if (req == WR_CHECKAMMO)
  40                 weapon_hasammo = rlauncher_check();
  41 };
  42
  43
  44 void W_Rocket_Explode (void)
  45 {
  46         vector  org2;
  47         sound (self, CHAN_BODY, "weapons/rocket_impact.ogg", 1, ATTN_NORM);
  48         org2 = findbetterlocation (self.origin);
  49         te_explosion (org2);
  50         effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  51         self.event_damage = SUB_Null;
  52         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  53
  54         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  55         {
  56                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  57                 {
  58                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  59                         self.owner.attack_finished = time;
  60                         self.owner.switchweapon = w_getbestweapon(self.owner);
  61                 }
  62                 if(cvar("g_laserguided_missile"))
  63                                   self.owner.attack_finished = time + cvar("g_balance_rocketlauncher_refire");
  64         }
  65         remove (self);
  66 }
  67
  68 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  69 {
  70         entity head, selected;
  71         vector dir;
  72         float dist, maxdist,// bestdist,
  73                 dot,// bestdot,
  74                 points, bestpoints;
  75         //bestdist = 9999;
  76         //bestdot = -2;
  77         bestpoints = 0;
  78         maxdist = 800;
  79         selected = world;
  80
  81         makevectors(e.angles);
  82
  83         head = find(world, classname, "laser_target");
  84         while(head)
  85         {
  86                 points = 0;
  87                 dir = normalize(head.origin - self.origin);
  88                 dot = dir * v_forward;
  89                 dist = vlen(head.origin - self.origin);
  90                 if(dist > maxdist)
  91                         dist = maxdist;
  92
  93                 // gain points for being in front
  94                 points = points + ((dot+1)*0.5) * 500
  95                         * (1 + crandom()*dot_variance);
  96                 // gain points for being close away
  97                 points = points + (1 - dist/maxdist) * 1000
  98                         * (1 + crandom()*dot_variance);
  99
 100                 traceline(e.origin, head.origin, TRUE, self);
 101                 if(trace_fraction < 1)
 102                 {
 103                         points = 0;
 104                 }
 105
 106                 if(points > bestpoints)//random() > 0.5)//
 107                 {
 108                         bestpoints = points;
 109                         selected = head;
 110                 }
 111
 112
 113                 /*
 114                 dot = dir * v_forward;
 115                 if(dot > bestdot * (1 + crandom()*dot_variance))
 116                 {
 117                         dist = vlen(head.origin - self.origin);
 118                         if(dist < bestdist * (1 + crandom()*dist_variance))
 119                         {
 120                                 traceline(e.origin, head.origin, TRUE, self);
 121                                 if(trace_fraction >= 1)
 122                                 {
 123                                 }
 124                         }
 125                 }
 126                 */
 127                 head = find(head, classname, "laser_target");
 128         }
 129
 130         //bprint(selected.owner.netname);
 131         //bprint("\n");
 132         return selected;
 133 }
 134
 135 void W_Rocket_Think (void)
 136 {
 137         entity e;
 138         vector desireddir, olddir, newdir;
 139         float turnrate;
 140         self.nextthink = time;
 141         if (time > self.cnt)
 142         {
 143                 W_Rocket_Explode ();
 144                 return;
 145         }
 146         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 147         {
 148                 if(cvar("g_laserguided_missile"))
 149                 {
 150                         if(!self.owner.button0)
 151                                 self.ltime = -1; // indicate that the player has let go of the button
 152
 153
 154                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 155                         {
 156                                   W_Rocket_Explode ();
 157                                   return;
 158                         }
 159
 160                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 161                         {
 162                                 if(self.owner.laser_on)
 163                                 {
 164                                         if(self.attack_finished < time)
 165                                         {
 166                                                 self.attack_finished = time + 0.2 + random()*0.3;
 167                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 168                                         }
 169
 170                                         if(!self.enemy)
 171                                                 self.enemy = self.owner.weaponentity.lasertarget;
 172                                 }
 173                                 else self.enemy = world;
 174                         }
 175                         else // don't allow stealing: always target my owner's laser (if it exists)
 176                                 self.enemy = self.owner.weaponentity.lasertarget;
 177
 178                         if(self.enemy != world)
 179                         {
 180                                 //bprint(strcat("Targeting ", self.enemy.owner.netname, "'s laser\n"));
 181                                 if(!self.speed)
 182                                         self.speed = vlen(self.velocity);
 183                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 184                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 185                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 186                                 olddir = normalize(self.velocity);                              // get my current direction
 187                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 188                                 self.velocity = newdir * self.speed;                    // make me fly in the new direction at my flight speed
 189                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 190
 191                                 self.owner.attack_finished = time + 0.2;
 192                         }
 193                 }
 194                 else
 195                 {
 196                         if (self.owner.button3)
 197                                   W_Rocket_Explode ();
 198                 }
 199         }
 200 }
 201
 202 void W_Rocket_Touch (void)
 203 {
 204         if (pointcontents (self.origin) == CONTENT_SKY)
 205         {
 206                 remove (self);
 207                 return;
 208         }
 209         else
 210                 W_Rocket_Explode ();
 211 }
 212
 213 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 214 {
 215         self.health = self.health - damage;
 216         if (self.health <= 0)
 217         {
 218                 self.owner = attacker;
 219                 W_Rocket_Explode();
 220         }
 221 }
 222
 223 void W_Rocket_Attack (void)
 224 {
 225         local entity missile;
 226         local entity flash;
 227         local vector org;
 228
 229         local vector trueaim;
 230         trueaim = W_TrueAim();
 231
 232         sound (self, CHAN_WEAPON, "weapons/rocket_fire.ogg", 1, ATTN_NORM);
 233         if (self.items & IT_STRENGTH)
 234                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 235
 236         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 237                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 238         self.punchangle_x = -4;
 239
 240         org = W_MuzzleOrigin (self, '15 3 -11');
 241         te_smallflash(org);
 242
 243         missile = spawn ();
 244         missile.owner = self;
 245         missile.classname = "missile";
 246
 247         missile.takedamage = DAMAGE_YES;
 248         missile.damageforcescale = 4;
 249         missile.health = 30;
 250         missile.event_damage = W_Rocket_Damage;
 251
 252         missile.movetype = MOVETYPE_FLY;
 253         missile.solid = SOLID_BBOX;
 254         setmodel (missile, "models/rocket.md3");
 255         setsize (missile, '0 0 0', '0 0 0');
 256
 257         setorigin (missile, org);
 258         if(cvar("g_laserguided_missile") && self.laser_on)
 259                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_laserguided_speed");
 260         else
 261                 missile.velocity = normalize(trueaim - org) * cvar("g_balance_rocketlauncher_speed");
 262         missile.angles = vectoangles (missile.velocity);
 263
 264         missile.touch = W_Rocket_Touch;
 265         missile.think = W_Rocket_Think;
 266         missile.nextthink = time;
 267         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 268         missile.effects = EF_NOSHADOW;
 269         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 270
 271         flash = spawn ();
 272         setorigin (flash, org);
 273         setmodel (flash, "models/flash.md3");
 274         flash.velocity = v_forward * 20;
 275         flash.angles = vectoangles (flash.velocity);
 276         SUB_SetFade (flash, time, 0.4);
 277         flash.effects = flash.effects | EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 278 }
 279
 280 // weapon frames
 281
 282 void()  rlauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, rlauncher_ready_01); self.weaponentity.state = WS_READY;};
 283 void()  rlauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0'); self.laser_on = 1;};
 284 void()  rlauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);  self.laser_on = 0;};
 285 void()  rlauncher_fire1_01 =
 286 {
 287         weapon_doattack(rlauncher_check, rlauncher_check, W_Rocket_Attack);
 288         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), rlauncher_ready_01);
 289 };