data/qcsrc/server/gamec/t_items.c

   1 void Item_ClearRespawnEffect (void) {
   2         self.effects = self.effects - (self.effects & EF_STARDUST);
   3 }
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // Savage: Add simple Respawn effect and make sure it gets removed
  13         self.effects = self.effects | EF_STARDUST;
  14         self.think = Item_ClearRespawnEffect;
  15         self.nextthink = time + 0.1;
  16 }
  17
  18 void Item_Touch (void)
  19 {
  20         local entity oldself;
  21         local float _switchweapon;
  22
  23         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  24         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  25         {
  26                 remove(self);
  27                 return;
  28         }
  29         if (other.classname != "player")
  30                 return;
  31         if (other.deadflag)
  32                 return;
  33         if (self.solid != SOLID_TRIGGER)
  34                 return;
  35         if (self.health && other.health >= other.max_health)
  36                 return;
  37         if (self.owner == other)
  38                 return;
  39         // Savage: Remove the respawn effect if still present
  40         self.effects = self.effects - (self.effects & EF_STARDUST);
  41
  42         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  43
  44         // in case the player has autoswitch enabled do the following:
  45         // if the player is using their best weapon before items are given, they
  46         // probably want to switch to an even better weapon after items are given
  47         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  48
  49         if (cvar("g_minstagib"))
  50         {
  51                 if (self.ammo_cells)
  52                 {
  53                         // play some cool sounds ;)
  54                         centerprint(other, "\n");
  55                         if(other.health <= 5)
  56                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  57                         else if(other.health < 50)
  58                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  59                         // sound not available
  60                         // else if(self.items == IT_CELLS)
  61                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  62
  63                         if (self.items & IT_NEX)
  64                                 W_GiveWeapon (other, IT_NEX, "Nex");
  65                         if (self.ammo_cells)
  66                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  67                         other.health = 100;
  68                 }
  69
  70                 // extralife powerup
  71                 if (self.max_health)
  72                 {
  73                         // sound not available
  74                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  75                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  76                         other.armorvalue = other.extralives;
  77                         sprint(other, "^3You picked up some extra lives\n");
  78                 }
  79
  80                 // invis powerup
  81                 if (self.strength_finished)
  82                 {
  83                         // sound not available
  84                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  85                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  86                 }
  87
  88                 // speed powerup
  89                 if (self.invincible_finished)
  90                 {
  91                         // sound not available
  92                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  93                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  94                 }
  95         }
  96         else
  97         {
  98                 if (cvar("deathmatch") == 2 && self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
  99                         return;
 100
 101                 if (self.ammo_shells)
 102                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 103                 if (self.ammo_nails)
 104                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 105                 if (self.ammo_rockets)
 106                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 107                 if (self.ammo_cells)
 108                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 109
 110                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 111                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 112                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 113                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 114                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 115                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 116                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 117                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 118
 119                 if (self.strength_finished)
 120                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 121                 if (self.invincible_finished)
 122                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 123                 //if (self.speed_finished)
 124                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 125                 //if (self.slowmo_finished)
 126                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 127
 128                 if (self.max_health)
 129                 {
 130                         other.health = other.health + self.max_health;
 131                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 132                 }
 133                 if (self.health && other.health < other.max_health)
 134                         other.health = min(other.health + self.health, other.max_health);
 135                 if (self.armorvalue)
 136                 {
 137                         other.armorvalue = other.armorvalue + self.armorvalue;
 138                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 139                 }
 140         }
 141
 142         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 143
 144         oldself = self;
 145         self = other;
 146
 147         if (_switchweapon)
 148                 self.switchweapon = w_getbestweapon(self);
 149         if (self.switchweapon != self.weapon)
 150                 self.cnt = self.weapon;
 151
 152         //w_updateweapon ();
 153         //w_updateammo ();
 154         weapon_action(self.weapon, WR_UPDATECOUNTS);
 155
 156         self = oldself;
 157
 158         if (self.classname == "droppedweapon")
 159                 remove (self);
 160         else
 161         {
 162                 self.solid = SOLID_NOT;
 163                 self.model = string_null;
 164                 self.nextthink = time + self.respawntime;
 165                 self.think = Item_Respawn;
 166                 setorigin (self, self.origin);
 167         }
 168 }
 169
 170 // Savage: used for item garbage-collection
 171 // TODO: perhaps nice special effect?
 172 void RemoveItem(void) = {
 173         remove(self);
 174 }
 175
 176 .float noalign;
 177
 178 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
 179 {
 180         vector org;
 181         org = self.origin;
 182
 183         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 184                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemname != "100 Health")
 185         {
 186                 remove (self);
 187                 return;
 188         }
 189
 190         if (cvar("g_minstagib"))
 191         {
 192                 // don't remove dropped items and powerups
 193                 if (self.classname != "droppedweapon" &&
 194                     self.classname != "minstagib")
 195                 {
 196                         remove (self);
 197                         return;
 198                 }
 199         }
 200
 201         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 202         {
 203                 remove(self);
 204                 return;
 205         }
 206
 207         if(cvar("g_instagib") || cvar("g_rocketarena"))
 208         {
 209                 remove(self);
 210                 return;
 211         }
 212
 213         if (self.classname == "droppedweapon")
 214         {
 215                 // don't drop if in a NODROP zone (such as lava)
 216                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 217                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 218                 {
 219                         remove(self);
 220                         return;
 221                 }
 222         }
 223
 224         self.mdl = itemmodel;
 225         //self.noise = pickupsound;
 226         self.item_pickupsound = pickupsound;
 227         // let mappers override respawntime
 228         if (!self.respawntime)
 229                 self.respawntime = defaultrespawntime;
 230         self.netname = itemname;
 231         self.items = itemid;
 232         self.flags = FL_ITEM | itemflags;
 233         setmodel (self, self.mdl);
 234         if (itemflags & FL_WEAPON)
 235         {
 236                 setorigin (self, self.origin + '0 0 23');
 237                 setsize (self, '-12 -12 -12', '12 12 12');
 238
 239                 // neutral team color for pickup weapons
 240                 self.colormap = 160 * 1024 + 160;
 241         }
 242         else
 243         {
 244                 setorigin (self, self.origin + '0 0 25');
 245         //      setsize (self, '-8 -8 -5', '8 8 8');
 246         }
 247         self.movetype = MOVETYPE_TOSS;
 248         self.solid = SOLID_TRIGGER;
 249         self.touch = Item_Touch;
 250
 251         // Savage: remove thrown items after a certain period of time ("garbage collection")
 252         if (self.classname == "droppedweapon")
 253         {
 254                 self.think = RemoveItem;
 255                 self.nextthink = time + 60;
 256         }
 257         else if (!self.noalign)
 258         {
 259                 vector z_offset;
 260
 261                 z_offset = '0 0 1';
 262
 263                 if (itemid == IT_SHELLS)
 264                         z_offset = '0 0 1' * 4;
 265                 else if (itemid == IT_ROCKETS)
 266                         z_offset = '0 0 1' * 4;
 267                 else if (itemid == IT_NAILS)
 268                         z_offset = '0 0 0';
 269                 else if (self.max_health == 25)
 270                         z_offset = '0 0 1' * 5;
 271                 else if (self.armorvalue == 100)
 272                         z_offset = '0 0 1' * 3;
 273
 274                 self.movetype = MOVETYPE_NONE;
 275                 traceline(self.origin, self.origin - '0 0 1' * 512, TRUE, self);
 276                 if (trace_fraction < 1)
 277                         setorigin(self, trace_endpos + z_offset);
 278         }
 279         else
 280         {
 281                 self.movetype = MOVETYPE_NONE;
 282                 setorigin(self, org);
 283         }
 284
 285         if (cvar("g_fullbrightitems"))
 286                 self.effects = self.effects | EF_FULLBRIGHT;
 287
 288 }
 289
 290 /* replace items in minstagib
 291  * IT_STRENGTH   = invisibility
 292  * IT_NAILS      = extra lives
 293  * IT_INVINCIBLE = speed
 294  */
 295 void minstagib_items (float itemid)
 296 {
 297         // we don't want to replace dropped weapons ;)
 298         if (self.classname == "droppedweapon")
 299         {
 300                 self.ammo_cells = 25;
 301                 StartItem ("models/weapons/g_nex.md3",
 302                         "weapons/weaponpickup.ogg", 15,
 303                         "Nex Gun", IT_NEX, FL_WEAPON);
 304                 return;
 305         }
 306
 307         local float rnd;
 308         self.classname = "minstagib";
 309
 310         // replace rocket launchers and nex guns with ammo cells
 311         if (itemid == IT_CELLS)
 312         {
 313                 self.ammo_cells = 1;
 314                 StartItem ("models/items/a_cells.md3",
 315                         "misc/itempickup.ogg", 45,
 316                         "Nex Ammo", IT_CELLS, 0);
 317                 return;
 318         }
 319
 320         // randomize
 321         rnd = random() * 3;
 322         if (rnd <= 1)
 323                 itemid = IT_STRENGTH;
 324         else if (rnd <= 2)
 325                 itemid = IT_NAILS;
 326         else
 327                 itemid = IT_INVINCIBLE;
 328
 329         // replace with invis
 330         if (itemid == IT_STRENGTH)
 331         {
 332                 self.effects = EF_ADDITIVE;
 333                 self.strength_finished = 30;
 334                 StartItem ("models/items/g_strength.md3",
 335                         "misc/powerup.ogg", 120,
 336                         "Invisibility", IT_STRENGTH, FL_POWERUP);
 337         }
 338         // replace with extra lives
 339         if (itemid == IT_NAILS)
 340         {
 341                 self.max_health = 1;
 342                 StartItem ("models/items/g_h100.md3",
 343                         "misc/megahealth.ogg", 120,
 344                         "Extralife", IT_NAILS, FL_POWERUP);
 345
 346         }
 347         // replace with ammo
 348         if (itemid == IT_INVINCIBLE)
 349         {
 350                 self.effects = EF_ADDITIVE;
 351                 self.invincible_finished = 30;
 352                 StartItem ("models/items/g_invincible.md3",
 353                         "misc/powerup_shield.ogg", 120,
 354                         "Speed", IT_INVINCIBLE, FL_POWERUP);
 355         }
 356
 357 }
 358
 359 void weapon_uzi (void) {
 360         self.ammo_nails = 120;
 361         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON);
 362 }
 363
 364 void weapon_shotgun (void) {
 365         self.ammo_shells = 15;
 366         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON);
 367 }
 368
 369 void weapon_grenadelauncher (void) {
 370         self.ammo_rockets = 15;
 371         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON);
 372 }
 373
 374 void weapon_electro (void) {
 375         self.ammo_cells = 25;
 376         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON);
 377 }
 378
 379 void weapon_crylink (void) {
 380         self.ammo_cells = 25;
 381         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON);
 382 }
 383
 384 void weapon_nex (void) {
 385         if (cvar("g_minstagib")) {
 386                 minstagib_items(IT_CELLS);
 387         } else {
 388                 self.ammo_cells = 25;
 389                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_NEX), IT_NEX, FL_WEAPON);
 390         }
 391 }
 392
 393 void weapon_hagar (void) {
 394         self.ammo_rockets = 15;
 395         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON);
 396 }
 397
 398 void weapon_rocketlauncher (void) {
 399         if (cvar("g_minstagib")) {
 400                 minstagib_items(IT_CELLS);
 401         } else {
 402                 self.ammo_rockets = 15;
 403                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON);
 404         }
 405 }
 406
 407 void item_rockets (void) {
 408         self.ammo_rockets = 15;
 409         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0);
 410 }
 411
 412 void item_bullets (void) {
 413         self.ammo_nails = 120;
 414         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0);
 415 }
 416
 417 void item_cells (void) {
 418         self.ammo_cells = 25;
 419         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0);
 420 }
 421
 422 void item_shells (void) {
 423         self.ammo_shells = 15;
 424         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0);
 425 }
 426
 427 void item_armor1 (void) {
 428         self.armorvalue = 5;
 429         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", 0, 0);
 430 }
 431
 432 void item_armor25 (void) {
 433         self.armorvalue = 100;
 434         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", 0, 0);
 435 }
 436
 437 void item_health1 (void) {
 438         self.max_health = 5;
 439         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", 0, 0);
 440 }
 441
 442 void item_health25 (void) {
 443         self.max_health = 25;
 444         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", 0, 0);
 445 }
 446
 447 void item_health100 (void) {
 448         if(!cvar("g_powerup_superhealth"))
 449                 return;
 450
 451         if(cvar("g_minstagib")) {
 452                 minstagib_items(IT_NAILS);
 453         } else {
 454                 self.max_health = 100;
 455                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", 0, 0);
 456         }
 457 }
 458
 459 void item_strength (void) {
 460         if(!cvar("g_powerup_strength"))
 461                 return;
 462
 463         if(cvar("g_minstagib")) {
 464                 minstagib_items(IT_STRENGTH);
 465         } else {
 466                 self.strength_finished = 30;
 467                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);
 468         }
 469 }
 470
 471 void item_invincible (void) {
 472         if(!cvar("g_powerup_shield"))
 473                 return;
 474
 475         if(cvar("g_minstagib")) {
 476                 minstagib_items(IT_INVINCIBLE);
 477         } else {
 478                 self.invincible_finished = 30;
 479                 self.effects = EF_ADDITIVE;
 480                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);
 481         }
 482 }
 483 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 484 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 485
 486 void misc_models (void)
 487 {
 488         precache_model (self.model);
 489         setmodel (self, self.model);
 490         setsize (self, self.mins, self.maxs);
 491 }
 492
 493