data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector animparseline(float animfile)
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize_sane(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void player_setupanimsformodel()
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void player_setanim(vector anim, float looping, float override, float restart)
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void player_updateframe()
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save;
 261         if(sv_gentle < 1)
 262                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 263         // damage resistance (ignore most of the damage from a bullet or similar)
 264         damage = max(damage - 5, 1);
 265
 266         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 267         take = bound(0, damage - save, damage);
 268
 269         if (save > 10)
 270                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 271         else if (take > 30)
 272                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 273         else if (take > 10)
 274                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 275
 276         if(independent_players)
 277         if(sv_gentle < 1) {
 278                 if (take > 50)
 279                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 280                 if (take > 100)
 281                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 282         }
 283
 284         if (!(self.flags & FL_GODMODE))
 285         {
 286                 self.armorvalue = self.armorvalue - save;
 287                 self.health = self.health - take;
 288                 // pause regeneration for 5 seconds
 289                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 290         }
 291         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 292         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 293         self.dmg_inflictor = inflictor;
 294
 295         if (self.health <= -50)
 296         {
 297                 // don't use any animations as a gib
 298                 self.frame = 0;
 299                 self.dead_frame = 0;
 300                 // view just above the floor
 301                 self.view_ofs = '0 0 4';
 302
 303                 // make a juicy mess
 304                 local float multiplier;
 305                 multiplier = 1;
 306                 if (cvar("ekg"))
 307                         multiplier = 5;
 308
 309
 310                 // make a meaty mess
 311                 if(independent_players)
 312                 {
 313                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 314                         self.solid = SOLID_TRIGGER; // undo SOLID_CORPSE
 315                         self.takedamage = DAMAGE_NO; // can't damage this gib, to prevent better jumps from it
 316                 }
 317                 else
 318                         TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 319
 320                 if not(independent_players)
 321                 if(sv_gentle < 1) {
 322                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 323                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 324
 325                         local float c;
 326                         c = 0;
 327
 328                         while (c < multiplier)
 329                         {
 330                                 c = c + 1;
 331                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 332                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 333                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 334                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 335                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 336                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 337
 338                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 339                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 340                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 341                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 342                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 343                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 344                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 345                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 346                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 347                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 348                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 349
 350                                 // these splat on impact
 351                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 352                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 353                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 354                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 355                         }
 356                         sound (self, CHAN_PLAYER, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 357                 }
 358         }
 359 }
 360
 361 void ClientKill_Now_TeamChange();
 362
 363 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 364 {
 365         local float take, save, waves, sdelay;
 366
 367         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 368         if(sv_gentle > 0) {
 369                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 370         } else {
 371                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 372         }
 373
 374         if(g_arena)
 375         if(numspawned < 2)
 376                 return;
 377
 378         if (!g_minstagib)
 379         {
 380                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 381                 take = bound(0, damage - save, damage);
 382         }
 383         else
 384         {
 385                 save = 0;
 386                 take = damage;
 387         }
 388
 389         if (save > 10)
 390                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 391         else if (take > 30)
 392                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 393         else if (take > 10)
 394                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 395
 396         if(sv_gentle < 1)
 397         if not(independent_players)
 398         {
 399                 if (take > 50)
 400                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 401                 if (take > 100)
 402                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 403         }
 404
 405         if (time > self.spawnshieldtime)
 406         {
 407                 if (!(self.flags & FL_GODMODE))
 408                 {
 409                         self.armorvalue = self.armorvalue - save;
 410                         self.health = self.health - take;
 411                         // pause regeneration for 5 seconds
 412                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 413
 414                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 415                         {
 416                                 self.pain_finished = time + 0.5;        //Supajoe
 417
 418                                 if(sv_gentle < 1) {
 419                                         if (random() > 0.5)
 420                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 421                                         else
 422                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 423
 424                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 425                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 426                                         {
 427                                                 if(self.health > 75) // TODO make a "gentle" version?
 428                                                         PlayerSound(playersound_pain100, CHAN_PAIN, 0);
 429                                                 else if(self.health > 50)
 430                                                         PlayerSound(playersound_pain75, CHAN_PAIN, 0);
 431                                                 else if(self.health > 25)
 432                                                         PlayerSound(playersound_pain50, CHAN_PAIN, 0);
 433                                                 else if(self.health > 1)
 434                                                         PlayerSound(playersound_pain25, CHAN_PAIN, 0);
 435                                         }
 436                                 }
 437
 438                                 // throw off bot aim temporarily
 439                                 local float shake;
 440                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 441                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 442                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 443                         }
 444                 }
 445                 else
 446                         self.max_armorvalue += (save + take);
 447         }
 448         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 449         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 450         self.dmg_inflictor = inflictor;
 451
 452         if(attacker == self)
 453         {
 454                 // don't reset pushltime for self damage as it may be an attempt to
 455                 // escape a lava pit or similar
 456                 //self.pushltime = 0;
 457         }
 458         else if(attacker.classname == "player" || attacker.classname == "gib")
 459         {
 460                 self.pusher = attacker;
 461                 self.pushltime = time + cvar("g_maxpushtime");
 462         }
 463         else if(time < self.pushltime)
 464         {
 465                 attacker = self.pusher;
 466                 self.pushltime = max(self.pushltime, time + 0.6);
 467         }
 468         else
 469                 self.pushltime = 0;
 470
 471         if (self.health < 1)
 472         {
 473                 float defer_ClientKill_Now_TeamChange;
 474                 defer_ClientKill_Now_TeamChange = FALSE;
 475
 476                 if(sv_gentle < 1) // TODO make a "gentle" version?
 477                 {
 478                         if(deathtype == DEATH_DROWN)
 479                                 PlayerSound(playersound_drown, CHAN_PAIN, 0);
 480                         else
 481                                 PlayerSound(playersound_death, CHAN_PAIN, 0);
 482                 }
 483
 484                 // get rid of kill indicator
 485                 if(self.killindicator)
 486                 {
 487                         remove(self.killindicator);
 488                         self.killindicator = world;
 489                         if(self.killindicator_teamchange)
 490                                 defer_ClientKill_Now_TeamChange = TRUE;
 491
 492                         if(self.classname == "body")
 493                         if(deathtype == DEATH_KILL)
 494                         {
 495                                 // for the lemmings fans, a small harmless explosion
 496                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 497                         }
 498                 }
 499
 500                 // become fully visible
 501                 self.alpha = 1;
 502                 // clear selected player display
 503                 ClearSelectedPlayer();
 504                 // throw a weapon
 505                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 506                 // print an obituary message
 507                 Obituary (attacker, inflictor, self, deathtype);
 508                 race_PreDie();
 509                 DropAllRunes(self);
 510                 if(self == attacker)
 511                         kh_Key_DropAll(self, TRUE);
 512                 else if(attacker.classname == "player" || attacker.classname == "gib")
 513                         kh_Key_DropAll(self, FALSE);
 514                 else
 515                         kh_Key_DropAll(self, TRUE);
 516                 if(self.flagcarried)
 517                 {
 518                         if(attacker.classname != "player" && attacker.classname != "gib")
 519                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 520                         else if(attacker.team == self.team)
 521                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 522                         else
 523                                 DropFlag(self.flagcarried, world, attacker);
 524                 }
 525                 Portal_ClearAllLater(self);
 526                 // clear waypoints
 527                 WaypointSprite_PlayerDead();
 528                 // make the corpse upright (not tilted)
 529                 self.angles_x = 0;
 530                 self.angles_z = 0;
 531                 // don't spin
 532                 self.avelocity = '0 0 0';
 533                 // view from the floor
 534                 self.view_ofs = '0 0 -8';
 535                 // toss the corpse
 536                 self.movetype = MOVETYPE_TOSS;
 537                 // shootable corpse
 538                 self.solid = SOLID_CORPSE;
 539                 // don't stick to the floor
 540                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 541                 // dying animation
 542                 self.deadflag = DEAD_DYING;
 543                 // when to allow respawn
 544                 sdelay = 0;
 545                 waves = 0;
 546                 if(cvar("g_respawn_mapsettings"))
 547                 {
 548                         sdelay = cvar("g_respawn_mapsettings_delay");
 549                         waves = cvar("g_respawn_mapsettings_waves");
 550                 }
 551                 if(!sdelay)
 552                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 553                 if(!sdelay)
 554                         sdelay = cvar("g_respawn_delay");
 555                 if(!waves)
 556                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 557                 if(!waves)
 558                         waves = cvar("g_respawn_waves");
 559                 if(waves)
 560                         self.death_time = ceil((time + sdelay) / waves) * waves;
 561                 else
 562                         self.death_time = time + sdelay;
 563                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 564                         self.respawn_countdown = 10; // first number to count down from is 10
 565                 else
 566                         self.respawn_countdown = -1; // do not count down
 567                 if (random() < 0.5)
 568                 {
 569                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 570                         self.dead_frame = self.anim_dead1_x;
 571                 }
 572                 else
 573                 {
 574                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 575                         self.dead_frame = self.anim_dead2_x;
 576                 }
 577                 // set damage function to corpse damage
 578                 self.event_damage = PlayerCorpseDamage;
 579                 // call the corpse damage function just in case it wants to gib
 580                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 581                 // set up to fade out later
 582                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 583
 584                 // remove laserdot
 585                 if(self.weaponentity)
 586                         if(self.weaponentity.lasertarget)
 587                                 remove(self.weaponentity.lasertarget);
 588
 589                 if(clienttype(self) == CLIENTTYPE_REAL)
 590                 {
 591                         self.fixangle = TRUE;
 592                         //msg_entity = self;
 593                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 594                         //WriteAngle (MSG_ONE, self.v_angle_x);
 595                         //WriteAngle (MSG_ONE, self.v_angle_y);
 596                         //WriteAngle (MSG_ONE, 80);
 597                 }
 598
 599                 if(g_arena)
 600                         Spawnqueue_Unmark(self);
 601
 602                 if(defer_ClientKill_Now_TeamChange)
 603                         ClientKill_Now_TeamChange();
 604
 605                 if(sv_gentle > 0) {
 606                         // remove corpse
 607                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 608                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 609                 }
 610         }
 611 }
 612
 613 float UpdateSelectedPlayer_countvalue(float v)
 614 {
 615         return max(0, (v - 1.0) / 0.5);
 616 }
 617
 618 // returns: -2 if no hit, otherwise cos of the angle
 619 // uses the global v_angle
 620 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 621 {
 622         vector so, d;
 623         float c;
 624
 625         if(p == self)
 626                 return -2;
 627
 628         if(p.deadflag)
 629                 return -2;
 630
 631         so = self.origin + self.view_ofs;
 632         d = p.origin - so;
 633
 634         // misaimed?
 635         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 636                 return -2;
 637
 638         // now find the cos of the angle...
 639         c = normalize(d) * v_forward;
 640
 641         if(c <= mincosangle)
 642                 return -2;
 643
 644         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 645         if(trace_fraction < 1)
 646                 return -2;
 647
 648         return c;
 649 }
 650
 651 void ClearSelectedPlayer()
 652 {
 653         if(self.selected_player)
 654         {
 655                 centerprint_expire(self, CENTERPRIO_POINT);
 656                 self.selected_player = world;
 657                 self.selected_player_display_needs_update = FALSE;
 658         }
 659 }
 660
 661 void UpdateSelectedPlayer()
 662 {
 663         entity selected;
 664         float selected_score;
 665         selected = world;
 666         selected_score = 0.95; // 18 degrees
 667
 668         if(!cvar("sv_allow_shownames"))
 669                 return;
 670
 671         if(clienttype(self) != CLIENTTYPE_REAL)
 672                 return;
 673
 674         if(self.cvar_cl_shownames == 0)
 675                 return;
 676
 677         if(self.cvar_cl_shownames == 1 && !teams_matter)
 678                 return;
 679
 680         makevectors(self.v_angle); // sets v_forward
 681
 682         // 1. cursor trace is always right
 683         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 684         {
 685                 selected = self.cursor_trace_ent;
 686         }
 687         else
 688         {
 689                 // 2. if we don't have a cursor trace, find the player which is least
 690                 //    mis-aimed at
 691                 entity p;
 692                 FOR_EACH_PLAYER(p)
 693                 {
 694                         float c;
 695                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 696                         if(c >= -1)
 697                         {
 698                                 selected = p;
 699                                 selected_score = c;
 700                         }
 701                 }
 702         }
 703
 704         if(selected)
 705         {
 706                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 707         }
 708         else
 709         {
 710                 if(time < self.selected_player_display_timeout)
 711                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 712                                 selected = self.selected_player;
 713         }
 714
 715         if(selected)
 716         {
 717                 if(selected == self.selected_player)
 718                 {
 719                         float save;
 720                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 721                         self.selected_player_count = self.selected_player_count + frametime;
 722                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 723                         {
 724                                 string namestr, healthstr;
 725                                 namestr = playername(selected);
 726                                 if(teams_matter)
 727                                 {
 728                                         healthstr = ftos(floor(selected.health));
 729                                         if(self.team == selected.team)
 730                                         {
 731                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 732                                                 self.selected_player_display_needs_update = TRUE;
 733                                         }
 734                                 }
 735                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 736                         }
 737                 }
 738                 else
 739                 {
 740                         ClearSelectedPlayer();
 741                         self.selected_player = selected;
 742                         self.selected_player_time = time;
 743                         self.selected_player_count = 0;
 744                         self.selected_player_display_needs_update = FALSE;
 745                 }
 746         }
 747         else
 748         {
 749                 ClearSelectedPlayer();
 750         }
 751
 752         if(self.selected_player)
 753                 self.last_selected_player = self.selected_player;
 754 }
 755
 756 float GetVoiceMessageTeamsayType(string type)
 757 {
 758         if(type == "taunt")
 759                 return 0;
 760         if(type == "teamshoot")
 761                 return 2;
 762         if(type == "teamshoot_auto")
 763                 return 3;
 764         return 1;
 765 }
 766
 767 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 768 float GetPlayerSoundSampleField_notFound;
 769 float GetPlayerSoundSampleField_fixed;
 770 .string GetVoiceMessageSampleField(string type)
 771 {
 772         GetPlayerSoundSampleField_notFound = 0;
 773         GetPlayerSoundSampleField_fixed = 0;
 774         switch(type)
 775         {
 776 #define _VOICEMSG(m) case #m: return playersound_##m;
 777                 ALLVOICEMSGS
 778 #undef _VOICEMSG
 779                 // exception:
 780                 case "teamshoot_auto": return playersound_teamshoot;
 781         }
 782         GetPlayerSoundSampleField_notFound = 1;
 783         return playersound_taunt;
 784 }
 785
 786 .string GetPlayerSoundSampleField(string type)
 787 {
 788         GetPlayerSoundSampleField_notFound = 0;
 789         GetPlayerSoundSampleField_fixed = 0;
 790         switch(type)
 791         {
 792 #define _VOICEMSG(m) case #m: return playersound_##m;
 793                 ALLPLAYERSOUNDS
 794 #undef _VOICEMSG
 795         }
 796         GetPlayerSoundSampleField_notFound = 1;
 797         return playersound_taunt;
 798 }
 799
 800 void PrecacheGlobalSound(string samplestring)
 801 {
 802         float n, i;
 803         tokenize_sane(samplestring);
 804         n = stof(argv(1));
 805         if(n > 0)
 806         {
 807                 for(i = 1; i <= n; ++i)
 808                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 809         }
 810         else
 811         {
 812                 precache_sound(strcat(argv(0), ".wav"));
 813         }
 814 }
 815
 816 void PrecachePlayerSounds(string f)
 817 {
 818         float fh;
 819         string s;
 820         fh = fopen(f, FILE_READ);
 821         if(fh < 0)
 822                 return;
 823         while((s = fgets(fh)))
 824         {
 825                 if(tokenize_sane(s) != 3)
 826                 {
 827                         dprint("Invalid sound info line: ", s, "\n");
 828                         continue;
 829                 }
 830                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 831         }
 832         fclose(fh);
 833 }
 834
 835 void ClearPlayerSounds()
 836 {
 837 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 838         ALLPLAYERSOUNDS
 839         ALLVOICEMSGS
 840 #undef _VOICEMSG
 841 }
 842
 843 void LoadPlayerSounds(string f, float first)
 844 {
 845         float fh;
 846         string s;
 847         var .string field;
 848         fh = fopen(f, FILE_READ);
 849         if(fh < 0)
 850                 return;
 851         while((s = fgets(fh)))
 852         {
 853                 if(tokenize_sane(s) != 3)
 854                         continue;
 855                 field = GetPlayerSoundSampleField(argv(0));
 856                 if(GetPlayerSoundSampleField_notFound)
 857                         field = GetVoiceMessageSampleField(argv(0));
 858                 if(GetPlayerSoundSampleField_notFound)
 859                         continue;
 860                 if(GetPlayerSoundSampleField_fixed)
 861                         if not(first)
 862                                 continue;
 863                 if(self.field)
 864                         strunzone(self.field);
 865                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 866         }
 867         fclose(fh);
 868 }
 869
 870 .float modelindex_for_playersound;
 871 void UpdatePlayerSounds()
 872 {
 873         if(self.modelindex == self.modelindex_for_playersound)
 874                 return;
 875         self.modelindex_for_playersound = self.modelindex;
 876         ClearPlayerSounds();
 877         LoadPlayerSounds("sound/player/default.sounds", 1);
 878         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 879 }
 880
 881 void GlobalSound(string sample, float chan, float teamsay)
 882 {
 883         float n;
 884
 885         if(sample == "")
 886                 return;
 887
 888         tokenize_sane(sample);
 889         n = stof(argv(1));
 890         if(n > 0)
 891                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
 892         else
 893                 sample = strcat(argv(0), ".wav"); // randomization
 894
 895         if(teamsay == 3) // only to last attacker
 896         {
 897                 if(self.pusher)
 898                         if(self.pusher.team == self.team)
 899                         {
 900                                 msg_entity = self.pusher;
 901                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 902                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 903                         }
 904         }
 905         else if(teamsay == 2) // only to last attacker and self
 906         {
 907                 if(self.pusher)
 908                         if(self.pusher.team == self.team)
 909                         {
 910                                 msg_entity = self.pusher;
 911                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 912                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 913                                 msg_entity = self;
 914                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 915                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 916                         }
 917         }
 918         else if(teamsay == 0) // to everyone
 919         {
 920                 // broadcast the sound, but it's directional
 921                 sound(self, chan, sample, VOL_BASE, ATTN_NORM);
 922         }
 923         else if(teamsay == 1) // to the same team
 924         {
 925                 if(teams_matter)
 926                 {
 927                         entity e;
 928                         FOR_EACH_REALCLIENT(e)
 929                                 if(!teams_matter || e.team == self.team)
 930                                 {
 931                                         msg_entity = e;
 932                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
 933                                 }
 934                 }
 935                 else
 936                 {
 937                         sound(self, chan, sample, VOL_BASE, ATTN_NONE);
 938                 }
 939         }
 940 }
 941
 942 void PlayerSound(.string samplefield, float chan, float teamsay)
 943 {
 944         string sample;
 945         sample = self.samplefield;
 946         GlobalSound(sample, chan, teamsay);
 947 }
 948
 949 void VoiceMessage(string type)
 950 {
 951         var .string sample;
 952         var float teamsay;
 953         sample = GetVoiceMessageSampleField(type);
 954
 955         if(GetPlayerSoundSampleField_notFound)
 956         {
 957                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 958                 return;
 959         }
 960
 961         teamsay = GetVoiceMessageTeamsayType(type);
 962
 963         PlayerSound(sample, CHAN_VOICE, teamsay);
 964 }