data/qcsrc/server/cl_weapons.qc

   1
   2 // generic weapons table
   3 // add new weapons here
   4 float weapon_action(float wpn, float wrequest)
   5 {
   6         if (wpn == WEP_LASER)
   7                 return w_laser(wrequest);
   8         else if (wpn == WEP_SHOTGUN)
   9                 return w_shotgun(wrequest);
  10         else if (wpn == WEP_UZI)
  11                 return w_uzi(wrequest);
  12         else if (wpn == WEP_GRENADE_LAUNCHER)
  13                 return w_glauncher(wrequest);
  14         else if (wpn == WEP_ELECTRO)
  15                 return w_electro(wrequest);
  16         else if (wpn == WEP_CRYLINK)
  17                 return w_crylink(wrequest);
  18         else if (wpn == WEP_NEX)
  19                 return w_nex(wrequest);
  20         else if (wpn == WEP_HAGAR)
  21                 return w_hagar(wrequest);
  22         else if (wpn == WEP_ROCKET_LAUNCHER)
  23                 return w_rlauncher(wrequest);
  24         return FALSE;
  25 };
  26
  27 string W_Name(float weaponid)
  28 {
  29         if(weaponid == WEP_LASER)             return "Laser";
  30         if(weaponid == WEP_UZI)               return "Machine Gun";
  31         if(weaponid == WEP_SHOTGUN)           return "Shotgun";
  32         if(weaponid == WEP_GRENADE_LAUNCHER)  return "Mortar";
  33         if(weaponid == WEP_ELECTRO)           return "Electro";
  34         if(weaponid == WEP_NEX)               return "Nex";
  35         if(weaponid == WEP_HAGAR)             return "Hagar";
  36         if(weaponid == WEP_ROCKET_LAUNCHER)   return "Rocket Launcher";
  37         if(weaponid == WEP_CRYLINK)           return "Crylink";
  38         return "@!#%'n Tuba";
  39 }
  40
  41 float W_ItemCode(float wpn)
  42 {
  43         switch(wpn)
  44         {
  45                 case WEP_LASER:            return IT_LASER;
  46                 case WEP_SHOTGUN:          return IT_SHOTGUN;
  47                 case WEP_UZI:              return IT_UZI;
  48                 case WEP_GRENADE_LAUNCHER: return IT_GRENADE_LAUNCHER;
  49                 case WEP_ELECTRO:          return IT_ELECTRO;
  50                 case WEP_CRYLINK:          return IT_CRYLINK;
  51                 case WEP_NEX:              return IT_NEX;
  52                 case WEP_HAGAR:            return IT_HAGAR;
  53                 case WEP_ROCKET_LAUNCHER:  return IT_ROCKET_LAUNCHER;
  54                 default:                   return 0;
  55         }
  56 }
  57
  58 float W_AmmoItemCode(float wpn)
  59 {
  60         switch(wpn)
  61         {
  62                 case WEP_SHOTGUN:          return IT_SHELLS;
  63                 case WEP_UZI:              return IT_NAILS;
  64                 case WEP_GRENADE_LAUNCHER: return IT_ROCKETS;
  65                 case WEP_ELECTRO:          return IT_CELLS;
  66                 case WEP_CRYLINK:          return IT_CELLS;
  67                 case WEP_NEX:              return IT_CELLS;
  68                 case WEP_HAGAR:            return IT_ROCKETS;
  69                 case WEP_ROCKET_LAUNCHER:  return IT_ROCKETS;
  70                 default:                   return 0;
  71         }
  72 }
  73
  74 // think function for tossed weapons
  75 void thrown_wep_think()
  76 {
  77         self.solid = SOLID_TRIGGER;
  78         self.owner = world;
  79         SUB_SetFade(self, time + 20, 1);
  80         setorigin(self, self.origin);
  81 };
  82
  83 // toss current weapon
  84 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
  85 {
  86         local float w, ammo;
  87         local entity wep, e;
  88         local .float ammofield;
  89
  90         w = self.weapon;
  91         if (w == 0)
  92                 return; // just in case
  93         if (w == WEP_LASER)
  94                 return;
  95         if (g_instagib)
  96                 return;
  97         if (g_rocketarena)
  98                 return;
  99         if (g_lms)
 100                 return;
 101         if (g_nixnex)
 102                 return;
 103         if (!cvar("g_pickup_items"))
 104                 return;
 105
 106         e = self;
 107         wep = spawn();
 108         self = wep;
 109
 110         setorigin(wep, e.origin + delta);
 111         makevectors(e.angles);
 112         wep.classname = "droppedweapon";
 113         wep.velocity = velo; // e.velocity * 0.5 + v_forward * 750;
 114         SUB_SetFade(wep, time + 20, 1);
 115
 116         ammofield = Item_CounterField(W_AmmoItemCode(w));
 117         w = W_ItemCode(w);
 118         if(!(e.items & w))
 119         {
 120                 remove(wep);
 121                 goto leave;
 122         }
 123         Item_SpawnByItemCode(w);
 124         if(startitem_failed)
 125                 goto leave;
 126         if(doreduce)
 127         {
 128                 ammo = min(e.ammofield, wep.ammofield);
 129                 wep.ammofield = ammo;
 130                 e.ammofield -= ammo;
 131         }
 132
 133         if(e.items & w)
 134                 if(e.health >= 1)
 135                         sprint(e, strcat("You dropped the ^2", wep.netname, " with ", ftos(wep.ammofield), " ammo", "\n"));
 136
 137         wep.owner = e;
 138         setorigin(wep, wep.origin);
 139         wep.nextthink = time + 0.5;
 140         wep.think = thrown_wep_think;
 141         wep.classname = "droppedweapon";
 142         wep.flags = wep.flags | FL_TOSSED;
 143         e.items = e.items - (e.items & w);
 144         e.switchweapon = w_getbestweapon(e);
 145         wep.colormap = e.colormap;
 146         if (e.switchweapon != e.weapon)
 147                 e.cnt = e.weapon;
 148
 149 :leave
 150         self = e;
 151 };
 152
 153 // switch between weapons
 154 void W_SwitchWeapon(float imp)
 155 {
 156         if (self.weapon != imp)
 157         if (client_hasweapon(self, imp, TRUE, TRUE))
 158         {
 159                 self.cnt = self.weapon ? self.weapon : self.switchweapon;
 160                 self.switchweapon = imp;
 161         }
 162 };
 163
 164 // next weapon
 165 void W_NextWeapon()
 166 {
 167         local float weaponwant, maxtries;
 168
 169         maxtries = WEP_LAST;
 170
 171         weaponwant = self.switchweapon + 1;
 172         if (weaponwant < WEP_FIRST)
 173                 weaponwant = WEP_LAST;
 174         if (weaponwant > WEP_LAST)
 175                 weaponwant = WEP_FIRST;
 176         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 177         {
 178                 if(!maxtries)
 179                         return;
 180
 181                 maxtries -= 1;
 182                 weaponwant = weaponwant + 1;
 183                 if (weaponwant < WEP_FIRST)
 184                         weaponwant = WEP_LAST;
 185                 if (weaponwant > WEP_LAST)
 186                         weaponwant = WEP_FIRST;
 187         }
 188         self.cnt = self.weapon ? self.weapon : self.switchweapon;
 189         self.switchweapon = weaponwant;
 190 };
 191
 192 // prev weapon
 193 void W_PreviousWeapon()
 194 {
 195         local float weaponwant, maxtries;
 196
 197         maxtries = WEP_LAST;
 198
 199         weaponwant = self.switchweapon - 1;
 200         if (weaponwant < WEP_FIRST)
 201                 weaponwant = WEP_LAST;
 202         if (weaponwant > WEP_LAST)
 203                 weaponwant = WEP_FIRST;
 204         while(!client_hasweapon(self, weaponwant, TRUE, FALSE))
 205         {
 206                 if(!maxtries)
 207                         return;
 208
 209                 maxtries -= 1;
 210                 weaponwant = weaponwant - 1;
 211                 if (weaponwant < WEP_FIRST)
 212                         weaponwant = WEP_LAST;
 213                 if (weaponwant > WEP_LAST)
 214                         weaponwant = WEP_FIRST;
 215         }
 216         self.cnt = self.weapon ? self.weapon : self.switchweapon;
 217         self.switchweapon = weaponwant;
 218 };
 219
 220 void W_CycleWeapon(string weaponorder, float dir)
 221 {
 222         float n, i, weaponwant, first_valid, prev_valid, switchtonext, switchtolast;
 223         n = tokenize(weaponorder);
 224         switchtonext = switchtolast = 0;
 225         first_valid = prev_valid = -1;
 226
 227         if(dir == 0)
 228                 switchtonext = 1;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 weaponwant = stof(argv(i));
 233                 if(client_hasweapon(self, weaponwant, TRUE, FALSE))
 234                 {
 235                         if(switchtonext)
 236                         {
 237                                 W_SwitchWeapon(weaponwant);
 238                                 return;
 239                         }
 240                         if(first_valid < 0)
 241                                 first_valid = weaponwant;
 242                         prev_valid = weaponwant;
 243                         if(weaponwant == self.weapon)
 244                         {
 245                                 if(dir >= 0)
 246                                         switchtonext = 1;
 247                                 else if(prev_valid >= 0)
 248                                         W_SwitchWeapon(prev_valid);
 249                                 else
 250                                 {
 251                                         switchtolast = 1;
 252                                         break;
 253                                 }
 254                         }
 255                 }
 256         }
 257         if(first_valid >= 0)
 258         {
 259                 if(switchtolast)
 260                         W_SwitchWeapon(prev_valid);
 261                 else
 262                         W_SwitchWeapon(first_valid);
 263                 return;
 264         }
 265         // none available
 266         sprint(self, "You do not have any of the specified weapons.\n");
 267 }
 268
 269 // Bringed back weapon frame
 270 void W_WeaponFrame()
 271 {
 272         if((arena_roundbased && time < warmup) || ((time < restart_countdown) && !cvar("sv_ready_restart_after_countdown")))
 273                 return;
 274
 275         if (!self.weaponentity || self.health < 1)
 276                 return; // Dead player can't use weapons and injure impulse commands
 277
 278         if(!self.switchweapon)
 279         {
 280                 self.weapon = 0;
 281                 self.weaponentity.state = WS_CLEAR;
 282                 return;
 283         }
 284
 285         makevectors(self.v_angle);
 286
 287         // Change weapon
 288         if (self.weapon != self.switchweapon)
 289         {
 290                 if (self.weaponentity.state == WS_CLEAR)
 291                 {
 292                         player_setanim(self.anim_draw, FALSE, TRUE, TRUE);
 293                         self.weaponentity.state = WS_RAISE;
 294                         weapon_action(self.switchweapon, WR_SETUP);
 295                         // VorteX: add player model weapon select frame here
 296                         // setcustomframe(PlayerWeaponRaise);
 297                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_ready);
 298                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 299                 }
 300                 else if (self.weaponentity.state == WS_READY)
 301                 {
 302 #ifndef INDEPENDENT_ATTACK_FINISHED
 303                         if(ATTACK_FINISHED(self) <= time + frametime * 0.5)
 304                         {
 305 #endif
 306                         sound (self, CHAN_WEAPON, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 307                         self.weaponentity.state = WS_DROP;
 308                         // set up weapon switch think in the future, and start drop anim
 309                         weapon_thinkf(WFRAME_IDLE, cvar("g_balance_weaponswitchdelay"), w_clear);
 310                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 311 #ifndef INDEPENDENT_ATTACK_FINISHED
 312                         }
 313 #endif
 314                 }
 315         }
 316
 317         // call the think code which may fire the weapon
 318         // and do so multiple times to resolve framerate dependency issues if the
 319         // server framerate is very low and the weapon fire rate very high
 320         local float c;
 321         c = 0;
 322         while (c < 5)
 323         {
 324                 c = c + 1;
 325                 weapon_action(self.weapon, WR_THINK);
 326                 if (time + frametime * 0.5 >= self.weapon_nextthink)
 327                         self.weapon_think();
 328         }
 329
 330         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 331         //if (ATTACK_FINISHED(self) < time)
 332         //      ATTACK_FINISHED(self) = time;
 333
 334         //if (self.weapon_nextthink < time)
 335         //      self.weapon_nextthink = time;
 336
 337         // update currentammo incase it has changed
 338         if (self.items & IT_CELLS)
 339                 self.currentammo = self.ammo_cells;
 340         else if (self.items & IT_ROCKETS)
 341                 self.currentammo = self.ammo_rockets;
 342         else if (self.items & IT_NAILS)
 343                 self.currentammo = self.ammo_nails;
 344         else if (self.items & IT_SHELLS)
 345                 self.currentammo = self.ammo_shells;
 346         else
 347                 self.currentammo = 1;
 348
 349 };
 350
 351 float nixnex_weapon;
 352 float nixnex_nextchange;
 353 float nixnex_nextweapon;
 354 .float nixnex_lastchange_id;
 355 .float nixnex_lastinfotime;
 356 .float nixnex_nextincr;
 357
 358 void Nixnex_ChooseNextWeapon()
 359 {
 360         float numberof, id;
 361         numberof = WEP_LAST - WEP_FIRST; // all but the current one
 362         if(g_nixnex_with_laser)
 363                 numberof = numberof - 1;
 364         id = WEP_FIRST + ceil(random() * numberof) - 1;
 365
 366         if(g_nixnex_with_laser) // skip the laser if needed
 367                 id = id + 1;
 368
 369         if(id >= nixnex_weapon) // skip the current weapon
 370                 id = id + 1;
 371
 372         if(id < WEP_FIRST) // can't happen, but to be sure...
 373         {
 374                 dprint("Won't happen (id < WEP_FIRST)\n");
 375                 id = WEP_FIRST;
 376         }
 377         if(id > WEP_LAST) // either
 378         {
 379                 dprint("Won't happen (id > WEP_LAST)\n");
 380                 id = WEP_LAST;
 381         }
 382
 383         nixnex_nextweapon = id;
 384 }
 385
 386 void Nixnex_GiveCurrentWeapon()
 387 {
 388         float dt;
 389         if(g_nixnex)
 390         {
 391                 if(!nixnex_nextweapon)
 392                         Nixnex_ChooseNextWeapon();
 393
 394                 dt = ceil(nixnex_nextchange - time);
 395
 396                 if(dt <= 0)
 397                 {
 398                         nixnex_weapon = nixnex_nextweapon;
 399                         nixnex_nextweapon = 0;
 400                         nixnex_nextchange = time + cvar("g_balance_nixnex_roundtime");
 401                         //weapon_action(nixnex_weapon, WR_PRECACHE); // forget it, too slow
 402                 }
 403
 404                 if(nixnex_nextchange != self.nixnex_lastchange_id) // this shall only be called once per round!
 405                 {
 406                         self.nixnex_lastchange_id = nixnex_nextchange;
 407                         if (cvar("g_use_ammunition"))
 408                         {
 409                                 self.ammo_shells = cvar("g_balance_nixnex_ammo_shells");
 410                                 self.ammo_nails = cvar("g_balance_nixnex_ammo_nails");
 411                                 self.ammo_rockets = cvar("g_balance_nixnex_ammo_rockets");
 412                                 self.ammo_cells = cvar("g_balance_nixnex_ammo_cells");
 413                         }
 414                         else
 415                         {
 416                                 self.ammo_shells = cvar("g_pickup_shells_max");
 417                                 self.ammo_nails = cvar("g_pickup_nails_max");
 418                                 self.ammo_rockets = cvar("g_pickup_rockets_max");
 419                                 self.ammo_cells = cvar("g_pickup_cells_max");
 420                         }
 421                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 422                         if(dt >= 1 && dt <= 5)
 423                                 self.nixnex_lastinfotime = -42;
 424                         else
 425                                 centerprint(self, strcat("\n\n^2Active weapon: ^3", W_Name(nixnex_weapon), "\n"));
 426                 }
 427                 if(self.nixnex_lastinfotime != dt)
 428                 {
 429                         self.nixnex_lastinfotime = dt; // initial value 0 should count as "not seen"
 430                         if(dt >= 1 && dt <= 5)
 431                                 centerprint(self, strcat("^3", ftos(dt), "^2 seconds until weapon change...\n\nNext weapon: ^3", W_Name(nixnex_nextweapon), "\n"));
 432                 }
 433
 434                 if(cvar("g_use_ammunition") && time > self.nixnex_nextincr)
 435                 {
 436                         self.ammo_shells = self.ammo_shells + cvar("g_balance_nixnex_ammoincr_shells");
 437                         self.ammo_nails = self.ammo_nails + cvar("g_balance_nixnex_ammoincr_nails");
 438                         self.ammo_rockets = self.ammo_rockets + cvar("g_balance_nixnex_ammoincr_rockets");
 439                         self.ammo_cells = self.ammo_cells + cvar("g_balance_nixnex_ammoincr_cells");
 440                         self.nixnex_nextincr = time + cvar("g_balance_nixnex_incrtime");
 441                 }
 442
 443                 self.items = self.items - (self.items & (IT_LASER | IT_SHOTGUN | IT_UZI | IT_GRENADE_LAUNCHER | IT_ELECTRO | IT_CRYLINK | IT_NEX | IT_HAGAR | IT_ROCKET_LAUNCHER));
 444                 if(g_nixnex_with_laser)
 445                         self.items = self.items | IT_LASER;
 446                 self.items = self.items | W_ItemCode(nixnex_weapon);
 447
 448                 if(self.switchweapon != nixnex_weapon)
 449                         if(!client_hasweapon(self, self.switchweapon, TRUE, FALSE))
 450                                 if(client_hasweapon(self, nixnex_weapon, TRUE, FALSE))
 451                                         W_SwitchWeapon(nixnex_weapon);
 452         }
 453 }
 454