data/qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, "\t", ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, "\t", ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep > WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_nexuiz = oldself.modelindex_lod0_from_nexuiz;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.takedamage = oldself.takedamage;
 146         self.think = oldself.think;
 147         self.customizeentityforclient = oldself.customizeentityforclient;
 148         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 149         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 150         if (keepvelocity == 1)
 151                 self.velocity = oldself.velocity;
 152         self.oldvelocity = self.velocity;
 153         self.fade_time = oldself.fade_time;
 154         self.fade_rate = oldself.fade_rate;
 155         //self.weapon = oldself.weapon;
 156         setorigin(self, oldself.origin);
 157         setsize(self, oldself.mins, oldself.maxs);
 158         self.prevorigin = oldself.origin;
 159         self.reset = SUB_Remove;
 160
 161         Drag_MoveDrag(oldself, self);
 162
 163         self = oldself;
 164 }
 165
 166 float player_getspecies()
 167 {
 168         local float glob, i, j, fh, len, s, sk;
 169         local string fn, l;
 170
 171         s = -1;
 172
 173         glob = search_begin("models/player/*.txt", TRUE, TRUE);
 174         if(glob < 0)
 175                 return s;
 176         for(j = 0; j <= 1; ++j)
 177         {
 178                 for(i = 0; i < search_getsize(glob); ++i)
 179                 {
 180                         fn = search_getfilename(glob, i);
 181                         fh = fopen(fn, FILE_READ);
 182                         if(fh < 0)
 183                                 continue;
 184                         fgets(fh); fgets(fh);
 185                         sk = stof(fgets(fh));
 186                         if(sk == (j ? 0 : self.skinindex)) // 2nd pass skips the skin test
 187                         if(fgets(fh) == self.model)
 188                         {
 189                                 l = fgets(fh);
 190                                 len = tokenize_console(l);
 191                                 if (len != 2)
 192                                         goto nospecies;
 193                                 if (argv(0) != "species")
 194                                         goto nospecies;
 195                                 switch(argv(1))
 196                                 {
 197                                         case "human":       s = SPECIES_HUMAN;       break;
 198                                         case "alien":       s = SPECIES_ALIEN;       break;
 199                                         case "robot_shiny": s = SPECIES_ROBOT_SHINY; break;
 200                                         case "robot_rusty": s = SPECIES_ROBOT_RUSTY; break;
 201                                         case "robot_solid": s = SPECIES_ROBOT_SOLID; break;
 202                                         case "animal":      s = SPECIES_ANIMAL;      break;
 203                                         case "reserved":    s = SPECIES_RESERVED;    break;
 204                                 }
 205                         }
 206 :nospecies
 207                         fclose(fh);
 208                 }
 209                 if (s >= 0)
 210                         break;
 211         }
 212         search_end(glob);
 213
 214         if (s < 0)
 215                 s = SPECIES_HUMAN;
 216
 217         return s;
 218 }
 219
 220 void player_setupanimsformodel()
 221 {
 222         local string animfilename;
 223         local float animfile;
 224         // defaults for legacy .zym models without animinfo files
 225         self.anim_die1 = '0 1 0.5'; // 2 seconds
 226         self.anim_die2 = '1 1 0.5'; // 2 seconds
 227         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 228         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 229         self.anim_duckwalk = '4 1 1';
 230         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 231         self.anim_duckidle = '6 1 1';
 232         self.anim_idle = '7 1 1';
 233         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 234         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 235         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 236         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 237         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 238         self.anim_run = '13 1 1';
 239         self.anim_runbackwards = '14 1 1';
 240         self.anim_strafeleft = '15 1 1';
 241         self.anim_straferight = '16 1 1';
 242         self.anim_dead1 = '17 1 1';
 243         self.anim_dead2 = '18 1 1';
 244         self.anim_forwardright = '19 1 1';
 245         self.anim_forwardleft = '20 1 1';
 246         self.anim_backright = '21 1 1';
 247         self.anim_backleft  = '22 1 1';
 248         animparseerror = FALSE;
 249         animfilename = strcat(self.model, ".animinfo");
 250         animfile = fopen(animfilename, FILE_READ);
 251         if (animfile >= 0)
 252         {
 253                 self.anim_die1         = animparseline(animfile);
 254                 self.anim_die2         = animparseline(animfile);
 255                 self.anim_draw         = animparseline(animfile);
 256                 self.anim_duck         = animparseline(animfile);
 257                 self.anim_duckwalk     = animparseline(animfile);
 258                 self.anim_duckjump     = animparseline(animfile);
 259                 self.anim_duckidle     = animparseline(animfile);
 260                 self.anim_idle         = animparseline(animfile);
 261                 self.anim_jump         = animparseline(animfile);
 262                 self.anim_pain1        = animparseline(animfile);
 263                 self.anim_pain2        = animparseline(animfile);
 264                 self.anim_shoot        = animparseline(animfile);
 265                 self.anim_taunt        = animparseline(animfile);
 266                 self.anim_run          = animparseline(animfile);
 267                 self.anim_runbackwards = animparseline(animfile);
 268                 self.anim_strafeleft   = animparseline(animfile);
 269                 self.anim_straferight  = animparseline(animfile);
 270                 self.anim_forwardright = animparseline(animfile);
 271                 self.anim_forwardleft  = animparseline(animfile);
 272                 self.anim_backright    = animparseline(animfile);
 273                 self.anim_backleft     = animparseline(animfile);
 274                 fclose(animfile);
 275
 276                 // derived anims
 277                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 278                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 279
 280                 if (animparseerror)
 281                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 282         }
 283         else
 284                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 285         // reset animstate now
 286         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 287 };
 288
 289 void player_anim (void)
 290 {
 291         updateanim(self);
 292         if (self.weaponentity)
 293                 updateanim(self.weaponentity);
 294
 295         if (self.deadflag != DEAD_NO)
 296         {
 297                 if (time > self.animstate_endtime)
 298                 {
 299                         if (self.maxs_z > 5)
 300                         {
 301                                 self.maxs_z = 5;
 302                                 setsize(self, self.mins, self.maxs);
 303                         }
 304                         self.frame = self.dead_frame;
 305                 }
 306                 return;
 307         }
 308
 309         if (!self.animstate_override)
 310         {
 311                 if (!(self.flags & FL_ONGROUND))
 312                 {
 313                         if (self.crouch)
 314                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 315                         else
 316                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 317                         self.restart_jump = FALSE;
 318                 }
 319                 else if (self.crouch)
 320                 {
 321                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 322                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(self.weapons & W_WeaponBit(j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 374 }
 375
 376 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 377 {
 378         local float take, save;
 379         vector v;
 380         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 381
 382         // damage resistance (ignore most of the damage from a bullet or similar)
 383         damage = max(damage - 5, 1);
 384
 385         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 386         take = v_x;
 387         save = v_y;
 388
 389         if(sound_allowed(MSG_BROADCAST, attacker))
 390         {
 391                 if (save > 10)
 392                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 393                 else if (take > 30)
 394                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 395                 else if (take > 10)
 396                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 397         }
 398
 399         if (take > 50)
 400                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 401         if (take > 100)
 402                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 403
 404         if (!(self.flags & FL_GODMODE))
 405         {
 406                 self.armorvalue = self.armorvalue - save;
 407                 self.health = self.health - take;
 408                 // pause regeneration for 5 seconds
 409                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 410         }
 411         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 412         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 413         self.dmg_inflictor = inflictor;
 414
 415         if (self.health <= -75 && self.modelindex != 0)
 416         {
 417                 // don't use any animations as a gib
 418                 self.frame = 0;
 419                 self.dead_frame = 0;
 420                 // view just above the floor
 421                 self.view_ofs = '0 0 4';
 422
 423                 Violence_GibSplash(self, 1, 1, attacker);
 424                 self.modelindex = 0; // restore later
 425                 self.solid = SOLID_NOT; // restore later
 426         }
 427 }
 428
 429 void ClientKill_Now_TeamChange();
 430
 431 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         local float take, save, waves, sdelay, dh, da;
 434         vector v;
 435         float valid_damage_for_weaponstats;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 461                 force = v_right * vlen(force);
 462                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 463                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 464                 if(f > 0)
 465                 {
 466                         hitloc = ear1;
 467                         force = force * -1;
 468                 }
 469                 else
 470                 {
 471                         hitloc = ear2;
 472                         // force is already good
 473                 }
 474         }
 475         else
 476                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 477
 478         if(g_arena)
 479         if(numspawned < 2)
 480                 return;
 481
 482         if (!g_minstagib)
 483         {
 484                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 485                 take = v_x;
 486                 save = v_y;
 487         }
 488         else
 489         {
 490                 save = 0;
 491                 take = damage;
 492         }
 493
 494         if(sound_allowed(MSG_BROADCAST, attacker))
 495         {
 496                 if (save > 10)
 497                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 498                 else if (take > 30)
 499                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 500                 else if (take > 10)
 501                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 502         }
 503
 504         if (take > 50)
 505                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 506         if (take > 100)
 507                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 508
 509         if (time > self.spawnshieldtime)
 510         {
 511                 if (!(self.flags & FL_GODMODE))
 512                 {
 513                         self.armorvalue = self.armorvalue - save;
 514                         self.health = self.health - take;
 515                         // pause regeneration for 5 seconds
 516                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 517
 518                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 519                         {
 520                                 self.pain_finished = time + 0.5;        //Supajoe
 521
 522                                 if(sv_gentle < 1) {
 523                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 524                                         {
 525                                                 if (random() > 0.5)
 526                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 527                                                 else
 528                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 529                                         }
 530
 531                                         if(sound_allowed(MSG_BROADCAST, attacker))
 532                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 533                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 534                                         {
 535                                                 if(self.health > 75) // TODO make a "gentle" version?
 536                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 537                                                 else if(self.health > 50)
 538                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 539                                                 else if(self.health > 25)
 540                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 541                                                 else if(self.health > 1)
 542                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 543                                         }
 544                                 }
 545
 546                                 // throw off bot aim temporarily
 547                                 local float shake;
 548                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 549                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 550                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 551                         }
 552                 }
 553                 else
 554                         self.max_armorvalue += (save + take);
 555         }
 556         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 557         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 558         self.dmg_inflictor = inflictor;
 559
 560         if(attacker == self)
 561         {
 562                 // don't reset pushltime for self damage as it may be an attempt to
 563                 // escape a lava pit or similar
 564                 //self.pushltime = 0;
 565         }
 566         else if(attacker.classname == "player" || attacker.classname == "gib")
 567         {
 568                 self.pusher = attacker;
 569                 self.pushltime = time + cvar("g_maxpushtime");
 570         }
 571         else if(time < self.pushltime)
 572         {
 573                 attacker = self.pusher;
 574                 self.pushltime = max(self.pushltime, time + 0.6);
 575         }
 576         else
 577                 self.pushltime = 0;
 578
 579         valid_damage_for_weaponstats = 0;
 580         if(clienttype(self) == CLIENTTYPE_REAL)
 581         if(clienttype(attacker) == CLIENTTYPE_REAL)
 582         if(self != attacker)
 583         if(!DEATH_ISSPECIAL(deathtype))
 584         if(IsDifferentTeam(self, attacker))
 585                 valid_damage_for_weaponstats = 1;
 586
 587         if(valid_damage_for_weaponstats)
 588         {
 589                 dh = dh - max(self.health, 0);
 590                 da = da - max(self.armorvalue, 0);
 591                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 592         }
 593
 594         if (self.health < 1)
 595         {
 596                 float defer_ClientKill_Now_TeamChange;
 597                 defer_ClientKill_Now_TeamChange = FALSE;
 598
 599                 if(valid_damage_for_weaponstats)
 600                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 601
 602                 if(sv_gentle < 1) // TODO make a "gentle" version?
 603                 if(sound_allowed(MSG_BROADCAST, attacker))
 604                 {
 605                         if(deathtype == DEATH_DROWN)
 606                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 607                         else
 608                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 609                 }
 610
 611                 // get rid of kill indicator
 612                 if(self.killindicator)
 613                 {
 614                         remove(self.killindicator);
 615                         self.killindicator = world;
 616                         if(self.killindicator_teamchange)
 617                                 defer_ClientKill_Now_TeamChange = TRUE;
 618
 619                         if(self.classname == "body")
 620                         if(deathtype == DEATH_KILL)
 621                         {
 622                                 // for the lemmings fans, a small harmless explosion
 623                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 624                         }
 625                 }
 626
 627                 // become fully visible
 628                 self.alpha = 1;
 629                 // clear selected player display
 630                 ClearSelectedPlayer();
 631                 // throw a weapon
 632                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 633                 // print an obituary message
 634                 Obituary (attacker, inflictor, self, deathtype);
 635                 race_PreDie();
 636                 DropAllRunes(self);
 637                 if(self == attacker)
 638                         kh_Key_DropAll(self, TRUE);
 639                 else if(attacker.classname == "player" || attacker.classname == "gib")
 640                         kh_Key_DropAll(self, FALSE);
 641                 else
 642                         kh_Key_DropAll(self, TRUE);
 643                 if(self.flagcarried)
 644                 {
 645                         if(attacker.classname != "player" && attacker.classname != "gib")
 646                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 647                         else if(attacker.team == self.team)
 648                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 649                         else
 650                                 DropFlag(self.flagcarried, world, attacker);
 651                 }
 652                 if(self.ballcarried)
 653                         DropBall(self.ballcarried, self.origin, self.velocity);
 654                 Portal_ClearAllLater(self);
 655                 // clear waypoints
 656                 WaypointSprite_PlayerDead();
 657                 // make the corpse upright (not tilted)
 658                 self.angles_x = 0;
 659                 self.angles_z = 0;
 660                 // don't spin
 661                 self.avelocity = '0 0 0';
 662                 // view from the floor
 663                 self.view_ofs = '0 0 -8';
 664                 // toss the corpse
 665                 self.movetype = MOVETYPE_TOSS;
 666                 // shootable corpse
 667                 self.solid = SOLID_CORPSE;
 668                 // don't stick to the floor
 669                 self.flags &~= FL_ONGROUND;
 670                 // dying animation
 671                 self.deadflag = DEAD_DYING;
 672                 // when to allow respawn
 673                 sdelay = 0;
 674                 waves = 0;
 675                 if(cvar("g_respawn_mapsettings"))
 676                 {
 677                         sdelay = cvar("g_respawn_mapsettings_delay");
 678                         waves = cvar("g_respawn_mapsettings_waves");
 679                 }
 680                 if(!sdelay)
 681                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 682                 if(!sdelay)
 683                         sdelay = cvar("g_respawn_delay");
 684                 if(!waves)
 685                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 686                 if(!waves)
 687                         waves = cvar("g_respawn_waves");
 688                 if(waves)
 689                         self.death_time = ceil((time + sdelay) / waves) * waves;
 690                 else
 691                         self.death_time = time + sdelay;
 692                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 693                         self.respawn_countdown = 10; // first number to count down from is 10
 694                 else
 695                         self.respawn_countdown = -1; // do not count down
 696                 if (random() < 0.5)
 697                 {
 698                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 699                         self.dead_frame = self.anim_dead1_x;
 700                 }
 701                 else
 702                 {
 703                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 704                         self.dead_frame = self.anim_dead2_x;
 705                 }
 706                 // set damage function to corpse damage
 707                 self.event_damage = PlayerCorpseDamage;
 708                 // call the corpse damage function just in case it wants to gib
 709                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 710                 // set up to fade out later
 711                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 712
 713                 // remove laserdot
 714                 if(self.weaponentity)
 715                         if(self.weaponentity.lasertarget)
 716                                 remove(self.weaponentity.lasertarget);
 717
 718                 if(clienttype(self) == CLIENTTYPE_REAL)
 719                 {
 720                         self.fixangle = TRUE;
 721                         //msg_entity = self;
 722                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 723                         //WriteAngle (MSG_ONE, self.v_angle_x);
 724                         //WriteAngle (MSG_ONE, self.v_angle_y);
 725                         //WriteAngle (MSG_ONE, 80);
 726                 }
 727
 728                 if(g_arena)
 729                         Spawnqueue_Unmark(self);
 730
 731                 if(defer_ClientKill_Now_TeamChange)
 732                         ClientKill_Now_TeamChange();
 733
 734                 if(sv_gentle > 0) {
 735                         // remove corpse
 736                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 737                 }
 738         }
 739 }
 740
 741 float UpdateSelectedPlayer_countvalue(float v)
 742 {
 743         return max(0, (v - 1.0) / 0.5);
 744 }
 745
 746 // returns: -2 if no hit, otherwise cos of the angle
 747 // uses the global v_angle
 748 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 749 {
 750         vector so, d;
 751         float c;
 752
 753         if(p == self)
 754                 return -2;
 755
 756         if(p.deadflag)
 757                 return -2;
 758
 759         so = self.origin + self.view_ofs;
 760         d = p.origin - so;
 761
 762         // misaimed?
 763         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 764                 return -2;
 765
 766         // now find the cos of the angle...
 767         c = normalize(d) * v_forward;
 768
 769         if(c <= mincosangle)
 770                 return -2;
 771
 772         // not visible in any way? forget it
 773         if(!checkpvs(so, p))
 774                 return -2;
 775
 776         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 777         if(trace_fraction < 1)
 778                 return -2;
 779
 780         return c;
 781 }
 782
 783 void ClearSelectedPlayer()
 784 {
 785         if(self.selected_player)
 786         {
 787                 centerprint_expire(self, CENTERPRIO_POINT);
 788                 self.selected_player = world;
 789                 self.selected_player_display_needs_update = FALSE;
 790         }
 791 }
 792
 793 void UpdateSelectedPlayer()
 794 {
 795         entity selected;
 796         float selected_score;
 797         selected = world;
 798         selected_score = 0.95; // 18 degrees
 799
 800         if(!cvar("sv_allow_shownames"))
 801                 return;
 802
 803         if(clienttype(self) != CLIENTTYPE_REAL)
 804                 return;
 805
 806         if(self.cvar_cl_shownames == 0)
 807                 return;
 808
 809         if(self.cvar_cl_shownames == 1 && !teams_matter)
 810                 return;
 811
 812         makevectors(self.v_angle); // sets v_forward
 813
 814         // 1. cursor trace is always right
 815         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 816         {
 817                 selected = self.cursor_trace_ent;
 818         }
 819         else
 820         {
 821                 // 2. if we don't have a cursor trace, find the player which is least
 822                 //    mis-aimed at
 823                 entity p;
 824                 FOR_EACH_PLAYER(p)
 825                 {
 826                         float c;
 827                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 828                         if(c >= -1)
 829                         {
 830                                 selected = p;
 831                                 selected_score = c;
 832                         }
 833                 }
 834         }
 835
 836         if(selected)
 837         {
 838                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 839         }
 840         else
 841         {
 842                 if(time < self.selected_player_display_timeout)
 843                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 844                                 selected = self.selected_player;
 845         }
 846
 847         if(selected)
 848         {
 849                 if(selected == self.selected_player)
 850                 {
 851                         float save;
 852                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 853                         self.selected_player_count = self.selected_player_count + frametime;
 854                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 855                         {
 856                                 string namestr, healthstr;
 857                                 namestr = playername(selected);
 858                                 if(teams_matter)
 859                                 {
 860                                         healthstr = ftos(floor(selected.health));
 861                                         if(self.team == selected.team)
 862                                         {
 863                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 864                                                 self.selected_player_display_needs_update = TRUE;
 865                                         }
 866                                 }
 867                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 868                         }
 869                 }
 870                 else
 871                 {
 872                         ClearSelectedPlayer();
 873                         self.selected_player = selected;
 874                         self.selected_player_time = time;
 875                         self.selected_player_count = 0;
 876                         self.selected_player_display_needs_update = FALSE;
 877                 }
 878         }
 879         else
 880         {
 881                 ClearSelectedPlayer();
 882         }
 883
 884         if(self.selected_player)
 885                 self.last_selected_player = self.selected_player;
 886 }
 887
 888 .float muted; // to be used by prvm_edictset server playernumber muted 1
 889 void Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 890 {
 891         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 892         float flood, privatemsgprefixlen;
 893         entity head;
 894
 895         if(Ban_MaybeEnforceBan(source))
 896                 return;
 897
 898         if(!teamsay && !privatesay)
 899                 if(substring(msgin, 0, 1) == " ")
 900                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 901
 902         msgin = formatmessage(msgin);
 903
 904         if(msgin == "")
 905                 return;
 906
 907         if(source.classname != "player")
 908                 colorstr = "^0"; // black for spectators
 909         else if(teams_matter)
 910                 colorstr = Team_ColorCode(source.team);
 911         else
 912                 teamsay = FALSE;
 913
 914         if(intermission_running)
 915                 teamsay = FALSE;
 916
 917         msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 918         if(msgin == "")
 919                 return;
 920
 921         /*
 922          * using bprint solves this... me stupid
 923         // how can we prevent the message from appearing in a listen server?
 924         // for now, just give "say" back and only handle say_team
 925         if(!teamsay)
 926         {
 927                 clientcommand(self, strcat("say ", msgin));
 928                 return;
 929         }
 930         */
 931
 932         if(cvar("g_chat_teamcolors"))
 933                 namestr = playername(source);
 934         else
 935                 namestr = source.netname;
 936
 937         if(privatesay)
 938         {
 939                 msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 940                 privatemsgprefixlen = strlen(msgstr);
 941                 msgstr = strcat(msgstr, msgin);
 942                 cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 943                 if(cvar("g_chat_teamcolors"))
 944                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 945                 else
 946                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 947         }
 948         else if(teamsay)
 949         {
 950                 msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 951                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 952         }
 953         else
 954         {
 955                 msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 956                 cmsgstr = "";
 957         }
 958
 959         msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 960         fullmsgstr = msgstr;
 961         fullcmsgstr = cmsgstr;
 962
 963         // FLOOD CONTROL
 964         flood = 0;
 965         if(floodcontrol)
 966         {
 967                 float flood_spl;
 968                 float flood_burst;
 969                 float flood_lmax;
 970                 var .float flood_field;
 971                 float lines;
 972                 if(privatesay)
 973                 {
 974                         flood_spl = cvar("g_chat_flood_spl_tell");
 975                         flood_burst = cvar("g_chat_flood_burst_tell");
 976                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 977                         flood_field = floodcontrol_chattell;
 978                 }
 979                 else if(teamsay)
 980                 {
 981                         flood_spl = cvar("g_chat_flood_spl_team");
 982                         flood_burst = cvar("g_chat_flood_burst_team");
 983                         flood_lmax = cvar("g_chat_flood_lmax_team");
 984                         flood_field = floodcontrol_chatteam;
 985                 }
 986                 else
 987                 {
 988                         flood_spl = cvar("g_chat_flood_spl");
 989                         flood_burst = cvar("g_chat_flood_burst");
 990                         flood_lmax = cvar("g_chat_flood_lmax");
 991                         flood_field = floodcontrol_chat;
 992                 }
 993                 flood_burst = max(0, flood_burst - 1);
 994                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 995
 996                 // do flood control for the default line size
 997                 getWrappedLine_remaining = msgstr;
 998                 msgstr = "";
 999                 lines = 0;
1000                 while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1001                 {
1002                         msgstr = strcat(msgstr, " ", getWrappedLine(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1003                         ++lines;
1004                 }
1005                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1006
1007                 if(getWrappedLine_remaining != "")
1008                 {
1009                         msgstr = strcat(msgstr, "\n");
1010                         flood = 2;
1011                 }
1012
1013                 if(time >= source.flood_field)
1014                 {
1015                         source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1016                 }
1017                 else
1018                 {
1019                         flood = 1;
1020                         msgstr = fullmsgstr;
1021                 }
1022         }
1023
1024         if (timeoutStatus == 2) //when game is paused, no flood protection
1025                 source.flood_field = flood = 0;
1026
1027         if(flood == 2)
1028         {
1029                 if(cvar("g_chat_flood_notify_flooder"))
1030                 {
1031                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1032                         sourcecmsgstr = "";
1033                 }
1034                 else
1035                 {
1036                         sourcemsgstr = fullmsgstr;
1037                         sourcecmsgstr = fullcmsgstr;
1038                 }
1039                 cmsgstr = "";
1040         }
1041         else
1042         {
1043                 sourcemsgstr = msgstr;
1044                 sourcecmsgstr = cmsgstr;
1045         }
1046
1047         if(!privatesay)
1048         if(source.classname != "player")
1049         {
1050                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1051                         teamsay = -1; // spectators
1052         }
1053
1054         if(flood)
1055                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1056
1057         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1058         if(privatesay)
1059                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1060
1061         if(source.muted)
1062         {
1063                 // always fake the message
1064                 sprint(source, sourcemsgstr);
1065                 if(cmsgstr != "" && !privatesay)
1066                         centerprint(source, sourcecmsgstr);
1067         }
1068         else if(flood == 1)
1069         {
1070                 if(cvar("g_chat_flood_notify_flooder"))
1071                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1072                 else
1073                 {
1074                         sprint(source, sourcemsgstr);
1075                         if(cmsgstr != "" && !privatesay)
1076                                 centerprint(source, sourcecmsgstr);
1077                 }
1078         }
1079         else if(privatesay)
1080         {
1081                 sprint(source, sourcemsgstr);
1082                 sprint(privatesay, msgstr);
1083                 if(cmsgstr != "")
1084                         centerprint(privatesay, cmsgstr);
1085         }
1086         else if(teamsay > 0)
1087         {
1088                 sprint(source, sourcemsgstr);
1089                 if(sourcecmsgstr != "")
1090                         centerprint(source, sourcecmsgstr);
1091                 FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1092                         if(head != source)
1093                         {
1094                                 sprint(head, msgstr);
1095                                 if(cmsgstr != "")
1096                                         centerprint(head, cmsgstr);
1097                         }
1098         }
1099         else if(teamsay < 0)
1100         {
1101                 sprint(source, sourcemsgstr);
1102                 FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1103                         if(head != source)
1104                                 sprint(head, msgstr);
1105         }
1106         else if(sourcemsgstr != msgstr)
1107         {
1108                 sprint(source, sourcemsgstr);
1109                 FOR_EACH_REALCLIENT(head)
1110                         if(head != source)
1111                                 sprint(head, msgstr);
1112         }
1113         else
1114                 bprint(msgstr);
1115 }
1116
1117 float GetVoiceMessageVoiceType(string type)
1118 {
1119         if(type == "taunt")
1120                 return VOICETYPE_TAUNT;
1121         if(type == "teamshoot")
1122                 return VOICETYPE_LASTATTACKER;
1123         return VOICETYPE_TEAMRADIO;
1124 }
1125
1126 string allvoicesamples;
1127 float GetPlayerSoundSampleField_notFound;
1128 float GetPlayerSoundSampleField_fixed;
1129 .string GetVoiceMessageSampleField(string type)
1130 {
1131         GetPlayerSoundSampleField_notFound = 0;
1132         GetPlayerSoundSampleField_fixed = 0;
1133         switch(type)
1134         {
1135 #define _VOICEMSG(m) case #m: return playersound_##m;
1136                 ALLVOICEMSGS
1137 #undef _VOICEMSG
1138         }
1139         GetPlayerSoundSampleField_notFound = 1;
1140         return playersound_taunt;
1141 }
1142
1143 .string GetPlayerSoundSampleField(string type)
1144 {
1145         GetPlayerSoundSampleField_notFound = 0;
1146         GetPlayerSoundSampleField_fixed = 0;
1147         switch(type)
1148         {
1149 #define _VOICEMSG(m) case #m: return playersound_##m;
1150                 ALLPLAYERSOUNDS
1151 #undef _VOICEMSG
1152         }
1153         GetPlayerSoundSampleField_notFound = 1;
1154         return playersound_taunt;
1155 }
1156
1157 void PrecacheGlobalSound(string samplestring)
1158 {
1159         float n, i;
1160         tokenize_console(samplestring);
1161         n = stof(argv(1));
1162         if(n > 0)
1163         {
1164                 for(i = 1; i <= n; ++i)
1165                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1166         }
1167         else
1168         {
1169                 precache_sound(strcat(argv(0), ".wav"));
1170         }
1171 }
1172
1173 void PrecachePlayerSounds(string f)
1174 {
1175         float fh;
1176         string s;
1177         fh = fopen(f, FILE_READ);
1178         if(fh < 0)
1179                 return;
1180         while((s = fgets(fh)))
1181         {
1182                 if(tokenize_console(s) != 3)
1183                 {
1184                         dprint("Invalid sound info line: ", s, "\n");
1185                         continue;
1186                 }
1187                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1188         }
1189         fclose(fh);
1190
1191         if not(allvoicesamples)
1192         {
1193 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1194                 ALLVOICEMSGS
1195 #undef _VOICEMSG
1196                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1197         }
1198 }
1199
1200 void ClearPlayerSounds()
1201 {
1202 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1203         ALLPLAYERSOUNDS
1204         ALLVOICEMSGS
1205 #undef _VOICEMSG
1206 }
1207
1208 void LoadPlayerSounds(string f, float first)
1209 {
1210         float fh;
1211         string s;
1212         var .string field;
1213         fh = fopen(f, FILE_READ);
1214         if(fh < 0)
1215                 return;
1216         while((s = fgets(fh)))
1217         {
1218                 if(tokenize_console(s) != 3)
1219                         continue;
1220                 field = GetPlayerSoundSampleField(argv(0));
1221                 if(GetPlayerSoundSampleField_notFound)
1222                         field = GetVoiceMessageSampleField(argv(0));
1223                 if(GetPlayerSoundSampleField_notFound)
1224                         continue;
1225                 if(GetPlayerSoundSampleField_fixed)
1226                         if not(first)
1227                                 continue;
1228                 if(self.field)
1229                         strunzone(self.field);
1230                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1231         }
1232         fclose(fh);
1233 }
1234
1235 .float modelindex_for_playersound;
1236 void UpdatePlayerSounds()
1237 {
1238         if(self.modelindex == self.modelindex_for_playersound)
1239                 return;
1240         self.modelindex_for_playersound = self.modelindex;
1241         ClearPlayerSounds();
1242         LoadPlayerSounds("sound/player/default.sounds", 1);
1243         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
1244 }
1245
1246 void GlobalSound(string sample, float chan, float voicetype)
1247 {
1248         float n;
1249         float tauntrand;
1250
1251         if(sample == "")
1252                 return;
1253
1254         tokenize_console(sample);
1255         n = stof(argv(1));
1256         if(n > 0)
1257                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1258         else
1259                 sample = strcat(argv(0), ".wav"); // randomization
1260
1261         switch(voicetype)
1262         {
1263                 case VOICETYPE_LASTATTACKER_ONLY:
1264                         if(self.pusher)
1265                                 if(self.pusher.team == self.team)
1266                                 {
1267                                         msg_entity = self.pusher;
1268                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1269                                         {
1270                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1271                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1272                                                 else
1273                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1274                                         }
1275                                 }
1276                         break;
1277                 case VOICETYPE_LASTATTACKER:
1278                         if(self.pusher)
1279                                 if(self.pusher.team == self.team)
1280                                 {
1281                                         msg_entity = self.pusher;
1282                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1283                                         {
1284                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1285                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1286                                                 else
1287                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1288                                         }
1289                                         msg_entity = self;
1290                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1291                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1292                                 }
1293                         break;
1294                 case VOICETYPE_TEAMRADIO:
1295                         FOR_EACH_REALCLIENT(msg_entity)
1296                                 if(!teams_matter || msg_entity.team == self.team)
1297                                 {
1298                                         if(msg_entity.cvar_cl_voice_directional == 1)
1299                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1300                                         else
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1302                                 }
1303                         break;
1304                 case VOICETYPE_AUTOTAUNT:
1305                         if(!sv_autotaunt)
1306                                 break;
1307                         if(!sv_taunt)
1308                                 break;
1309                         if(sv_gentle)
1310                                 break;
1311                         tauntrand = random();
1312                         FOR_EACH_REALCLIENT(msg_entity)
1313                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1314                                 {
1315                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1316                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1317                                         else
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                                 }
1320                         break;
1321                 case VOICETYPE_TAUNT:
1322                         if(self.classname == "player")
1323                                 if(self.deadflag == DEAD_NO)
1324                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1325                         if(!sv_taunt)
1326                                 break;
1327                         if(sv_gentle)
1328                                 break;
1329                         FOR_EACH_REALCLIENT(msg_entity)
1330                         {
1331                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1332                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1333                                 else
1334                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1335                         }
1336                 case VOICETYPE_PLAYERSOUND:
1337                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1338                         break;
1339                 default:
1340                         backtrace("Invalid voice type!");
1341                         break;
1342         }
1343 }
1344
1345 void PlayerSound(.string samplefield, float chan, float voicetype)
1346 {
1347         string sample;
1348         sample = self.samplefield;
1349         GlobalSound(sample, chan, voicetype);
1350 }
1351
1352 void VoiceMessage(string type, string msg)
1353 {
1354         var .string sample;
1355         var float voicetype, ownteam;
1356         sample = GetVoiceMessageSampleField(type);
1357
1358         if(GetPlayerSoundSampleField_notFound)
1359         {
1360                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1361                 return;
1362         }
1363
1364         voicetype = GetVoiceMessageVoiceType(type);
1365         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1366
1367         float flood;
1368         float flood_spv;
1369         var .float flood_field;
1370
1371         flood = 0;
1372         if(ownteam)
1373         {
1374                 flood_spv = cvar("g_voice_flood_spv_team");
1375                 flood_field = floodcontrol_voiceteam;
1376         }
1377         else
1378         {
1379                 flood_spv = cvar("g_voice_flood_spv");
1380                 flood_field = floodcontrol_voice;
1381         }
1382
1383         if(time >= self.flood_field)
1384                 self.flood_field = max(time, self.flood_field) + flood_spv;
1385         else
1386                 flood = 1;
1387
1388         if (timeoutStatus == 2) //when game is paused, no flood protection
1389                 self.flood_field = flood = 0;
1390
1391         if (msg != "")
1392                 Say(self, ownteam, world, msg, 0);
1393
1394         if (!flood)
1395                 PlayerSound(sample, CHAN_VOICE, voicetype);
1396 }