data/qcsrc/server/gamec/cl_weapons.c

   1 // generic weapons table
   2 // add new weapons here
   3 void(float wpn, float wrequest) weapon_action =
   4 {
   5         if (cvar("g_minstagib"))
   6         {
   7                 if (wpn == WEP_NEX)
   8                         w_nex(wrequest);
   9                 return;
  10         }
  11
  12         if (wpn == WEP_LASER)
  13                 w_laser(wrequest);
  14         else if (wpn == WEP_SHOTGUN)
  15                 w_shotgun(wrequest);
  16         else if (wpn == WEP_UZI)
  17                 w_uzi(wrequest);
  18         else if (wpn == WEP_GRENADE_LAUNCHER)
  19                 w_glauncher(wrequest);
  20         else if (wpn == WEP_ELECTRO)
  21                 w_electro(wrequest);
  22         else if (wpn == WEP_CRYLINK)
  23                 w_crylink(wrequest);
  24         else if (wpn == WEP_NEX)
  25                 w_nex(wrequest);
  26         else if (wpn == WEP_HAGAR)
  27                 w_hagar(wrequest);
  28         else if (wpn == WEP_ROCKET_LAUNCHER)
  29                 w_rlauncher(wrequest);
  30 };
  31
  32 // think function for tossed weapons
  33 void() thrown_wep_think =
  34 {
  35         self.solid = SOLID_TRIGGER;
  36         SUB_SetFade(self, time + 20, 1);
  37         setorigin(self, self.origin);
  38 };
  39
  40 // toss current weapon
  41 void() W_ThrowWeapon
  42 {
  43         local float w;
  44         local entity wep, e;
  45
  46         e = self;
  47         wep = spawn();
  48         self = wep;
  49         w = e.weapon;
  50         setorigin(wep, e.origin);
  51         makevectors(e.angles);
  52         wep.classname = "droppedweapon";
  53         wep.velocity = e.velocity * 0.5 + v_forward * 750;
  54         SUB_SetFade(wep, time + 20, 1);
  55
  56         if(w == WEP_SHOTGUN)
  57         {
  58                 w = IT_SHOTGUN;
  59                 if(!(e.items & w))
  60                 {
  61                         remove(wep);
  62                         return;
  63                 }
  64                 weapon_shotgun();
  65                 wep.ammo_shells = 1;
  66                 e.ammo_shells -= 1;
  67         }
  68         else if(w == WEP_UZI)
  69         {
  70                 w = IT_UZI;
  71                 if(!(e.items & w))
  72                 {
  73                         remove(wep);
  74                         return;
  75                 }
  76                 weapon_uzi();
  77                 wep.ammo_nails = 1;
  78                 e.ammo_nails -= 1;
  79         }
  80         else if(w == WEP_GRENADE_LAUNCHER)
  81         {
  82                 w = IT_GRENADE_LAUNCHER;
  83                 if(!(e.items & w))
  84                 {
  85                         remove(wep);
  86                         return;
  87                 }
  88                 weapon_grenadelauncher();
  89                 wep.ammo_rockets = 1;
  90                 e.ammo_rockets -= 1;
  91         }
  92         else if(w == WEP_ELECTRO)
  93         {
  94                 w = IT_ELECTRO;
  95                 if(!(e.items & w))
  96                 {
  97                         remove(wep);
  98                         return;
  99                 }
 100                 weapon_electro();
 101                 wep.ammo_cells = 1;
 102                 e.ammo_cells -= 1;
 103         }
 104         else if(w == WEP_CRYLINK)
 105         {
 106                 w = IT_CRYLINK;
 107                 if(!(e.items & w))
 108                 {
 109                         remove(wep);
 110                         return;
 111                 }
 112                 weapon_crylink();
 113                 wep.ammo_cells = 1;
 114                 e.ammo_cells -= 1;
 115         }
 116         else if(w == WEP_NEX)
 117         {
 118                 w = IT_NEX;
 119                 if(!(e.items & w))
 120                 {
 121                         remove(wep);
 122                         return;
 123                 }
 124                 weapon_nex();
 125                 wep.ammo_cells = 1;
 126                 e.ammo_cells -= 1;
 127         }
 128         else if(w == WEP_HAGAR)
 129         {
 130                 w = IT_HAGAR;
 131                 if(!(e.items & w))
 132                 {
 133                         remove(wep);
 134                         return;
 135                 }
 136                 weapon_hagar();
 137                 wep.ammo_rockets = 1;
 138                 e.ammo_rockets -= 1;
 139         }
 140         else if(w == WEP_ROCKET_LAUNCHER)
 141         {
 142                 w = IT_ROCKET_LAUNCHER;
 143                 if(!(e.items & w))
 144                 {
 145                         remove(wep);
 146                         return;
 147                 }
 148                 weapon_rocketlauncher();
 149                 wep.ammo_rockets = 1;
 150                 e.ammo_rockets -= 1;
 151         }
 152
 153         if(e.items & w)
 154                 sprint(e, strcat("You dropped the ^2", wep.netname, "\n"));
 155         wep.solid = SOLID_NOT;
 156         setorigin(wep, wep.origin);
 157         wep.nextthink = time + 0.25;
 158         wep.think = thrown_wep_think;
 159         wep.classname = "droppedweapon";
 160         e.items = e.items - (e.items & w);
 161         e.switchweapon = w_getbestweapon(e);
 162         self = e;
 163 };
 164
 165 // switch between weapons
 166 void(float imp) W_SwitchWeapon
 167 {
 168         weapon_hasammo = TRUE;
 169         if (!client_hasweapon(self, imp, TRUE))
 170         {
 171                 if (!weapon_hasammo)
 172                         sprint(self, "You don't have any ammo for that weapon\n");
 173                 else
 174                         sprint(self, "You don't own that weapon\n");
 175         }
 176         else
 177         {
 178                 self.cnt = self.weapon;
 179                 self.switchweapon = imp;
 180         }
 181 };
 182
 183 // next weapon
 184 void() W_NextWeapon =
 185 {
 186         local float weaponwant, maxtries;
 187
 188         maxtries = WEP_LAST;
 189
 190         weaponwant = self.switchweapon + 1;
 191         if (weaponwant < WEP_FIRST)
 192                 weaponwant = WEP_LAST;
 193         if (weaponwant > WEP_LAST)
 194                 weaponwant = WEP_FIRST;
 195         weapon_hasammo = TRUE;
 196         while(!client_hasweapon(self, weaponwant, TRUE))
 197         {
 198                 if(!maxtries)
 199                         return;
 200
 201                 maxtries -= 1;
 202                 weaponwant = weaponwant + 1;
 203                 if (weaponwant < WEP_FIRST)
 204                         weaponwant = WEP_LAST;
 205                 if (weaponwant > WEP_LAST)
 206                         weaponwant = WEP_FIRST;
 207         }
 208         self.cnt = self.weapon;
 209         self.switchweapon = weaponwant;
 210 };
 211
 212 // prev weapon
 213 void() W_PreviousWeapon =
 214 {
 215         local float weaponwant, maxtries;
 216
 217         maxtries = WEP_LAST;
 218
 219         weaponwant = self.switchweapon - 1;
 220         if (weaponwant < WEP_FIRST)
 221                 weaponwant = WEP_LAST;
 222         if (weaponwant > WEP_LAST)
 223                 weaponwant = WEP_FIRST;
 224         weapon_hasammo = TRUE;
 225         while(!client_hasweapon(self, weaponwant, TRUE))
 226         {
 227                 if(!maxtries)
 228                         return;
 229
 230                 maxtries -= 1;
 231                 weaponwant = weaponwant - 1;
 232                 if (weaponwant < WEP_FIRST)
 233                         weaponwant = WEP_LAST;
 234                 if (weaponwant > WEP_LAST)
 235                         weaponwant = WEP_FIRST;
 236         }
 237         self.cnt = self.weapon;
 238         self.switchweapon = weaponwant;
 239 };
 240
 241 // Bringed back weapon frame
 242 void() W_WeaponFrame =
 243 {
 244         if (!self.weaponentity || self.health <= 0)
 245                 return; // Dead player can't use weapons and injure impulse commands
 246
 247         makevectors(self.v_angle);
 248
 249         // Change weapon
 250         if (self.weapon != self.switchweapon)
 251         {
 252                 if (self.weaponentity.state == WS_CLEAR)
 253                 {
 254                         self.weaponentity.state = WS_RAISE;
 255                         weapon_action(self.switchweapon, WR_SETUP);
 256                         // VorteX: add player model weapon select frame here
 257                         // setcustomframe(PlayerWeaponRaise);
 258                         weapon_action(self.weapon, WR_UPDATECOUNTS);
 259                         weapon_action(self.weapon, WR_RAISE);
 260                 }
 261                 else if (self.weaponentity.state == WS_READY)
 262                 {
 263                         sound (self, CHAN_WEAPON, "weapons/weapon_switch.ogg", 1, ATTN_NORM);
 264                         self.weaponentity.state = WS_DROP;
 265                         // VorteX: add player model weapon deselect frame here
 266                         // setcustomframe(PlayerWeaponDrop);
 267                         weapon_action(self.weapon, WR_DROP);
 268                 }
 269         }
 270
 271         if (self.button0)
 272                 weapon_action(self.weapon, WR_FIRE1);
 273         if (self.button3)
 274                 weapon_action(self.weapon, WR_FIRE2);
 275
 276         // do weapon think
 277         if (time >= self.weapon_nextthink)
 278                 if (self.weapon_nextthink > 0)
 279                         self.weapon_think();
 280
 281         // weapon bobbing and script actions
 282         local float bobintensity, q1pitching, framespeed, diff;
 283         local vector vel, realorg, layer1, boblayer;
 284
 285         bobintensity = cvar("g_viewweapon_bobintensity"); // weapon bob intensity
 286         q1pitching = fabs(cvar("g_viewweapon_q1pitching")); // q1 style of "bob" when looking up and down
 287
 288         realorg = self.weaponentity.origin + self.weaponentity.view_ofs;
 289         realorg = realorg - self.weaponentity.finaldest; // finaldest is last bob position
 290
 291         // VorteX: actually this is needed for weapon screen offset
 292         if (q1pitching)
 293         {
 294                 self.weaponentity.view_ofs_x = q1pitching*bound(-5.5, self.v_angle_x/45, 5.5);
 295                 self.weaponentity.view_ofs_z = q1pitching*bound(-1.5, self.v_angle_x/60, 1.5);
 296         }
 297
 298         // weapon origin interpolation, layer 1
 299         if (realorg != self.weaponentity.pos1)
 300         {
 301                 framespeed = frametime*self.weaponentity.lip*10; // lip is speed of origin changing (of layer1)
 302                 diff = vlen(realorg - self.weaponentity.pos1);
 303                 // VorteX: add speed modifier (haste)?
 304                 layer1 = frametime*10*self.weaponentity.lip*normalize(self.weaponentity.pos1 - realorg);
 305                 if (diff <= vlen(layer1))
 306                         layer1 = normalize(self.weaponentity.pos1 - realorg)*diff;
 307         }
 308
 309         // weapon bobbing (q3-style)
 310         if (self.flags & FL_ONGROUND && self.waterlevel < 2)
 311         {
 312                 // VorteX: only xy velocity matters
 313                 vel_x = self.velocity_x;
 314                 vel_y = self.velocity_y;
 315                 framespeed = vlen(vel);
 316                 // Y axis
 317                 diff = bobintensity*framespeed/300;
 318                 self.weaponentity.destvec_y = self.weaponentity.destvec_y + frametime*10;
 319                 boblayer_y = diff*cos(self.weaponentity.destvec_y + 90);
 320                 // Z axis
 321                 diff = bobintensity*framespeed/540;
 322                 self.weaponentity.destvec_z = self.weaponentity.destvec_z + frametime*20;
 323                 boblayer_z = diff*cos(self.weaponentity.destvec_z);
 324                 self.weaponentity.finaldest = boblayer;
 325         }
 326         else if (self.waterlevel > 0)
 327         {// swim, all velocity matters
 328                 // X axis
 329                 framespeed = vlen(self.velocity);
 330                 diff = bobintensity*framespeed/100;
 331                 self.weaponentity.destvec_x = self.weaponentity.destvec_x + frametime*6;
 332                 boblayer_x = diff*cos(self.weaponentity.destvec_x);
 333                 self.weaponentity.finaldest = boblayer;
 334         }
 335         else
 336                 self.weaponentity.finaldest = '0 0 0';
 337         self.weaponentity.origin = realorg + boblayer + layer1 - self.weaponentity.view_ofs;
 338 };