data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16 .float wasFlying;
  17 .float spectatorspeed;
  18
  19 #define SHTEST_DELTA 10
  20 #define SHTEST_THRESHOLD 1.1
  21 .float shtest_next;
  22 .float shtest_accumulator;
  23
  24 /*
  25 =============
  26 PlayerJump
  27
  28 When you press the jump key
  29 =============
  30 */
  31 void PlayerJump (void)
  32 {
  33         float mjumpheight;
  34
  35         mjumpheight = cvar("sv_jumpvelocity");
  36         if (self.waterlevel >= 2)
  37         {
  38                 if (self.watertype == CONTENT_WATER)
  39                         self.velocity_z = 200;
  40                 else if (self.watertype == CONTENT_SLIME)
  41                         self.velocity_z = 80;
  42                 else
  43                         self.velocity_z = 50;
  44
  45                 return;
  46         }
  47
  48
  49         if (!(self.flags & FL_ONGROUND))
  50                 return;
  51
  52         if(!sv_pogostick)
  53                 if (!(self.flags & FL_JUMPRELEASED))
  54                         return;
  55
  56         if(g_runematch)
  57         {
  58                 if(self.runes & RUNE_SPEED)
  59                 {
  60                         if(self.runes & CURSE_SLOW)
  61                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  62                         else
  63                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  64                 }
  65                 else if(self.runes & CURSE_SLOW)
  66                 {
  67                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  68                 }
  69         }
  70
  71         if(g_minstagib && (self.items & IT_INVINCIBLE))
  72         {
  73                 mjumpheight = mjumpheight * cvar("g_minstagib_speed_jumpheight");
  74         }
  75
  76         self.velocity_z = self.velocity_z + mjumpheight;
  77         self.oldvelocity_z = self.velocity_z;
  78
  79         self.flags = self.flags - FL_ONGROUND;
  80         self.flags = self.flags - FL_JUMPRELEASED;
  81
  82         if (self.crouch)
  83                 player_setanim(self.anim_duckjump, FALSE, TRUE, TRUE);
  84         else
  85                 player_setanim(self.anim_jump, FALSE, TRUE, TRUE);
  86
  87         if(g_jump_grunt)
  88                 PlayerSound(playersound_jump, CHAN_PLAYER, 0);
  89 }
  90
  91 void CheckWaterJump()
  92 {
  93         local vector start, end;
  94
  95 // check for a jump-out-of-water
  96         makevectors (self.angles);
  97         start = self.origin;
  98         start_z = start_z + 8;
  99         v_forward_z = 0;
 100         normalize(v_forward);
 101         end = start + v_forward*24;
 102         traceline (start, end, TRUE, self);
 103         if (trace_fraction < 1)
 104         {       // solid at waist
 105                 start_z = start_z + self.maxs_z - 8;
 106                 end = start + v_forward*24;
 107                 self.movedir = trace_plane_normal * -50;
 108                 traceline (start, end, TRUE, self);
 109                 if (trace_fraction == 1)
 110                 {       // open at eye level
 111                         self.flags = self.flags | FL_WATERJUMP;
 112                         self.velocity_z = 225;
 113                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 114                         self.teleport_time = time + 2;  // safety net
 115                         return;
 116                 }
 117         }
 118 };
 119
 120 float racecar_angle(float forward, float down)
 121 {
 122         float ret, angle_mult;
 123
 124         if(forward < 0)
 125         {
 126                 forward = -forward;
 127                 down = -down;
 128         }
 129
 130         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 131
 132         angle_mult = forward / (800 + forward);
 133
 134         if(ret > 180)
 135                 return ret * angle_mult + 360 * (1 - angle_mult);
 136         else
 137                 return ret * angle_mult;
 138 }
 139
 140 void RaceCarPhysics()
 141 {
 142         // using this move type for "big rigs"
 143         // the engine does not push the entity!
 144
 145         float accel, steer, f;
 146         vector angles_save, rigvel;
 147
 148         angles_save = self.angles;
 149         accel = bound(-1, self.movement_x / sv_maxspeed, 1);
 150         steer = bound(-1, self.movement_y / sv_maxspeed, 1);
 151
 152         if(g_bugrigs_reverse_speeding)
 153         {
 154                 if(accel < 0)
 155                 {
 156                         // back accel is DIGITAL
 157                         // to prevent speedhack
 158                         if(accel < -0.5)
 159                                 accel = -1;
 160                         else
 161                                 accel = 0;
 162                 }
 163         }
 164
 165         self.angles_x = 0;
 166         self.angles_z = 0;
 167         makevectors(self.angles); // new forward direction!
 168
 169         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 170         {
 171                 float myspeed, upspeed, steerfactor, accelfactor;
 172
 173                 myspeed = self.velocity * v_forward;
 174                 upspeed = self.velocity * v_up;
 175
 176                 // responsiveness factor for steering and acceleration
 177                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 178
 179                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 180                         steerfactor = -myspeed * g_bugrigs_steer;
 181                 else
 182                         steerfactor = -myspeed * f * g_bugrigs_steer;
 183
 184                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 185                         accelfactor = g_bugrigs_accel;
 186                 else
 187                         accelfactor = f * g_bugrigs_accel;
 188
 189                 if(accel < 0)
 190                 {
 191                         if(myspeed > 0)
 192                         {
 193                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 194                         }
 195                         else
 196                         {
 197                                 if(!g_bugrigs_reverse_speeding)
 198                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 199                         }
 200                 }
 201                 else
 202                 {
 203                         if(myspeed >= 0)
 204                         {
 205                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 206                         }
 207                         else
 208                         {
 209                                 if(g_bugrigs_reverse_stopping)
 210                                         myspeed = 0;
 211                                 else
 212                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 213                         }
 214                 }
 215                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 216
 217                 self.angles_y += steer * frametime * steerfactor; // apply steering
 218                 makevectors(self.angles); // new forward direction!
 219
 220                 myspeed += accel * accelfactor * frametime;
 221
 222                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 223         }
 224         else
 225         {
 226                 myspeed = vlen(self.velocity);
 227
 228                 // responsiveness factor for steering and acceleration
 229                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 230                 steerfactor = -myspeed * f;
 231                 self.angles_y += steer * frametime * steerfactor; // apply steering
 232
 233                 rigvel = self.velocity;
 234                 makevectors(self.angles); // new forward direction!
 235         }
 236
 237         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air);
 238
 239         if(g_bugrigs_planar_movement)
 240         {
 241                 vector rigvel_xy, neworigin, up;
 242                 float mt;
 243
 244                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 245                 rigvel_xy = rigvel;
 246                 rigvel_xy_z = 0;
 247
 248                 if(g_bugrigs_planar_movement_car_jumping && !g_touchexplode) // touchexplode is a better way to handle collisions
 249                         mt = MOVE_NORMAL;
 250                 else
 251                         mt = MOVE_NOMONSTERS;
 252
 253                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 254                 up = trace_endpos - self.origin;
 255
 256                 // BUG RIGS: align the move to the surface instead of doing collision testing
 257                 // can we move?
 258                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 259
 260                 // align to surface
 261                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 262
 263                 if(trace_fraction < 0.5)
 264                 {
 265                         trace_fraction = 1;
 266                         neworigin = self.origin;
 267                 }
 268                 else
 269                         neworigin = trace_endpos;
 270
 271                 if(trace_fraction < 1)
 272                 {
 273                         // now set angles_x so that the car points parallel to the surface
 274                         self.angles = vectoangles(
 275                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 276                                         +
 277                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 278                                         +
 279                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 280                                         );
 281                         self.flags |= FL_ONGROUND;
 282                 }
 283                 else
 284                 {
 285                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 286                         self.flags (-) FL_ONGROUND;
 287                 }
 288
 289                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 290                 self.movetype = MOVETYPE_NOCLIP;
 291         }
 292         else
 293         {
 294                 rigvel_z -= frametime * sv_gravity; // 4x gravity plays better
 295                 self.velocity = rigvel;
 296                 self.movetype = MOVETYPE_FLY;
 297         }
 298
 299         trace_fraction = 1;
 300         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 301         if(trace_fraction != 1)
 302         {
 303                 self.angles = vectoangles(
 304                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 305                                 +
 306                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 307                                 +
 308                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 309                                 );
 310         }
 311         else
 312         {
 313                 vector vel_local;
 314
 315                 vel_local_x = v_forward * self.velocity;
 316                 vel_local_y = v_right * self.velocity;
 317                 vel_local_z = v_up * self.velocity;
 318
 319                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 320                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 321         }
 322
 323         // smooth the angles
 324         vector vf1, vu1, smoothangles;
 325         makevectors(self.angles);
 326         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 327         if(f == 0)
 328                 f = 1;
 329         vf1 = v_forward * f;
 330         vu1 = v_up * f;
 331         makevectors(angles_save);
 332         vf1 = vf1 + v_forward * (1 - f);
 333         vu1 = vu1 + v_up * (1 - f);
 334         smoothangles = vectoangles2(vf1, vu1);
 335         self.angles_x = -smoothangles_x;
 336         self.angles_z =  smoothangles_z;
 337 }
 338
 339 .vector movement_old;
 340 .float buttons_old;
 341 .vector v_angle_old;
 342
 343 void Nixnex_GiveCurrentWeapon();
 344 void SV_PlayerPhysics()
 345 {
 346         local vector wishvel, wishdir, v;
 347         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, shtest_score, buttons;
 348         string temps;
 349
 350         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE;
 351         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 352         {
 353                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 354                         self.parm_idlesince = time;
 355         }
 356         self.buttons_old = buttons;
 357         self.movement_old = self.movement;
 358         self.v_angle_old = self.v_angle;
 359
 360         if(time > self.shtest_next)
 361         {
 362                 if(self.shtest_next > 0)
 363                 {
 364                         // self.shtest_accumulator:
 365                         //   started at time - SHTEST_DELTA
 366                         //   should be at SHTEST_DELTA
 367                         shtest_score = self.shtest_accumulator / (SHTEST_DELTA + time - self.shtest_next);
 368                         if(shtest_score > SHTEST_THRESHOLD)
 369                                 print("TIME PARADOX: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 370                         else if(cvar("developer_shtest"))
 371                                 dprint("okay: shtest for ", self.netname, " said ", ftos(shtest_score), "\n");
 372                 }
 373                 self.shtest_next = time + SHTEST_DELTA;
 374                 self.shtest_accumulator = 0;
 375         }
 376         self.shtest_accumulator += frametime;
 377
 378         if (clienttype(self) == CLIENTTYPE_BOT)
 379                 bot_think();
 380
 381         if (self.movetype == MOVETYPE_NONE && self.disableclientprediction != 2)
 382                 return;
 383
 384         if (self.punchangle != '0 0 0')
 385         {
 386                 f = vlen(self.punchangle) - 10 * frametime;
 387                 if (f > 0)
 388                         self.punchangle = normalize(self.punchangle) * f;
 389                 else
 390                         self.punchangle = '0 0 0';
 391         }
 392
 393         if (self.punchvector != '0 0 0')
 394         {
 395                 f = vlen(self.punchvector) - 30 * frametime;
 396                 if (f > 0)
 397                         self.punchvector = normalize(self.punchvector) * f;
 398                 else
 399                         self.punchvector = '0 0 0';
 400         }
 401
 402         maxspd_mod = 1;
 403
 404         if(g_runematch)
 405         {
 406                 if(self.runes & RUNE_SPEED)
 407                 {
 408                         if(self.runes & CURSE_SLOW)
 409                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 410                         else
 411                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 412                 }
 413                 else if(self.runes & CURSE_SLOW)
 414                 {
 415                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 416                 }
 417         }
 418
 419         if(g_minstagib && (self.items & IT_INVINCIBLE))
 420         {
 421                 maxspd_mod = cvar("g_minstagib_speed_moverate");
 422         }
 423
 424         swampspd_mod = 1;
 425         if(self.in_swamp) {
 426                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 427         }
 428
 429         if(self.flags & FL_NOTARGET)
 430         {
 431                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 432                 if(!self.spectatorspeed)
 433                         self.spectatorspeed = maxspd_mod;
 434                 if(self.impulse && self.impulse <= 19)
 435                 {
 436                         if(self.lastflags & FL_NOTARGET)
 437                         {
 438                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 439                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 440                                 else if(self.impulse == 11)
 441                                         self.spectatorspeed = maxspd_mod;
 442                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19)
 443                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 444                                 else if(self.impulse >= 1 && self.impulse <= 9)
 445                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 446                         } // otherwise just clear
 447                         self.impulse = 0;
 448                 }
 449                 maxspd_mod = self.spectatorspeed;
 450         }
 451
 452         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 453
 454         if(self.speed != spd)
 455         {
 456                 self.speed = spd;
 457                 temps = ftos(spd);
 458                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 459                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 460                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 461                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 462
 463                 temps = ftos(sv_accelerate * maxspd_mod);
 464                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 465         }
 466
 467         // if dead, behave differently
 468         if (self.deadflag)
 469                 return;
 470
 471         if (!self.fixangle && !g_bugrigs)
 472         {
 473                 self.angles_x = 0;
 474                 self.angles_y = self.v_angle_y;
 475                 self.angles_z = 0;
 476         }
 477
 478         if(self.flags & FL_ONGROUND)
 479         if(self.wasFlying)
 480         {
 481                 self.wasFlying = 0;
 482
 483                 if(self.waterlevel < 2)
 484                 if(time >= self.ladder_time)
 485                 if not(self.hook)
 486                 {
 487                         self.nextstep = time + 0.3 + random() * 0.1;
 488                         trace_dphitq3surfaceflags = 0;
 489                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 490                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 491                         {
 492                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 493                                         GlobalSound(globalsound_metalfall, CHAN_PLAYER, 0);
 494                                 else
 495                                         GlobalSound(globalsound_fall, CHAN_PLAYER, 0);
 496                         }
 497                 }
 498         }
 499
 500         if(IsFlying(self))
 501                 self.wasFlying = 1;
 502
 503         if(self.classname == "player")
 504         {
 505                 if(sv_doublejump)
 506                 {
 507                         self.flags = self.flags - (self.flags & FL_ONGROUND);
 508                         tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 2', MOVE_NORMAL, self);
 509                         if(trace_fraction < 1 && trace_plane_normal_z > 0.7)
 510                                 self.flags = self.flags | FL_ONGROUND;
 511                 }
 512
 513                 if (self.BUTTON_JUMP)
 514                         PlayerJump ();
 515                 else
 516                         self.flags = self.flags | FL_JUMPRELEASED;
 517
 518                 if (self.waterlevel == 2)
 519                         CheckWaterJump ();
 520         }
 521
 522         if (self.flags & FL_WATERJUMP )
 523         {
 524                 self.velocity_x = self.movedir_x;
 525                 self.velocity_y = self.movedir_y;
 526                 if (time > self.teleport_time || self.waterlevel == 0)
 527                 {
 528                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 529                         self.teleport_time = 0;
 530                 }
 531         }
 532         else if (g_bugrigs && self.classname == "player")
 533         {
 534                 RaceCarPhysics();
 535         }
 536         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 537         {
 538                 // noclipping or flying
 539                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 540
 541                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 542                 makevectors(self.v_angle);
 543                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 544                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 545                 // acceleration
 546                 wishdir = normalize(wishvel);
 547                 wishspeed = vlen(wishvel);
 548                 if (wishspeed > sv_maxspeed*maxspd_mod)
 549                         wishspeed = sv_maxspeed*maxspd_mod;
 550                 if (time >= self.teleport_time)
 551                 {
 552                         f = wishspeed - (self.velocity * wishdir);
 553                         if (f > 0)
 554                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 555                 }
 556         }
 557         else if (self.waterlevel >= 2)
 558         {
 559                 // swimming
 560                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 561
 562                 makevectors(self.v_angle);
 563                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 564                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 565                 if (wishvel == '0 0 0')
 566                         wishvel = '0 0 -60'; // drift towards bottom
 567
 568                 wishdir = normalize(wishvel);
 569                 wishspeed = vlen(wishvel);
 570                 if (wishspeed > sv_maxspeed*maxspd_mod)
 571                         wishspeed = sv_maxspeed*maxspd_mod;
 572                 wishspeed = wishspeed * 0.7;
 573
 574                 // water friction
 575                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 576
 577                 // water acceleration
 578                 f = wishspeed - (self.velocity * wishdir);
 579                 if (f > 0)
 580                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 581         }
 582         else if (time < self.ladder_time)
 583         {
 584                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 585                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 586
 587                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 588                 makevectors(self.v_angle);
 589                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 590                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 591                 if (self.gravity)
 592                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 593                 else
 594                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 595                 if (self.ladder_entity.classname == "func_water")
 596                 {
 597                         f = vlen(wishvel);
 598                         if (f > self.ladder_entity.speed)
 599                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 600
 601                         self.watertype = self.ladder_entity.skin;
 602                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 603                         if ((self.origin_z + self.view_ofs_z) < f)
 604                                 self.waterlevel = 3;
 605                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 606                                 self.waterlevel = 2;
 607                         else if ((self.origin_z + self.mins_z + 1) < f)
 608                                 self.waterlevel = 1;
 609                         else
 610                         {
 611                                 self.waterlevel = 0;
 612                                 self.watertype = CONTENT_EMPTY;
 613                         }
 614                 }
 615                 // acceleration
 616                 wishdir = normalize(wishvel);
 617                 wishspeed = vlen(wishvel);
 618                 if (wishspeed > sv_maxspeed)
 619                         wishspeed = sv_maxspeed;
 620                 if (time >= self.teleport_time)
 621                 {
 622                         f = wishspeed - (self.velocity * wishdir);
 623                         if (f > 0)
 624                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 625                 }
 626         }
 627         else if (self.flags & FL_ONGROUND)
 628         {
 629                 // walking
 630                 makevectors(self.v_angle_y * '0 1 0');
 631                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 632
 633                 if(!(self.lastflags & FL_ONGROUND))
 634                 {
 635                         if(cvar("speedmeter"))
 636                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 637                         if(self.lastground < time - 0.3)
 638                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 639                         if(self.jumppadcount > 1)
 640                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 641                         self.jumppadcount = 0;
 642                 }
 643
 644                 if (self.velocity_x || self.velocity_y)
 645                 if (!(self.flags & FL_JUMPRELEASED) || !self.BUTTON_JUMP)
 646                 {
 647                         v = self.velocity;
 648                         v_z = 0;
 649                         f = vlen(v);
 650                         if (f < sv_stopspeed)
 651                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 652                         else
 653                                 f = 1 - frametime * sv_friction;
 654                         if (f > 0)
 655                                 self.velocity = self.velocity * f;
 656                         else
 657                                 self.velocity = '0 0 0';
 658                 }
 659                 // acceleration
 660                 wishdir = normalize(wishvel);
 661                 wishspeed = vlen(wishvel);
 662                 if (wishspeed > sv_maxspeed*maxspd_mod)
 663                         wishspeed = sv_maxspeed*maxspd_mod;
 664                 if (self.crouch)
 665                         wishspeed = wishspeed * 0.5;
 666                 if (time >= self.teleport_time)
 667                 {
 668                         f = wishspeed - (self.velocity * wishdir);
 669                         if (f > 0)
 670                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 671                 }
 672         }
 673         else
 674         {
 675                 if(maxspd_mod < 1)
 676                 {
 677                         maxairspd = sv_maxairspeed*maxspd_mod;
 678                         airaccel = sv_airaccelerate*maxspd_mod;
 679                 }
 680                 else
 681                 {
 682                         maxairspd = sv_maxairspeed;
 683                         airaccel = sv_airaccelerate;
 684                 }
 685                 // airborn
 686                 makevectors(self.v_angle_y * '0 1 0');
 687                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 688                 // acceleration
 689                 wishdir = normalize(wishvel);
 690                 wishspeed = vlen(wishvel);
 691                 if (wishspeed > maxairspd)
 692                         wishspeed = maxairspd;
 693                 if (self.crouch)
 694                         wishspeed = wishspeed * 0.5;
 695                 if (time >= self.teleport_time)
 696                 {
 697                         // NOTE: this does the same as the commented out old code if:
 698                         //   sv_airaccel_qw 0
 699                         //   sv_airaccel_sideways_friction 0
 700
 701                         float vel_straight;
 702                         float vel_z;
 703                         vector vel_perpend;
 704                         vel_straight = self.velocity * wishdir;
 705                         vel_z = self.velocity_z;
 706                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 707
 708                         f = wishspeed - vel_straight;
 709                         if(f > 0)
 710                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 711                         if(wishspeed > 0)
 712                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 713
 714                         // anti-sideways friction to fix QW-style bunnyhopping
 715                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 716
 717                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 718
 719                         /*
 720                         f = wishspeed;// - (self.velocity * wishdir);
 721                         if (f > 0)
 722                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 723                         */
 724                 }
 725         }
 726
 727         if(self.flags & FL_ONGROUND)
 728                 self.lastground = time;
 729
 730         self.lastflags = self.flags;
 731 };