data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121         string spotname;
 122
 123         spot = find (world, classname, "testplayerstart");
 124         if (spot)
 125                 return spot;
 126
 127         spotname = "info_player_deathmatch";
 128         teamcheck = 0;
 129
 130         if(!anypoint && cvar("g_ctf") )
 131                 teamcheck = self.team;
 132
 133         // get the list of players
 134         playerlist = findchain(classname, "player");
 135         // get the entire list of spots
 136         firstspot = findchain(classname, "info_player_deathmatch");
 137         // filter out the bad ones
 138         // (note this returns the original list if none survived)
 139         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 140
 141         // there is 50/50 chance of choosing a random spot or the furthest spot
 142         // (this means that roughly every other spawn will be furthest, so you
 143         // usually won't get fragged at spawn twice in a row)
 144         if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string CheckPlayerModel(string plyermodel) {
 169         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 170
 171         /* Possible Fixme: Check if server can open the model?
 172            This would kill custom models, however. */
 173
 174         return plyermodel;
 175 }
 176
 177 /*
 178 =============
 179 PutObserverInServer
 180
 181 putting a client as observer in the server
 182 =============
 183 */
 184 void PutObserverInServer (void)
 185 {
 186         entity  spot;
 187         spot = SelectSpawnPoint (FALSE);
 188         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 189
 190         if(self.frags == 0 && cvar("g_lms") && self.killcount != -666)
 191                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 192         else if(self.killcount != -666)
 193                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 194
 195         self.classname = "observer";
 196         self.health = -666;
 197         self.takedamage = DAMAGE_NO;
 198         self.solid = SOLID_NOT;
 199         self.movetype = MOVETYPE_NOCLIP;
 200         self.flags = FL_CLIENT | FL_NOTARGET;
 201         self.armorvalue = 666;
 202         self.effects = 0;
 203         self.armorvalue = cvar("g_balance_armor_start");
 204         self.pauserotarmor_finished = 0;
 205         self.pauserothealth_finished = 0;
 206         self.pauseregen_finished = 0;
 207         self.damageforcescale = 0;
 208         self.death_time = 0;
 209         self.dead_time = 0;
 210         self.dead_frame = 0;
 211         self.die_frame = 0;
 212         self.deaths = 0;
 213         self.alpha = 0;
 214         self.scale = 0;
 215         self.fade_time = 0;
 216         self.pain_frame = 0;
 217         self.pain_finished = 0;
 218         self.strength_finished = 0;
 219         self.invincible_finished = 0;
 220         self.pushltime = 0;
 221         self.think = SUB_Null;
 222         self.nextthink = 0;
 223         self.hook_time = 0;
 224         self.runes = 0;
 225         self.deadflag = DEAD_NO;
 226         self.angles = spot.angles;
 227         self.angles_z = 0;
 228         self.fixangle = TRUE;
 229         self.crouch = FALSE;
 230         self.view_ofs = PL_VIEW_OFS;
 231         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 14));
 232         self.oldorigin = self.origin;
 233         self.items = 0;
 234         self.model = "";
 235         self.modelindex = 0;
 236         self.weapon = 0;
 237         self.weaponmodel = "";
 238         self.weaponframe = 0;
 239         self.weaponentity = world;
 240         self.killcount = -666;
 241         self.velocity = '0 0 0';
 242         self.avelocity = '0 0 0';
 243         self.punchangle = '0 0 0';
 244         self.punchvector = '0 0 0';
 245         self.oldvelocity = self.velocity;
 246
 247         if(!cvar("g_lms"))
 248                 self.frags = -666;
 249         //stuffcmd(self, "set viewsize 120 \n");
 250 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 251 }
 252
 253
 254 /*
 255 =============
 256 PutClientInServer
 257
 258 Called when a client spawns in the server
 259 =============
 260 */
 261 void PutClientInServer (void)
 262 {
 263         if(clienttype(self) ==  CLIENTTYPE_BOT)
 264         {
 265                 self.classname = "player";
 266         }
 267
 268         // player is dead and becomes observer
 269         if(cvar("g_lms") && self.frags < 1)
 270                 self.classname = "observer";
 271
 272         if(self.classname == "player") {
 273                 entity  spot;
 274
 275                 spot = SelectSpawnPoint (FALSE);
 276
 277                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 278
 279                 self.classname = "player";
 280                 self.iscreature = TRUE;
 281                 self.movetype = MOVETYPE_WALK;
 282                 self.solid = SOLID_SLIDEBOX;
 283                 self.flags = FL_CLIENT;
 284                 self.takedamage = DAMAGE_AIM;
 285                 self.effects = 0;
 286                 self.health = cvar("g_balance_health_start");
 287                 self.armorvalue = cvar("g_balance_armor_start");
 288                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 289                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 290                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 291                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 292                 self.damageforcescale = 2;
 293                 self.death_time = 0;
 294                 self.dead_time = 0;
 295                 self.dead_frame = 0;
 296                 self.die_frame = 0;
 297                 self.alpha = 0;
 298                 self.scale = 0;
 299                 self.fade_time = 0;
 300                 self.pain_frame = 0;
 301                 self.pain_finished = 0;
 302                 self.strength_finished = 0;
 303                 self.invincible_finished = 0;
 304                 self.pushltime = 0;
 305                 //self.speed_finished = 0;
 306                 //self.slowmo_finished = 0;
 307                 // players have no think function
 308                 self.think = SUB_Null;
 309                 self.nextthink = 0;
 310                 self.weapon = 0;
 311                 self.switchweapon = 0;
 312                 self.hook_time = 0;
 313
 314                 self.runes = 0;
 315
 316                 self.deadflag = DEAD_NO;
 317
 318                 self.angles = spot.angles;
 319
 320                 self.angles_z = 0; // never spawn tilted even if the spot says to
 321                 self.fixangle = TRUE; // turn this way immediately
 322                 self.velocity = '0 0 0';
 323                 self.avelocity = '0 0 0';
 324                 self.punchangle = '0 0 0';
 325                 self.punchvector = '0 0 0';
 326                 self.oldvelocity = self.velocity;
 327
 328                 self.viewzoom = 0.6;
 329
 330                 if(cvar("sv_defaultcharacter") == 1) {
 331                         local string defaultmodel;
 332                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 333
 334                         precache_model (defaultmodel);
 335                         setmodel (self, defaultmodel);
 336                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 337                 } else {
 338                         self.playermodel = CheckPlayerModel(self.playermodel);
 339
 340                         precache_model (self.playermodel);
 341                         setmodel (self, self.playermodel);
 342                         self.skin = stof(self.playerskin);
 343
 344                 }
 345
 346                 self.crouch = FALSE;
 347                 self.view_ofs = PL_VIEW_OFS;
 348                 setsize (self, PL_MIN, PL_MAX);
 349                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 350                 // don't reset back to last position, even if new position is stuck in solid
 351                 self.oldorigin = self.origin;
 352
 353                 if(cvar("g_lms"))
 354                 {
 355                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 356                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 357                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 358                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 359                         self.health = cvar("g_lms_start_health");
 360                         self.armorvalue = cvar("g_lms_start_armor");
 361                 }
 362                 else if (cvar("g_use_ammunition")) {
 363                         self.ammo_shells = cvar("g_start_ammo_shells");
 364                         self.ammo_nails = cvar("g_start_ammo_nails");
 365                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 366                         self.ammo_cells = cvar("g_start_ammo_cells");
 367                 } else {
 368                         self.ammo_shells = 999;
 369                         self.ammo_nails = 999;
 370                         self.ammo_rockets = 999;
 371                         self.ammo_cells = 999;
 372                 }
 373
 374                 self.items = 0;
 375                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 376                 {
 377                         self.items = self.items | IT_LASER;
 378                         self.switchweapon = WEP_LASER;
 379                 }
 380                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 381                 {
 382                         self.items = self.items | IT_SHOTGUN;
 383                         self.switchweapon = WEP_SHOTGUN;
 384                 }
 385                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 386                 {
 387                         self.items = self.items | IT_UZI;
 388                         self.switchweapon = WEP_UZI;
 389                 }
 390                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 391                 {
 392                         self.items = self.items | IT_GRENADE_LAUNCHER;
 393                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 394                 }
 395                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 396                 {
 397                         self.items = self.items | IT_ELECTRO;
 398                         self.switchweapon = WEP_ELECTRO;
 399                 }
 400                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 401                 {
 402                         self.items = self.items | IT_CRYLINK;
 403                         self.switchweapon = WEP_CRYLINK;
 404                 }
 405                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 406                 {
 407                         self.items = self.items | IT_NEX;
 408                         self.switchweapon = WEP_NEX;
 409                 }
 410                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 411                 {
 412                         self.items = self.items | IT_HAGAR;
 413                         self.switchweapon = WEP_HAGAR;
 414                 }
 415                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 416                 {
 417                         self.items = self.items | IT_ROCKET_LAUNCHER;
 418                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 419                 }
 420
 421                 if(cvar("g_instagib"))
 422                 {
 423                         self.items = IT_NEX;
 424                         self.switchweapon = WEP_NEX;
 425                         self.ammo_cells = 999;
 426                 }
 427
 428                 if(cvar("g_rocketarena"))
 429                 {
 430                         self.items = IT_ROCKET_LAUNCHER;
 431                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 432                         self.ammo_rockets = 999;
 433                 }
 434
 435                 if(cvar("g_nixnex"))
 436                 {
 437                         self.items = 0;
 438                         // will be done later
 439                 }
 440
 441                 if(cvar("g_minstagib"))
 442                 {
 443                         self.health = 100;
 444                         self.armorvalue = 0;
 445                         self.items = IT_NEX;
 446                         self.switchweapon = WEP_NEX;
 447                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 448                         self.extralives = 0;
 449                         self.jump_interval = time;
 450                 }
 451
 452                 self.event_damage = PlayerDamage;
 453
 454                 self.statdraintime = time + 5;
 455                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 456
 457                 if(self.killcount == -666) {
 458                         self.killcount = 0;
 459                         self.frags = 0;
 460                 }
 461
 462                 self.cnt = WEP_LASER;
 463                 self.nixnex_lastchange_id = -1;
 464
 465                 /*
 466                 W_UpdateWeapon();
 467                 W_UpdateAmmo();
 468                 */
 469                 CL_SpawnWeaponentity();
 470                 self.alpha = 1;
 471                 self.exteriorweaponentity.alpha = 1;
 472
 473                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 474                 self.lms_traveled_distance = 0;
 475
 476                 if(cvar("spawn_debug"))
 477                 {
 478                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 479                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 480                 }
 481
 482                 //stuffcmd(self, "chase_active 0");
 483                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 484         } else if(self.classname == "observer") {
 485                 PutObserverInServer ();
 486         }
 487 }
 488
 489 /*
 490 =============
 491 SetNewParms
 492 =============
 493 */
 494 void SetNewParms (void)
 495 {
 496
 497 }
 498
 499 /*
 500 =============
 501 SetChangeParms
 502 =============
 503 */
 504 void SetChangeParms (void)
 505 {
 506
 507 }
 508
 509 /*
 510 =============
 511 ClientKill
 512
 513 Called when a client types 'kill' in the console
 514 =============
 515 */
 516 void ClientKill (void)
 517 {
 518         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 519 }
 520
 521 /*
 522 =============
 523 ClientConnect
 524
 525 Called when a client connects to the server
 526 =============
 527 */
 528 string ColoredTeamName(float t);
 529 //void dom_player_join_team(entity pl);
 530 void ClientConnect (void)
 531 {
 532         self.classname = "player_joining";
 533
 534         if(player_count<0) player_count = 0;
 535
 536         //if(cvar("g_domination"))
 537         //      dom_player_join_team(self);
 538
 539         //JoinBestTeam(self, FALSE);
 540
 541         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 542                 self.classname = "observer";
 543         } else {
 544                 self.classname = "player";
 545         }
 546
 547         self.playerid = (playerid_last = playerid_last + 1);
 548         if(cvar("sv_eventlog"))
 549         {
 550                 string s;
 551                 if(clienttype(self) == CLIENTTYPE_REAL)
 552                         s = "player";
 553                 else
 554                         s = "bot";
 555                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 556                 s = strcat(":team:", ftos(self.playerid), ":");
 557                 s = strcat(s, ftos(self.team));
 558                 GameLogEcho(s, FALSE);
 559         }
 560
 561         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 562
 563         bprint ("^4",self.netname);
 564         bprint ("^4 connected");
 565
 566         if(cvar("g_domination") || cvar("g_ctf"))
 567         {
 568                 bprint(" and joined the ");
 569                 bprint(ColoredTeamName(self.team));
 570         }
 571
 572         bprint("\n");
 573
 574         self.welcomemessage_time = time + cvar("welcome_message_time");
 575         self.welcomemessage_time2 = 0;
 576
 577         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 578         // send prediction settings to the client
 579         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 580         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 581         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 582         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 583         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 584         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 585         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 586         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 587         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 588         // Wazat's grappling hook
 589         SetGrappleHookBindings();
 590
 591         // get autoswitch state from player
 592         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 593         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 594
 595         // get version info from player
 596         stuffcmd(self, "cmd clientversion $gameversion\n");
 597
 598         // set cvar for team scoreboard
 599         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 600
 601         if(cvar("g_lms"))
 602         {
 603                 self.frags = cvar("fraglimit");
 604                 // no fraglimit was set, so player gets 999 lives
 605                 if(self.frags < 1)
 606                         self.frags = 999;
 607
 608                 // disallow player to join after the worst player has lost g_lms_last_join lives
 609                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 610                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 611                 {
 612                         self.frags = -1;
 613                         lms_dead_count += 1;
 614                 }
 615                 else if(cvar("fraglimit") > lms_lowest_lives)
 616                 {
 617                         self.frags = lms_lowest_lives;
 618                 }
 619         }
 620
 621         player_count += 1;
 622         self.jointime = time;
 623 }
 624
 625 /*
 626 =============
 627 ClientDisconnect
 628
 629 Called when a client disconnects from the server
 630 =============
 631 */
 632 void(entity e) DropFlag;
 633 .entity chatbubbleentity;
 634 .entity teambubbleentity;
 635 void ClientDisconnect (void)
 636 {
 637         if(cvar("sv_eventlog"))
 638                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 639         bprint ("^4",self.netname);
 640         bprint ("^4 disconnected\n");
 641
 642         if (self.chatbubbleentity)
 643         {
 644                 remove (self.chatbubbleentity);
 645                 self.chatbubbleentity = world;
 646         }
 647
 648         if (self.teambubbleentity)
 649         {
 650                 remove (self.teambubbleentity);
 651                 self.teambubbleentity = world;
 652         }
 653
 654         DropAllRunes(self);
 655
 656         if(self.flagcarried)
 657                 DropFlag(self.flagcarried);
 658
 659         // decrease player count for lms
 660         player_count -= 1;
 661         // player was dead, decrease dead count
 662         if(cvar("g_lms") && self.frags < 1)
 663                 lms_dead_count -= 1;
 664         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 665 }
 666
 667 .float buttonchat;
 668 void() ChatBubbleThink =
 669 {
 670         self.nextthink = time;
 671         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 672         {
 673                 remove(self);
 674                 return;
 675         }
 676         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 677         if (self.owner.buttonchat && !self.owner.deadflag)
 678                 self.model = self.mdl;
 679         else
 680                 self.model = "";
 681 };
 682
 683 void() UpdateChatBubble =
 684 {
 685         if (!self.modelindex)
 686                 return;
 687         // spawn a chatbubble entity if needed
 688         if (!self.chatbubbleentity)
 689         {
 690                 self.chatbubbleentity = spawn();
 691                 self.chatbubbleentity.owner = self;
 692                 self.chatbubbleentity.exteriormodeltoclient = self;
 693                 self.chatbubbleentity.think = ChatBubbleThink;
 694                 self.chatbubbleentity.nextthink = time;
 695                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 696                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 697                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 698                 self.chatbubbleentity.model = "";
 699         }
 700 }
 701
 702
 703 void() TeamBubbleThink =
 704 {
 705         self.nextthink = time;
 706         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 707         {
 708                 remove(self);
 709                 return;
 710         }
 711 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 712         if (self.owner.buttonchat || self.owner.deadflag)
 713                 self.model = "";
 714         else
 715                 self.model = self.mdl;
 716
 717 };
 718
 719 .float() customizeentityforclient;
 720 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 721
 722 void() UpdateTeamBubble =
 723 {
 724         if (!self.modelindex || !cvar("teamplay"))
 725                 return;
 726         // spawn a teambubble entity if needed
 727         if (!self.teambubbleentity && cvar("teamplay"))
 728         {
 729                 self.teambubbleentity = spawn();
 730                 self.teambubbleentity.owner = self;
 731                 self.teambubbleentity.exteriormodeltoclient = self;
 732                 self.teambubbleentity.think = TeamBubbleThink;
 733                 self.teambubbleentity.nextthink = time;
 734                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 735 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 736                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 737                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 738                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 739                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 740                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 741         }
 742 }
 743
 744 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 745 // added to the model skins
 746 /*void() UpdateColorModHack =
 747 {
 748         local float c;
 749         c = self.clientcolors & 15;
 750         // LordHavoc: only bothering to support white, green, red, yellow, blue
 751              if (teamplay == 0) self.colormod = '0 0 0';
 752         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 753         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 754         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 755         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 756         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 757         else self.colormod = '1 1 1';
 758 };*/
 759
 760 void UpdatePlayerColors () {
 761         if(self.weaponentity) {
 762                 self.weaponentity.colormap = self.colormap;
 763                 self.exteriorweaponentity.colormap = self.colormap;
 764         }
 765 }
 766 /*
 767 =============
 768 PlayerJump
 769
 770 When you press the jump key
 771 =============
 772 */
 773 void PlayerJump (void)
 774 {
 775         float mjumpheight;
 776
 777         mjumpheight = cvar("g_balance_jumpheight");
 778         if (self.waterlevel >= 2)
 779         {
 780                 if (self.watertype == CONTENT_WATER)
 781                         self.velocity_z = 200;
 782                 else if (self.watertype == CONTENT_SLIME)
 783                         self.velocity_z = 80;
 784                 else
 785                         self.velocity_z = 50;
 786
 787                 return;
 788         }
 789
 790
 791         if (!(self.flags & FL_ONGROUND))
 792                 return;
 793
 794         if (!(self.flags & FL_JUMPRELEASED))
 795                 return;
 796
 797         if(cvar("g_runematch"))
 798         {
 799                 if(self.runes & RUNE_SPEED)
 800                 {
 801                         if(self.runes & CURSE_SLOW)
 802                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 803                         else
 804                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 805                 }
 806                 else if(self.runes & CURSE_SLOW)
 807                 {
 808                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 809                 }
 810         }
 811
 812         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 813         {
 814                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 815         }
 816
 817         self.velocity_z = self.velocity_z + mjumpheight;
 818         self.oldvelocity_z = self.velocity_z;
 819
 820         self.flags = self.flags - FL_ONGROUND;
 821         self.flags = self.flags - FL_JUMPRELEASED;
 822 }
 823
 824 void() CheckWaterJump =
 825 {
 826         local vector start, end;
 827
 828 // check for a jump-out-of-water
 829         makevectors (self.angles);
 830         start = self.origin;
 831         start_z = start_z + 8;
 832         v_forward_z = 0;
 833         normalize(v_forward);
 834         end = start + v_forward*24;
 835         traceline (start, end, TRUE, self);
 836         if (trace_fraction < 1)
 837         {       // solid at waist
 838                 start_z = start_z + self.maxs_z - 8;
 839                 end = start + v_forward*24;
 840                 self.movedir = trace_plane_normal * -50;
 841                 traceline (start, end, TRUE, self);
 842                 if (trace_fraction == 1)
 843                 {       // open at eye level
 844                         self.flags = self.flags | FL_WATERJUMP;
 845                         self.velocity_z = 225;
 846                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 847                         self.teleport_time = time + 2;  // safety net
 848                         return;
 849                 }
 850         }
 851 };
 852
 853
 854 void respawn(void)
 855 {
 856         CopyBody(1);
 857         PutClientInServer();
 858 }
 859
 860 void player_powerups (void)
 861 {
 862         if (cvar("g_minstagib"))
 863         {
 864                 self.effects = EF_FULLBRIGHT;
 865                 if (self.items & IT_STRENGTH)
 866                 {
 867                         if (time > self.strength_finished)
 868                         {
 869                                 self.alpha = 1;
 870                                 self.exteriorweaponentity.alpha = 1;
 871                                 self.items = self.items - (self.items & IT_STRENGTH);
 872                                 sprint(self, "^3Invisibility has worn off\n");
 873                         }
 874                 }
 875                 else
 876                 {
 877                         if (time < self.strength_finished)
 878                         {
 879                                 self.alpha = cvar("g_minstagib_invis_alpha");
 880                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 881                                 self.items = self.items | IT_STRENGTH;
 882                                 sprint(self, "^3You are invisible\n");
 883                         }
 884                 }
 885
 886                 if (self.items & IT_INVINCIBLE)
 887                 {
 888                         if (time > self.invincible_finished)
 889                         {
 890                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 891                                 sprint(self, "^3Speed has worn off\n");
 892                         }
 893                 }
 894                 else
 895                 {
 896                         if (time < self.invincible_finished)
 897                         {
 898                                 self.items = self.items | IT_INVINCIBLE;
 899                                 sprint(self, "^3You are on speed\n");
 900                         }
 901                 }
 902                 return;
 903         }
 904
 905         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 906         if (self.items & IT_STRENGTH)
 907         {
 908                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 909                 if (time > self.strength_finished)
 910                 {
 911                         self.items = self.items - (self.items & IT_STRENGTH);
 912                         sprint(self, "^3Strength has worn off\n");
 913                 }
 914         }
 915         else
 916         {
 917                 if (time < self.strength_finished)
 918                 {
 919                         self.items = self.items | IT_STRENGTH;
 920                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 921                 }
 922         }
 923         if (self.items & IT_INVINCIBLE)
 924         {
 925                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 926                 if (time > self.invincible_finished)
 927                 {
 928                         self.items = self.items - (self.items & IT_INVINCIBLE);
 929                         sprint(self, "^3Shield has worn off\n");
 930                 }
 931         }
 932         else
 933         {
 934                 if (time < self.invincible_finished)
 935                 {
 936                         self.items = self.items | IT_INVINCIBLE;
 937                         sprint(self, "^3Shield surrounds you\n");
 938                 }
 939         }
 940
 941         if (cvar("g_fullbrightplayers"))
 942                 self.effects = self.effects | EF_FULLBRIGHT;
 943
 944         // midair gamemode: damage only while in the air
 945         // if in midair mode, being on ground grants temporary invulnerability
 946         // (this is so that multishot weapon don't clear the ground flag on the
 947         // first damage in the frame, leaving the player vulnerable to the
 948         // remaining hits in the same frame)
 949         if (self.flags & FL_ONGROUND)
 950         if (cvar("g_midair"))
 951                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
 952
 953         if (time < self.spawnshieldtime)
 954                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
 955 }
 956
 957 void player_regen (void)
 958 {
 959         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
 960         maxh = cvar("g_balance_health_stable");
 961         maxa = cvar("g_balance_armor_stable");
 962         limith = cvar("g_balance_health_limit");
 963         limita = cvar("g_balance_armor_limit");
 964
 965         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
 966                 return;
 967
 968         if(cvar("g_runematch"))
 969         {
 970                 max_mod = regen_mod = rot_mod = limit_mod = 1;
 971                 if (self.runes & RUNE_REGEN)
 972                 {
 973                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 974                         {
 975                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 976                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 977                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
 978                         }
 979                         else
 980                         {
 981                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 982                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 983                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
 984                         }
 985                 }
 986                 else if (self.runes & CURSE_VENOM)
 987                 {
 988                         max_mod = cvar("g_balance_curse_venom_hpmod");
 989                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 990                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 991                         else
 992                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 993                         limit_mod = cvar("g_balance_curse_venom_limitmod");
 994                         //if (!self.runes & RUNE_REGEN)
 995                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 996                 }
 997                 maxh = maxh * max_mod;
 998                 //maxa = maxa * max_mod;
 999
1000                 if (time > self.pauserotarmor_finished)
1001                 {
1002                         if (self.armorvalue > maxa)
1003                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1004                 }
1005                 if (time > self.pauserothealth_finished)
1006                 {
1007                         if (self.health > maxh)
1008                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1009                 }
1010                 if (time > self.pauseregen_finished)
1011                 {
1012                         if (self.health < maxh)
1013                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
1014                         if (self.armorvalue < maxa)
1015                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
1016                 }
1017         }
1018         else
1019         {
1020                 if (time > self.pauserothealth_finished)
1021                 if (self.health > maxh)
1022                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1023                 if (time > self.pauserotarmor_finished)
1024                 if (self.armorvalue > maxa)
1025                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1026                 if (time > self.pauseregen_finished)
1027                 {
1028                         if (self.health < maxh)
1029                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1030                         if (self.armorvalue < maxa)
1031                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1032                 }
1033         }
1034         if (self.health > limith)
1035                 self.health = limith;
1036         if (self.armorvalue > limita)
1037                 self.armorvalue = limita;
1038 }
1039
1040 /*
1041 ======================
1042 spectate mode routines
1043 ======================
1044 */
1045 void SpectateCopy(entity spectatee) {
1046         self.armortype = spectatee.armortype;
1047         self.armorvalue = spectatee.armorvalue;
1048         self.currentammo = spectatee.currentammo;
1049         self.effects = spectatee.effects;
1050         self.health = spectatee.health;
1051         self.impulse = 0;
1052         self.items = spectatee.items;
1053         self.punchangle = spectatee.punchangle;
1054         self.view_ofs = spectatee.view_ofs;
1055         self.v_angle = spectatee.v_angle;
1056         self.viewzoom = spectatee.viewzoom;
1057         setorigin(self, spectatee.origin);
1058         setsize(self, spectatee.mins, spectatee.maxs);
1059 }
1060
1061 void SpectateUpdate() {
1062         if (self != self.enemy) {
1063                 SpectateCopy(self.enemy);
1064                 msg_entity = self;
1065                 WriteByte(MSG_ONE, SVC_SETANGLE);
1066                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1067                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1068                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1069         }
1070 }
1071
1072 float SpectateNext() {
1073         other = find(self.enemy, classname, "player");
1074         if (!other) {
1075                 other = find(other, classname, "player");
1076         }
1077         if (other) {
1078                 self.enemy = other;
1079         }
1080         if(self.enemy.classname == "player") {
1081                 msg_entity = self;
1082                 WriteByte(MSG_ONE, SVC_SETVIEW);
1083                 WriteEntity(MSG_ONE, self.enemy);
1084                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1085                 SpectateUpdate();
1086                 return 1;
1087         } else {
1088                 return 0;
1089         }
1090 }
1091
1092 /*
1093 =============
1094 PlayerPreThink
1095
1096 Called every frame for each client before the physics are run
1097 =============
1098 */
1099 void PlayerPreThink (void)
1100 {
1101         if(self.classname == "player") {
1102                 local vector m1, m2;
1103
1104 //              MauveBot_AI();
1105
1106 //              if(self.netname == "Wazat")
1107 //                      bprint(strcat(self.classname, "\n"));
1108
1109                 CheckRules_Player();
1110
1111                 if(self.button7)
1112                         PrintWelcomeMessage(self);
1113
1114                 if(cvar("g_lms") || !cvar("sv_spectate"))
1115                 if((time - self.jointime) <= cvar("welcome_message_time"))
1116                         PrintWelcomeMessage(self);
1117
1118                 if (intermission_running)
1119                 {
1120                         IntermissionThink ();   // otherwise a button could be missed between
1121                         return;                                 // the think tics
1122                 }
1123
1124                 if (self.deadflag != DEAD_NO)
1125                 {
1126                         player_anim();
1127                         weapon_freeze();
1128                         if (self.deadflag == DEAD_DYING)
1129                         {
1130                                 if (time > self.dead_time)
1131                                         self.deadflag = DEAD_DEAD;
1132                         }
1133                         else if (self.deadflag == DEAD_DEAD)
1134                         {
1135                                 if (cvar("g_lms") || cvar("g_forced_respawn"))
1136                                         self.button0 = self.button2 = self.button3 = 0;
1137
1138                                 if (!self.button0 && !self.button2 && !self.button3)
1139                                         self.deadflag = DEAD_RESPAWNABLE;
1140                         }
1141                         else if (self.deadflag == DEAD_RESPAWNABLE)
1142                         {
1143                                 if (self.button0  ||
1144                                     self.button2  ||
1145                                     self.button3  ||
1146                                     self.button4  ||
1147                                     cvar("g_lms") ||
1148                                     cvar("g_forced_respawn"))
1149                                         respawn();
1150                         }
1151                         return;
1152                 }
1153
1154                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1155                 {
1156                         vector dist;
1157
1158                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1159                         dist = self.oldorigin - self.origin;
1160                         dist_z = 0;
1161                         self.lms_traveled_distance += fabs(vlen(dist));
1162
1163                         if(time > self.lms_nextcheck)
1164                         {
1165                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1166                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1167                                 {
1168                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1169                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1170                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1171                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1172                                 }
1173                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1174                                 self.lms_traveled_distance = 0;
1175                         }
1176                 }
1177
1178                 if (self.button5)
1179                 {
1180                         if (!self.crouch)
1181                         {
1182                                 self.crouch = TRUE;
1183                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1184                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1185                         }
1186                 }
1187                 else
1188                 {
1189                         if (self.crouch)
1190                         {
1191                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1192                                 if (!trace_startsolid)
1193                                 {
1194                                         self.crouch = FALSE;
1195                                         self.view_ofs = PL_VIEW_OFS;
1196                                         setsize (self, PL_MIN, PL_MAX);
1197                                 }
1198                         }
1199                 }
1200
1201                 if(cvar("sv_defaultcharacter") == 1) {
1202                         local string defaultmodel;
1203                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1204
1205                         if (defaultmodel != self.model)
1206                         {
1207                                 m1 = self.mins;
1208                                 m2 = self.maxs;
1209                                 precache_model (defaultmodel);
1210                                 setmodel (self, defaultmodel);
1211                                 setsize (self, m1, m2);
1212                         }
1213
1214                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1215                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1216                 } else {
1217                         if (self.playermodel != self.model)
1218                         {
1219                                 self.playermodel = CheckPlayerModel(self.playermodel);
1220                                 m1 = self.mins;
1221                                 m2 = self.maxs;
1222                                 precache_model (self.playermodel);
1223                                 setmodel (self, self.playermodel);
1224                                 setsize (self, m1, m2);
1225                         }
1226
1227                         if (self.skin != stof(self.playerskin))
1228                                 self.skin = stof(self.playerskin);
1229                 }
1230                 // Savage: Check for nameless players
1231                 if (strlen(self.netname) < 1) {
1232                         self.netname = "Player";
1233                         stuffcmd(self, "name Player\n");
1234                 }
1235
1236                 GrapplingHookFrame();
1237
1238                 W_WeaponFrame();
1239
1240                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1241                 {
1242                         if (cvar("g_minstagib") && self.button3)
1243                         {
1244                                 if (self.jump_interval <= (time + 0.1))
1245                                 {
1246                                         self.jump_interval = time + 1;
1247                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1248                                 }
1249                         }
1250                         else if (self.viewzoom > 0.4)
1251                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1252                 }
1253                 else if (self.viewzoom < 1.0)
1254                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1255
1256
1257                 if (self.button2)
1258                         PlayerJump ();
1259                 else
1260                         self.flags = self.flags | FL_JUMPRELEASED;
1261
1262                 player_powerups();
1263                 player_regen();
1264                 player_anim();
1265
1266                 //self.angles_y=self.v_angle_y + 90;   // temp
1267
1268                 if (self.waterlevel == 2)
1269                         CheckWaterJump ();
1270
1271                 //if (TetrisPreFrame()) return;
1272         } else if(gameover) {
1273                 if (intermission_running)
1274                         IntermissionThink ();   // otherwise a button could be missed between
1275                 return;
1276         } else if(self.classname == "observer") {
1277
1278                 if (self.flags & FL_JUMPRELEASED) {
1279                         if (self.button2 && self.version == cvar("gameversion")) {
1280                                 if(!cvar("teamplay")) {
1281                                         self.flags = self.flags & !FL_JUMPRELEASED;
1282                                         self.classname = "player";
1283                                         if(!cvar("g_lms"))
1284                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1285                                         PutClientInServer();
1286                                         centerprint(self,"");
1287                                         return;
1288                                 } else {
1289                                         self.flags = self.flags & !FL_JUMPRELEASED;
1290                                         stuffcmd(self,"menu_showteamselect\n");
1291                                         return;
1292                                 }
1293                         } else if(self.button0 && self.version == cvar("gameversion")) {
1294                                 self.flags = self.flags & !FL_JUMPRELEASED;
1295                                 if(SpectateNext() == 1) {
1296                                         self.classname = "spectator";
1297                                 }
1298                         }
1299                 } else {
1300                         if (!(self.button0 || self.button2)) {
1301                                 self.flags = self.flags | FL_JUMPRELEASED;
1302                         }
1303                 }
1304                 if(cvar("g_lms") && self.frags == 0)
1305                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1306                 else if(cvar("g_lms") && self.frags == -1)
1307                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1308                 else
1309                         PrintWelcomeMessage(self);
1310                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1311         } else if(self.classname == "spectator") {
1312
1313                 if (self.flags & FL_JUMPRELEASED) {
1314                         if (self.button2 && self.version == cvar("gameversion")) {
1315                                 if(!cvar("teamplay")) {
1316                                         self.flags = self.flags & !FL_JUMPRELEASED;
1317                                         self.classname = "player";
1318                                         if(!cvar("g_lms"))
1319                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1320
1321                                         msg_entity = self;
1322                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1323                                         WriteEntity(MSG_ONE, self);
1324                                         PutClientInServer();
1325                                         centerprint(self,"");
1326                                         return;
1327                                 } else {
1328                                         self.flags = self.flags & !FL_JUMPRELEASED;
1329                                         stuffcmd(self,"menu_showteamselect\n");
1330                                         return;
1331                                 }
1332                         } else if(self.button0) {
1333                                 self.flags = self.flags & !FL_JUMPRELEASED;
1334                                 if(SpectateNext() == 1) {
1335                                         self.classname = "spectator";
1336                                 } else {
1337                                         self.classname = "observer";
1338                                         msg_entity = self;
1339                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1340                                         WriteEntity(MSG_ONE, self);
1341                                         PutClientInServer();
1342                                 }
1343                         } else if (self.button3) {
1344                                 self.flags = self.flags & !FL_JUMPRELEASED;
1345                                 self.classname = "observer";
1346                                 msg_entity = self;
1347                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1348                                 WriteEntity(MSG_ONE, self);
1349                                 PutClientInServer();
1350                         } else {
1351                                 SpectateUpdate();
1352                         }
1353         } else {
1354                 if (!(self.button0 || self.button3)) {
1355                         self.flags = self.flags | FL_JUMPRELEASED;
1356                 }
1357                 }
1358                 if (cvar("g_lms") && self.frags < 1)
1359                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1360                 else
1361                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press jump to play\n^7press attack for next player\npress attack2 for free fly mode"));
1362
1363         }
1364 }
1365
1366
1367 /*
1368 =============
1369 PlayerPostThink
1370
1371 Called every frame for each client after the physics are run
1372 =============
1373 */
1374 void PlayerPostThink (void)
1375 {
1376         if(self.classname == "player") {
1377                 CheckRules_Player();
1378                 UpdateChatBubble();
1379                 UpdateTeamBubble();
1380                 UpdatePlayerColors();
1381                 if (self.deadflag == DEAD_NO)
1382                 if (self.impulse)
1383                         ImpulseCommands ();
1384                 if (intermission_running)
1385                         return;         // intermission or finale
1386
1387                 //PrintWelcomeMessage(self);
1388                 //if (TetrisPostFrame()) return;
1389         } else if (self.classname == "observer") {
1390                 //do nothing
1391         } else if (self.classname == "spectator") {
1392                 //do nothing
1393         }
1394 }