data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.customizeentityforclient = oldself.customizeentityforclient;
  55         if (keepvelocity == 1)
  56                 self.velocity = oldself.velocity;
  57         self.oldvelocity = self.velocity;
  58         self.fade_time = oldself.fade_time;
  59         self.fade_rate = oldself.fade_rate;
  60         //self.weapon = oldself.weapon;
  61         setorigin(self, oldself.origin);
  62         setsize(self, oldself.mins, oldself.maxs);
  63         self.oldorigin = oldself.origin;
  64         self = oldself;
  65 }
  66
  67 float animparseerror;
  68 vector animparseline(float animfile)
  69 {
  70         local string line;
  71         local float c;
  72         local vector anim;
  73         if (animfile < 0)
  74                 return '0 1 2';
  75         line = fgets(animfile);
  76         c = tokenize_sane(line);
  77         if (c != 3)
  78         {
  79                 animparseerror = TRUE;
  80                 return '0 1 2';
  81         }
  82         anim_x = stof(argv(0));
  83         anim_y = stof(argv(1));
  84         anim_z = stof(argv(2));
  85         // don't allow completely bogus values
  86         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  87                 anim = '0 1 2';
  88         return anim;
  89 };
  90
  91 void player_setupanimsformodel()
  92 {
  93         local string animfilename;
  94         local float animfile;
  95         // defaults for legacy .zym models without animinfo files
  96         self.anim_die1 = '0 1 0.5'; // 2 seconds
  97         self.anim_die2 = '1 1 0.5'; // 2 seconds
  98         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
  99         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 100         self.anim_duckwalk = '4 1 1';
 101         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 102         self.anim_duckidle = '6 1 1';
 103         self.anim_idle = '7 1 1';
 104         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 105         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 106         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 107         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 108         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 109         self.anim_run = '13 1 1';
 110         self.anim_runbackwards = '14 1 1';
 111         self.anim_strafeleft = '15 1 1';
 112         self.anim_straferight = '16 1 1';
 113         self.anim_dead1 = '17 1 1';
 114         self.anim_dead2 = '18 1 1';
 115         self.anim_forwardright = '19 1 1';
 116         self.anim_forwardleft = '20 1 1';
 117         self.anim_backright = '21 1 1';
 118         self.anim_backleft  = '22 1 1';
 119         animparseerror = FALSE;
 120         animfilename = strcat(self.model, ".animinfo");
 121         animfile = fopen(animfilename, FILE_READ);
 122         if (animfile >= 0)
 123         {
 124                 self.anim_die1         = animparseline(animfile);
 125                 self.anim_die2         = animparseline(animfile);
 126                 self.anim_draw         = animparseline(animfile);
 127                 self.anim_duck         = animparseline(animfile);
 128                 self.anim_duckwalk     = animparseline(animfile);
 129                 self.anim_duckjump     = animparseline(animfile);
 130                 self.anim_duckidle     = animparseline(animfile);
 131                 self.anim_idle         = animparseline(animfile);
 132                 self.anim_jump         = animparseline(animfile);
 133                 self.anim_pain1        = animparseline(animfile);
 134                 self.anim_pain2        = animparseline(animfile);
 135                 self.anim_shoot        = animparseline(animfile);
 136                 self.anim_taunt        = animparseline(animfile);
 137                 self.anim_run          = animparseline(animfile);
 138                 self.anim_runbackwards = animparseline(animfile);
 139                 self.anim_strafeleft   = animparseline(animfile);
 140                 self.anim_straferight  = animparseline(animfile);
 141                 self.anim_forwardright = animparseline(animfile);
 142                 self.anim_forwardleft  = animparseline(animfile);
 143                 self.anim_backright    = animparseline(animfile);
 144                 self.anim_backleft     = animparseline(animfile);
 145                 fclose(animfile);
 146
 147                 // derived anims
 148                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 149                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 150
 151                 if (animparseerror)
 152                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 153         }
 154         else
 155                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 156         // reset animstate now
 157         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 158 };
 159
 160 void player_setanim(vector anim, float looping, float override, float restart)
 161 {
 162         if (!restart)
 163         if (anim_x == self.animstate_startframe)
 164         if (anim_y == self.animstate_numframes)
 165         if (anim_z == self.animstate_framerate)
 166                 return;
 167         self.animstate_startframe = anim_x;
 168         self.animstate_numframes = anim_y;
 169         self.animstate_framerate = anim_z;
 170         self.animstate_starttime = time;
 171         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 172         self.animstate_looping = looping;
 173         self.animstate_override = override;
 174         self.frame = self.animstate_startframe;
 175 };
 176
 177 void player_updateframe()
 178 {
 179         if (time >= self.animstate_endtime)
 180         {
 181                 if (self.animstate_looping)
 182                 {
 183                         self.animstate_starttime = self.animstate_endtime;
 184                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 185                 }
 186                 self.animstate_override = FALSE;
 187         }
 188         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 189 };
 190
 191 void player_anim (void)
 192 {
 193         player_updateframe();
 194
 195         if (self.deadflag != DEAD_NO)
 196         {
 197                 if (time > self.animstate_endtime)
 198                 {
 199                         if (self.maxs_z > 5)
 200                         {
 201                                 self.maxs_z = 5;
 202                                 setsize(self, self.mins, self.maxs);
 203                         }
 204                         self.frame = self.dead_frame;
 205                 }
 206                 return;
 207         }
 208
 209         if (!self.animstate_override)
 210         {
 211                 if (!(self.flags & FL_ONGROUND))
 212                 {
 213                         if (self.crouch)
 214                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 215                         else
 216                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 217                 }
 218                 else if (self.crouch)
 219                 {
 220                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 221                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 222                         else
 223                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 224                 }
 225                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 226                 {
 227                         if (self.movement_x > 0 && self.movement_y == 0)
 228                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 229                         else if (self.movement_x < 0 && self.movement_y == 0)
 230                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 231                         else if (self.movement_x == 0 && self.movement_y > 0)
 232                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 233                         else if (self.movement_x == 0 && self.movement_y < 0)
 234                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 235                         else if (self.movement_x > 0 && self.movement_y > 0)
 236                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 237                         else if (self.movement_x > 0 && self.movement_y < 0)
 238                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 239                         else if (self.movement_x < 0 && self.movement_y > 0)
 240                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 241                         else if (self.movement_x < 0 && self.movement_y < 0)
 242                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 243                         else
 244                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 245                 }
 246                 else
 247                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 248         }
 249 }
 250 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 251
 252 void SpawnThrownWeapon (vector org, float w)
 253 {
 254         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 255 }
 256
 257 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 258 {
 259         local float take, save;
 260         Violence_GibSplash_At(hitloc, '0 0 0', '0 0 0', force, 2, bound(0, damage, 200) / 16);
 261
 262         // damage resistance (ignore most of the damage from a bullet or similar)
 263         damage = max(damage - 5, 1);
 264
 265         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 266         take = bound(0, damage - save, damage);
 267
 268         if (save > 10)
 269                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 270         else if (take > 30)
 271                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 272         else if (take > 10)
 273                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 274
 275         if (take > 50)
 276                 Violence_GibSplash_At(hitloc, '0 0 0', '0 0 0', force * -0.1, 3, 1);
 277         if (take > 100)
 278                 Violence_GibSplash_At(hitloc, '0 0 0', '0 0 0', force * -0.2, 3, 1);
 279
 280         if (!(self.flags & FL_GODMODE))
 281         {
 282                 self.armorvalue = self.armorvalue - save;
 283                 self.health = self.health - take;
 284                 // pause regeneration for 5 seconds
 285                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 286         }
 287         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 288         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 289         self.dmg_inflictor = inflictor;
 290
 291         if (self.health <= -75 && self.modelindex != 0)
 292         {
 293                 // don't use any animations as a gib
 294                 self.frame = 0;
 295                 self.dead_frame = 0;
 296                 // view just above the floor
 297                 self.view_ofs = '0 0 4';
 298
 299                 Violence_GibSplash(self, 1, 1);
 300                 self.modelindex = 0; // restore later
 301                 self.solid = SOLID_NOT; // restore later
 302         }
 303 }
 304
 305 void ClientKill_Now_TeamChange();
 306
 307 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 308 {
 309         local float take, save, waves, sdelay;
 310
 311         if(!DEATH_ISSPECIAL(deathtype))
 312         {
 313                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 314                 if(self != attacker)
 315                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 316         }
 317
 318         Violence_GibSplash_At(hitloc, '0 0 0', '0 0 0', force, 2, bound(0, damage, 200) / 16);
 319
 320         if(g_arena)
 321         if(numspawned < 2)
 322                 return;
 323
 324         if (!g_minstagib)
 325         {
 326                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 327                 take = bound(0, damage - save, damage);
 328         }
 329         else
 330         {
 331                 save = 0;
 332                 take = damage;
 333         }
 334
 335         if (save > 10)
 336                 sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 337         else if (take > 30)
 338                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 339         else if (take > 10)
 340                 sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 341
 342         if (take > 50)
 343                 Violence_GibSplash_At(hitloc, '0 0 0', '0 0 0', force * -0.1, 3, 1);
 344         if (take > 100)
 345                 Violence_GibSplash_At(hitloc, '0 0 0', '0 0 0', force * -0.2, 3, 1);
 346
 347         if (time > self.spawnshieldtime)
 348         {
 349                 if (!(self.flags & FL_GODMODE))
 350                 {
 351                         self.armorvalue = self.armorvalue - save;
 352                         self.health = self.health - take;
 353                         // pause regeneration for 5 seconds
 354                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 355
 356                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 357                         {
 358                                 self.pain_finished = time + 0.5;        //Supajoe
 359
 360                                 if(sv_gentle < 1) {
 361                                         if (random() > 0.5)
 362                                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 363                                         else
 364                                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 365
 366                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 367                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 368                                         {
 369                                                 if(self.health > 75) // TODO make a "gentle" version?
 370                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 371                                                 else if(self.health > 50)
 372                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 373                                                 else if(self.health > 25)
 374                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 375                                                 else if(self.health > 1)
 376                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 377                                         }
 378                                 }
 379
 380                                 // throw off bot aim temporarily
 381                                 local float shake;
 382                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 383                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 384                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 385                         }
 386                 }
 387                 else
 388                         self.max_armorvalue += (save + take);
 389         }
 390         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 391         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 392         self.dmg_inflictor = inflictor;
 393
 394         if(attacker == self)
 395         {
 396                 // don't reset pushltime for self damage as it may be an attempt to
 397                 // escape a lava pit or similar
 398                 //self.pushltime = 0;
 399         }
 400         else if(attacker.classname == "player" || attacker.classname == "gib")
 401         {
 402                 self.pusher = attacker;
 403                 self.pushltime = time + cvar("g_maxpushtime");
 404         }
 405         else if(time < self.pushltime)
 406         {
 407                 attacker = self.pusher;
 408                 self.pushltime = max(self.pushltime, time + 0.6);
 409         }
 410         else
 411                 self.pushltime = 0;
 412
 413         if (self.health < 1)
 414         {
 415                 float defer_ClientKill_Now_TeamChange;
 416                 defer_ClientKill_Now_TeamChange = FALSE;
 417
 418                 if(sv_gentle < 1) // TODO make a "gentle" version?
 419                 {
 420                         if(deathtype == DEATH_DROWN)
 421                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 422                         else
 423                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 424                 }
 425
 426                 // get rid of kill indicator
 427                 if(self.killindicator)
 428                 {
 429                         remove(self.killindicator);
 430                         self.killindicator = world;
 431                         if(self.killindicator_teamchange)
 432                                 defer_ClientKill_Now_TeamChange = TRUE;
 433
 434                         if(self.classname == "body")
 435                         if(deathtype == DEATH_KILL)
 436                         {
 437                                 // for the lemmings fans, a small harmless explosion
 438                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 439                         }
 440                 }
 441
 442                 // become fully visible
 443                 self.alpha = 1;
 444                 // clear selected player display
 445                 ClearSelectedPlayer();
 446                 // throw a weapon
 447                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 448                 // print an obituary message
 449                 Obituary (attacker, inflictor, self, deathtype);
 450                 race_PreDie();
 451                 DropAllRunes(self);
 452                 if(self == attacker)
 453                         kh_Key_DropAll(self, TRUE);
 454                 else if(attacker.classname == "player" || attacker.classname == "gib")
 455                         kh_Key_DropAll(self, FALSE);
 456                 else
 457                         kh_Key_DropAll(self, TRUE);
 458                 if(self.flagcarried)
 459                 {
 460                         if(attacker.classname != "player" && attacker.classname != "gib")
 461                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 462                         else if(attacker.team == self.team)
 463                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 464                         else
 465                                 DropFlag(self.flagcarried, world, attacker);
 466                 }
 467                 Portal_ClearAllLater(self);
 468                 // clear waypoints
 469                 WaypointSprite_PlayerDead();
 470                 // make the corpse upright (not tilted)
 471                 self.angles_x = 0;
 472                 self.angles_z = 0;
 473                 // don't spin
 474                 self.avelocity = '0 0 0';
 475                 // view from the floor
 476                 self.view_ofs = '0 0 -8';
 477                 // toss the corpse
 478                 self.movetype = MOVETYPE_TOSS;
 479                 // shootable corpse
 480                 self.solid = SOLID_CORPSE;
 481                 // don't stick to the floor
 482                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 483                 // dying animation
 484                 self.deadflag = DEAD_DYING;
 485                 // when to allow respawn
 486                 sdelay = 0;
 487                 waves = 0;
 488                 if(cvar("g_respawn_mapsettings"))
 489                 {
 490                         sdelay = cvar("g_respawn_mapsettings_delay");
 491                         waves = cvar("g_respawn_mapsettings_waves");
 492                 }
 493                 if(!sdelay)
 494                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 495                 if(!sdelay)
 496                         sdelay = cvar("g_respawn_delay");
 497                 if(!waves)
 498                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 499                 if(!waves)
 500                         waves = cvar("g_respawn_waves");
 501                 if(waves)
 502                         self.death_time = ceil((time + sdelay) / waves) * waves;
 503                 else
 504                         self.death_time = time + sdelay;
 505                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 506                         self.respawn_countdown = 10; // first number to count down from is 10
 507                 else
 508                         self.respawn_countdown = -1; // do not count down
 509                 if (random() < 0.5)
 510                 {
 511                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 512                         self.dead_frame = self.anim_dead1_x;
 513                 }
 514                 else
 515                 {
 516                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 517                         self.dead_frame = self.anim_dead2_x;
 518                 }
 519                 // set damage function to corpse damage
 520                 self.event_damage = PlayerCorpseDamage;
 521                 // call the corpse damage function just in case it wants to gib
 522                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 523                 // set up to fade out later
 524                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 525
 526                 // remove laserdot
 527                 if(self.weaponentity)
 528                         if(self.weaponentity.lasertarget)
 529                                 remove(self.weaponentity.lasertarget);
 530
 531                 if(clienttype(self) == CLIENTTYPE_REAL)
 532                 {
 533                         self.fixangle = TRUE;
 534                         //msg_entity = self;
 535                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 536                         //WriteAngle (MSG_ONE, self.v_angle_x);
 537                         //WriteAngle (MSG_ONE, self.v_angle_y);
 538                         //WriteAngle (MSG_ONE, 80);
 539                 }
 540
 541                 if(g_arena)
 542                         Spawnqueue_Unmark(self);
 543
 544                 if(defer_ClientKill_Now_TeamChange)
 545                         ClientKill_Now_TeamChange();
 546
 547                 if(sv_gentle > 0) {
 548                         // remove corpse
 549                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 550                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 551                 }
 552         }
 553 }
 554
 555 float UpdateSelectedPlayer_countvalue(float v)
 556 {
 557         return max(0, (v - 1.0) / 0.5);
 558 }
 559
 560 // returns: -2 if no hit, otherwise cos of the angle
 561 // uses the global v_angle
 562 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 563 {
 564         vector so, d;
 565         float c;
 566
 567         if(p == self)
 568                 return -2;
 569
 570         if(p.deadflag)
 571                 return -2;
 572
 573         so = self.origin + self.view_ofs;
 574         d = p.origin - so;
 575
 576         // misaimed?
 577         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 578                 return -2;
 579
 580         // now find the cos of the angle...
 581         c = normalize(d) * v_forward;
 582
 583         if(c <= mincosangle)
 584                 return -2;
 585
 586         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 587         if(trace_fraction < 1)
 588                 return -2;
 589
 590         return c;
 591 }
 592
 593 void ClearSelectedPlayer()
 594 {
 595         if(self.selected_player)
 596         {
 597                 centerprint_expire(self, CENTERPRIO_POINT);
 598                 self.selected_player = world;
 599                 self.selected_player_display_needs_update = FALSE;
 600         }
 601 }
 602
 603 void UpdateSelectedPlayer()
 604 {
 605         entity selected;
 606         float selected_score;
 607         selected = world;
 608         selected_score = 0.95; // 18 degrees
 609
 610         if(!cvar("sv_allow_shownames"))
 611                 return;
 612
 613         if(clienttype(self) != CLIENTTYPE_REAL)
 614                 return;
 615
 616         if(self.cvar_cl_shownames == 0)
 617                 return;
 618
 619         if(self.cvar_cl_shownames == 1 && !teams_matter)
 620                 return;
 621
 622         makevectors(self.v_angle); // sets v_forward
 623
 624         // 1. cursor trace is always right
 625         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 626         {
 627                 selected = self.cursor_trace_ent;
 628         }
 629         else
 630         {
 631                 // 2. if we don't have a cursor trace, find the player which is least
 632                 //    mis-aimed at
 633                 entity p;
 634                 FOR_EACH_PLAYER(p)
 635                 {
 636                         float c;
 637                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 638                         if(c >= -1)
 639                         {
 640                                 selected = p;
 641                                 selected_score = c;
 642                         }
 643                 }
 644         }
 645
 646         if(selected)
 647         {
 648                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 649         }
 650         else
 651         {
 652                 if(time < self.selected_player_display_timeout)
 653                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 654                                 selected = self.selected_player;
 655         }
 656
 657         if(selected)
 658         {
 659                 if(selected == self.selected_player)
 660                 {
 661                         float save;
 662                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 663                         self.selected_player_count = self.selected_player_count + frametime;
 664                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 665                         {
 666                                 string namestr, healthstr;
 667                                 namestr = playername(selected);
 668                                 if(teams_matter)
 669                                 {
 670                                         healthstr = ftos(floor(selected.health));
 671                                         if(self.team == selected.team)
 672                                         {
 673                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 674                                                 self.selected_player_display_needs_update = TRUE;
 675                                         }
 676                                 }
 677                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 678                         }
 679                 }
 680                 else
 681                 {
 682                         ClearSelectedPlayer();
 683                         self.selected_player = selected;
 684                         self.selected_player_time = time;
 685                         self.selected_player_count = 0;
 686                         self.selected_player_display_needs_update = FALSE;
 687                 }
 688         }
 689         else
 690         {
 691                 ClearSelectedPlayer();
 692         }
 693
 694         if(self.selected_player)
 695                 self.last_selected_player = self.selected_player;
 696 }
 697
 698 .float floodcontrol_chat;
 699 .float floodcontrol_chatteam;
 700 void Say(entity source, float teamsay, string msgin, float floodcontrol)
 701 {
 702         string msgstr, colorstr, cmsgstr, namestr;
 703         float flood;
 704         entity head;
 705
 706         if(Ban_MaybeEnforceBan(source))
 707                 return;
 708
 709         if(!teamsay)
 710                 if(substring(msgin, 0, 1) == " ")
 711                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 712
 713         msgin = formatmessage(msgin);
 714
 715         if(msgin == "")
 716                 return;
 717
 718         if(source.classname != "player")
 719                 colorstr = "^0"; // black for spectators
 720         else if(teams_matter)
 721                 colorstr = Team_ColorCode(source.team);
 722         else
 723                 teamsay = FALSE;
 724
 725         if(intermission_running)
 726                 teamsay = FALSE;
 727
 728         /*
 729          * using bprint solves this... me stupid
 730         // how can we prevent the message from appearing in a listen server?
 731         // for now, just give "say" back and only handle say_team
 732         if(!teamsay)
 733         {
 734                 clientcommand(self, strcat("say ", msgin));
 735                 return;
 736         }
 737         */
 738
 739         if(cvar("g_chat_teamcolors"))
 740                 namestr = playername(source);
 741         else
 742                 namestr = source.netname;
 743         if(teamsay)
 744         {
 745                 msgstr = strzone(strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin, "\n"));
 746                 cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", wordwrap(msgin, 50));
 747         }
 748         else
 749                 msgstr = strzone(strcat("\{1}", namestr, "^7: ", msgin, "\n"));
 750
 751         // FLOOD CONTROL
 752         flood = 0;
 753         if(floodcontrol)
 754         {
 755                 float flood_spl;
 756                 float flood_burst;
 757                 float flood_lmax;
 758                 var .float flood_field;
 759                 float lines;
 760                 if(teamsay)
 761                 {
 762                         flood_spl = cvar("g_chat_flood_spl_team");
 763                         flood_burst = cvar("g_chat_flood_burst_team");
 764                         flood_lmax = cvar("g_chat_flood_lmax_team");
 765                         flood_field = floodcontrol_chatteam;
 766                 }
 767                 else
 768                 {
 769                         flood_spl = cvar("g_chat_flood_spl");
 770                         flood_burst = cvar("g_chat_flood_burst");
 771                         flood_lmax = cvar("g_chat_flood_lmax");
 772                         flood_field = floodcontrol_chat;
 773                 }
 774                 flood_burst = max(0, flood_burst - 1);
 775                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 776                 lines = ceil(strlennocol(msgstr) / 75);
 777                 if(flood_lmax && lines > flood_lmax)
 778                         flood = 2;
 779                 else if(time >= self.flood_field)
 780                         self.flood_field = max(time - flood_burst * flood_spl, self.flood_field) + lines * flood_spl;
 781                 else
 782                         flood = 1;
 783         }
 784
 785         if(flood)
 786         {
 787                 if(cvar("g_chat_flood_notify_flooder"))
 788                 {
 789                         if(flood == 1)
 790                                 sprint(self, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(self.flood_field - time), "^3 seconds\n"));
 791                         else if(flood == 2)
 792                                 sprint(self, "^3FLOOD CONTROL: ^7message too long\n");
 793                 }
 794                 else
 795                         sprint(self, msgstr);
 796                 print("NOTE: ", playername(self), "^7 is flooding.\n");
 797         }
 798         else if(teamsay)
 799         {
 800                 if(source.classname == "player")
 801                 {
 802                         FOR_EACH_REALPLAYER(head)
 803                         {
 804                                 if(head.team == source.team)
 805                                 {
 806                                         sprint(head, msgstr);
 807                                         centerprint(head, cmsgstr);
 808                                 }
 809                         }
 810                 }
 811                 else
 812                 {
 813                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 814                         {
 815                                 sprint(head, msgstr);
 816                                 centerprint(head, cmsgstr);
 817                         }
 818                 }
 819         }
 820         else
 821         {
 822                 // TODO invent a cvar name for allowing global chat by spectators during warmup anyway
 823                 if(cvar("g_chat_nospectators") && source.classname != "player") {
 824                         FOR_EACH_REALCLIENT(head) if(head.classname != "player") {
 825                                 sprint(head, msgstr);
 826                         }
 827                 }
 828                 else
 829                         bprint(msgstr);
 830         }
 831
 832         strunzone(msgstr);
 833 }
 834
 835 float GetVoiceMessageVoiceType(string type)
 836 {
 837         if(type == "taunt")
 838                 return VOICETYPE_TAUNT;
 839         if(type == "teamshoot")
 840                 return VOICETYPE_LASTATTACKER;
 841         return VOICETYPE_TEAMRADIO;
 842 }
 843
 844 string allvoicesamples;
 845 float GetPlayerSoundSampleField_notFound;
 846 float GetPlayerSoundSampleField_fixed;
 847 .string GetVoiceMessageSampleField(string type)
 848 {
 849         GetPlayerSoundSampleField_notFound = 0;
 850         GetPlayerSoundSampleField_fixed = 0;
 851         switch(type)
 852         {
 853 #define _VOICEMSG(m) case #m: return playersound_##m;
 854                 ALLVOICEMSGS
 855 #undef _VOICEMSG
 856         }
 857         GetPlayerSoundSampleField_notFound = 1;
 858         return playersound_taunt;
 859 }
 860
 861 .string GetPlayerSoundSampleField(string type)
 862 {
 863         GetPlayerSoundSampleField_notFound = 0;
 864         GetPlayerSoundSampleField_fixed = 0;
 865         switch(type)
 866         {
 867 #define _VOICEMSG(m) case #m: return playersound_##m;
 868                 ALLPLAYERSOUNDS
 869 #undef _VOICEMSG
 870         }
 871         GetPlayerSoundSampleField_notFound = 1;
 872         return playersound_taunt;
 873 }
 874
 875 void PrecacheGlobalSound(string samplestring)
 876 {
 877         float n, i;
 878         tokenize_sane(samplestring);
 879         n = stof(argv(1));
 880         if(n > 0)
 881         {
 882                 for(i = 1; i <= n; ++i)
 883                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 884         }
 885         else
 886         {
 887                 precache_sound(strcat(argv(0), ".wav"));
 888         }
 889 }
 890
 891 void PrecachePlayerSounds(string f)
 892 {
 893         float fh;
 894         string s;
 895         fh = fopen(f, FILE_READ);
 896         if(fh < 0)
 897                 return;
 898         while((s = fgets(fh)))
 899         {
 900                 if(tokenize_sane(s) != 3)
 901                 {
 902                         dprint("Invalid sound info line: ", s, "\n");
 903                         continue;
 904                 }
 905                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 906         }
 907         fclose(fh);
 908
 909         if not(allvoicesamples)
 910         {
 911 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 912                 ALLVOICEMSGS
 913 #undef _VOICEMSG
 914                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 915         }
 916 }
 917
 918 void ClearPlayerSounds()
 919 {
 920 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 921         ALLPLAYERSOUNDS
 922         ALLVOICEMSGS
 923 #undef _VOICEMSG
 924 }
 925
 926 void LoadPlayerSounds(string f, float first)
 927 {
 928         float fh;
 929         string s;
 930         var .string field;
 931         fh = fopen(f, FILE_READ);
 932         if(fh < 0)
 933                 return;
 934         while((s = fgets(fh)))
 935         {
 936                 if(tokenize_sane(s) != 3)
 937                         continue;
 938                 field = GetPlayerSoundSampleField(argv(0));
 939                 if(GetPlayerSoundSampleField_notFound)
 940                         field = GetVoiceMessageSampleField(argv(0));
 941                 if(GetPlayerSoundSampleField_notFound)
 942                         continue;
 943                 if(GetPlayerSoundSampleField_fixed)
 944                         if not(first)
 945                                 continue;
 946                 if(self.field)
 947                         strunzone(self.field);
 948                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 949         }
 950         fclose(fh);
 951 }
 952
 953 .float modelindex_for_playersound;
 954 void UpdatePlayerSounds()
 955 {
 956         if(self.modelindex == self.modelindex_for_playersound)
 957                 return;
 958         self.modelindex_for_playersound = self.modelindex;
 959         ClearPlayerSounds();
 960         LoadPlayerSounds("sound/player/default.sounds", 1);
 961         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
 962 }
 963
 964 void GlobalSound(string sample, float chan, float voicetype)
 965 {
 966         float n;
 967         float tauntrand;
 968
 969         if(sample == "")
 970                 return;
 971
 972         tokenize_sane(sample);
 973         n = stof(argv(1));
 974         if(n > 0)
 975                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
 976         else
 977                 sample = strcat(argv(0), ".wav"); // randomization
 978
 979         switch(voicetype)
 980         {
 981                 case VOICETYPE_LASTATTACKER_ONLY:
 982                         if(self.pusher)
 983                                 if(self.pusher.team == self.team)
 984                                 {
 985                                         msg_entity = self.pusher;
 986                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
 987                                         {
 988                                                 if(msg_entity.cvar_cl_voice_directional == 1)
 989                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
 990                                                 else
 991                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
 992                                         }
 993                                 }
 994                         break;
 995                 case VOICETYPE_LASTATTACKER:
 996                         if(self.pusher)
 997                                 if(self.pusher.team == self.team)
 998                                 {
 999                                         msg_entity = self.pusher;
1000                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1001                                         {
1002                                                 if(msg_entity.cvar_cl_voice_directional == 1)
1003                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1004                                                 else
1005                                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1006                                         }
1007                                         msg_entity = self;
1008                                         if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1009                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1010                                 }
1011                         break;
1012                 case VOICETYPE_TEAMRADIO:
1013                         FOR_EACH_REALCLIENT(msg_entity)
1014                                 if(!teams_matter || msg_entity.team == self.team)
1015                                 {
1016                                         if(msg_entity.cvar_cl_voice_directional == 1)
1017                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1018                                         else
1019                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1020                                 }
1021                         break;
1022                 case VOICETYPE_AUTOTAUNT:
1023                         tauntrand = random();
1024                         FOR_EACH_REALCLIENT(msg_entity)
1025                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1026                                 {
1027                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1028                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1029                                         else
1030                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1031                                 }
1032                         break;
1033                 case VOICETYPE_TAUNT:
1034                         FOR_EACH_REALCLIENT(msg_entity)
1035                         {
1036                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1037                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1038                                 else
1039                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1040                         }
1041                 case VOICETYPE_PLAYERSOUND:
1042                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1043                         break;
1044                 default:
1045                         backtrace("Invalid voice type!");
1046                         break;
1047         }
1048 }
1049
1050 void PlayerSound(.string samplefield, float chan, float voicetype)
1051 {
1052         string sample;
1053         sample = self.samplefield;
1054         GlobalSound(sample, chan, voicetype);
1055 }
1056
1057 .float floodcontrol_voice;
1058 .float floodcontrol_voiceteam;
1059 void VoiceMessage(string type, string msg)
1060 {
1061         var .string sample;
1062         var float voicetype, ownteam;
1063         sample = GetVoiceMessageSampleField(type);
1064
1065         if(GetPlayerSoundSampleField_notFound)
1066         {
1067                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1068                 return;
1069         }
1070
1071         voicetype = GetVoiceMessageVoiceType(type);
1072         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1073
1074         float flood;
1075         float flood_spv;
1076         var .float flood_field;
1077
1078         flood = 0;
1079         if(ownteam)
1080         {
1081                 flood_spv = cvar("g_voice_flood_spv_team");
1082                 flood_field = floodcontrol_voiceteam;
1083         }
1084         else
1085         {
1086                 flood_spv = cvar("g_voice_flood_spv");
1087                 flood_field = floodcontrol_voice;
1088         }
1089
1090         if(time >= self.flood_field)
1091                 self.flood_field = max(time, self.flood_field) + flood_spv;
1092         else
1093                 flood = 1;
1094
1095         if (msg != "")
1096                 Say(self, ownteam, msg, 0);
1097
1098         if (!flood)
1099                 PlayerSound(sample, CHAN_VOICE, voicetype);
1100 }