data/qcsrc/server/g_damage.qc

   1
   2 float checkrules_firstblood;
   3
   4 void(entity player, float f) UpdateFrags =
   5 {
   6         player.frags += f;
   7         player.totalfrags += f;
   8 }
   9
  10 void GiveFrags (entity attacker, entity targ, float f)
  11 {
  12         if(gameover) return;
  13
  14         if(cvar("g_arena"))
  15                 if(cvar("g_arena_roundbased"))
  16                         return;
  17
  18         if(cvar("g_domination"))
  19         {
  20                 if(cvar("g_domination_disable_frags"))
  21                         if(f > 0)
  22                                 return;
  23         }
  24         else if(cvar("g_runematch"))
  25         {
  26                 if(f > 0)
  27                         f = RunematchHandleFrags(attacker, targ, f);
  28         }
  29         else if(cvar("g_keyhunt"))
  30         {
  31                 f = kh_HandleFrags(attacker, targ, f);
  32         }
  33         else if(cvar("g_lms"))
  34         {
  35                 // count remaining lives, not frags in lms
  36                 targ.frags -= 1;
  37                 // keep track of the worst players lives
  38                 if(targ.frags < lms_lowest_lives)
  39                         lms_lowest_lives = targ.frags;
  40                 // player has no more lives left
  41                 if (!targ.frags)
  42                 {
  43                         if(!lms_next_place)
  44                                 lms_next_place = player_count;
  45                         targ.frags = -lms_next_place;
  46                         lms_next_place -= 1;
  47                 }
  48                 return;
  49         }
  50
  51         if(f)
  52                 UpdateFrags(attacker, f);
  53 }
  54
  55 string AppendItemcodes(string s, entity player)
  56 {
  57         float w;
  58         w = player.weapon;
  59         //if(w == 0)
  60         //      w = player.switchweapon;
  61         if(w == 0)
  62                 w = player.cnt; // previous weapon!
  63         s = strcat(s, ftos(W_ItemCode(w)));
  64         if(time < player.strength_finished)
  65                 s = strcat(s, "S");
  66         if(time < player.invincible_finished)
  67                 s = strcat(s, "I");
  68         if(player.flagcarried != world)
  69                 s = strcat(s, "F");
  70         if(player.buttonchat)
  71                 s = strcat(s, "T");
  72         if(player.kh_next)
  73                 s = strcat(s, "K");
  74         if(player.runes)
  75                 s = strcat(s, "|", ftos(player.runes));
  76         return s;
  77 }
  78
  79 void LogDeath(string mode, float deathtype, entity killer, entity killed)
  80 {
  81         string s;
  82         if(!cvar("sv_eventlog"))
  83                 return;
  84         s = strcat(":kill:", mode);
  85         s = strcat(s, ":", ftos(killer.playerid));
  86         s = strcat(s, ":", ftos(killed.playerid));
  87         s = strcat(s, ":type=", ftos(deathtype));
  88         s = strcat(s, ":items=");
  89         s = AppendItemcodes(s, killer);
  90         if(killed != killer)
  91         {
  92                 s = strcat(s, ":victimitems=");
  93                 s = AppendItemcodes(s, killed);
  94         }
  95         GameLogEcho(s, FALSE);
  96 }
  97
  98 void Obituary (entity attacker, entity targ, float deathtype)
  99 {
 100         string  s, a;
 101
 102         if (targ.classname == "player" || targ.classname == "corpse")
 103         {
 104                 if (targ.classname == "corpse")
 105                         s = "A corpse";
 106                 else
 107                         s = targ.netname;
 108                 a = attacker.netname;
 109
 110                 if (targ == attacker)
 111                 {
 112                         if (deathtype == DEATH_TEAMCHANGE)
 113                         {
 114                                 centerprint(targ, strcat("You are now on: ", ColoredTeamName(targ.team)));
 115                         }
 116                         else if (deathtype == DEATH_AUTOTEAMCHANGE)
 117                         {
 118                                 centerprint(targ, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(targ.team)));
 119                                 return;
 120                         }
 121                         else if (deathtype == DEATH_CAMP)
 122                                 centerprint(targ, "^1Die camper!\n\n\n");
 123                         else if (deathtype == DEATH_NOAMMO)
 124                                 centerprint(targ, "^1You were killed for running out of ammo...\n\n\n");
 125                         else if (deathtype == DEATH_ROT)
 126                                 centerprint(targ, "^1You grew too old without taking your medicine\n\n\n");
 127                         else if (deathtype == DEATH_MIRRORDAMAGE)
 128                                 centerprint(targ, "^1Don't shoot your team mates!\n\n\n");
 129                         else
 130                                 centerprint(targ, "^1You killed your own dumb self!\n\n\n");
 131
 132                         if (deathtype == IT_GRENADE_LAUNCHER)
 133                                 bprint ("^1",s, "^1 detonated\n");
 134                         else if (deathtype == IT_ELECTRO)
 135                                 bprint ("^1",s, "^1 played with plasma\n");
 136                         else if (deathtype == IT_ROCKET_LAUNCHER)
 137                                 bprint ("^1",s, "^1 exploded\n");
 138                         else if (deathtype == DEATH_KILL)
 139                                 bprint ("^1",s, "^1 couldn't take it anymore\n");
 140                         else if (deathtype == DEATH_ROT)
 141                                 bprint ("^1",s, "^1 died\n");
 142                         else if (deathtype == DEATH_NOAMMO)
 143                         {
 144                                 bprint ("^7",s, " ^7committed suicide. What's the point of living without ammo?\n");
 145                                 //sound (self, CHAN_BODY, "minstagib/mockery.wav", 1, ATTN_NONE);
 146                         }
 147                         else if (deathtype == DEATH_CAMP)
 148                                 bprint ("^1",s, "^1 thought he found a nice camping ground\n");
 149                         else if (deathtype == DEATH_MIRRORDAMAGE)
 150                                 bprint ("^1",s, "^1 didn't become friends with the Lord of Teamplay\n");
 151                         else if (deathtype != DEATH_TEAMCHANGE)
 152                                 bprint ("^1",s, "^1 couldn't resist the urge to self-destruct\n");
 153
 154                         if(deathtype != DEATH_TEAMCHANGE)
 155                         {
 156                                 LogDeath("suicide", deathtype, targ, targ);
 157                                 GiveFrags(attacker, targ, -1);
 158                         }
 159                         if (targ.killcount > 2)
 160                                 bprint ("^1",s,"^1 ended it all with a ",ftos(targ.killcount)," kill spree\n");
 161                 }
 162                 else if (attacker.classname == "player" || attacker.classname == "gib")
 163                 {
 164                         if(teamplay && attacker.team == targ.team)
 165                         {
 166                                 centerprint(attacker, "^1Moron! You fragged a teammate!\n\n\n");
 167                                 bprint ("^1", a, "^1 mows down a teammate\n");
 168                                 GiveFrags(attacker, targ, -1);
 169                                 if (targ.killcount > 2)
 170                                         bprint ("^1",s,"'s ^1",ftos(targ.killcount)," kill spree was ended by a teammate!\n");
 171                                 if (attacker.killcount > 2)
 172                                         bprint ("^1",a,"^1 ended a ",ftos(attacker.killcount)," kill spree by killing a teammate\n");
 173                                 attacker.killcount = 0;
 174
 175                                 LogDeath("tk", deathtype, attacker, targ);
 176                         }
 177                         else
 178                         {
 179                                 if (!checkrules_firstblood)
 180                                 {
 181                                         checkrules_firstblood = TRUE;
 182                                         //sound(world, CHAN_AUTO, "announcer/firstblood.wav", 1, ATTN_NONE);
 183                                         //if (cvar("g_minstagib"))
 184                                                 //sound(world, CHAN_AUTO, "announce/male/mapkill1.wav", 1, ATTN_NONE);
 185                                         bprint("^1",a, "^1 drew first blood", "\n");
 186                                 }
 187
 188                                 centerprint(attacker, strcat("^4You fragged ^7", s, "\n\n\n"));
 189                                 centerprint(targ, strcat("^1You were fragged by ^7", a, "\n\n\n"));
 190
 191                                 if (deathtype == IT_LASER)
 192                                         bprint ("^1",s, "^1 was blasted by ", a, "\n");
 193                                 else if (deathtype == IT_UZI)
 194                                         bprint ("^1",s, "^1 was riddled full of holes by ", a, "\n");
 195                                 else if (deathtype == IT_SHOTGUN)
 196                                         bprint ("^1",s, "^1 was gunned by ", a, "\n");
 197                                 else if (deathtype == IT_GRENADE_LAUNCHER)
 198                                         bprint ("^1", s, "^1 was blasted by ", a, "\n");
 199                                 else if (deathtype == IT_ELECTRO)
 200                                         bprint ("^1",s, "^1 was blasted by ", a, "\n");
 201                                 else if (deathtype == IT_CRYLINK)
 202                                         bprint ("^1",s, "^1 was blasted by ", a, "\n");
 203                                 else if (deathtype == IT_NEX)
 204                                         bprint ("^1",s, "^1 has been vaporized by ", a, "\n");
 205                                 else if (deathtype == IT_HAGAR)
 206                                         bprint ("^1",s, "^1 was pummeled by ", a, "\n");
 207                                 else if (deathtype == IT_ROCKET_LAUNCHER)
 208                                         bprint ("^1",s, "^1 was blasted by ", a, "\n");
 209                                 else if (deathtype == DEATH_TELEFRAG)
 210                                         bprint ("^1",s, "^1 was telefragged by ", a, "\n");
 211                                 else if (deathtype == DEATH_DROWN)
 212                                         bprint ("^1",s, "^1 was drowned by ", a, "\n");
 213                                 else if (deathtype == DEATH_SLIME)
 214                                         bprint ("^1",s, "^1 was slimed by ", a, "\n");
 215                                 else if (deathtype == DEATH_LAVA)
 216                                         bprint ("^1",s, "^1 was cooked by ", a, "\n");
 217                                 else if (deathtype == DEATH_FALL)
 218                                         bprint ("^1",s, "^1 was grounded by ", a, "\n");
 219                                 else if (deathtype == DEATH_SHOOTING_STAR)
 220                                         bprint ("^1",s, "^1 was shot into space by ", a, "\n");
 221                                 else if (deathtype == DEATH_SWAMP)
 222                                         bprint ("^1",s, "^1 was conserved by ", a, "\n");
 223                                 else if (deathtype == DEATH_HURTTRIGGER)
 224                                         bprint ("^1",s, "^1 was thrown into a world of hurt by ", a, "\n");
 225                                 else
 226                                         bprint ("^1",s, "^1 was fragged by ", a, "\n");
 227
 228                                 GiveFrags(attacker, targ, 1);
 229                                 if (targ.killcount > 2)
 230                                         bprint ("^1",s,"'s ^1", ftos(targ.killcount), " kill spree was ended by ", a, "\n");
 231                                 attacker.killcount = attacker.killcount + 1;
 232                                 if (attacker.killcount > 2)
 233                                         bprint ("^1",a,"^1 has ",ftos(attacker.killcount)," frags in a row\n");
 234
 235                                 LogDeath("frag", deathtype, attacker, targ);
 236
 237                                 if (attacker.killcount == 3)
 238                                 {
 239                                         bprint (a,"^7 made a ^1TRIPLE FRAG\n");
 240                                         play2(attacker, "announcer/male/03kills.ogg");
 241                                 }
 242                                 else if (attacker.killcount == 5)
 243                                 {
 244                                         bprint (a,"^7 made a ^1FIVE FRAG COMBO\n");
 245                                         play2(attacker, "announcer/male/05kills.ogg");
 246                                 }
 247                                 else if (attacker.killcount == 10)
 248                                 {
 249                                         bprint (a,"^7 is on a ^1RAGE\n");
 250                                         play2(attacker, "announcer/male/10kills.ogg");
 251                                 }
 252                                 else if (attacker.killcount == 15)
 253                                 {
 254                                         bprint (a,"^7 has done a ^1MASSACRE!\n");
 255                                         play2(attacker, "announcer/male/15kills.ogg");
 256                                 }
 257                                 else if (attacker.killcount == 20)
 258                                 {
 259                                         bprint (a,"^7 is ^1UNHUMAN!\n");
 260                                         play2(attacker, "announcer/male/20kills.ogg");
 261                                 }
 262                                 else if (attacker.killcount == 25)
 263                                 {
 264                                         bprint (a,"^7 is a ^1DEATH INCARNATION!\n");
 265                                         play2(attacker, "announcer/male/25kills.ogg");
 266                                 }
 267                                 else if (attacker.killcount == 30)
 268                                 {
 269                                         bprint (a,"^7 is maybe a ^1AIMBOTTER?!\n");
 270                                         play2(attacker, "announcer/male/30kills.ogg");
 271                                 }
 272                         }
 273                 }
 274                 else
 275                 {
 276                         centerprint(targ, "^1Watch your step!\n\n\n");
 277                         if (deathtype == DEATH_HURTTRIGGER && attacker.message != "")
 278                                 bprint ("^1",s, "^1 ", attacker.message, "\n");
 279                         else if (deathtype == DEATH_DROWN)
 280                                 bprint ("^1",s, "^1 drowned\n");
 281                         else if (deathtype == DEATH_SLIME)
 282                                 bprint ("^1",s, "^1 was slimed\n");
 283                         else if (deathtype == DEATH_LAVA)
 284                                 bprint ("^1",s, "^1 turned into hot slag\n");
 285                         else if (deathtype == DEATH_FALL)
 286                                 bprint ("^1",s, "^1 hit the ground with a crunch\n");
 287                         else if (deathtype == DEATH_SHOOTING_STAR)
 288                                 bprint ("^1",s, "^1 became a shooting star\n");
 289                         else if (deathtype == DEATH_SWAMP)
 290                                 bprint ("^1",s, "^1 is now conserved for centuries to come\n");
 291                         else
 292                                 bprint ("^1",s, "^1 died\n");
 293                         GiveFrags(targ, targ, -1);
 294                         if(targ.frags == -5) {
 295                                 play2(targ, "announcer/male/botlike.ogg");
 296                         }
 297
 298                         if (targ.killcount > 2)
 299                                 bprint ("^1",s,"^1 died with a ",ftos(targ.killcount)," kill spree\n");
 300
 301                         LogDeath("accident", deathtype, targ, targ);
 302                 }
 303                 targ.death_origin = targ.origin;
 304                 if(targ != attacker)
 305                         targ.killer_origin = attacker.origin;
 306                 // FIXME: this should go in PutClientInServer
 307                 if (targ.killcount)
 308                         targ.killcount = 0;
 309         }
 310 }
 311
 312 // these are updated by each Damage call for use in button triggering and such
 313 entity damage_targ;
 314 entity damage_inflictor;
 315 entity damage_attacker;
 316
 317 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 318 {
 319         float mirrordamage;
 320         float mirrorforce;
 321         entity attacker_save;
 322         mirrordamage = 0;
 323         mirrorforce = 0;
 324
 325         if (gameover || targ.killcount == -666)
 326                 return;
 327
 328         local entity oldself;
 329         oldself = self;
 330         self = targ;
 331         damage_targ = targ;
 332         damage_inflictor = inflictor;
 333         damage_attacker = attacker;
 334                 attacker_save = attacker;
 335
 336         if (targ.classname == "player")
 337         if (attacker.classname == "player")
 338         if (!targ.isbot)
 339         if (attacker.isbot)
 340                 damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 341
 342         // nullify damage if teamplay is on
 343         if(deathtype != DEATH_TELEFRAG)
 344         {
 345                 if(teamplay == 1)
 346                         if(attacker.team)
 347                                 if(attacker.team == targ.team)
 348                                         damage = 0;
 349                 if(teamplay == 3)
 350                         if(attacker != targ)
 351                                 if(attacker.team)
 352                                         if(attacker.team == targ.team)
 353                                                 damage = 0;
 354                 if(teamplay == 4)
 355                         if(attacker != targ)
 356                                 if(attacker.team == targ.team)
 357                                         if(attacker.classname == "player")
 358                                                 if((targ.classname == "player") && (targ.health > 0))
 359                                                 {
 360                                                         mirrordamage = cvar("g_mirrordamage") * damage;
 361                                                         mirrorforce = cvar("g_mirrordamage") * vlen(force);
 362                                                         if(cvar("g_minstagib"))
 363                                                         {
 364                                                                 if(cvar("g_friendlyfire") == 0)
 365                                                                         damage = 0;
 366                                                         }
 367                                                         else
 368                                                                 damage = cvar("g_friendlyfire") * damage;
 369                                                         // mirrordamage will be used LATER
 370                                                 }
 371         }
 372
 373         if(cvar("g_lms"))
 374         if(targ.classname == "player")
 375         if(attacker.classname == "player")
 376         if(attacker != targ)
 377         {
 378                 targ.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 379                 attacker.lms_traveled_distance = cvar("g_lms_campcheck_distance");
 380         }
 381
 382         if(targ != attacker)
 383         if(!targ.deadflag)
 384         if(damage > 0)
 385         if(targ.classname == "player")
 386         if(attacker)
 387                 attacker.hitsound += 1;
 388
 389         if (cvar("g_minstagib"))
 390         {
 391                 if ((deathtype == DEATH_FALL)  ||
 392                     (deathtype == DEATH_DROWN) ||
 393                     (deathtype == DEATH_SLIME) ||
 394                     (deathtype == DEATH_LAVA))
 395                         return;
 396                 if (targ.armorvalue && (deathtype == IT_NEX) && damage)
 397                 {
 398                         targ.armorvalue -= 1;
 399                         centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue),"\n"));
 400                         damage = 0;
 401                         targ.hitsound += 1;
 402                 }
 403                 else if (deathtype == IT_NEX && targ.items & IT_STRENGTH)
 404                 {
 405                         if(clienttype(attacker) == CLIENTTYPE_REAL) play2(attacker, "announcer/male/yoda.ogg");
 406                 }
 407                 if (deathtype == IT_LASER)
 408                 {
 409                         damage = 0;
 410                         if (targ != attacker)
 411                         {
 412                                 if (targ.classname == "player")
 413                                         centerprint(attacker, "Secondary fire inflicts no damage!\n");
 414                                 damage = 0;
 415                                 mirrordamage = 0;
 416                                 force = '0 0 0';
 417                                 // keep mirrorforce
 418                                 attacker = targ;
 419                         }
 420                 }
 421         } else {
 422                 if (deathtype == IT_NEX && !targ.deadflag && !(attacker.flags & FL_ONGROUND) && !(targ.flags & FL_ONGROUND) && attacker.waterlevel < 2 && targ.waterlevel < 2 && attacker.killcount != 3 && attacker.killcount != 5 && attacker.killcount != 10 && attacker.killcount != 15 && attacker.killcount != 20 && attacker.killcount != 25 && attacker.killcount != 30)
 423                 {
 424                         if(clienttype(attacker) == CLIENTTYPE_REAL)  play2(attacker, "announcer/male/yoda.ogg");
 425                 }
 426         }
 427
 428         // apply strength multiplier
 429         if (attacker.items & IT_STRENGTH && !cvar("g_minstagib"))
 430         {
 431                 damage = damage * cvar("g_balance_powerup_strength_damage");
 432                 force = force * cvar("g_balance_powerup_strength_force");
 433         }
 434         // apply invincibility multiplier
 435         if (targ.items & IT_INVINCIBLE && !cvar("g_minstagib"))
 436                 damage = damage * cvar("g_balance_powerup_invincible_takedamage");
 437
 438
 439         if(cvar("g_runematch"))
 440         {
 441                 // apply strength rune
 442                 if (attacker.runes & RUNE_STRENGTH)
 443                 {
 444                         if(attacker.runes & CURSE_WEAK) // have both curse & rune
 445                         {
 446                                 damage = damage * cvar("g_balance_rune_strength_combo_damage");
 447                                 force = force * cvar("g_balance_rune_strength_combo_force");
 448                         }
 449                         else
 450                         {
 451                                 damage = damage * cvar("g_balance_rune_strength_damage");
 452                                 force = force * cvar("g_balance_rune_strength_force");
 453                         }
 454                 }
 455                 else if (attacker.runes & CURSE_WEAK)
 456                 {
 457                         damage = damage * cvar("g_balance_curse_weak_damage");
 458                         force = force * cvar("g_balance_curse_weak_force");
 459                 }
 460
 461                 // apply defense rune
 462                 if (targ.runes & RUNE_DEFENSE)
 463                 {
 464                         if (targ.runes & CURSE_VULNER) // have both curse & rune
 465                                 damage = damage * cvar("g_balance_rune_defense_combo_takedamage");
 466                         else
 467                                 damage = damage * cvar("g_balance_rune_defense_takedamage");
 468                 }
 469                 else if (targ.runes & CURSE_VULNER)
 470                         damage = damage * cvar("g_balance_curse_vulner_takedamage");
 471         }
 472
 473         // apply push
 474         if (self.damageforcescale)
 475         {
 476                 self.velocity = self.velocity + self.damageforcescale * force;
 477                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 478         }
 479         // apply damage
 480         if (self.event_damage)
 481                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 482         self = oldself;
 483
 484         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 485         {
 486                 // Savage: vampire mode
 487                 if(cvar("g_vampire") && !cvar("g_minstagib"))
 488                 {
 489                         attacker.health += damage;
 490                 }
 491                 if(cvar("g_runematch"))
 492                 {
 493                         if (attacker.runes & RUNE_VAMPIRE)
 494                         {
 495                         // apply vampire rune
 496                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 497                                 {
 498                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb");
 499                                         attacker.health = bound(
 500                                                 cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 40
 501                                                 attacker.health + damage * cvar("g_balance_rune_vampire_combo_absorb"),
 502                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 503                                 }
 504                                 else
 505                                 {
 506                                         //attacker.health = attacker.health + damage * cvar("g_balance_rune_vampire_absorb");
 507                                         attacker.health = bound(
 508                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 509                                                                                         // empathy won't let you gain health in the same way...
 510                                                 attacker.health + damage * cvar("g_balance_rune_vampire_absorb"),
 511                                                 cvar("g_balance_rune_vampire_maxhealth"));      // LA: was 1000, now 500
 512                                         }
 513                         }
 514                         // apply empathy curse
 515                         else if (attacker.runes & CURSE_EMPATHY)
 516                         {
 517                                 attacker.health = bound(
 518                                         cvar("g_balance_curse_empathy_minhealth"), // LA: was 3, now 20
 519                                         attacker.health + damage * cvar("g_balance_curse_empathy_takedamage"),
 520                                         attacker.health);
 521                         }
 522                 }
 523         }
 524
 525         // apply mirror damage if any
 526         if(mirrordamage > 0 || mirrorforce > 0)
 527         {
 528                 attacker = attacker_save;
 529                 if(cvar("g_minstagib"))
 530                         if(mirrordamage > 0)
 531                         {
 532                                 // just lose extra LIVES, don't kill the player for mirror damage
 533                                 if(attacker.armorvalue > 0)
 534                                 {
 535                                         attacker.armorvalue = attacker.armorvalue - 1;
 536                                         centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue),"\n"));
 537                                         attacker.hitsound += 1;
 538                                 }
 539                                 mirrordamage = 0;
 540                         }
 541                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 542                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 543         }
 544 }
 545
 546 void RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype)
 547 {
 548         entity  targ;
 549         float   finaldmg;
 550         float   power;
 551         vector  blastorigin;
 552         vector  force;
 553         vector  m1;
 554         vector  m2;
 555         vector  nearest;
 556         vector  diff;
 557         vector center;
 558
 559         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 560
 561         targ = findradius (blastorigin, rad);
 562         while (targ)
 563         {
 564                 if (targ != inflictor)
 565                         if (ignore != targ)
 566                         {
 567                                 // LordHavoc: measure distance to nearest point on target (not origin)
 568                                 // (this guarentees 100% damage on a touch impact)
 569                                 nearest = blastorigin;
 570                                 m1 = targ.origin + targ.mins;
 571                                 m2 = targ.origin + targ.maxs;
 572                                 if (nearest_x < m1_x) nearest_x = m1_x;
 573                                 if (nearest_y < m1_y) nearest_y = m1_y;
 574                                 if (nearest_z < m1_z) nearest_z = m1_z;
 575                                 if (nearest_x > m2_x) nearest_x = m2_x;
 576                                 if (nearest_y > m2_y) nearest_y = m2_y;
 577                                 if (nearest_z > m2_z) nearest_z = m2_z;
 578                                 diff = nearest - blastorigin;
 579                                 // round up a little on the damage to ensure full damage on impacts
 580                                 // and turn the distance into a fraction of the radius
 581                                 power = 1 - ((vlen (diff) - 2) / rad);
 582                                 //bprint(" ");
 583                                 //bprint(ftos(power));
 584                                 if (power > 0)
 585                                 {
 586                                         if (power > 1)
 587                                                 power = 1;
 588                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 589                                         if (finaldmg > 0)
 590                                         {
 591                                                 center = (m1 + m2) * 0.5;
 592                                                 // if it's a player, use the view origin as reference
 593                                                 if (targ.classname == "player")
 594                                                         center = targ.origin + targ.view_ofs;
 595                                                 force = normalize(center - blastorigin) * (finaldmg / coredamage) * forceintensity;
 596                                                 if (targ == attacker)
 597                                                         finaldmg = finaldmg * cvar("g_balance_selfdamagepercent");      // Partial damage if the attacker hits himself
 598                                                 // test line of sight to multiple positions on box,
 599                                                 // and do damage if any of them hit
 600                                                 local float c;
 601                                                 c = ceil(finaldmg / 10);
 602                                                 if (c > 20)
 603                                                         c = 20;
 604                                                 while (c > 0)
 605                                                 {
 606                                                         c = c - 1;
 607                                                         traceline(blastorigin, nearest, TRUE, inflictor);
 608                                                         if (trace_fraction == 1 || trace_ent == targ
 609                                                             || cvar("g_throughfloor"))
 610                                                         {
 611                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
 612                                                                 break;
 613                                                         }
 614                                                         nearest_x = m1_x + random() * targ.size_x;
 615                                                         nearest_y = m1_y + random() * targ.size_y;
 616                                                         nearest_z = m1_z + random() * targ.size_z;
 617                                                 }
 618                                         }
 619                                 }
 620                         }
 621                 targ = targ.chain;
 622         }
 623 }
 624
 625 /*
 626 entity  multi_ent;
 627 float   multi_damage;
 628 vector  multi_force;
 629
 630 void ClearMultiDamage (void)
 631 {
 632         multi_ent = world;
 633         multi_damage = 0;
 634         multi_force = '0 0 0';
 635 }
 636
 637 void ApplyMultiDamage (void)
 638 {
 639         if (!multi_ent)
 640                 return;
 641
 642         Damage (self, multi_ent.origin, multi_ent, 0, multi_damage, multi_force);
 643 }
 644
 645 void AddMultiDamage (entity hit, float damage, vector force)
 646 {
 647         if (!hit)
 648                 return;
 649
 650         if (hit != multi_ent)
 651         {
 652                 ApplyMultiDamage ();
 653                 ClearMultiDamage ();
 654                 multi_ent = hit;
 655         }
 656         multi_damage = multi_damage + damage;
 657         multi_force = multi_force + force;
 658 }
 659
 660 void FireBullets (float shotcount, vector dir, vector spread, float deathtype)
 661 {
 662         vector  direction;
 663         vector  source;
 664         vector  vel;
 665         vector  org;
 666
 667         makevectors (self.v_angle);
 668
 669         source = self.origin + v_forward * 10;  // FIXME
 670         source_x = self.absmin_z + self.size_z * 0.7;   // ??? whaddabout view_ofs
 671
 672         // LordHavoc: better to use normal damage
 673         //ClearMultiDamage ();
 674         while (shotcount > 0)
 675         {
 676                 direction = dir + crandom () * spread_x * v_right + crandom () * spread_y * v_up;
 677
 678                 traceline (source, source + direction * 2048, FALSE, self);
 679                 if (trace_fraction != 1.0)
 680                 {
 681                         vel = normalize (direction + v_up * crandom () + v_right * crandom ());
 682                         vel = vel + 2 * trace_plane_normal;
 683                         vel = vel * 200;
 684
 685                         org = trace_endpos - direction * 4;
 686
 687                         if (!trace_ent.takedamage)
 688                                 te_gunshot (org);
 689                         // LordHavoc: better to use normal damage
 690                         //AddMultiDamage (trace_ent, 4, direction * 4);
 691                         Damage (trace_ent, self, self, 4, deathtype, trace_endpos, direction * 4);
 692                 }
 693
 694                 shotcount = shotcount + 1;
 695         }
 696
 697         // LordHavoc: better to use normal damage
 698         //ApplyMultiDamage ();
 699 }
 700 */
 701
 702
 703