data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 .string fog;
  12
  13 void SetDefaultAlpha()
  14 {
  15         if(cvar("g_running_guns"))
  16         {
  17                 default_player_alpha = -1;
  18                 default_weapon_alpha = +1;
  19         }
  20         else if(g_cloaked)
  21         {
  22                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  23                 default_weapon_alpha = default_player_alpha;
  24         }
  25         else
  26         {
  27                 default_player_alpha = cvar("g_player_alpha");
  28                 if(default_player_alpha <= 0)
  29                         default_player_alpha = 1;
  30                 default_weapon_alpha = default_player_alpha;
  31         }
  32 }
  33
  34 void fteqcc_testbugs()
  35 {
  36         float a, b;
  37
  38         if(!cvar("developer_fteqccbugs"))
  39                 return;
  40
  41         dprint("*** fteqcc test: checking for bugs...\n");
  42
  43         a = 1;
  44         b = 5;
  45         if(sqrt(a) - sqrt(b - a) == 0)
  46                 dprint("*** fteqcc test: found same-function-twice bug\n");
  47         else
  48                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  49
  50         world.frags = -10;
  51         world.enemy = world;
  52         world.enemy.frags += 10;
  53         if(world.frags > 0.2 || world.frags < -0.2) // don't error out if it's just roundoff errors
  54                 dprint("*** fteqcc test: found += bug\n");
  55         else
  56                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  57         world.frags = 0;
  58 }
  59
  60 /**
  61  * Takes care of pausing and unpausing the game.
  62  * Centerprints the information about an upcoming or active timeout to all active
  63  * players. Also plays reminder sounds.
  64  */
  65 void timeoutHandler_Think() {
  66         local string timeStr;
  67         local entity plr;
  68         if (timeoutStatus == 1) {
  69                 if (remainingLeadTime > 0) {
  70                         //centerprint the information to every player
  71                         timeStr = getTimeoutText(0);
  72                         FOR_EACH_REALCLIENT(plr) {
  73                                 if(plr.classname == "player") {
  74                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  75                                 }
  76                         }
  77                         remainingLeadTime -= 1;
  78                         //think again in 1 second:
  79                         self.nextthink = time + 1;
  80                 }
  81                 else {
  82                         //now pause the game:
  83                         timeoutStatus = 2;
  84                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  85                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  86                         FOR_EACH_REALPLAYER(plr) {
  87                                 plr.lastV_angle = plr.v_angle;
  88                         }
  89                         self.nextthink = time;
  90                 }
  91         }
  92         else if (timeoutStatus == 2) {
  93                 if (remainingTimeoutTime > 0) {
  94                         timeStr = getTimeoutText(0);
  95                         FOR_EACH_REALCLIENT(plr) {
  96                                 if(plr.classname == "player") {
  97                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  98                                 }
  99                         }
 100                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 101                                 sound(world, CHAN_AUTO, "announcer/robotic/prepareforbattle.wav", 1, ATTN_NONE);
 102                         }
 103                         remainingTimeoutTime -= 1;
 104                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 105                 }
 106                 else {
 107                         //unpause the game again
 108                         remainingTimeoutTime = timeoutStatus = 0;
 109                         cvar_set("slowmo", ftos(orig_slowmo));
 110                         //and unlock the fixed view again once there is no timeout active anymore
 111                         FOR_EACH_REALPLAYER(plr) {
 112                                 plr.fixangle = FALSE;
 113                         }
 114                         //get rid of the countdown message
 115                         FOR_EACH_REALCLIENT(plr) {
 116                                 if(plr.classname == "player") {
 117                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 118                                 }
 119                         }
 120                         remove(self);
 121                         return;
 122                 }
 123
 124         }
 125         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 126                 FOR_EACH_REALCLIENT(plr) {
 127                         if(plr.classname == "player") {
 128                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 129                         }
 130                 }
 131                 remove(self);
 132                 return;
 133         }
 134 }
 135
 136 float GotoFirstMap()
 137 {
 138         if(cvar("_sv_init"))
 139         {
 140                 cvar_set("_sv_init", "0");
 141                 if(cvar("g_maplist_shuffle"))
 142                         ShuffleMaplist();
 143 #ifdef MAPINFO
 144                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 145 #else
 146                 tokenize(cvar_string("g_maplist"));
 147                 if(argv(0) != GetMapname())
 148 #endif
 149                 {
 150                         cvar_set("nextmap", argv(0));
 151
 152 #ifdef MAPINFO
 153                         MapInfo_Enumerate();
 154                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 155 #endif
 156
 157                         if(!DoNextMapOverride())
 158                                 GotoNextMap();
 159
 160                         return 1;
 161                 }
 162         }
 163         return 0;
 164 }
 165
 166 float world_already_spawned;
 167 void spawnfunc_worldspawn (void)
 168 {
 169         float fd, l;
 170         string s;
 171
 172         dprint_load(); // load dprint status from cvar
 173
 174         if(world_already_spawned)
 175                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 176         world_already_spawned = TRUE;
 177
 178         local entity head;
 179         head = nextent(world);
 180         maxclients = 0;
 181         while(head)
 182         {
 183                 ++maxclients;
 184                 head = nextent(head);
 185         }
 186
 187         if(GotoFirstMap())
 188                 return;
 189
 190 #ifdef MAPINFO
 191         MapInfo_LoadMapSettings(mapname);
 192 #endif
 193
 194         if(sv_cheats)
 195                 ServerProgsDB = db_create();
 196         else
 197                 ServerProgsDB = db_load("server.db");
 198
 199         /*
 200         TODO sound pack system
 201         // initialize sound pack system
 202         soundpack = cvar_string("g_soundpack");
 203         if(soundpack != "")
 204                 soundpack = strcat(soundpack, "/");
 205         soundpack = strzone(soundpack);
 206         */
 207
 208         // 0 normal
 209         lightstyle(0, "m");
 210
 211         // 1 FLICKER (first variety)
 212         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 213
 214         // 2 SLOW STRONG PULSE
 215         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 216
 217         // 3 CANDLE (first variety)
 218         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 219
 220         // 4 FAST STROBE
 221         lightstyle(4, "mamamamamama");
 222
 223         // 5 GENTLE PULSE 1
 224         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 225
 226         // 6 FLICKER (second variety)
 227         lightstyle(6, "nmonqnmomnmomomno");
 228
 229         // 7 CANDLE (second variety)
 230         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 231
 232         // 8 CANDLE (third variety)
 233         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 234
 235         // 9 SLOW STROBE (fourth variety)
 236         lightstyle(9, "aaaaaaaazzzzzzzz");
 237
 238         // 10 FLUORESCENT FLICKER
 239         lightstyle(10, "mmamammmmammamamaaamammma");
 240
 241         // 11 SLOW PULSE NOT FADE TO BLACK
 242         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 243
 244         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 245
 246         // 63 testing
 247         lightstyle(63, "a");
 248
 249         // for setting by mapinfo
 250         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 251         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 252
 253         player_count = 0;
 254         lms_lowest_lives = 0;
 255         lms_next_place = 0;
 256
 257         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 258         if(bot_waypoints_for_items == 1)
 259                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 260                         bot_waypoints_for_items = 0;
 261
 262         if(cvar("g_campaign"))
 263                 CampaignPreInit();
 264
 265         InitGameplayMode();
 266         readlevelcvars();
 267         precache();
 268
 269         WaypointSprite_Init();
 270
 271         //if (g_domination)
 272         //      dom_init();
 273
 274         GameLogInit(); // prepare everything
 275         if(cvar("sv_eventlog"))
 276         {
 277                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 278                 s = strcat(s, ftos(random()));
 279 #ifdef MAPINFO
 280                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s), FALSE);
 281 #else
 282                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 283 #endif
 284                 s = ":gameinfo:mutators:LIST";
 285                 if(cvar("g_grappling_hook"))
 286                         s = strcat(s, ":grappling_hook");
 287                 if(!cvar("g_use_ammunition"))
 288                         s = strcat(s, ":no_use_ammunition");
 289                 if(!cvar("g_pickup_items"))
 290                         s = strcat(s, ":no_pickup_items");
 291                 if(cvar("g_instagib"))
 292                         s = strcat(s, ":instagib");
 293                 if(cvar("g_rocketarena"))
 294                         s = strcat(s, ":rockerarena");
 295                 if(cvar("g_nixnex"))
 296                         s = strcat(s, ":nixnex");
 297                 if(cvar("g_vampire"))
 298                         s = strcat(s, ":vampire");
 299                 if(cvar("g_laserguided_missile"))
 300                         s = strcat(s, ":laserguided_missile");
 301                 if(cvar("g_norecoil"))
 302                         s = strcat(s, ":norecoil");
 303                 if(cvar("g_midair"))
 304                         s = strcat(s, ":midair");
 305                 if(cvar("g_minstagib"))
 306                         s = strcat(s, ":minstagib");
 307                 GameLogEcho(s, FALSE);
 308                 GameLogEcho(":gameinfo:end", FALSE);
 309         }
 310
 311         cvar_set("nextmap", "");
 312
 313         SetDefaultAlpha();
 314
 315         if(cvar("g_campaign"))
 316                 CampaignPostInit();
 317
 318         fteqcc_testbugs();
 319
 320         Ban_LoadBans();
 321
 322         //initialise globals related to sv_timeout
 323         sys_ticrate = cvar("sys_ticrate");
 324         orig_slowmo = cvar("slowmo");
 325
 326 #ifdef MAPINFO
 327         MapInfo_Enumerate();
 328         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1);
 329 #endif
 330
 331         //if tourney is used map starts in warmup mode. if this mode shall stay unlimited, reset timelimit, but save the original one
 332         if(g_tourney && cvar("g_tourney_warmup_unlimited_time")) {
 333                 timelimit_orig = cvar("timelimit");
 334                 cvar_set("timelimit", "0");
 335         }
 336
 337         fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 338         if(fd != -1)
 339         {
 340                 while((s = fgets(fd)))
 341                 {
 342                         l = tokenize(s);
 343                         if(l < 2)
 344                                 continue;
 345                         if(argv(0) != "fog")
 346                                 continue;
 347                         s = "";
 348                         while(l >= 2)
 349                         {
 350                                 --l;
 351                                 s = strcat(argv(l), " ", s);
 352                         }
 353                         s = substring(s, 0, strlen(s) - 1);
 354                         print("Found ^1DEPRECATED^7 fog command in .cfg file: ", s, "\n");
 355                         world.fog = strzone(s);
 356                 }
 357                 fclose(fd);
 358         }
 359
 360         next_pingtime = time + 5;
 361         world_initialized = 1;
 362 }
 363
 364 void spawnfunc_light (void)
 365 {
 366         //makestatic (self); // Who the f___ did that?
 367         remove(self);
 368 }
 369
 370 float TryFile( string pFilename )
 371 {
 372         local float lHandle;
 373         dprint("TryFile(\"", pFilename, "\")\n");
 374         lHandle = fopen( pFilename, FILE_READ );
 375         if( lHandle != -1 ) {
 376                 fclose( lHandle );
 377                 return TRUE;
 378         } else {
 379                 return FALSE;
 380         }
 381 };
 382
 383 string GetGametype()
 384 {
 385         if (game == GAME_DEATHMATCH)
 386                 return "dm";
 387         else if (game == GAME_TEAM_DEATHMATCH)
 388                 return "tdm";
 389         else if (game == GAME_DOMINATION)
 390                 return "dom";
 391         else if (game == GAME_CTF)
 392                 return "ctf";
 393         else if (game == GAME_RUNEMATCH)
 394                 return "rune";
 395         else if (game == GAME_LMS)
 396                 return "lms";
 397         else if (game == GAME_KEYHUNT)
 398                 return "kh";
 399         else if (game == GAME_ONSLAUGHT)
 400                 return "ons";
 401         else if (game == GAME_ASSAULT)
 402                 return "as";
 403         return "dm";
 404 }
 405
 406 float IsSameGametype(string mapcfgname)
 407 {
 408 #ifdef MAPINFO
 409         return TRUE; // can't change game type by map name here
 410 #else
 411         string gt;
 412         gt = GetGametype();
 413         if(substring(mapcfgname, 0, strlen(gt) + 1) == strcat(gt, "_"))
 414                 return TRUE;
 415         return FALSE;
 416 #endif
 417 }
 418
 419 string getmapname_stored;
 420 string GetMapname()
 421 {
 422 #ifdef MAPINFO
 423         return mapname;
 424 #else
 425         if(getmapname_stored == "")
 426                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 427         return getmapname_stored;
 428 #endif
 429 }
 430
 431 float Map_Count, Map_Current;
 432 string Map_Current_Name;
 433
 434 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 435 float GetMaplistPosition()
 436 {
 437         float pos, idx;
 438         string map;
 439
 440         map = GetMapname();
 441         idx = cvar("g_maplist_index");
 442
 443         if(idx >= 0)
 444                 if(idx < Map_Count)
 445                         if(map == argv(idx))
 446                                 return idx;
 447
 448         for(pos = 0; pos < Map_Count; ++pos)
 449                 if(map == argv(pos))
 450                         return pos;
 451
 452         // resume normal maplist rotation if current map is not in g_maplist
 453         return idx;
 454 }
 455
 456 float MapHasRightSize(string map)
 457 {
 458         float fh;
 459         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 460         if(cvar("g_maplist_check_waypoints"))
 461         {
 462                 dprint("checkwp "); dprint(map);
 463                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 464                 if(fh < 0)
 465                 {
 466                         dprint(": no waypoints\n");
 467                         return FALSE;
 468                 }
 469                 dprint(": has waypoints\n");
 470                 fclose(fh);
 471         }
 472
 473         // open map size restriction file
 474         dprint("opensize "); dprint(map);
 475         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 476         if(fh >= 0)
 477         {
 478                 float mapmin, mapmax;
 479                 dprint(": ok, ");
 480                 mapmin = stof(fgets(fh));
 481                 mapmax = stof(fgets(fh));
 482                 fclose(fh);
 483                 if(player_count < mapmin)
 484                 {
 485                         dprint("not enough\n");
 486                         return FALSE;
 487                 }
 488                 if(player_count > mapmax)
 489                 {
 490                         dprint("too many\n");
 491                         return FALSE;
 492                 }
 493                 dprint("right size\n");
 494                 return TRUE;
 495         }
 496         dprint(": not found\n");
 497         return TRUE;
 498 }
 499
 500 string Map_Filename(float position)
 501 {
 502 #ifdef MAPINFO
 503         return strcat("maps/", argv(position), ".bsp");
 504 #else
 505         return strcat("maps/", argv(position), ".mapcfg");
 506 #endif
 507 }
 508
 509 string strwords(string s, float w)
 510 {
 511         float endpos;
 512         for(endpos = 0; w && endpos >= 0; --w)
 513                 endpos = strstrofs(s, " ", endpos + 1);
 514         if(endpos < 0)
 515                 return s;
 516         else
 517                 return substring(s, 0, endpos);
 518 }
 519
 520 float strhasword(string s, string w)
 521 {
 522         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 523 }
 524
 525 void Map_MarkAsRecent(string m)
 526 {
 527         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 528 }
 529
 530 float Map_IsRecent(string m)
 531 {
 532         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 533 }
 534
 535 float Map_Check(float position, float pass)
 536 {
 537         string filename;
 538         string map_next;
 539         map_next = argv(position);
 540         if(pass <= 1)
 541         {
 542                 if(map_next == Map_Current_Name) // same map again in first pass?
 543                         return 0;
 544                 if(Map_IsRecent(map_next))
 545                         return 0;
 546         }
 547         filename = Map_Filename(position);
 548 #ifdef MAPINFO
 549         if(MapInfo_CheckMap(map_next))
 550 #else
 551         if(TryFile(filename))
 552 #endif
 553         {
 554                 if(pass == 2)
 555                         return 1;
 556                 if(MapHasRightSize(map_next))
 557                         return 1;
 558                 return 0;
 559         }
 560         else
 561                 dprint( "Couldn't select '", filename, "'..\n" );
 562
 563         return 0;
 564 }
 565
 566 void Map_Goto_SetStr(string nextmapname)
 567 {
 568         if(getmapname_stored != "")
 569                 strunzone(getmapname_stored);
 570         if(nextmapname == "")
 571                 getmapname_stored = "";
 572         else
 573                 getmapname_stored = strzone(nextmapname);
 574 }
 575
 576 void Map_Goto_SetFloat(float position)
 577 {
 578         cvar_set("g_maplist_index", ftos(position));
 579         Map_Goto_SetStr(argv(position));
 580 }
 581
 582 void GameResetCfg()
 583 {
 584 #ifdef MAPINFO
 585         // settings persist, except...
 586         if(cvar("g_campaign"))
 587                 localcmd("\nexec mutator_reset.cfg\n");
 588         localcmd("\nsettemp_restore\n");
 589 #else
 590         // if an exit cfg is defined by exiting map, exec it.
 591         string exit_cfg;
 592         exit_cfg = cvar_string("exit_cfg");
 593         if(exit_cfg != "")
 594                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 595
 596         localcmd("exec game_reset.cfg\n");
 597 #endif
 598 };
 599
 600 void Map_Goto()
 601 {
 602         Map_MarkAsRecent(getmapname_stored);
 603         GameResetCfg();
 604 #ifdef MAPINFO
 605         MapInfo_LoadMap(getmapname_stored);
 606 #else
 607         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 608 #endif
 609 }
 610
 611 // return codes of map selectors:
 612 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 613 //   -2 = permanent failure
 614 float() MaplistMethod_Iterate = // usual method
 615 {
 616         float pass, i;
 617
 618         for(pass = 1; pass <= 2; ++pass)
 619         {
 620                 for(i = 1; i < Map_Count; ++i)
 621                 {
 622                         float mapindex;
 623                         mapindex = mod(i + Map_Current, Map_Count);
 624                         if(Map_Check(mapindex, pass))
 625                                 return mapindex;
 626                 }
 627         }
 628         return -1;
 629 }
 630
 631 float() MaplistMethod_Repeat = // fallback method
 632 {
 633         if(Map_Check(Map_Current, 2))
 634                 return Map_Current;
 635         return -2;
 636 }
 637
 638 float() MaplistMethod_Random = // random map selection
 639 {
 640         float i, imax;
 641
 642         imax = 42;
 643
 644         for(i = 0; i <= imax; ++i)
 645         {
 646                 float mapindex;
 647                 mapindex = mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 648                 if(Map_Check(mapindex, 1))
 649                         return mapindex;
 650         }
 651         return -1;
 652 }
 653
 654 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 655 // the exponent sets a bias on the map selection:
 656 // the higher the exponent, the less likely "shortly repeated" same maps are
 657 {
 658         float i, j, imax, insertpos;
 659
 660         imax = 42;
 661
 662         for(i = 0; i <= imax; ++i)
 663         {
 664                 string newlist;
 665
 666                 // now reinsert this at another position
 667                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 668                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 669                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 670                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 671
 672                 // insert the current map there
 673                 newlist = "";
 674 #ifdef MAPINFO
 675                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 676                         newlist = strcat(newlist, " ", argv(j));
 677                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 678                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 679                         newlist = strcat(newlist, " ", argv(j));
 680                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 681 #else
 682                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 683                         newlist = strcat(newlist, "'", argv(j), "'");
 684                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 685                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 686                         newlist = strcat(newlist, "'", argv(j), "'");
 687 #endif
 688                 cvar_set("g_maplist", newlist);
 689 #ifdef MAPINFO
 690                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 691 #else
 692                 Map_Count = tokenize(newlist);
 693 #endif
 694
 695                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 696                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 697                 if(Map_Check(Map_Current, 1))
 698                         return Map_Current;
 699         }
 700         return -1;
 701 }
 702
 703 void Maplist_Init()
 704 {
 705         string temp;
 706         temp = cvar_string("g_maplist");
 707 #ifdef MAPINFO
 708         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 709 #else
 710         Map_Count = tokenize(temp);
 711 #endif
 712         if(Map_Count == 0)
 713         {
 714                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 715 #ifdef MAPINFO
 716                 cvar_set("g_maplist", temp = MapInfo_ListAllowedMaps());
 717                 localcmd("\nmenu_cmd sync\n");
 718                 Map_Count = tokenizebyseparator(temp, " ");
 719 #else
 720                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 721                 Map_Count = tokenize(temp);
 722 #endif
 723         }
 724         if(Map_Count == 0)
 725                 error("empty maplist, cannot select a new map");
 726         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 727
 728         if(Map_Current_Name)
 729                 strunzone(Map_Current_Name);
 730         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 731         // this may or may not be correct, but who cares, in the worst case a map
 732         // isn't chosen in the first pass that should have been
 733 }
 734
 735 string GetNextMap()
 736 {
 737         float nextMap;
 738
 739         Maplist_Init();
 740         nextMap = -1;
 741
 742         if(nextMap == -1)
 743                 if(cvar("g_maplist_shuffle") > 0)
 744                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 745
 746         if(nextMap == -1)
 747                 if(cvar("g_maplist_selectrandom"))
 748                         nextMap = MaplistMethod_Random();
 749
 750         if(nextMap == -1)
 751                 nextMap = MaplistMethod_Iterate();
 752
 753         if(nextMap == -1)
 754                 nextMap = MaplistMethod_Repeat();
 755
 756         if(nextMap >= 0)
 757         {
 758                 Map_Goto_SetFloat(nextMap);
 759                 return getmapname_stored;
 760         }
 761
 762         return "";
 763 };
 764
 765 float DoNextMapOverride()
 766 {
 767         if(cvar("g_campaign"))
 768         {
 769                 CampaignPostIntermission();
 770                 alreadychangedlevel = TRUE;
 771                 return TRUE;
 772         }
 773         if(cvar("quit_when_empty"))
 774         {
 775                 if(player_count <= currentbots)
 776                 {
 777                         localcmd("quit\n");
 778                         alreadychangedlevel = TRUE;
 779                         return TRUE;
 780                 }
 781         }
 782         if(cvar_string("quit_and_redirect") != "")
 783         {
 784                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 785                 alreadychangedlevel = TRUE;
 786                 return TRUE;
 787         }
 788         if (cvar("samelevel")) // if samelevel is set, stay on same level
 789         {
 790                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 791                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 792                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 793                 localcmd("restart\n");
 794                 //changelevel (mapname);
 795                 alreadychangedlevel = TRUE;
 796                 return TRUE;
 797         }
 798         if(cvar_string("nextmap") != "")
 799 #ifdef MAPINFO
 800                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 801 #else
 802                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 803 #endif
 804                 {
 805                         Map_Goto_SetStr(cvar_string("nextmap"));
 806                         Map_Goto();
 807                         alreadychangedlevel = TRUE;
 808                         return TRUE;
 809                 }
 810         if(cvar("lastlevel"))
 811         {
 812                 GameResetCfg();
 813                 localcmd("set lastlevel 0\ntogglemenu\n");
 814                 alreadychangedlevel = TRUE;
 815                 return TRUE;
 816         }
 817         return FALSE;
 818 };
 819
 820 void GotoNextMap()
 821 {
 822         //local string nextmap;
 823         //local float n, nummaps;
 824         //local string s;
 825         if (alreadychangedlevel)
 826                 return;
 827         alreadychangedlevel = TRUE;
 828
 829         {
 830                 string nextMap;
 831                 float allowReset;
 832
 833                 for(allowReset = 1; allowReset >= 0; --allowReset)
 834                 {
 835                         nextMap = GetNextMap();
 836                         if(nextMap != "")
 837                                 break;
 838
 839                         if(allowReset)
 840                         {
 841                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 842 #ifdef MAPINFO
 843                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
 844                                 localcmd("\nmenu_cmd sync\n");
 845 #else
 846                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 847 #endif
 848                         }
 849                         else
 850                         {
 851                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 852                         }
 853                 }
 854                 Map_Goto();
 855         }
 856 };
 857
 858
 859 /*
 860 ============
 861 IntermissionThink
 862
 863 When the player presses attack or jump, change to the next level
 864 ============
 865 */
 866 .float autoscreenshot;
 867 void() MapVote_Start;
 868 void() MapVote_Think;
 869 float mapvote_initialized;
 870 void IntermissionThink()
 871 {
 872         FixIntermissionClient(self);
 873
 874         if(cvar("sv_autoscreenshot"))
 875         if(self.autoscreenshot > 0)
 876         if(time > self.autoscreenshot)
 877         {
 878                 self.autoscreenshot = -1;
 879                 if(clienttype(self) == CLIENTTYPE_REAL)
 880                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 881                 return;
 882         }
 883
 884         if (time < intermission_exittime)
 885                 return;
 886
 887         if(!mapvote_initialized)
 888                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 889                         return;
 890
 891         MapVote_Start();
 892 };
 893
 894 /*
 895 ============
 896 FindIntermission
 897
 898 Returns the entity to view from
 899 ============
 900 */
 901 /*
 902 entity FindIntermission()
 903 {
 904         local   entity spot;
 905         local   float cyc;
 906
 907 // look for info_intermission first
 908         spot = find (world, classname, "info_intermission");
 909         if (spot)
 910         {       // pick a random one
 911                 cyc = random() * 4;
 912                 while (cyc > 1)
 913                 {
 914                         spot = find (spot, classname, "info_intermission");
 915                         if (!spot)
 916                                 spot = find (spot, classname, "info_intermission");
 917                         cyc = cyc - 1;
 918                 }
 919                 return spot;
 920         }
 921
 922 // then look for the start position
 923         spot = find (world, classname, "info_player_start");
 924         if (spot)
 925                 return spot;
 926
 927 // testinfo_player_start is only found in regioned levels
 928         spot = find (world, classname, "testplayerstart");
 929         if (spot)
 930                 return spot;
 931
 932 // then look for the start position
 933         spot = find (world, classname, "info_player_deathmatch");
 934         if (spot)
 935                 return spot;
 936
 937         //objerror ("FindIntermission: no spot");
 938         return world;
 939 };
 940 */
 941
 942 /*
 943 ===============================================================================
 944
 945 RULES
 946
 947 ===============================================================================
 948 */
 949
 950 void DumpStats(float final)
 951 {
 952         local float file;
 953         local string s;
 954         local float to_console;
 955         local float to_eventlog;
 956         local float to_file;
 957
 958         to_console = cvar("sv_logscores_console");
 959         to_eventlog = cvar("sv_eventlog");
 960         to_file = cvar("sv_logscores_file");
 961
 962         if(!final)
 963         {
 964                 to_console = TRUE; // always print printstats replies
 965                 to_eventlog = FALSE; // but never print them to the event log
 966         }
 967
 968         if(to_eventlog)
 969                 if(cvar("sv_eventlog_console"))
 970                         to_console = FALSE; // otherwise we get the output twice
 971
 972         if(final)
 973                 s = ":scores:";
 974         else
 975                 s = ":status:";
 976 #ifdef MAPINFO
 977         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
 978 #else
 979         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 980 #endif
 981
 982         if(to_console)
 983                 ServerConsoleEcho(s, FALSE);
 984         if(to_eventlog)
 985                 GameLogEcho(s, FALSE);
 986         if(to_file)
 987         {
 988                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 989                 if(file == -1)
 990                         to_file = FALSE;
 991                 else
 992                         fputs(file, strcat(s, "\n"));
 993         }
 994
 995         FOR_EACH_CLIENT(other)
 996         {
 997                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 998                 {
 999                         s = strcat(":player:", ftos(other.frags), ":");
1000                         s = strcat(s, ftos(other.deaths), ":");
1001                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1002                         s = strcat(s, ftos(other.team), ":");
1003
1004                         if(to_console)
1005                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
1006                         if(to_eventlog)
1007                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
1008                         if(to_file)
1009                                 fputs(file, strcat(s, other.netname, "\n"));
1010                 }
1011         }
1012
1013         if(g_ctf)
1014         if(cvar("g_ctf_win_mode") != 2)
1015         {
1016                 s = strcat(":teamscores:", ftos(COLOR_TEAM1), ":");
1017                 s = strcat(s, ftos(caps_team1), ":");
1018                 s = strcat(s, ftos(COLOR_TEAM2), ":");
1019                 s = strcat(s, ftos(caps_team2));
1020                 if(to_console)
1021                         ServerConsoleEcho(s, TRUE);
1022                 if(to_eventlog)
1023                         GameLogEcho(s, TRUE);
1024                 if(to_file)
1025                         fputs(file, strcat(s, "\n"));
1026         }
1027
1028         if(to_console)
1029                 ServerConsoleEcho(":end", FALSE);
1030         if(to_eventlog)
1031                 GameLogEcho(":end", FALSE);
1032         if(to_file)
1033         {
1034                 fputs(file, ":end\n");
1035                 fclose(file);
1036         }
1037 }
1038
1039 void FixIntermissionClient(entity e)
1040 {
1041         string s;
1042         if(!e.autoscreenshot) // initial call
1043         {
1044                 e.angles = e.v_angle;
1045                 e.angles_x = -e.angles_x;
1046                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1047                 e.health = -2342;
1048                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1049                 e.solid = SOLID_NOT;
1050                 e.movetype = MOVETYPE_NONE;
1051                 e.takedamage = DAMAGE_NO;
1052                 if(e.weaponentity)
1053                         e.weaponentity.effects = EF_NODRAW;
1054                 if(clienttype(e) == CLIENTTYPE_REAL)
1055                 {
1056                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1057                         s = cvar_string("sv_intermission_cdtrack");
1058                         if(s != "")
1059                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1060                         msg_entity = e;
1061                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1062                 }
1063         }
1064
1065         //e.velocity = '0 0 0';
1066         //e.fixangle = TRUE;
1067
1068         // TODO halt weapon animation
1069 }
1070
1071
1072 /*
1073 go to the next level for deathmatch
1074 only called if a time or frag limit has expired
1075 */
1076 void NextLevel()
1077 {
1078         float minTotalFrags;
1079         float maxTotalFrags;
1080         float score;
1081         float f;
1082
1083         gameover = TRUE;
1084
1085         intermission_running = 1;
1086
1087 // enforce a wait time before allowing changelevel
1088         if(player_count > 0)
1089                 intermission_exittime = time + cvar("sv_mapchange_delay");
1090         else
1091                 intermission_exittime = -1;
1092
1093         /*
1094         WriteByte (MSG_ALL, SVC_CDTRACK);
1095         WriteByte (MSG_ALL, 3);
1096         WriteByte (MSG_ALL, 3);
1097         // done in FixIntermission
1098         */
1099
1100         //pos = FindIntermission ();
1101
1102         VoteReset();
1103
1104         DumpStats(TRUE);
1105
1106         if(cvar("sv_eventlog"))
1107                 GameLogEcho(":gameover", FALSE);
1108
1109         GameLogClose();
1110
1111         FOR_EACH_CLIENT(other)
1112         {
1113                 FixIntermissionClient(other);
1114
1115                 if(other.winning)
1116                         bprint(other.netname, " ^7wins.\n");
1117         }
1118
1119         minTotalFrags = 0;
1120         maxTotalFrags = 0;
1121         FOR_EACH_PLAYER(other)
1122         {
1123                 if(maxTotalFrags < other.totalfrags)
1124                         maxTotalFrags = other.totalfrags;
1125                 if(minTotalFrags > other.totalfrags)
1126                         minTotalFrags = other.totalfrags;
1127         }
1128
1129         if(!currentbots)
1130         {
1131                 FOR_EACH_PLAYER(other)
1132                 {
1133                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1134                         f = bound(0, other.play_time / max(time, 1), 1);
1135                         // store some statistics?
1136                 }
1137         }
1138
1139         if(cvar("g_campaign"))
1140                 CampaignPreIntermission();
1141
1142         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1143 };
1144
1145 /*
1146 ============
1147 CheckRules_Player
1148
1149 Exit deathmatch games upon conditions
1150 ============
1151 */
1152 .float fogtime;
1153 void CheckRules_Player()
1154 {
1155         if (gameover)   // someone else quit the game already
1156                 return;
1157
1158         if(self.deadflag == DEAD_NO)
1159                 self.play_time += frametime;
1160
1161         if(sv_foginterval)
1162         if(world.fog)
1163         if(time > self.fogtime)
1164         {
1165                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1166                 self.fogtime = time + sv_foginterval;
1167         }
1168
1169         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1170         //   (div0: and that in CheckRules_World please)
1171 };
1172
1173 float checkrules_oneminutewarning;
1174 float checkrules_leaderfrags;
1175 float tdm_max_score, tdm_old_score;
1176
1177 float checkrules_equality;
1178 float checkrules_overtimewarning;
1179 float checkrules_overtimeend;
1180
1181 void InitiateOvertime()
1182 {
1183         if(!checkrules_overtimeend)
1184                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1185 }
1186
1187 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1188 float WINNING_YES = 1; // winner found
1189 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1190 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1191
1192 float GetWinningCode(float fraglimitreached, float equality)
1193 {
1194         if(equality)
1195                 if(fraglimitreached)
1196                         return WINNING_STARTOVERTIME;
1197                 else
1198                         return WINNING_NEVER;
1199         else
1200                 if(fraglimitreached)
1201                         return WINNING_YES;
1202                 else
1203                         return WINNING_NO;
1204 }
1205
1206 // set the .winning flag for exactly those players with a given field value
1207 void SetWinners(.float field, float value)
1208 {
1209         entity head;
1210         FOR_EACH_PLAYER(head)
1211                 head.winning = (head.field == value);
1212 }
1213
1214 // set the .winning flag for those players with a given field value
1215 void AddWinners(.float field, float value)
1216 {
1217         entity head;
1218         FOR_EACH_PLAYER(head)
1219                 if(head.field == value)
1220                         head.winning = 1;
1221 }
1222
1223 // clear frags for all players but the team given (when they ran out of spawnpoints)
1224 void ClearFragsForEveryoneBut(.float field, float value)
1225 {
1226         entity head;
1227         FOR_EACH_PLAYER(head)
1228                 if(head.field != value)
1229                         head.frags = max(head.frags, 0);
1230 }
1231
1232 // clear the .winning flags
1233 void ClearWinners(void)
1234 {
1235         entity head;
1236         FOR_EACH_PLAYER(head)
1237                 head.winning = 0;
1238 }
1239
1240 // Onslaught winning condition:
1241 // game terminates if only one team has a working generator (or none)
1242 float WinningCondition_Onslaught()
1243 {
1244         entity head;
1245         local float t1, t2, t3, t4;
1246         // first check if the game has ended
1247         t1 = t2 = t3 = t4 = 0;
1248         head = find(world, classname, "onslaught_generator");
1249         while (head)
1250         {
1251                 if (head.health > 0)
1252                 {
1253                         if (head.team == COLOR_TEAM1) t1 = 1;
1254                         if (head.team == COLOR_TEAM2) t2 = 1;
1255                         if (head.team == COLOR_TEAM3) t3 = 1;
1256                         if (head.team == COLOR_TEAM4) t4 = 1;
1257                 }
1258                 head = find(head, classname, "onslaught_generator");
1259         }
1260         if (t1 + t2 + t3 + t4 < 2)
1261         {
1262                 // game over, only one team remains (or none)
1263                 ClearWinners();
1264                 if (t1) SetWinners(team, COLOR_TEAM1);
1265                 if (t2) SetWinners(team, COLOR_TEAM2);
1266                 if (t3) SetWinners(team, COLOR_TEAM3);
1267                 if (t4) SetWinners(team, COLOR_TEAM4);
1268                 dprint("Have a winner, ending game.\n");
1269                 return WINNING_YES;
1270         }
1271
1272         // Two or more teams remain
1273         return WINNING_NO;
1274 }
1275
1276 float LMS_NewPlayerLives()
1277 {
1278         float fl;
1279         fl = cvar("fraglimit");
1280         if(fl == 0)
1281                 fl = 999;
1282
1283         // first player has left the game for dying too much? Nobody else can get in.
1284         if(lms_lowest_lives < 1)
1285                 return FALSE;
1286
1287         if(!cvar("g_lms_join_anytime"))
1288                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1289                         return FALSE;
1290
1291         return bound(1, lms_lowest_lives, fl);
1292 }
1293
1294 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1295 // they win. Otherwise the defending team wins once the timelimit passes.
1296 void assault_new_round();
1297 float WinningCondition_Assault()
1298 {
1299         local float status;
1300         status = WINNING_NO;
1301
1302         // as the timelimit has not yet passed just assume the defending team will win
1303         if(assault_attacker_team == COLOR_TEAM1)
1304         {
1305                 SetWinners(team, COLOR_TEAM2);
1306         }
1307         else
1308         {
1309                 SetWinners(team, COLOR_TEAM1);
1310         }
1311
1312         local entity ent;
1313         ent = find(world, classname, "target_assault_roundend");
1314         if(ent)
1315         {
1316                 if(ent.winning) // round end has been triggered by attacking team
1317                 {
1318                         SetWinners(team, assault_attacker_team);
1319                         if(assault_attacker_team == COLOR_TEAM1)
1320                         {
1321                                 team1_score = team1_score + 50;
1322                         }
1323                         else
1324                         {
1325                                 team2_score = team2_score + 50;
1326                         }
1327
1328                         if(ent.cnt == 1) // this was the second round
1329                         {
1330                                 status = WINNING_YES;
1331                         }
1332                         else
1333                         {
1334                                 local entity oldself;
1335                                 oldself = self;
1336                                 self = ent;
1337                                 cvar_set("timelimit", ftos((2*time)/60));
1338                                 assault_new_round();
1339                                 self = oldself;
1340                         }
1341                 }
1342         }
1343
1344         return status;
1345
1346 }
1347
1348
1349 // LMS winning condition: game terminates if and only if there's at most one
1350 // one player who's living lives. Top two scores being equal cancels the time
1351 // limit.
1352 float WinningCondition_LMS()
1353 {
1354         entity head;
1355         float have_player;
1356         float have_players;
1357         float l;
1358
1359         have_player = FALSE;
1360         have_players = FALSE;
1361         l = LMS_NewPlayerLives();
1362
1363         head = find(world, classname, "player");
1364         if(head)
1365                 have_player = TRUE;
1366         head = find(head, classname, "player");
1367         if(head)
1368                 have_players = TRUE;
1369
1370         if(have_player)
1371         {
1372                 // we have at least one player
1373                 if(have_players)
1374                 {
1375                         // two or more active players - continue with the game
1376                 }
1377                 else
1378                 {
1379                         // exactly one player?
1380                         if(l)
1381                         {
1382                                 // but no game has taken place yet
1383                         }
1384                         else
1385                         {
1386                                 // a winner!
1387                                 ClearWinners(); SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1388                                 dprint("Have a winner, ending game.\n");
1389                                 return WINNING_YES;
1390                         }
1391                 }
1392         }
1393         else
1394         {
1395                 // nobody is playing at all...
1396                 if(l)
1397                 {
1398                         // wait for players...
1399                 }
1400                 else
1401                 {
1402                         // SNAFU (maybe a draw game?)
1403                         ClearWinners();
1404                         dprint("No players, ending game.\n");
1405                         return WINNING_YES;
1406                 }
1407         }
1408
1409         // When we get here, we have at least two players who are actually LIVING,
1410         // or one player who is still waiting for a victim to join the server. Now
1411         // check if the top two players have equal score.
1412
1413         checkrules_leaderfrags = 0;
1414         checkrules_equality = FALSE;
1415         FOR_EACH_PLAYER(head)
1416         {
1417                 if(head.frags > checkrules_leaderfrags)
1418                 {
1419                         checkrules_leaderfrags = head.frags;
1420                         checkrules_equality = FALSE;
1421                 }
1422                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1423                         checkrules_equality = TRUE;
1424         }
1425
1426         SetWinners(frags, checkrules_leaderfrags);
1427
1428         // The top two players have the same amount of lives? No timelimit then,
1429         // enter overtime...
1430
1431         if(checkrules_equality)
1432                 return WINNING_NEVER;
1433
1434         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1435         return WINNING_NO;
1436 }
1437
1438 // DM winning condition: game terminates if a player reached the fraglimit,
1439 // unless the first two players have the same score. The latter case also
1440 // breaks the time limit.
1441 float WinningCondition_MaxIndividualScore(float fraglimit)
1442 {
1443         float checkrules_oldleaderfrags;
1444         entity head;
1445
1446         checkrules_oldleaderfrags = checkrules_leaderfrags;
1447         checkrules_leaderfrags = 0;
1448         checkrules_equality = FALSE;
1449         FOR_EACH_PLAYER(head)
1450         {
1451                 if(head.frags > checkrules_leaderfrags)
1452                 {
1453                         checkrules_leaderfrags = head.frags;
1454                         checkrules_equality = FALSE;
1455                 }
1456                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
1457                         checkrules_equality = TRUE;
1458         }
1459
1460         if(checkrules_leaderfrags > 0)
1461                 SetWinners(frags, checkrules_leaderfrags);
1462         else
1463                 ClearWinners();
1464
1465         if (!g_runematch)
1466                 if (checkrules_leaderfrags != checkrules_oldleaderfrags)
1467                 {
1468                         if (checkrules_leaderfrags == fraglimit - 1)
1469                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.wav", 1, ATTN_NONE);
1470                         else if (checkrules_leaderfrags == fraglimit - 2)
1471                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.wav", 1, ATTN_NONE);
1472                         else if (checkrules_leaderfrags == fraglimit - 3)
1473                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.wav", 1, ATTN_NONE);
1474                 }
1475
1476         return GetWinningCode(fraglimit && checkrules_leaderfrags >= fraglimit, checkrules_equality);
1477 }
1478
1479 float WinningConditionBase_Teamplay(float fraglimit)
1480 {
1481         tdm_old_score = tdm_max_score;
1482         tdm_max_score = max4(team1_score, team2_score, team3_score, team4_score);
1483
1484         checkrules_equality =
1485         (
1486                 (tdm_max_score > 0)
1487                 &&
1488                 (
1489                           (team1_score == tdm_max_score)
1490                         + (team2_score == tdm_max_score)
1491                         + (team3_score == tdm_max_score)
1492                         + (team4_score == tdm_max_score)
1493                         >= 2));
1494
1495         ClearWinners();
1496         if(tdm_max_score > 0)
1497         {
1498                 if(team1_score == tdm_max_score)
1499                         AddWinners(team, COLOR_TEAM1);
1500                 if(team2_score == tdm_max_score)
1501                         AddWinners(team, COLOR_TEAM2);
1502                 if(team3_score == tdm_max_score)
1503                         AddWinners(team, COLOR_TEAM3);
1504                 if(team4_score == tdm_max_score)
1505                         AddWinners(team, COLOR_TEAM4);
1506         }
1507
1508         if(!g_runematch && !g_domination && !g_ctf)
1509                 if(tdm_max_score != tdm_old_score)
1510                 {
1511                         if(tdm_max_score == fraglimit - 1)
1512                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.wav", 1, ATTN_NONE);
1513                         else if(tdm_max_score == fraglimit - 2)
1514                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.wav", 1, ATTN_NONE);
1515                         else if(tdm_max_score == fraglimit - 3)
1516                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.wav", 1, ATTN_NONE);
1517                 }
1518
1519         return GetWinningCode(fraglimit && tdm_max_score >= fraglimit, checkrules_equality);
1520 }
1521
1522 // TDM winning condition: game terminates if a team's score sum reached the
1523 // fraglimit, unless the first two teams have the same total score. The latter
1524 // case also breaks the time limit.
1525 float WinningCondition_MaxTeamSum(float fraglimit)
1526 {
1527         entity head;
1528
1529         team1_score = team2_score = team3_score = team4_score = 0;
1530
1531         FOR_EACH_PLAYER(head)
1532         {
1533                 if(head.team == COLOR_TEAM1)
1534                         team1_score += head.frags;
1535                 else if(head.team == COLOR_TEAM2)
1536                         team2_score += head.frags;
1537                 else if(head.team == COLOR_TEAM3)
1538                         team3_score += head.frags;
1539                 else if(head.team == COLOR_TEAM4)
1540                         team4_score += head.frags;
1541         }
1542
1543         return WinningConditionBase_Teamplay(fraglimit);
1544 }
1545
1546 // DOM/CTF winning condition: game terminates if the max of a team's players'
1547 // score reached the fraglimit, unless the first two teams have the same
1548 // maximum score. The latter case also breaks the time limit.
1549 float WinningCondition_MaxTeamMax(float fraglimit)
1550 {
1551         entity head;
1552
1553         team1_score = team2_score = team3_score = team4_score = 0;
1554
1555         FOR_EACH_PLAYER(head)
1556         {
1557                 if(head.team == COLOR_TEAM1)
1558                 {
1559                         if(head.frags > team1_score)
1560                                 team1_score = head.frags;
1561                 }
1562                 else if(head.team == COLOR_TEAM2)
1563                 {
1564                         if(head.frags > team2_score)
1565                                 team2_score = head.frags;
1566                 }
1567                 else if(head.team == COLOR_TEAM3)
1568                 {
1569                         if(head.frags > team3_score)
1570                                 team3_score = head.frags;
1571                 }
1572                 else if(head.team == COLOR_TEAM4)
1573                 {
1574                         if(head.frags > team4_score)
1575                                 team4_score = head.frags;
1576                 }
1577         }
1578
1579         return WinningConditionBase_Teamplay(fraglimit);
1580 }
1581
1582 float WinningCondition_CTF(float capturelimit, float fraglimit)
1583 {
1584         if(cvar("g_ctf_win_mode") == 2)
1585                 return WinningCondition_MaxTeamSum(fraglimit);
1586
1587         team1_score = caps_team1;
1588         team2_score = caps_team2;
1589         team3_score = team4_score = 0;
1590
1591         if(team1_score == team2_score && cvar("g_ctf_win_mode"))
1592         {
1593                 return WinningCondition_MaxTeamSum(0);
1594         }
1595
1596         return WinningConditionBase_Teamplay(capturelimit);
1597 }
1598
1599 void print_to(entity e, string s)
1600 {
1601         if(e)
1602                 sprint(e, strcat(s, "\n"));
1603         else
1604                 ServerConsoleEcho(s, TRUE);
1605 }
1606
1607 void PrintScoreboardFor(entity e, string name, string colorcode, float whichteam)
1608 {
1609         entity head;
1610         float v;
1611         float teamvalue;
1612         float fragtotal;
1613         string s;
1614         float found;
1615         found = FALSE;
1616         teamvalue = 0;
1617         FOR_EACH_PLAYER(head)
1618         {
1619                 if(!whichteam || head.team == whichteam)
1620                 {
1621                         if(name != "")
1622                                 if(!found)
1623                                         print_to(e, strcat(" ", colorcode, name, ":"));
1624                         found = TRUE;
1625                         fragtotal = fragtotal + head.frags;
1626                         s = ftos(head.frags);
1627                         s = strcat(s, "/", ftos(head.deaths));
1628                         s = strcat(s, " @ ", ftos(head.ping));
1629                         if(clienttype(head) == CLIENTTYPE_BOT)
1630                                 s = strcat(s, "botms");
1631                         else
1632                                 s = strcat(s, "ms");
1633                         v = PlayerValue(head);
1634                         teamvalue += v;
1635                         s = strcat(s, " / ", ftos(v));
1636                         print_to(e, strcat("  ", colorcode, head.netname, colorcode, " (", s, ")"));
1637                 }
1638         }
1639         if(whichteam && found)
1640         {
1641                 s = ftos(fragtotal);
1642                 s = strcat(s, " / ", ftos(teamvalue));
1643                 print_to(e, strcat(colorcode, "  (total: ", s, ")"));
1644         }
1645 }
1646
1647 void PrintScoreboard(entity e)
1648 {
1649         print_to(e, strcat("Time:      ", ftos(time / 60)));
1650         print_to(e, strcat("Timelimit: ", ftos(cvar("timelimit"))));
1651         print_to(e, strcat("Fraglimit: ", ftos(cvar("fraglimit"))));
1652         print_to(e, "Scoreboard:");
1653         if(teams_matter)
1654         {
1655                 PrintScoreboardFor(e, "Red", "^1", COLOR_TEAM1);
1656                 PrintScoreboardFor(e, "Blue", "^4", COLOR_TEAM2);
1657                 PrintScoreboardFor(e, "Yellow", "^3", COLOR_TEAM3);
1658                 PrintScoreboardFor(e, "Pink", "^6", COLOR_TEAM4);
1659         }
1660         else
1661         {
1662                 PrintScoreboardFor(e, "", "^7", 0);
1663         }
1664         print_to(e, ".");
1665 }
1666
1667 void ShuffleMaplist()
1668 {
1669         string result;
1670         float start;
1671         float litems;
1672         float selected;
1673         float i;
1674
1675         result = cvar_string("g_maplist");
1676 #ifdef MAPINFO
1677         litems = tokenizebyseparator(result, " ");
1678 #else
1679         litems = tokenize(result);
1680 #endif
1681
1682         for(start = 0; start < litems - 1; ++start)
1683         {
1684                 result = "";
1685
1686                 // select a random item
1687                 selected = ceil(random() * (litems - start) + start) - 1;
1688
1689                 // shift this item to the place start
1690 #ifdef MAPINFO
1691                 for(i = 0; i < start; ++i)
1692                         result = strcat(result, " ", argv(i));
1693                 result = strcat(result, " ", argv(selected));
1694                 for(i = start; i < litems; ++i)
1695                         if(i != selected)
1696                                 result = strcat(result, " ", argv(i));
1697                 result = substring(result, 1, strlen(result) - 1);
1698
1699                 litems = tokenizebyseparator(result, " ");
1700 #else
1701                 for(i = 0; i < start; ++i)
1702                         result = strcat(result, "'", argv(i), "'");
1703                 result = strcat(result, "'", argv(selected), "'");
1704                 for(i = start; i < litems; ++i)
1705                         if(i != selected)
1706                                 result = strcat(result, "'", argv(i), "'");
1707
1708                 litems = tokenize(result);
1709 #endif
1710
1711                 //dprint(result, "\n");
1712         }
1713
1714         cvar_set("g_maplist", result);
1715 }
1716
1717 float WinningCondition_RanOutOfSpawns()
1718 {
1719         entity head;
1720
1721         if(!have_team_spawns)
1722                 return WINNING_NO;
1723
1724         if(!some_spawn_has_been_used)
1725                 return WINNING_NO;
1726
1727         team1_score = team2_score = team3_score = team4_score = 0;
1728
1729         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1730         {
1731                 if(head.team == COLOR_TEAM1)
1732                         team1_score = 1;
1733                 else if(head.team == COLOR_TEAM2)
1734                         team2_score = 1;
1735                 else if(head.team == COLOR_TEAM3)
1736                         team3_score = 1;
1737                 else if(head.team == COLOR_TEAM4)
1738                         team4_score = 1;
1739         }
1740
1741         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1742         {
1743                 if(head.team == COLOR_TEAM1)
1744                         team1_score = 1;
1745                 else if(head.team == COLOR_TEAM2)
1746                         team2_score = 1;
1747                 else if(head.team == COLOR_TEAM3)
1748                         team3_score = 1;
1749                 else if(head.team == COLOR_TEAM4)
1750                         team4_score = 1;
1751         }
1752
1753         ClearWinners();
1754         if(team1_score + team2_score + team3_score + team4_score == 0)
1755         {
1756                 checkrules_equality = TRUE;
1757                 return WINNING_YES;
1758         }
1759         else if(team1_score + team2_score + team3_score + team4_score == 1)
1760         {
1761                 if(team1_score)
1762                 {
1763                         AddWinners(team, COLOR_TEAM1);
1764                         ClearFragsForEveryoneBut(team, COLOR_TEAM1);
1765                 }
1766                 if(team2_score)
1767                 {
1768                         AddWinners(team, COLOR_TEAM2);
1769                         ClearFragsForEveryoneBut(team, COLOR_TEAM2);
1770                 }
1771                 if(team3_score)
1772                 {
1773                         AddWinners(team, COLOR_TEAM3);
1774                         ClearFragsForEveryoneBut(team, COLOR_TEAM3);
1775                 }
1776                 if(team4_score)
1777                 {
1778                         AddWinners(team, COLOR_TEAM4);
1779                         ClearFragsForEveryoneBut(team, COLOR_TEAM4);
1780                 }
1781                 return WINNING_YES;
1782         }
1783         else
1784                 return WINNING_NO;
1785 }
1786
1787 /*
1788 ============
1789 CheckRules_World
1790
1791 Exit deathmatch games upon conditions
1792 ============
1793 */
1794 void CheckRules_World()
1795 {
1796         local float status;
1797         local float timelimit;
1798         local float fraglimit;
1799         local float capturelimit;
1800
1801         VoteThink();
1802         MapVote_Think();
1803
1804         SetDefaultAlpha();
1805
1806         /*
1807         MapVote_Think should now do that part
1808         if (intermission_running)
1809                 if (time >= intermission_exittime + 60)
1810                 {
1811                         if(!DoNextMapOverride())
1812                                 GotoNextMap();
1813                         return;
1814                 }
1815         */
1816
1817         if (gameover)   // someone else quit the game already
1818         {
1819                 if(player_count == 0) // Nobody there? Then let's go to the next map
1820                         MapVote_Start();
1821                         // this will actually check the player count in the next frame
1822                         // again, but this shouldn't hurt
1823                 return;
1824         }
1825
1826         timelimit = cvar("timelimit") * 60;
1827         fraglimit = cvar("fraglimit");
1828         capturelimit = cvar("capturelimit");
1829
1830         if(checkrules_overtimeend)
1831         {
1832                 if(!checkrules_overtimewarning)
1833                 {
1834                         checkrules_overtimewarning = TRUE;
1835                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1836                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1837                 }
1838         }
1839         else
1840         {
1841                 if (timelimit && time >= timelimit)
1842                         InitiateOvertime();
1843         }
1844
1845         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1846         {
1847                 NextLevel();
1848                 return;
1849         }
1850
1851         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1852         {
1853                 checkrules_oneminutewarning = TRUE;
1854                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", 1, ATTN_NONE);
1855         }
1856
1857         status = WinningCondition_RanOutOfSpawns();
1858         if(status == WINNING_YES)
1859         {
1860                 bprint("Hey! Someone ran out of spawns!\n");
1861         }
1862         else if(g_assault)
1863         {
1864                 status = WinningCondition_Assault();
1865         }
1866         else if(g_lms)
1867         {
1868                 status = WinningCondition_LMS();
1869         }
1870         else if (g_onslaught)
1871         {
1872                 status = WinningCondition_Onslaught();
1873         }
1874         else if(g_ctf)
1875         {
1876                 status = WinningCondition_CTF(capturelimit, fraglimit);
1877         }
1878         else
1879         {
1880                 if(teams_matter)
1881                 {
1882                         if(g_tdm || g_runematch || g_ctf || g_domination || g_keyhunt)
1883                                 status = WinningCondition_MaxTeamSum(fraglimit);
1884                         //else if()
1885                         //      status = WinningCondition_MaxTeamMax(fraglimit);
1886                         else
1887                         {
1888                                 dprint("div0: How can this happen?\n");
1889                                 status = WinningCondition_MaxTeamMax(fraglimit);
1890                         }
1891                 }
1892                 else
1893                         status = WinningCondition_MaxIndividualScore(fraglimit);
1894         }
1895
1896         if(status == WINNING_STARTOVERTIME)
1897         {
1898                 status = WINNING_NEVER;
1899                 InitiateOvertime();
1900         }
1901
1902         if(status == WINNING_NEVER)
1903                 // equality cases! Nobody wins if the overtime ends in a draw.
1904                 ClearWinners();
1905
1906         if(checkrules_overtimeend)
1907                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1908                         status = WINNING_YES;
1909
1910         if(status == WINNING_YES)
1911                 NextLevel();
1912 };
1913
1914 float mapvote_nextthink;
1915 float mapvote_initialized;
1916 float mapvote_keeptwotime;
1917 float mapvote_timeout;
1918 string mapvote_message;
1919 string mapvote_screenshot_dir;
1920
1921 float mapvote_count;
1922 float mapvote_count_real;
1923 string mapvote_maps[MAPVOTE_COUNT];
1924 float mapvote_maps_suggested[MAPVOTE_COUNT];
1925 string mapvote_suggestions[MAPVOTE_COUNT];
1926 float mapvote_suggestion_ptr;
1927 float mapvote_maxlen;
1928 float mapvote_voters;
1929 float mapvote_votes[MAPVOTE_COUNT];
1930 float mapvote_run;
1931 float mapvote_detail;
1932 float mapvote_abstain;
1933 float mapvote_dirty;
1934 .float mapvote;
1935
1936 void MapVote_ClearAllVotes()
1937 {
1938         FOR_EACH_CLIENT(other)
1939                 other.mapvote = 0;
1940 }
1941
1942 string MapVote_Suggest(string m)
1943 {
1944         float i;
1945         if(m == "")
1946                 return "That's not how to use this command.";
1947         if(!cvar("g_maplist_votable_suggestions"))
1948                 return "Suggestions are not accepted on this server.";
1949         if(mapvote_initialized)
1950                 return "Can't suggest - voting is already in progress!";
1951 #ifdef MAPINFO
1952         m = MapInfo_FixName(m);
1953         if(!m)
1954                 return "The map you suggested is not available on this server.";
1955 #else
1956         if(!cvar("g_maplist_votable_suggestions_change_gametype"))
1957                 if(!IsSameGametype(m))
1958                         return "This server does not allow changing the game type by map suggestions.";
1959 #endif
1960         if(!cvar("g_maplist_votable_override_mostrecent"))
1961                 if(Map_IsRecent(m))
1962                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1963
1964 #ifdef MAPINFO
1965         if(!MapInfo_CheckMap(m))
1966                 return "The map you suggested does not support the current game mode.";
1967 #else
1968         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1969                 return "The map you suggested is not available on this server.";
1970 #endif
1971         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1972                 if(mapvote_suggestions[i] == m)
1973                         return "This map was already suggested.";
1974         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1975         {
1976                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1977         }
1978         else
1979         {
1980                 i = mapvote_suggestion_ptr;
1981                 mapvote_suggestion_ptr += 1;
1982         }
1983         if(mapvote_suggestions[i] != "")
1984                 strunzone(mapvote_suggestions[i]);
1985         mapvote_suggestions[i] = strzone(m);
1986         if(cvar("sv_eventlog"))
1987                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)), TRUE);
1988         return strcat("Suggestion of ", m, " accepted.");
1989 }
1990
1991 void MapVote_AddVotable(string nextMap, float isSuggestion)
1992 {
1993         float j;
1994         if(nextMap == "")
1995                 return;
1996         for(j = 0; j < mapvote_count; ++j)
1997                 if(mapvote_maps[j] == nextMap)
1998                         return;
1999         if(strlen(nextMap) > mapvote_maxlen)
2000                 mapvote_maxlen = strlen(nextMap);
2001         mapvote_maps[mapvote_count] = strzone(nextMap);
2002         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2003         mapvote_count += 1;
2004 }
2005
2006 void MapVote_SendData(float target);
2007 void MapVote_Init()
2008 {
2009         float i;
2010         float nmax, smax;
2011
2012         MapVote_ClearAllVotes();
2013
2014         mapvote_count = 0;
2015         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2016         mapvote_abstain = cvar("g_maplist_votable_abstain");
2017
2018         if(mapvote_abstain)
2019                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2020         else
2021                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2022         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2023
2024         if(mapvote_suggestion_ptr)
2025                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2026                         MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
2027
2028         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2029                 MapVote_AddVotable(GetNextMap(), FALSE);
2030
2031         if(mapvote_count == 0)
2032         {
2033                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2034 #ifdef MAPINFO
2035                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
2036                 localcmd("\nmenu_cmd sync\n");
2037 #else
2038                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
2039 #endif
2040                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2041                         MapVote_AddVotable(GetNextMap(), FALSE);
2042         }
2043
2044         mapvote_count_real = mapvote_count;
2045         if(mapvote_abstain)
2046                 MapVote_AddVotable("don't care", 0);
2047
2048         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2049
2050         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2051         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2052         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2053                 mapvote_keeptwotime = 0;
2054         mapvote_message = "Choose a map and press its key!";
2055
2056         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2057         if(mapvote_screenshot_dir == "")
2058                 mapvote_screenshot_dir = "maps";
2059         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2060
2061         if(!cvar("g_maplist_textonly"))
2062                 MapVote_SendData(MSG_BROADCAST);
2063 }
2064
2065 void MapVote_SendPicture(float id)
2066 {
2067         msg_entity = self;
2068         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2069         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
2070         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
2071         WriteByte(MSG_ONE, id);
2072         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 1024);
2073 }
2074
2075 float GameCommand_MapVote(string cmd)
2076 {
2077         if(!intermission_running)
2078                 return FALSE;
2079         if(!cvar("g_maplist_textonly"))
2080         {
2081                 if(cmd == "mv_getpic")
2082                 {
2083                         MapVote_SendPicture(stof(argv(1)));
2084                         return TRUE;
2085                 }
2086         }
2087
2088         return FALSE;
2089 }
2090
2091 float MapVote_GetMapMask()
2092 {
2093         float mask, i, power;
2094         mask = 0;
2095         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2096                 if(mapvote_maps[i] != "")
2097                         mask |= power;
2098         return mask;
2099 }
2100
2101 void MapVote_SendData(float targ)
2102 {
2103         string mapfile, pakfile;
2104         float i, o;
2105         WriteByte(targ, SVC_TEMPENTITY);
2106         WriteByte(targ, TE_CSQC_CONFIG);
2107         WriteString(targ, "mv_screenshot_dir");
2108         WriteString(targ, mapvote_screenshot_dir);
2109
2110         WriteByte(targ, SVC_TEMPENTITY);
2111         WriteByte(targ, TE_CSQC_MAPVOTE);
2112         WriteByte(targ, MAPVOTE_NET_INIT);
2113
2114         WriteByte(targ, mapvote_count);
2115         WriteByte(targ, mapvote_abstain);
2116         WriteByte(targ, mapvote_detail);
2117         WriteByte(targ, mapvote_timeout - time);
2118         if(mapvote_count <= 8)
2119                 WriteByte(targ, MapVote_GetMapMask());
2120         else
2121                 WriteShort(targ, MapVote_GetMapMask());
2122         for(i = 0; i < mapvote_count; ++i)
2123                 if(mapvote_maps[i] != "")
2124                 {
2125                         WriteString(targ, mapvote_maps[i]);
2126                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2127                         pakfile = whichpack(strcat(mapfile, ".tga"));
2128                         if(pakfile == "")
2129                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2130                         if(pakfile == "")
2131                                 pakfile = whichpack(strcat(mapfile, ".png"));
2132                         print("pakfile is ", pakfile, "\n");
2133                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2134                                 pakfile = substring(pakfile, o, 999);
2135                         WriteString(targ, pakfile);
2136                 }
2137 }
2138
2139 void MapVote_UpdateData(float targ)
2140 {
2141         float i;
2142         WriteByte(targ, SVC_TEMPENTITY);
2143         WriteByte(targ, TE_CSQC_MAPVOTE);
2144         WriteByte(targ, MAPVOTE_NET_UPDATE);
2145         if(mapvote_count <= 8)
2146                 WriteByte(targ, MapVote_GetMapMask());
2147         else
2148                 WriteShort(targ, MapVote_GetMapMask());
2149         if(mapvote_detail)
2150                 for(i = 0; i < mapvote_count; ++i)
2151                         if(mapvote_maps[i] != "")
2152                                 WriteByte(targ, mapvote_votes[i]);
2153 }
2154
2155 void MapVote_TellVote(float targ, float vote)
2156 {
2157         WriteByte(targ, SVC_TEMPENTITY);
2158         WriteByte(targ, TE_CSQC_MAPVOTE);
2159         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
2160         WriteByte(targ, vote);
2161 }
2162
2163 float MapVote_Finished(float mappos)
2164 {
2165         string result;
2166         float i;
2167         float didntvote;
2168
2169         if(cvar("sv_eventlog"))
2170         {
2171                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2172                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2173                 didntvote = mapvote_voters;
2174                 for(i = 0; i < mapvote_count; ++i)
2175                         if(mapvote_maps[i] != "")
2176                         {
2177                                 didntvote -= mapvote_votes[i];
2178                                 if(i != mappos)
2179                                 {
2180                                         result = strcat(result, ":", mapvote_maps[i]);
2181                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2182                                 }
2183                         }
2184                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2185
2186                 GameLogEcho(result, FALSE);
2187                 if(mapvote_maps_suggested[mappos])
2188                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
2189         }
2190
2191         FOR_EACH_REALCLIENT(other)
2192                 FixClientCvars(other);
2193
2194         Map_Goto_SetStr(mapvote_maps[mappos]);
2195         Map_Goto();
2196         alreadychangedlevel = TRUE;
2197         return TRUE;
2198 }
2199 void MapVote_CheckRules_1()
2200 {
2201         float i;
2202
2203         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2204         {
2205                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2206                 mapvote_votes[i] = 0;
2207         }
2208
2209         mapvote_voters = 0;
2210         FOR_EACH_REALCLIENT(other)
2211         {
2212                 ++mapvote_voters;
2213                 if(other.mapvote)
2214                 {
2215                         i = other.mapvote - 1;
2216                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2217                         mapvote_votes[i] = mapvote_votes[i] + 1;
2218                 }
2219         }
2220 }
2221
2222 float MapVote_CheckRules_2()
2223 {
2224         float i;
2225         float firstPlace, secondPlace;
2226         float firstPlaceVotes, secondPlaceVotes;
2227         float mapvote_voters_real;
2228         string result;
2229
2230         mapvote_voters_real = mapvote_voters;
2231         if(mapvote_abstain)
2232                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2233
2234         RandomSelection_Init();
2235         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2236                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2237         firstPlace = RandomSelection_chosen_float;
2238         firstPlaceVotes = RandomSelection_best_priority;
2239         //dprint("First place: ", ftos(firstPlace), "\n");
2240         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2241
2242         RandomSelection_Init();
2243         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2244                 if(i != firstPlace)
2245                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2246         secondPlace = RandomSelection_chosen_float;
2247         secondPlaceVotes = RandomSelection_best_priority;
2248         //dprint("Second place: ", ftos(secondPlace), "\n");
2249         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2250
2251         if(firstPlace == -1)
2252                 error("No first place in map vote... WTF?");
2253
2254         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2255                 return MapVote_Finished(firstPlace);
2256
2257         if(mapvote_keeptwotime)
2258                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2259                 {
2260                         float didntvote;
2261                         mapvote_dirty = TRUE;
2262                         mapvote_message = "Now decide between the TOP TWO!";
2263                         mapvote_keeptwotime = 0;
2264                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2265                         result = strcat(result, ":", ftos(firstPlaceVotes));
2266                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2267                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2268                         didntvote = mapvote_voters;
2269                         for(i = 0; i < mapvote_count; ++i)
2270                                 if(mapvote_maps[i] != "")
2271                                 {
2272                                         didntvote -= mapvote_votes[i];
2273                                         if(i != firstPlace)
2274                                                 if(i != secondPlace)
2275                                                 {
2276                                                         result = strcat(result, ":", mapvote_maps[i]);
2277                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2278                                                         if(i < mapvote_count_real)
2279                                                         {
2280                                                                 strunzone(mapvote_maps[i]);
2281                                                                 mapvote_maps[i] = "";
2282                                                         }
2283                                                 }
2284                                 }
2285                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2286                         if(cvar("sv_eventlog"))
2287                                 GameLogEcho(result, FALSE);
2288                 }
2289
2290         return FALSE;
2291 }
2292 void MapVote_Tick()
2293 {
2294         string msgstr;
2295         string tmp;
2296         float i;
2297         float keeptwo;
2298         float totalvotes;
2299
2300         keeptwo = mapvote_keeptwotime;
2301         MapVote_CheckRules_1(); // count
2302         if(MapVote_CheckRules_2()) // decide
2303                 return;
2304
2305         totalvotes = 0;
2306         FOR_EACH_REALCLIENT(other)
2307         {
2308                 // hide scoreboard again
2309                 if(other.health != 2342)
2310                 {
2311                         other.health = 2342;
2312                         other.impulse = 0;
2313                         if(clienttype(other) == CLIENTTYPE_REAL)
2314                         {
2315                                 if(cvar("g_maplist_textonly"))
2316                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2317
2318                                 msg_entity = other;
2319                                 WriteByte(MSG_ONE, SVC_FINALE);
2320                                 WriteString(MSG_ONE, "");
2321                         }
2322                 }
2323
2324                 // notify about keep-two
2325                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2326                         play2(other, "misc/invshot.wav");
2327
2328                 // clear possibly invalid votes
2329                 if(mapvote_maps[other.mapvote - 1] == "")
2330                         other.mapvote = 0;
2331                 // use impulses as new vote
2332                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2333                         if(mapvote_maps[other.impulse - 1] != "")
2334                         {
2335                                 other.mapvote = other.impulse;
2336                                 if(mapvote_detail)
2337                                         mapvote_dirty = TRUE;
2338
2339                                 msg_entity = other;
2340                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2341                         }
2342                 other.impulse = 0;
2343
2344                 if(other.mapvote)
2345                         ++totalvotes;
2346         }
2347
2348         MapVote_CheckRules_1(); // just count
2349
2350         if(!cvar("g_maplist_textonly"))
2351         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2352         {
2353                 MapVote_UpdateData(MSG_BROADCAST);
2354                 mapvote_dirty = FALSE;
2355         }
2356
2357         if(cvar("g_maplist_textonly"))
2358         {
2359                 FOR_EACH_REALCLIENT(other)
2360                 {
2361                         // display voting screen
2362                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2363                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2364                         if(mapvote_abstain)
2365                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2366                         msgstr = strcat(msgstr, mapvote_message);
2367                         msgstr = strcat(msgstr, "\n\n");
2368                         for(i = 0; i < mapvote_count; ++i)
2369                                 if(mapvote_maps[i] == "")
2370                                         msgstr = strcat(msgstr, "\n");
2371                                 else
2372                                 {
2373                                         tmp = mapvote_maps[i];
2374                                         tmp = strpad(mapvote_maxlen, tmp);
2375                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2376                                         if(mapvote_detail)
2377                                         {
2378                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2379                                                 if(mapvote_votes[i] != 1)
2380                                                         tmp = strcat(tmp, "s");
2381                                                 tmp = strcat(tmp, ")");
2382                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2383                                         }
2384                                         if(mapvote_abstain)
2385                                                 if(i == mapvote_count - 1)
2386                                                         msgstr = strcat(msgstr, "\n");
2387                                         if(other.mapvote == i + 1)
2388                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2389                                         else
2390                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2391                                 }
2392
2393                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2394                         if(totalvotes != 1)
2395                                 msgstr = strcat(msgstr, "s");
2396                         msgstr = strcat(msgstr, " cast");
2397                         i = ceil(mapvote_timeout - time);
2398                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2399                         if(i != 1)
2400                                 msgstr = strcat(msgstr, "s");
2401                         msgstr = strcat(msgstr, " left");
2402
2403                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2404                 }
2405         }
2406 }
2407 void MapVote_Start()
2408 {
2409         if(mapvote_run)
2410                 return;
2411
2412 #ifdef MAPINFO
2413         MapInfo_Enumerate();
2414         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1))
2415 #endif
2416                 mapvote_run = TRUE;
2417 }
2418 void MapVote_Think()
2419 {
2420         if(!mapvote_run)
2421                 return;
2422
2423         if(alreadychangedlevel)
2424                 return;
2425
2426         if(time < mapvote_nextthink)
2427                 return;
2428         //dprint("tick\n");
2429
2430         mapvote_nextthink = time + 0.5;
2431
2432         if(!mapvote_initialized)
2433         {
2434                 mapvote_initialized = TRUE;
2435                 if(DoNextMapOverride())
2436                         return;
2437                 if(!cvar("g_maplist_votable") || player_count <= 0)
2438                 {
2439                         GotoNextMap();
2440                         return;
2441                 }
2442                 MapVote_Init();
2443         }
2444
2445         MapVote_Tick();
2446 };
2447
2448 string GotoMap(string m)
2449 {
2450 #ifdef MAPINFO
2451         if(!MapInfo_CheckMap(m))
2452 #else
2453         if(!TryFile(strcat("maps/", m, ".mapcfg")))
2454 #endif
2455                 return "The map you chose is not available on this server.";
2456         cvar_set("nextmap", m);
2457         cvar_set("timelimit", "-1");
2458         if(mapvote_initialized || alreadychangedlevel)
2459         {
2460                 if(DoNextMapOverride())
2461                         return "Map switch initiated.";
2462                 else
2463                         return "Hm... no. For some reason I like THIS map more.";
2464         }
2465         else
2466                 return "Map switch will happen after scoreboard.";
2467 }
2468
2469
2470 void EndFrame()
2471 {
2472         FOR_EACH_REALCLIENT(self)
2473         {
2474                 if(self.classname == "spectator")
2475                 {
2476                         if(self.enemy.hitsound)
2477                                 play2(self, "misc/hit.wav");
2478                 }
2479                 else
2480                 {
2481                         if(self.hitsound)
2482                                 play2(self, "misc/hit.wav");
2483                 }
2484         }
2485         FOR_EACH_CLIENT(self)
2486                 self.hitsound = FALSE;
2487 }
2488
2489
2490 /*
2491  * RedirectionThink:
2492  * returns TRUE if redirecting
2493  */
2494 float redirection_timeout;
2495 float redirection_nextthink;
2496 float RedirectionThink()
2497 {
2498         float clients_found;
2499
2500         if(redirection_target == "")
2501                 return FALSE;
2502
2503         if(!redirection_timeout)
2504         {
2505                 cvar_set("sv_public", "-2");
2506                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2507                 if(redirection_target == "self")
2508                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2509                 else
2510                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2511         }
2512
2513         if(time < redirection_nextthink)
2514                 return TRUE;
2515
2516         redirection_nextthink = time + 1;
2517
2518         clients_found = 0;
2519         FOR_EACH_REALCLIENT(self)
2520         {
2521                 ServerConsoleEcho(strcat("Redirecting: sending connect command to ", self.netname), FALSE);
2522                 if(redirection_target == "self")
2523                         stuffcmd(self, "\ndisconnect; reconnect\n");
2524                 else
2525                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2526                 ++clients_found;
2527         }
2528
2529         ServerConsoleEcho(strcat("Redirecting: ", ftos(clients_found), " clients left."), FALSE);
2530
2531         if(time > redirection_timeout || clients_found == 0)
2532                 localcmd("\nwait; wait; wait; quit\n");
2533
2534         return TRUE;
2535 }
2536
2537 void SV_Shutdown()
2538 {
2539         if(world_initialized)
2540         {
2541                 world_initialized = 0;
2542                 print("Saving persistent data...\n");
2543                 Ban_SaveBans();
2544                 if(!sv_cheats)
2545                         db_save(ServerProgsDB, "server.db");
2546                 db_close(ServerProgsDB);
2547                 print("done!\n");
2548                 // tell the bot system the game is ending now
2549                 bot_endgame();
2550
2551                 MapInfo_Shutdown();
2552         }
2553         else
2554         {
2555                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2556         }
2557 }