data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         found = 1;
 129                         if(ent.classname == "target_objective")
 130                         {
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 if(self.classname == "player") // spectators may spawn everywhere
 138                                 {
 139                                         if(g_race_qualifying)
 140                                         {
 141                                                 // spawn at first
 142                                                 if(ent.race_checkpoint != 0)
 143                                                         return -1;
 144                                                 if(spot.race_place != race_lowest_place_spawn)
 145                                                         return -1;
 146                                         }
 147                                         else
 148                                         {
 149                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 150                                                         return -1;
 151                                                 float pl;
 152                                                 pl = self.race_place;
 153                                                 if(pl > race_highest_place_spawn)
 154                                                         pl = 0;
 155                                                 if(spot.race_place != pl)
 156                                                         return -1;
 157                                         }
 158                                 }
 159                                 good = 1;
 160                         }
 161                         else
 162                         {
 163                         }
 164                         ent = find(ent, targetname, spot.target);
 165                 }
 166
 167                 if(found && !good)
 168                         return -1;
 169         }
 170
 171         player = playerlist;
 172         shortest = vlen(world.maxs - world.mins);
 173         for(player = playerlist; player; player = player.chain)
 174                 if (player != self)
 175                 {
 176                         thisdist = vlen(player.origin - spot.origin);
 177                         if (thisdist < shortest)
 178                                 shortest = thisdist;
 179                 }
 180         return shortest;
 181 }
 182
 183 float spawn_allbad;
 184 float spawn_allgood;
 185 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 186 {
 187         local entity spot, spotlist, spotlistend;
 188         spawn_allgood = TRUE;
 189         spawn_allbad = TRUE;
 190
 191         spotlist = world;
 192         spotlistend = world;
 193
 194         for(spot = firstspot; spot; spot = spot.chain)
 195         {
 196                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 197
 198                 if(cvar("spawn_debugview"))
 199                 {
 200                         setmodel(spot, "models/runematch/rune.mdl");
 201                         if(spot.SPAWNPOINT_SCORE < mindist)
 202                         {
 203                                 spot.colormod = '1 0 0';
 204                                 spot.scale = 1;
 205                         }
 206                         else
 207                         {
 208                                 spot.colormod = '0 1 0';
 209                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 210                         }
 211                 }
 212
 213                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 214                 {
 215                         if(spot.SPAWNPOINT_SCORE < mindist)
 216                         {
 217                                 // too short distance
 218                                 spawn_allgood = FALSE;
 219                         }
 220                         else
 221                         {
 222                                 // perfect
 223                                 spawn_allbad = FALSE;
 224
 225                                 if(spotlistend)
 226                                         spotlistend.chain = spot;
 227                                 spotlistend = spot;
 228                                 if(!spotlist)
 229                                         spotlist = spot;
 230
 231                                 /*
 232                                 if(teamcheck)
 233                                 if(spot.team != teamcheck)
 234                                         error("invalid spawn added");
 235
 236                                 print("added ", etos(spot), "\n");
 237                                 */
 238                         }
 239                 }
 240         }
 241         if(spotlistend)
 242                 spotlistend.chain = world;
 243
 244         /*
 245                 entity e;
 246                 if(teamcheck)
 247                         for(e = spotlist; e; e = e.chain)
 248                         {
 249                                 print("seen ", etos(e), "\n");
 250                                 if(e.team != teamcheck)
 251                                         error("invalid spawn found");
 252                         }
 253         */
 254
 255         return spotlist;
 256 }
 257
 258 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 259 {
 260         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 261         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 262         local entity spot;
 263
 264         RandomSelection_Init();
 265         for(spot = firstspot; spot; spot = spot.chain)
 266                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 267
 268         return RandomSelection_chosen_ent;
 269 }
 270
 271 /*
 272 =============
 273 SelectSpawnPoint
 274
 275 Finds a point to respawn
 276 =============
 277 */
 278 entity SelectSpawnPoint (float anypoint)
 279 {
 280         local float teamcheck;
 281         local entity firstspot_new;
 282         local entity spot, firstspot, playerlist;
 283
 284         spot = find (world, classname, "testplayerstart");
 285         if (spot)
 286                 return spot;
 287
 288         teamcheck = 0;
 289
 290         if(!anypoint && have_team_spawns)
 291                 teamcheck = self.team;
 292
 293         // get the list of players
 294         playerlist = findchain(classname, "player");
 295         // get the entire list of spots
 296         firstspot = findchain(classname, "info_player_deathmatch");
 297         // filter out the bad ones
 298         // (note this returns the original list if none survived)
 299         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 300         if(!firstspot_new)
 301                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 302         firstspot = firstspot_new;
 303
 304         // there is 50/50 chance of choosing a random spot or the furthest spot
 305         // (this means that roughly every other spawn will be furthest, so you
 306         // usually won't get fragged at spawn twice in a row)
 307         if (arena_roundbased)
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 310                 if(firstspot_new)
 311                         firstspot = firstspot_new;
 312                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 313         }
 314         else if (random() > cvar("g_spawn_furthest"))
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 316         else
 317                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 318
 319         if(cvar("spawn_debugview"))
 320         {
 321                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 322
 323                 entity e;
 324                 if(teamcheck)
 325                         for(e = firstspot; e; e = e.chain)
 326                                 if(e.team != teamcheck)
 327                                         error("invalid spawn found");
 328         }
 329
 330         if (!spot)
 331         {
 332                 if(cvar("spawn_debug"))
 333                         GotoNextMap();
 334                 else
 335                 {
 336                         if(some_spawn_has_been_used)
 337                                 return world; // team can't spawn any more, because of actions of other team
 338                         else
 339                                 error("Cannot find a spawn point - please fix the map!");
 340                 }
 341         }
 342
 343         return spot;
 344 }
 345
 346 /*
 347 =============
 348 CheckPlayerModel
 349
 350 Checks if the argument string can be a valid playermodel.
 351 Returns a valid one in doubt.
 352 =============
 353 */
 354 string FallbackPlayerModel = "models/player/marine.zym";
 355 string CheckPlayerModel(string plyermodel) {
 356         if(strlen(plyermodel) < 4)
 357                 return FallbackPlayerModel;
 358         if( substring(plyermodel,0,14) != "models/player/")
 359                 return FallbackPlayerModel;
 360         else if(cvar("sv_servermodelsonly"))
 361         {
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 364                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 365                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 366                         return FallbackPlayerModel;
 367                 if(plyermodel != strtolower(plyermodel))
 368                         return FallbackPlayerModel;
 369                 if(!fexists(plyermodel))
 370                         return FallbackPlayerModel;
 371         }
 372         return plyermodel;
 373 }
 374
 375 /*
 376 =============
 377 Client_customizeentityforclient
 378
 379 LOD reduction
 380 =============
 381 */
 382 float Client_customizeentityforclient()
 383 {
 384 #ifdef ALLOW_VARIABLE_LOD
 385         // self: me
 386         // other: the player viewing me
 387         float distance;
 388         float f;
 389
 390         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 391                 return TRUE;
 392
 393         if(other.cvar_cl_playerdetailreduction <= 0)
 394         {
 395                 if(other.cvar_cl_playerdetailreduction <= -2)
 396                         self.modelindex = self.modelindex_lod2;
 397                 else if(other.cvar_cl_playerdetailreduction <= -1)
 398                         self.modelindex = self.modelindex_lod1;
 399                 else
 400                         self.modelindex = self.modelindex_lod0;
 401         }
 402         else
 403         {
 404                 distance = vlen(self.origin - other.origin);
 405                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 406                 if(f > 10000)
 407                         self.modelindex = self.modelindex_lod2;
 408                 else if(f > 5000)
 409                         self.modelindex = self.modelindex_lod1;
 410                 else
 411                         self.modelindex = self.modelindex_lod0;
 412         }
 413 #endif
 414
 415         return TRUE;
 416 }
 417
 418 void UpdatePlayerSounds();
 419 void setmodel_lod(entity e, string modelname)
 420 {
 421 #ifdef ALLOW_VARIABLE_LOD
 422         string s;
 423
 424         // FIXME: this only supports 3-letter extensions
 425         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 426         if(fexists(s))
 427         {
 428                 precache_model(s);
 429                 setmodel(e, s); // players have high precision
 430                 self.modelindex_lod1 = self.modelindex;
 431         }
 432         else
 433                 self.modelindex_lod1 = -1;
 434
 435         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 436         if(fexists(s))
 437         {
 438                 precache_model(s);
 439                 setmodel(e, s); // players have high precision
 440                 self.modelindex_lod2 = self.modelindex;
 441         }
 442         else
 443                 self.modelindex_lod2 = -1;
 444
 445         precache_model(modelname);
 446         setmodel(e, modelname); // players have high precision
 447         self.modelindex_lod0 = self.modelindex;
 448
 449         if(self.modelindex_lod1 < 0)
 450                 self.modelindex_lod1 = self.modelindex;
 451
 452         if(self.modelindex_lod2 < 0)
 453                 self.modelindex_lod2 = self.modelindex;
 454 #else
 455         precache_model(modelname);
 456         setmodel(e, modelname); // players have high precision
 457 #endif
 458         player_setupanimsformodel();
 459         UpdatePlayerSounds();
 460 }
 461
 462 /*
 463 =============
 464 PutObserverInServer
 465
 466 putting a client as observer in the server
 467 =============
 468 */
 469 void PutObserverInServer (void)
 470 {
 471         entity  spot;
 472
 473         race_PreSpawnObserver();
 474
 475         spot = SelectSpawnPoint (TRUE);
 476         if(!spot)
 477                 error("No spawnpoints for observers?!?\n");
 478         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 479
 480         if(clienttype(self) == CLIENTTYPE_REAL)
 481         {
 482                 msg_entity = self;
 483                 WriteByte(MSG_ONE, SVC_SETVIEW);
 484                 WriteEntity(MSG_ONE, self);
 485         }
 486
 487         DropAllRunes(self);
 488         kh_Key_DropAll(self, TRUE);
 489
 490         Portal_ClearAll(self);
 491
 492         if(self.flagcarried)
 493                 DropFlag(self.flagcarried, world, world);
 494
 495         WaypointSprite_PlayerDead();
 496
 497         if(self.killcount != -666)
 498         {
 499                 if(g_lms)
 500                 {
 501                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 502                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 503                         else
 504                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 505                 }
 506                 else
 507                         bprint ("^4", self.netname, "^4 is spectating now\n");
 508         }
 509
 510         PlayerScore_Clear(self); // clear scores when needed
 511
 512         self.spectatortime = time;
 513
 514         self.classname = "observer";
 515         self.iscreature = FALSE;
 516         self.health = -666;
 517         self.takedamage = DAMAGE_NO;
 518         self.solid = SOLID_NOT;
 519         self.movetype = MOVETYPE_NOCLIP;
 520         self.flags = FL_CLIENT | FL_NOTARGET;
 521         self.armorvalue = 666;
 522         self.effects = 0;
 523         self.armorvalue = cvar("g_balance_armor_start");
 524         self.pauserotarmor_finished = 0;
 525         self.pauserothealth_finished = 0;
 526         self.pauseregen_finished = 0;
 527         self.damageforcescale = 0;
 528         self.death_time = 0;
 529         self.dead_frame = 0;
 530         self.alpha = 0;
 531         self.scale = 0;
 532         self.fade_time = 0;
 533         self.pain_frame = 0;
 534         self.pain_finished = 0;
 535         self.strength_finished = 0;
 536         self.invincible_finished = 0;
 537         self.pushltime = 0;
 538         self.think = SUB_Null;
 539         self.nextthink = 0;
 540         self.hook_time = 0;
 541         self.runes = 0;
 542         self.deadflag = DEAD_NO;
 543         self.angles = spot.angles;
 544         self.angles_z = 0;
 545         self.fixangle = TRUE;
 546         self.crouch = FALSE;
 547
 548         self.view_ofs = PL_VIEW_OFS;
 549         setorigin (self, spot.origin);
 550         setsize (self, '0 0 0', '0 0 0');
 551         self.oldorigin = self.origin;
 552         self.items = 0;
 553         self.weapons = 0;
 554         self.model = "";
 555         self.modelindex = 0;
 556         self.weapon = 0;
 557         self.weaponmodel = "";
 558         self.weaponentity = world;
 559         self.exteriorweaponentity = world;
 560         self.killcount = -666;
 561         self.velocity = '0 0 0';
 562         self.avelocity = '0 0 0';
 563         self.punchangle = '0 0 0';
 564         self.punchvector = '0 0 0';
 565         self.oldvelocity = self.velocity;
 566         self.customizeentityforclient = Client_customizeentityforclient;
 567
 568         if(g_arena)
 569         {
 570                 if(self.version_mismatch)
 571                 {
 572                         Spawnqueue_Unmark(self);
 573                         Spawnqueue_Remove(self);
 574                 }
 575                 else
 576                 {
 577                         Spawnqueue_Insert(self);
 578                 }
 579         }
 580         else if(g_lms)
 581         {
 582                 // Only if the player cannot play at all
 583                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 584                         self.frags = FRAGS_SPECTATOR;
 585                 else
 586                         self.frags = FRAGS_LMS_LOSER;
 587         }
 588         else
 589                 self.frags = FRAGS_SPECTATOR;
 590 }
 591
 592 float RestrictSkin(float s)
 593 {
 594         if(!teams_matter)
 595                 return s;
 596         if(s == 6)
 597                 return 6;
 598         return mod(s, 3);
 599 }
 600
 601 void FixPlayermodel()
 602 {
 603         local string defaultmodel;
 604         local float defaultskin;
 605         local vector m1, m2;
 606
 607         defaultmodel = "";
 608
 609         if(cvar("sv_defaultcharacter") == 1) {
 610                 defaultskin = 0;
 611
 612                 if(teams_matter)
 613                 {
 614                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 615                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 616                 }
 617
 618                 if(defaultmodel == "")
 619                 {
 620                         defaultmodel = cvar_string("sv_defaultplayermodel");
 621                         defaultskin = cvar("sv_defaultplayerskin");
 622                 }
 623         }
 624
 625         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 626         {
 627                 if(self.model != "")
 628                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 629                 self.model = ""; // force the != checks to return true
 630         }
 631
 632         if(defaultmodel != "")
 633         {
 634                 if (defaultmodel != self.model)
 635                 {
 636                         m1 = self.mins;
 637                         m2 = self.maxs;
 638                         setmodel_lod (self, defaultmodel);
 639                         setsize (self, m1, m2);
 640                 }
 641
 642                 self.skin = defaultskin;
 643         } else {
 644                 if (self.playermodel != self.model)
 645                 {
 646                         self.playermodel = CheckPlayerModel(self.playermodel);
 647                         m1 = self.mins;
 648                         m2 = self.maxs;
 649                         setmodel_lod (self, self.playermodel);
 650                         setsize (self, m1, m2);
 651                 }
 652
 653                 self.skin = RestrictSkin(stof(self.playerskin));
 654         }
 655
 656         if(!teams_matter)
 657                 if(strlen(cvar_string("sv_defaultplayercolors")))
 658                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 659                                 setcolor(self, cvar("sv_defaultplayercolors"));
 660 }
 661
 662 void PlayerTouchExplode(entity p1, entity p2)
 663 {
 664         vector org;
 665         org = (p1.origin + p2.origin) * 0.5;
 666         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 667
 668         te_explosion(org);
 669
 670         entity e;
 671         e = spawn();
 672         setorigin(e, org);
 673         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 674         remove(e);
 675 }
 676
 677 /*
 678 =============
 679 PutClientInServer
 680
 681 Called when a client spawns in the server
 682 =============
 683 */
 684 //void() ctf_playerchanged;
 685 void PutClientInServer (void)
 686 {
 687         if(clienttype(self) == CLIENTTYPE_BOT)
 688         {
 689                 self.classname = "player";
 690         }
 691         else if(clienttype(self) == CLIENTTYPE_REAL)
 692         {
 693                 msg_entity = self;
 694                 WriteByte(MSG_ONE, SVC_SETVIEW);
 695                 WriteEntity(MSG_ONE, self);
 696         }
 697
 698         // player is dead and becomes observer
 699         // FIXME fix LMS scoring for new system
 700         if(g_lms)
 701         {
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 703                         self.classname = "observer";
 704         }
 705
 706         if(g_arena)
 707         if(!self.spawned)
 708                 self.classname = "observer";
 709
 710         if(self.classname == "player") {
 711                 entity spot, oldself;
 712
 713                 race_PreSpawn();
 714
 715                 spot = SelectSpawnPoint (FALSE);
 716                 if(!spot)
 717                 {
 718                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 719                         return; // spawn failed
 720                 }
 721
 722                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 723                 self.campingrifle_bulletcounter = 0;
 724
 725                 self.classname = "player";
 726                 self.wasplayer = TRUE;
 727                 self.iscreature = TRUE;
 728                 self.movetype = MOVETYPE_WALK;
 729                 self.solid = SOLID_SLIDEBOX;
 730                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 731                 self.frags = FRAGS_PLAYER;
 732                 if(independent_players)
 733                         MAKE_INDEPENDENT_PLAYER(self);
 734                 self.flags = FL_CLIENT;
 735                 self.takedamage = DAMAGE_AIM;
 736                 if(g_minstagib)
 737                         self.effects = EF_FULLBRIGHT;
 738                 else
 739                         self.effects = 0;
 740                 self.air_finished = time + 12;
 741                 self.dmg = 2;
 742
 743                 if(inWarmupStage)
 744                 {
 745                         self.ammo_shells = warmup_start_ammo_shells;
 746                         self.ammo_nails = warmup_start_ammo_nails;
 747                         self.ammo_rockets = warmup_start_ammo_rockets;
 748                         self.ammo_cells = warmup_start_ammo_cells;
 749                         self.health = warmup_start_health;
 750                         self.armorvalue = warmup_start_armorvalue;
 751                         self.weapons = warmup_start_weapons;
 752                 }
 753                 else
 754                 {
 755                         self.ammo_shells = start_ammo_shells;
 756                         self.ammo_nails = start_ammo_nails;
 757                         self.ammo_rockets = start_ammo_rockets;
 758                         self.ammo_cells = start_ammo_cells;
 759                         self.health = start_health;
 760                         self.armorvalue = start_armorvalue;
 761                         self.weapons = start_weapons;
 762                 }
 763                 self.ammo_fuel = start_fuel;
 764                 self.items = start_items;
 765                 self.switchweapon = w_getbestweapon(self);
 766                 self.cnt = self.switchweapon;
 767                 self.weapon = 0;
 768                 self.jump_interval = time;
 769
 770                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 771                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 772                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 773                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 774                 //extend the pause of rotting if client was reset at the beginning of the countdown
 775                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 776                         self.spawnshieldtime += game_starttime - time;
 777                         self.pauserotarmor_finished += game_starttime - time;
 778                         self.pauserothealth_finished += game_starttime - time;
 779                         self.pauseregen_finished += game_starttime - time;
 780                 }
 781                 self.damageforcescale = 2;
 782                 self.death_time = 0;
 783                 self.dead_frame = 0;
 784                 self.alpha = 0;
 785                 self.scale = 0;
 786                 self.fade_time = 0;
 787                 self.pain_frame = 0;
 788                 self.pain_finished = 0;
 789                 self.strength_finished = 0;
 790                 self.invincible_finished = 0;
 791                 self.pushltime = 0;
 792                 //self.speed_finished = 0;
 793                 //self.slowmo_finished = 0;
 794                 // players have no think function
 795                 self.think = SUB_Null;
 796                 self.nextthink = 0;
 797                 self.hook_time = 0;
 798                 self.dmg_team = 0;
 799
 800                 self.runes = 0;
 801
 802                 self.deadflag = DEAD_NO;
 803
 804                 self.angles = spot.angles;
 805
 806                 self.angles_z = 0; // never spawn tilted even if the spot says to
 807                 self.fixangle = TRUE; // turn this way immediately
 808                 self.velocity = '0 0 0';
 809                 self.avelocity = '0 0 0';
 810                 self.punchangle = '0 0 0';
 811                 self.punchvector = '0 0 0';
 812                 self.oldvelocity = self.velocity;
 813
 814                 msg_entity = self;
 815                 WRITESPECTATABLE_MSG_ONE({
 816                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 817                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 818                 });
 819
 820                 self.customizeentityforclient = Client_customizeentityforclient;
 821
 822                 self.model = "";
 823                 FixPlayermodel();
 824
 825                 self.crouch = FALSE;
 826                 self.view_ofs = PL_VIEW_OFS;
 827                 setsize (self, PL_MIN, PL_MAX);
 828                 self.spawnorigin = spot.origin;
 829                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 830                 // don't reset back to last position, even if new position is stuck in solid
 831                 self.oldorigin = self.origin;
 832
 833                 if(g_arena)
 834                 {
 835                         Spawnqueue_Remove(self);
 836                         Spawnqueue_Mark(self);
 837                 }
 838
 839                 self.event_damage = PlayerDamage;
 840
 841                 self.bot_attack = TRUE;
 842
 843                 self.statdraintime = time + 5;
 844                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 845
 846                 if(self.killcount == -666) {
 847                         PlayerScore_Clear(self);
 848                         self.killcount = 0;
 849                 }
 850
 851                 self.cnt = WEP_LASER;
 852                 self.nixnex_lastchange_id = -1;
 853
 854                 CL_SpawnWeaponentity();
 855                 self.alpha = default_player_alpha;
 856                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 857                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 858
 859                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 860                 self.lms_traveled_distance = 0;
 861                 self.speedrunning = FALSE;
 862
 863                 race_PostSpawn(spot);
 864
 865                 if(cvar("spawn_debug"))
 866                 {
 867                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 868                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 869                 }
 870
 871                 //stuffcmd(self, "chase_active 0");
 872                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 873
 874                 if (cvar("g_spawnsound"))
 875                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 876
 877                 if(g_assault) {
 878                         if(self.team == assault_attacker_team)
 879                                 centerprint(self, "You are attacking!");
 880                         else
 881                                 centerprint(self, "You are defending!");
 882                 }
 883
 884                 target_voicescript_clear(self);
 885
 886                 oldself = self;
 887                 self = spot;
 888                         activator = oldself;
 889                                 SUB_UseTargets();
 890                         activator = world;
 891                 self = oldself;
 892
 893         } else if(self.classname == "observer") {
 894                 PutObserverInServer ();
 895         }
 896
 897         //if(g_ctf)
 898         //      ctf_playerchanged();
 899 }
 900
 901 float ClientInit_SendEntity(entity to, float sf)
 902 {
 903         float i;
 904         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 905         WriteShort(MSG_ENTITY, CSQC_REVISION);
 906         for(i = 1; i <= 24; ++i)
 907                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 908         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 909         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 910         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 911
 912         if(sv_foginterval && world.fog != "")
 913                 WriteString(MSG_ENTITY, world.fog);
 914         else
 915                 WriteString(MSG_ENTITY, "");
 916
 917         return TRUE;
 918 }
 919
 920 void ClientInit_Spawn()
 921 {
 922         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 923 }
 924
 925 /*
 926 =============
 927 SetNewParms
 928 =============
 929 */
 930 void SetNewParms (void)
 931 {
 932         // initialize parms for a new player
 933         parm1 = -(86400 * 366);
 934 }
 935
 936 /*
 937 =============
 938 SetChangeParms
 939 =============
 940 */
 941 void SetChangeParms (void)
 942 {
 943         // save parms for level change
 944         parm1 = self.parm_idlesince - time;
 945 }
 946
 947 /*
 948 =============
 949 DecodeLevelParms
 950 =============
 951 */
 952 void DecodeLevelParms (void)
 953 {
 954         // load parms
 955         self.parm_idlesince = parm1;
 956         if(self.parm_idlesince == -(86400 * 366))
 957                 self.parm_idlesince = time;
 958
 959         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 960         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 961 }
 962
 963 /*
 964 =============
 965 ClientKill
 966
 967 Called when a client types 'kill' in the console
 968 =============
 969 */
 970
 971 void ClientKill_Now_TeamChange()
 972 {
 973         if(self.killindicator_teamchange == -1)
 974         {
 975                 self.team = -1;
 976                 JoinBestTeam( self, FALSE, FALSE );
 977         }
 978         else
 979         {
 980                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 981         }
 982 }
 983
 984 void ClientKill_Now()
 985 {
 986         if(self.killindicator_teamchange)
 987                 ClientKill_Now_TeamChange();
 988
 989         // in any case:
 990         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 991
 992         if(self.killindicator)
 993         {
 994                 dprint("Cleaned up after a leaked kill indicator.\n");
 995                 remove(self.killindicator);
 996                 self.killindicator = world;
 997         }
 998 }
 999 void KillIndicator_Think()
1000 {
1001         if (!self.owner.modelindex)
1002         {
1003                 self.owner.killindicator = world;
1004                 remove(self);
1005                 return;
1006         }
1007
1008         if(self.cnt <= 0)
1009         {
1010                 self = self.owner;
1011                 ClientKill_Now(); // no oldself needed
1012                 return;
1013         }
1014         else
1015         {
1016                 if(self.cnt <= 10)
1017                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1018                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1019                 {
1020                         if(self.cnt <= 10)
1021                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1022                         if(self.owner.killindicator_teamchange)
1023                         {
1024                                 if(self.owner.killindicator_teamchange == -1)
1025                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1026                                 else
1027                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1028                         }
1029                         else
1030                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1031                 }
1032                 self.nextthink = time + 1;
1033                 self.cnt -= 1;
1034         }
1035 }
1036
1037 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1038 {
1039         float killtime;
1040         entity e;
1041         killtime = cvar("g_balance_kill_delay");
1042
1043         self.killindicator_teamchange = targetteam;
1044
1045         if(!self.killindicator)
1046         {
1047                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1048                 {
1049                         ClientKill_Now();
1050                 }
1051                 else
1052                 {
1053                         self.killindicator = spawn();
1054                         self.killindicator.owner = self;
1055                         self.killindicator.scale = 0.5;
1056                         setattachment(self.killindicator, self, "");
1057                         setorigin(self.killindicator, '0 0 52');
1058                         self.killindicator.think = KillIndicator_Think;
1059                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1060                         self.killindicator.cnt = ceil(killtime);
1061                         self.killindicator.count = bound(0, ceil(killtime), 10);
1062                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1063
1064                         for(e = world; (e = find(e, classname, "body")) != world; )
1065                         {
1066                                 if(e.enemy != self)
1067                                         continue;
1068                                 e.killindicator = spawn();
1069                                 e.killindicator.owner = e;
1070                                 e.killindicator.scale = 0.5;
1071                                 setattachment(e.killindicator, e, "");
1072                                 setorigin(e.killindicator, '0 0 52');
1073                                 e.killindicator.think = KillIndicator_Think;
1074                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1075                                 e.killindicator.cnt = ceil(killtime);
1076                         }
1077                         self.lip = 0;
1078                 }
1079         }
1080         if(self.killindicator)
1081         {
1082                 if(targetteam)
1083                         self.killindicator.colormod = TeamColor(targetteam);
1084                 else
1085                         self.killindicator.colormod = '0 0 0';
1086         }
1087 }
1088
1089 void ClientKill (void)
1090 {
1091         ClientKill_TeamChange(0);
1092 }
1093
1094 void DoTeamChange(float destteam)
1095 {
1096         float t, c0;
1097         if(!teams_matter)
1098         {
1099                 if(destteam >= 0)
1100                         SetPlayerColors(self, destteam);
1101                 return;
1102         }
1103         if(self.classname == "player")
1104         if(destteam == -1)
1105         {
1106                 CheckAllowedTeams(self);
1107                 t = FindSmallestTeam(self, TRUE);
1108                 switch(self.team)
1109                 {
1110                         case COLOR_TEAM1: c0 = c1; break;
1111                         case COLOR_TEAM2: c0 = c2; break;
1112                         case COLOR_TEAM3: c0 = c3; break;
1113                         case COLOR_TEAM4: c0 = c4; break;
1114                         default:          c0 = 999;
1115                 }
1116                 switch(t)
1117                 {
1118                         case 1:
1119                                 if(c0 > c1)
1120                                         destteam = COLOR_TEAM1;
1121                                 break;
1122                         case 2:
1123                                 if(c0 > c2)
1124                                         destteam = COLOR_TEAM2;
1125                                 break;
1126                         case 3:
1127                                 if(c0 > c3)
1128                                         destteam = COLOR_TEAM3;
1129                                 break;
1130                         case 4:
1131                                 if(c0 > c4)
1132                                         destteam = COLOR_TEAM4;
1133                                 break;
1134                 }
1135                 if(destteam == -1)
1136                         return;
1137         }
1138         if(destteam == self.team && !self.killindicator)
1139                 return;
1140         ClientKill_TeamChange(destteam);
1141 }
1142
1143 void FixClientCvars(entity e)
1144 {
1145         // send prediction settings to the client
1146         stuffcmd(e, "\nin_bindmap 0 0\n");
1147         /*
1148          * we no longer need to stuff this. Remove this comment block if you feel
1149          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1150         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1151         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1152         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1153         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1154         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1155         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1156         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1157         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1158         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1159         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1160         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1161         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1162         stuffcmd(e, "cl_movement_edgefriction 1\n");
1163          */
1164 }
1165
1166 /*
1167 =============
1168 ClientConnect
1169
1170 Called when a client connects to the server
1171 =============
1172 */
1173 //void ctf_clientconnect();
1174 string ColoredTeamName(float t);
1175 void DecodeLevelParms (void);
1176 //void dom_player_join_team(entity pl);
1177 void ClientConnect (void)
1178 {
1179         local string s;
1180         float t;
1181
1182         if(self.flags & FL_CLIENT)
1183         {
1184                 print("Warning: ClientConnect, but already connected!\n");
1185                 return;
1186         }
1187
1188         if(Ban_MaybeEnforceBan(self))
1189                 return;
1190
1191         DecodeLevelParms();
1192
1193         self.classname = "player_joining";
1194
1195         self.flags = FL_CLIENT;
1196         self.version_nagtime = time + 10 + random() * 10;
1197
1198         if(player_count<0)
1199         {
1200                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1201                 player_count = 0;
1202         }
1203
1204         PlayerScore_Attach(self);
1205         ClientData_Attach();
1206
1207         bot_clientconnect();
1208
1209         race_PreSpawnObserver();
1210
1211         //if(g_domination)
1212         //      dom_player_join_team(self);
1213
1214         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1215
1216         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1217                 self.classname = "observer";
1218         } else {
1219                 if(teams_matter)
1220                 {
1221                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1222                         {
1223                                 self.classname = "player";
1224                                 campaign_bots_may_start = 1;
1225                         }
1226                         else
1227                         {
1228                                 self.classname = "observer"; // do it anyway
1229                         }
1230                 }
1231                 else
1232                 {
1233                         self.classname = "player";
1234                         campaign_bots_may_start = 1;
1235                 }
1236         }
1237
1238         self.playerid = (playerid_last = playerid_last + 1);
1239         if(cvar("sv_eventlog"))
1240         {
1241                 if(clienttype(self) == CLIENTTYPE_REAL)
1242                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1243                 else
1244                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1245                 s = strcat(":team:", ftos(self.playerid), ":");
1246                 s = strcat(s, ftos(self.team));
1247                 GameLogEcho(s);
1248         }
1249         self.netname_previous = strzone(self.netname);
1250
1251         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1252
1253         bprint ("^4",self.netname);
1254         bprint ("^4 connected");
1255
1256         if(g_domination || g_ctf)
1257         {
1258                 bprint(" and joined the ");
1259                 bprint(ColoredTeamName(self.team));
1260         }
1261
1262         bprint("\n");
1263
1264         self.welcomemessage_time = 0;
1265
1266         stuffcmd(self, strcat(clientstuff, "\n"));
1267         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1268         stuffcmd(self, "cl_particles_reloadeffects\n");
1269
1270         FixClientCvars(self);
1271
1272         // spawnfunc_waypoint sprites
1273         WaypointSprite_InitClient(self);
1274
1275         // Wazat's grappling hook
1276         SetGrappleHookBindings();
1277
1278         // get autoswitch state from player when he toggles it
1279         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1280
1281         // get version info from player
1282         stuffcmd(self, "cmd clientversion $gameversion\n");
1283
1284         // get other cvars from player
1285         GetCvars(0);
1286
1287         // set cvar for team scoreboard
1288         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1289
1290         // notify about available teams
1291         if(teams_matter)
1292         {
1293                 CheckAllowedTeams(self);
1294                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1295                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1296         }
1297         else
1298                 stuffcmd(self, "set _teams_available 0\n");
1299
1300         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1301
1302         if(g_arena)
1303         {
1304                 self.classname = "observer";
1305                 Spawnqueue_Insert(self);
1306         }
1307         /*else if(g_ctf)
1308         {
1309                 ctf_clientconnect();
1310         }*/
1311
1312         if(teams_matter)
1313                 attach_entcs();
1314
1315         bot_relinkplayerlist();
1316
1317         self.spectatortime = time;
1318         if(blockSpectators)
1319         {
1320                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1321         }
1322
1323         self.jointime = time;
1324         self.allowedTimeouts = cvar("sv_timeout_number");
1325
1326         if(clienttype(self) == CLIENTTYPE_REAL)
1327         {
1328                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1329
1330                 if(cvar("g_bugrigs"))
1331                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1332         }
1333
1334         if(g_lms)
1335         {
1336                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1337                 {
1338                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1339                         self.frags = FRAGS_SPECTATOR;
1340                 }
1341         }
1342
1343         if(!sv_foginterval && world.fog != "")
1344                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1345
1346         SoundEntity_Attach(self);
1347 }
1348
1349 /*
1350 =============
1351 ClientDisconnect
1352
1353 Called when a client disconnects from the server
1354 =============
1355 */
1356 .entity chatbubbleentity;
1357 .entity teambubbleentity;
1358 void ReadyCount();
1359 void ClientDisconnect (void)
1360 {
1361         if not(self.flags & FL_CLIENT)
1362         {
1363                 print("Warning: ClientDisconnect without ClientConnect\n");
1364                 return;
1365         }
1366
1367         bot_clientdisconnect();
1368
1369         if(teams_matter)
1370                 detach_entcs();
1371
1372         if(cvar("sv_eventlog"))
1373                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1374         bprint ("^4",self.netname);
1375         bprint ("^4 disconnected\n");
1376
1377         SoundEntity_Detach(self);
1378
1379         DropAllRunes(self);
1380         kh_Key_DropAll(self, TRUE);
1381
1382         Portal_ClearAll(self);
1383
1384         if(self.flagcarried)
1385                 DropFlag(self.flagcarried, world, world);
1386
1387         // Here, everything has been done that requires this player to be a client.
1388
1389         self.flags &~= FL_CLIENT;
1390
1391         if (self.chatbubbleentity)
1392                 remove (self.chatbubbleentity);
1393
1394         if (self.teambubbleentity)
1395                 remove (self.teambubbleentity);
1396
1397         if (self.killindicator)
1398                 remove (self.killindicator);
1399
1400         WaypointSprite_PlayerGone();
1401
1402         bot_relinkplayerlist();
1403
1404         // remove laserdot
1405         if(self.weaponentity)
1406                 if(self.weaponentity.lasertarget)
1407                         remove(self.weaponentity.lasertarget);
1408
1409         if(g_arena)
1410         {
1411                 Spawnqueue_Unmark(self);
1412                 Spawnqueue_Remove(self);
1413         }
1414
1415         ClientData_Detach();
1416         PlayerScore_Detach(self);
1417
1418         if(self.netname_previous)
1419                 strunzone(self.netname_previous);
1420
1421         ClearPlayerSounds();
1422
1423         self.playerid = 0;
1424         ReadyCount();
1425
1426         // free cvars
1427         GetCvars(-1);
1428 }
1429
1430 .float BUTTON_CHAT;
1431 void ChatBubbleThink()
1432 {
1433         self.nextthink = time;
1434         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1435         {
1436                 if(self.owner) // but why can that ever be world?
1437                         self.owner.chatbubbleentity = world;
1438                 remove(self);
1439                 return;
1440         }
1441         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1442                 self.model = self.mdl;
1443         else
1444                 self.model = "";
1445 };
1446
1447 void UpdateChatBubble()
1448 {
1449         if (!self.modelindex)
1450                 return;
1451         // spawn a chatbubble entity if needed
1452         if (!self.chatbubbleentity)
1453         {
1454                 self.chatbubbleentity = spawn();
1455                 self.chatbubbleentity.owner = self;
1456                 self.chatbubbleentity.exteriormodeltoclient = self;
1457                 self.chatbubbleentity.think = ChatBubbleThink;
1458                 self.chatbubbleentity.nextthink = time;
1459                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1460                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1461                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1462                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1463                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1464                 self.chatbubbleentity.model = "";
1465                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1466         }
1467 }
1468
1469
1470 void TeamBubbleThink()
1471 {
1472         self.nextthink = time;
1473         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1474         {
1475                 if(self.owner) // but why can that ever be world?
1476                         self.owner.teambubbleentity = world;
1477                 remove(self);
1478                 return;
1479         }
1480 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1481         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1482                 self.model = "";
1483         else
1484                 self.model = self.mdl;
1485
1486 };
1487
1488 float TeamBubble_customizeentityforclient()
1489 {
1490         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1491 }
1492
1493 void UpdateTeamBubble()
1494 {
1495         if (!self.modelindex || !teams_matter)
1496                 return;
1497         // spawn a teambubble entity if needed
1498         if (!self.teambubbleentity && teams_matter)
1499         {
1500                 self.teambubbleentity = spawn();
1501                 self.teambubbleentity.owner = self;
1502                 self.teambubbleentity.exteriormodeltoclient = self;
1503                 self.teambubbleentity.think = TeamBubbleThink;
1504                 self.teambubbleentity.nextthink = time;
1505                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1506 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1507                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1508                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1509                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1510                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1511                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1512                 self.teambubbleentity.effects = EF_LOWPRECISION;
1513         }
1514 }
1515
1516 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1517 // added to the model skins
1518 /*void UpdateColorModHack()
1519 {
1520         local float c;
1521         c = self.clientcolors & 15;
1522         // LordHavoc: only bothering to support white, green, red, yellow, blue
1523              if (!teams_matter) self.colormod = '0 0 0';
1524         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1525         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1526         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1527         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1528         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1529         else self.colormod = '1 1 1';
1530 };*/
1531
1532 void respawn(void)
1533 {
1534         CopyBody(1);
1535         self.effects |= EF_NODRAW; // prevent another CopyBody
1536         PutClientInServer();
1537 }
1538
1539 /**
1540  * When sv_timeout is used this function returs strings like
1541  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1542  * Called by centerprint functions
1543  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1544  */
1545 string getTimeoutText(float addOneSecond) {
1546         if (!cvar("sv_timeout") || !timeoutStatus)
1547                 return "";
1548
1549         local string retStr;
1550         if (timeoutStatus == 1) {
1551                 if (addOneSecond == 1) {
1552                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1553                 }
1554                 else {
1555                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1556                 }
1557                 return retStr;
1558         }
1559         else if (timeoutStatus == 2) {
1560                 if (addOneSecond) {
1561                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1562                         //don't show messages like "Timeout ends in 0 seconds"...
1563                         if ((remainingTimeoutTime + 1) > 0)
1564                                 return retStr;
1565                         else
1566                                 return "";
1567                 }
1568                 else {
1569                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1570                         //don't show messages like "Timeout ends in 0 seconds"...
1571                         if (remainingTimeoutTime > 0)
1572                                 return retStr;
1573                         else
1574                                 return "";
1575                 }
1576         }
1577         else return "";
1578 }
1579
1580 void player_powerups (void)
1581 {
1582         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1583         {
1584                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, ATTN_IDLE);
1585                 self.modelflags |= MF_ROCKET;
1586         }
1587         else
1588         {
1589                 SoundEntity_StopSound(self, CHAN_PLAYER);
1590                 self.modelflags &~= MF_ROCKET;
1591         }
1592
1593         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1594
1595         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1596                 return;
1597
1598         if (g_minstagib)
1599         {
1600                 if (self.items & IT_STRENGTH)
1601                 {
1602                         if (time > self.strength_finished)
1603                         {
1604                                 self.alpha = default_player_alpha;
1605                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1606                                 self.items &~= IT_STRENGTH;
1607                                 sprint(self, "^3Invisibility has worn off\n");
1608                         }
1609                 }
1610                 else
1611                 {
1612                         if (time < self.strength_finished)
1613                         {
1614                                 self.alpha = g_minstagib_invis_alpha;
1615                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1616                                 self.items |= IT_STRENGTH;
1617                                 sprint(self, "^3You are invisible\n");
1618                         }
1619                 }
1620
1621                 if (self.items & IT_INVINCIBLE)
1622                 {
1623                         if (time > self.invincible_finished)
1624                         {
1625                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1626                                 sprint(self, "^3Speed has worn off\n");
1627                         }
1628                 }
1629                 else
1630                 {
1631                         if (time < self.invincible_finished)
1632                         {
1633                                 self.items = self.items | IT_INVINCIBLE;
1634                                 sprint(self, "^3You are on speed\n");
1635                         }
1636                 }
1637                 return;
1638         }
1639
1640         if (self.items & IT_STRENGTH)
1641         {
1642                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1643                 if (time > self.strength_finished)
1644                 {
1645                         self.items = self.items - (self.items & IT_STRENGTH);
1646                         sprint(self, "^3Strength has worn off\n");
1647                 }
1648         }
1649         else
1650         {
1651                 if (time < self.strength_finished)
1652                 {
1653                         self.items = self.items | IT_STRENGTH;
1654                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1655                 }
1656         }
1657         if (self.items & IT_INVINCIBLE)
1658         {
1659                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1660                 if (time > self.invincible_finished)
1661                 {
1662                         self.items = self.items - (self.items & IT_INVINCIBLE);
1663                         sprint(self, "^3Shield has worn off\n");
1664                 }
1665         }
1666         else
1667         {
1668                 if (time < self.invincible_finished)
1669                 {
1670                         self.items = self.items | IT_INVINCIBLE;
1671                         sprint(self, "^3Shield surrounds you\n");
1672                 }
1673         }
1674
1675         if (cvar("g_fullbrightplayers"))
1676                 self.effects = self.effects | EF_FULLBRIGHT;
1677
1678         // midair gamemode: damage only while in the air
1679         // if in midair mode, being on ground grants temporary invulnerability
1680         // (this is so that multishot weapon don't clear the ground flag on the
1681         // first damage in the frame, leaving the player vulnerable to the
1682         // remaining hits in the same frame)
1683         if (self.flags & FL_ONGROUND)
1684         if (g_midair)
1685                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1686
1687         if (time >= game_starttime)
1688         if (time < self.spawnshieldtime)
1689                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1690 }
1691
1692 float CalcRegen(float current, float stable, float regenfactor)
1693 {
1694         if(current > stable)
1695                 return current;
1696         else if(current > stable - 0.25) // when close enough, "snap"
1697                 return stable;
1698         else
1699                 return min(stable, current + (stable - current) * regenfactor * frametime);
1700 }
1701
1702 void player_regen (void)
1703 {
1704         float maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1705         maxh = cvar("g_balance_health_stable");
1706         maxa = cvar("g_balance_armor_stable");
1707         maxf = cvar("g_balance_fuel_stable");
1708         limith = cvar("g_balance_health_limit");
1709         limita = cvar("g_balance_armor_limit");
1710         limitf = cvar("g_balance_fuel_limit");
1711
1712         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1713                 return;
1714
1715         max_mod = regen_mod = rot_mod = limit_mod = 1;
1716
1717         if (self.runes & RUNE_REGEN)
1718         {
1719                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1720                 {
1721                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1722                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1723                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1724                 }
1725                 else
1726                 {
1727                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1728                         max_mod = cvar("g_balance_rune_regen_hpmod");
1729                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1730                 }
1731         }
1732         else if (self.runes & CURSE_VENOM)
1733         {
1734                 max_mod = cvar("g_balance_curse_venom_hpmod");
1735                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1736                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1737                 else
1738                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1739                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1740                 //if (!self.runes & RUNE_REGEN)
1741                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1742         }
1743         maxh = maxh * max_mod;
1744         //maxa = maxa * max_mod;
1745         //maxf = maxf * max_mod;
1746         limith = limith * limit_mod;
1747         limita = limita * limit_mod;
1748         //limitf = limitf * limit_mod;
1749
1750         if (self.armorvalue > maxa)
1751         {
1752                 if (time > self.pauserotarmor_finished)
1753                 {
1754                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1755                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1756                 }
1757         }
1758         else if (self.armorvalue < maxa)
1759         {
1760                 if (time > self.pauseregen_finished)
1761                 {
1762                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1763                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1764                 }
1765         }
1766         if (self.health > maxh)
1767         {
1768                 if (time > self.pauserothealth_finished)
1769                 {
1770                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1771                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1772                 }
1773         }
1774         else if (self.health < maxh)
1775         {
1776                 if (time > self.pauseregen_finished)
1777                 {
1778                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1779                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1780                 }
1781         }
1782         if (self.ammo_fuel > maxf)
1783         {
1784                 if (time > self.pauserotfuel_finished)
1785                 {
1786                         self.ammo_fuel = max(maxf, self.ammo_fuel + (maxf - self.ammo_fuel) * rot_mod*cvar("g_balance_fuel_rot") * frametime);
1787                         self.ammo_fuel = max(maxf, self.ammo_fuel - rot_mod*cvar("g_balance_fuel_rotlinear") * frametime);
1788                 }
1789         }
1790         else if (self.ammo_fuel < maxf)
1791         {
1792                 if(self.items & IT_FUEL_REGEN)
1793                 {
1794                         if (time > self.pauseregen_finished)
1795                         {
1796                                 self.ammo_fuel = CalcRegen(self.ammo_fuel, maxf, regen_mod * cvar("g_balance_fuel_regen"));
1797                                 self.ammo_fuel = min(maxf, self.ammo_fuel + regen_mod*cvar("g_balance_fuel_regenlinear") * frametime);
1798                         }
1799                 }
1800         }
1801
1802         if (self.health > limith)
1803                 self.health = limith;
1804         if (self.armorvalue > limita)
1805                 self.armorvalue = limita;
1806         if (self.ammo_fuel > limitf)
1807                 self.ammo_fuel = limitf;
1808
1809         // if player rotted to death...  die!
1810         if(self.health < 1)
1811                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1812 }
1813
1814 float zoomstate_set;
1815 void SetZoomState(float z)
1816 {
1817         if(z != self.zoomstate)
1818                 ClientData_Touch(self);
1819         zoomstate_set = 1;
1820 }
1821
1822 void GetPressedKeys(void) {
1823         if (self.movement_x > 0) // get if movement keys are pressed
1824         {       // forward key pressed
1825                 self.pressedkeys |= KEY_FORWARD;
1826                 self.pressedkeys &~= KEY_BACKWARD;
1827         }
1828         else if (self.movement_x < 0)
1829         {       // backward key pressed
1830                 self.pressedkeys |= KEY_BACKWARD;
1831                 self.pressedkeys &~= KEY_FORWARD;
1832         }
1833         else
1834         {       // no x input
1835                 self.pressedkeys &~= KEY_FORWARD;
1836                 self.pressedkeys &~= KEY_BACKWARD;
1837         }
1838
1839         if (self.movement_y > 0)
1840         {       // right key pressed
1841                 self.pressedkeys |= KEY_RIGHT;
1842                 self.pressedkeys &~= KEY_LEFT;
1843         }
1844         else if (self.movement_y < 0)
1845         {       // left key pressed
1846                 self.pressedkeys |= KEY_LEFT;
1847                 self.pressedkeys &~= KEY_RIGHT;
1848         }
1849         else
1850         {       // no y input
1851                 self.pressedkeys &~= KEY_RIGHT;
1852                 self.pressedkeys &~= KEY_LEFT;
1853         }
1854
1855         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1856                 self.pressedkeys |= KEY_JUMP;
1857         else
1858                 self.pressedkeys &~= KEY_JUMP;
1859         if (self.BUTTON_CROUCH)
1860                 self.pressedkeys |= KEY_CROUCH;
1861         else
1862                 self.pressedkeys &~= KEY_CROUCH;
1863 }
1864
1865 /*
1866 ======================
1867 spectate mode routines
1868 ======================
1869 */
1870 void SpectateCopy(entity spectatee) {
1871         self.armortype = spectatee.armortype;
1872         self.armorvalue = spectatee.armorvalue;
1873         self.ammo_cells = spectatee.ammo_cells;
1874         self.ammo_shells = spectatee.ammo_shells;
1875         self.ammo_nails = spectatee.ammo_nails;
1876         self.ammo_rockets = spectatee.ammo_rockets;
1877         self.ammo_fuel = spectatee.ammo_fuel;
1878         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1879         self.health = spectatee.health;
1880         self.impulse = 0;
1881         self.items = spectatee.items;
1882         self.strength_finished = spectatee.strength_finished;
1883         self.invincible_finished = spectatee.invincible_finished;
1884         self.pressedkeys = spectatee.pressedkeys;
1885         self.weapons = spectatee.weapons;
1886         self.switchweapon = spectatee.switchweapon;
1887         self.weapon = spectatee.weapon;
1888         self.punchangle = spectatee.punchangle;
1889         self.view_ofs = spectatee.view_ofs;
1890         self.v_angle = spectatee.v_angle;
1891         self.velocity = spectatee.velocity;
1892         self.dmg_take = spectatee.dmg_take;
1893         self.dmg_save = spectatee.dmg_save;
1894         self.dmg_inflictor = spectatee.dmg_inflictor;
1895         self.angles = spectatee.v_angle;
1896         self.fixangle = TRUE;
1897         setorigin(self, spectatee.origin);
1898         setsize(self, spectatee.mins, spectatee.maxs);
1899         SetZoomState(spectatee.zoomstate);
1900 }
1901
1902 float SpectateUpdate() {
1903         if(!self.enemy)
1904                 return 0;
1905
1906         if (self == self.enemy)
1907                 return 0;
1908
1909         if(self.enemy.flags & FL_NOTARGET)
1910                 return 0;
1911
1912         SpectateCopy(self.enemy);
1913
1914         return 1;
1915 }
1916
1917 float SpectateNext() {
1918         other = find(self.enemy, classname, "player");
1919         if (!other) {
1920                 other = find(other, classname, "player");
1921         }
1922         if (other) {
1923                 self.enemy = other;
1924         }
1925         if(self.enemy.classname == "player") {
1926                 msg_entity = self;
1927                 WriteByte(MSG_ONE, SVC_SETVIEW);
1928                 WriteEntity(MSG_ONE, self.enemy);
1929                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1930                 if(!SpectateUpdate())
1931                         PutObserverInServer();
1932                 return 1;
1933         } else {
1934                 return 0;
1935         }
1936 }
1937
1938 /*
1939 =============
1940 ShowRespawnCountdown()
1941
1942 Update a respawn countdown display.
1943 =============
1944 */
1945 void ShowRespawnCountdown()
1946 {
1947         float number;
1948         if(self.deadflag == DEAD_NO) // just respawned?
1949                 return;
1950         else
1951         {
1952                 number = ceil(self.death_time - time);
1953                 if(number <= 0)
1954                         return;
1955                 if(number <= self.respawn_countdown)
1956                 {
1957                         self.respawn_countdown = number - 1;
1958                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1959                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1960                 }
1961         }
1962 }
1963
1964 void LeaveSpectatorMode()
1965 {
1966         if(isJoinAllowed()) {
1967                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
1968                         self.classname = "player";
1969                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1970                                 JoinBestTeam(self, FALSE, TRUE);
1971                         if(cvar("g_campaign"))
1972                                 campaign_bots_may_start = 1;
1973                         PutClientInServer();
1974                         if(!(self.flags & FL_NOTARGET))
1975                                 bprint ("^4", self.netname, "^4 is playing now\n");
1976                         centerprint(self,"");
1977                         return;
1978                 } else {
1979                         stuffcmd(self,"menu_showteamselect\n");
1980                         return;
1981                 }
1982         }
1983         else {
1984                 //player may not join because of g_maxplayers is set
1985                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1986         }
1987 }
1988
1989 /**
1990  * Determines whether the player is allowed to join. This depends on cvar
1991  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1992  * it checks whether the number of currently playing players exceeds g_maxplayers.
1993  * @return bool TRUE if the player is allowed to join, false otherwise
1994  */
1995 float isJoinAllowed() {
1996         if (!cvar("g_maxplayers"))
1997                 return TRUE;
1998
1999         local entity e;
2000         local float currentlyPlaying;
2001         FOR_EACH_REALPLAYER(e) {
2002                 if(e.classname == "player")
2003                         currentlyPlaying += 1;
2004         }
2005         if(currentlyPlaying < cvar("g_maxplayers"))
2006                 return TRUE;
2007
2008         return FALSE;
2009 }
2010
2011 /**
2012  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2013  * g_maxplayers_spectator_blocktime seconds
2014  */
2015 void checkSpectatorBlock() {
2016         if(self.classname == "spectator" || self.classname == "observer") {
2017                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2018                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2019                         dropclient(self);
2020                 }
2021         }
2022 }
2023
2024 float vercmp_recursive(string v1, string v2)
2025 {
2026         float dot1, dot2;
2027         string s1, s2;
2028         float r;
2029
2030         dot1 = strstrofs(v1, ".", 0);
2031         dot2 = strstrofs(v2, ".", 0);
2032         if(dot1 == -1)
2033                 s1 = v1;
2034         else
2035                 s1 = substring(v1, 0, dot1);
2036         if(dot2 == -1)
2037                 s2 = v2;
2038         else
2039                 s2 = substring(v2, 0, dot2);
2040
2041         r = stof(s1) - stof(s2);
2042         if(r != 0)
2043                 return r;
2044
2045         r = strcasecmp(s1, s2);
2046         if(r != 0)
2047                 return r;
2048
2049         if(dot1 == -1)
2050                 if(dot2 == -1)
2051                         return 0;
2052                 else
2053                         return -1;
2054         else
2055                 if(dot2 == -1)
2056                         return 1;
2057                 else
2058                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2059 }
2060
2061 float vercmp(string v1, string v2)
2062 {
2063         if(strcasecmp(v1, v2) == 0) // early out check
2064                 return 0;
2065         return vercmp_recursive(v1, v2);
2066 }
2067
2068 void ObserverThink()
2069 {
2070         if (self.flags & FL_JUMPRELEASED) {
2071                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2072                         self.welcomemessage_time = 0;
2073                         self.flags &~= FL_JUMPRELEASED;
2074                         self.flags |= FL_SPAWNING;
2075                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2076                         self.welcomemessage_time = 0;
2077                         self.flags &~= FL_JUMPRELEASED;
2078                         if(SpectateNext() == 1) {
2079                                 self.classname = "spectator";
2080                         }
2081                 }
2082         } else {
2083                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2084                         self.flags |= FL_JUMPRELEASED;
2085                         if(self.flags & FL_SPAWNING)
2086                         {
2087                                 self.flags &~= FL_SPAWNING;
2088                                 LeaveSpectatorMode();
2089                                 return;
2090                         }
2091                 }
2092         }
2093         PrintWelcomeMessage(self);
2094 }
2095
2096 void SpectatorThink()
2097 {
2098         if (self.flags & FL_JUMPRELEASED) {
2099                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2100                         self.welcomemessage_time = 0;
2101                         self.flags &~= FL_JUMPRELEASED;
2102                         self.flags |= FL_SPAWNING;
2103                 } else if(self.BUTTON_ATCK) {
2104                         self.welcomemessage_time = 0;
2105                         self.flags &~= FL_JUMPRELEASED;
2106                         if(SpectateNext() == 1) {
2107                                 self.classname = "spectator";
2108                         } else {
2109                                 self.classname = "observer";
2110                                 PutClientInServer();
2111                         }
2112                 } else if (self.BUTTON_ATCK2) {
2113                         self.welcomemessage_time = 0;
2114                         self.flags &~= FL_JUMPRELEASED;
2115                         self.classname = "observer";
2116                         PutClientInServer();
2117                 } else {
2118                         if(!SpectateUpdate())
2119                                 PutObserverInServer();
2120                 }
2121         } else {
2122                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2123                         self.flags |= FL_JUMPRELEASED;
2124                         if(self.flags & FL_SPAWNING)
2125                         {
2126                                 self.flags &~= FL_SPAWNING;
2127                                 LeaveSpectatorMode();
2128                                 return;
2129                         }
2130                 }
2131         }
2132         PrintWelcomeMessage(self);
2133         self.flags |= FL_CLIENT | FL_NOTARGET;
2134 }
2135
2136 .float touchexplode_time;
2137
2138 /*
2139 =============
2140 PlayerPreThink
2141
2142 Called every frame for each client before the physics are run
2143 =============
2144 */
2145 void() ctf_setstatus;
2146 void PlayerPreThink (void)
2147 {
2148         self.stat_sys_ticrate = cvar("sys_ticrate");
2149         self.stat_game_starttime = game_starttime;
2150         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2151
2152         if(blockSpectators && frametime)
2153                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2154                 checkSpectatorBlock();
2155
2156         zoomstate_set = 0;
2157
2158         if(self.netname_previous != self.netname)
2159         {
2160                 if(cvar("sv_eventlog"))
2161                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2162                 if(self.netname_previous)
2163                         strunzone(self.netname_previous);
2164                 self.netname_previous = strzone(self.netname);
2165         }
2166
2167         // version nagging
2168         if(self.version_nagtime)
2169                 if(self.cvar_g_nexuizversion)
2170                         if(time > self.version_nagtime)
2171                         {
2172                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2173                                 {
2174                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2175                                         {
2176                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2177                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2178                                         }
2179                                         else
2180                                         {
2181                                                 float r;
2182                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2183                                                 if(r < 0)
2184                                                 {
2185                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2186                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2187                                                 }
2188                                                 else if(r > 0)
2189                                                 {
2190                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2191                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2192                                                 }
2193                                         }
2194                                 }
2195                                 self.version_nagtime = 0;
2196                         }
2197
2198         // GOD MODE info
2199         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2200         {
2201                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2202                 self.max_armorvalue = 0;
2203         }
2204
2205         if(frametime)
2206                 antilag_record(self);
2207
2208         if(self.classname == "player") {
2209 //              if(self.netname == "Wazat")
2210 //                      bprint(self.classname, "\n");
2211
2212                 CheckRules_Player();
2213
2214                 PrintWelcomeMessage(self);
2215
2216                 if (intermission_running)
2217                 {
2218                         IntermissionThink ();   // otherwise a button could be missed between
2219                         return;                                 // the think tics
2220                 }
2221
2222                 if(self.teleport_time)
2223                 if(time > self.teleport_time)
2224                 {
2225                         self.teleport_time = 0;
2226                         self.effects = self.effects - (self.effects & EF_NODRAW);
2227                 }
2228
2229                 Nixnex_GiveCurrentWeapon();
2230
2231                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2232                         UpdateSelectedPlayer();
2233
2234                 //don't allow the player to turn around while game is paused!
2235                 if(timeoutStatus == 2) {
2236                         self.v_angle = self.lastV_angle;
2237                         self.angles = self.lastV_angle;
2238                         self.fixangle = TRUE;
2239                 }
2240
2241                 player_powerups();
2242
2243                 if (self.deadflag != DEAD_NO)
2244                 {
2245                         float button_pressed, force_respawn;
2246                         if(frametime)
2247                                 player_anim();
2248                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2249                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2250                         if (self.deadflag == DEAD_DYING)
2251                         {
2252                                 if(force_respawn)
2253                                         self.deadflag = DEAD_RESPAWNING;
2254                                 else if(!button_pressed)
2255                                         self.deadflag = DEAD_DEAD;
2256                         }
2257                         else if (self.deadflag == DEAD_DEAD)
2258                         {
2259                                 if(button_pressed)
2260                                         self.deadflag = DEAD_RESPAWNABLE;
2261                         }
2262                         else if (self.deadflag == DEAD_RESPAWNABLE)
2263                         {
2264                                 if(!button_pressed)
2265                                         self.deadflag = DEAD_RESPAWNING;
2266                         }
2267                         else if (self.deadflag == DEAD_RESPAWNING)
2268                         {
2269                                 if(time > self.death_time)
2270                                 {
2271                                         self.death_time = time + 1; // only retry once a second
2272                                         respawn();
2273                                 }
2274                         }
2275                         ShowRespawnCountdown();
2276                         return;
2277                 }
2278
2279                 if(g_touchexplode)
2280                 if(time > self.touchexplode_time)
2281                 if(self.classname == "player")
2282                 if(self.deadflag == DEAD_NO)
2283                 if not(IS_INDEPENDENT_PLAYER(self))
2284                 FOR_EACH_PLAYER(other) if(self != other)
2285                 {
2286                         if(time > other.touchexplode_time)
2287                         if(other.classname == "player")
2288                         if(other.deadflag == DEAD_NO)
2289                         if not(IS_INDEPENDENT_PLAYER(other))
2290                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2291                         {
2292                                 PlayerTouchExplode(self, other);
2293                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2294                         }
2295                 }
2296
2297                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2298                 {
2299                         vector dist;
2300
2301                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2302                         dist = self.oldorigin - self.origin;
2303                         dist_z = 0;
2304                         self.lms_traveled_distance += fabs(vlen(dist));
2305
2306                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2307                         {
2308                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2309                                 self.lms_traveled_distance = 0;
2310                         }
2311
2312                         if(time > self.lms_nextcheck)
2313                         {
2314                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2315                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2316                                 {
2317                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2318                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2319                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2320                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2321                                 }
2322                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2323                                 self.lms_traveled_distance = 0;
2324                         }
2325                 }
2326
2327                 self.oldorigin = self.origin;
2328
2329                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2330                 {
2331                         if (!self.crouch)
2332                         {
2333                                 self.crouch = TRUE;
2334                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2335                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2336                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2337                         }
2338                 }
2339                 else
2340                 {
2341                         if (self.crouch)
2342                         {
2343                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2344                                 if (!trace_startsolid)
2345                                 {
2346                                         self.crouch = FALSE;
2347                                         self.view_ofs = PL_VIEW_OFS;
2348                                         setsize (self, PL_MIN, PL_MAX);
2349                                 }
2350                         }
2351                 }
2352
2353                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2354                 {
2355                         if(self.bloodloss_timer < time)
2356                         {
2357                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2358                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2359                         }
2360                 }
2361
2362                 FixPlayermodel();
2363
2364                 GrapplingHookFrame();
2365
2366                 if(frametime)
2367                 {
2368                         W_WeaponFrame();
2369                         if(self.items & IT_JETPACK)
2370                                 self.items |= IT_FUEL;
2371                 }
2372
2373                 player_regen();
2374                 if(frametime)
2375                         player_anim();
2376
2377                 if (g_minstagib)
2378                         minstagib_ammocheck();
2379
2380                 ctf_setstatus();
2381                 kh_setstatus();
2382
2383                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2384
2385                 //self.angles_y=self.v_angle_y + 90;   // temp
2386
2387                 //if (TetrisPreFrame()) return;
2388         } else if(gameover) {
2389                 if (intermission_running)
2390                         IntermissionThink ();   // otherwise a button could be missed between
2391                 return;
2392         } else if(self.classname == "observer") {
2393                 ObserverThink();
2394         } else if(self.classname == "spectator") {
2395                 SpectatorThink();
2396         }
2397
2398         if(!zoomstate_set)
2399                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2400
2401         float oldspectatee_status;
2402         oldspectatee_status = self.spectatee_status;
2403         if(self.classname == "spectator")
2404                 self.spectatee_status = num_for_edict(self.enemy);
2405         else if(self.classname == "observer")
2406                 self.spectatee_status = num_for_edict(self);
2407         else
2408                 self.spectatee_status = 0;
2409         if(self.spectatee_status != oldspectatee_status)
2410         {
2411                 ClientData_Touch(self);
2412                 if(g_race)
2413                         race_InitSpectator();
2414         }
2415
2416         if(self.teamkill_soundtime)
2417         if(time > self.teamkill_soundtime)
2418         {
2419                 self.teamkill_soundtime = 0;
2420
2421                 entity oldpusher, oldself;
2422
2423                 oldself = self; self = self.teamkill_soundsource;
2424                 oldpusher = self.pusher; self.pusher = oldself;
2425
2426                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2427
2428                 self.pusher = oldpusher;
2429                 self = oldself;
2430         }
2431
2432         if(self.taunt_soundtime)
2433         if(time > self.taunt_soundtime)
2434         {
2435                 self.taunt_soundtime = 0;
2436                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2437         }
2438
2439         target_voicescript_next(self);
2440 }
2441
2442 // on dragger:
2443 .entity dragentity;
2444 .float draggravity;
2445 .float dragspeed; // speed of mouse wheel action
2446 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2447 .vector draglocalvector; // local attachment vector of the dragentity
2448 .float draglocalangle;
2449 // on draggee:
2450 .entity draggedby;
2451 .float dragmovetype;
2452 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2453 {
2454         float tagscale;
2455
2456         draggee.dragmovetype = draggee.movetype;
2457         draggee.draggravity = draggee.gravity;
2458         draggee.movetype = MOVETYPE_WALK;
2459         draggee.gravity = 0.00001;
2460         draggee.flags &~= FL_ONGROUND;
2461         draggee.draggedby = dragger;
2462
2463         dragger.dragentity = draggee;
2464
2465         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2466         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2467         touchpoint = touchpoint - gettaginfo(draggee, 0);
2468         tagscale = pow(vlen(v_forward), -2);
2469         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2470         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2471         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2472
2473         dragger.dragspeed = 64;
2474 }
2475
2476 void Drag_Finish(entity dragger)
2477 {
2478         entity draggee;
2479         draggee = dragger.dragentity;
2480         if(dragger)
2481                 dragger.dragentity = world;
2482         draggee.draggedby = world;
2483         draggee.movetype = draggee.dragmovetype;
2484         draggee.gravity = draggee.draggravity;
2485
2486         switch(draggee.movetype)
2487         {
2488                 case MOVETYPE_TOSS:
2489                 case MOVETYPE_WALK:
2490                 case MOVETYPE_STEP:
2491                 case MOVETYPE_FLYMISSILE:
2492                 case MOVETYPE_BOUNCE:
2493                 case MOVETYPE_BOUNCEMISSILE:
2494                         break;
2495                 default:
2496                         draggee.velocity = '0 0 0';
2497                         break;
2498         }
2499
2500         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2501         {
2502                 draggee.velocity = '0 0 0';
2503                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2504         }
2505 }
2506
2507 float Drag_IsDraggable(entity draggee)
2508 {
2509         // TODO add more checks for bad stuff here
2510         if(draggee.classname == "func_bobbing")
2511                 return FALSE;
2512         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2513                 return FALSE;
2514         if(draggee.classname == "plat")
2515                 return FALSE;
2516         if(draggee.classname == "func_button")
2517                 return FALSE;
2518         if(draggee.model == "")
2519                 return FALSE;
2520         if(draggee.classname == "spectator")
2521                 return FALSE;
2522         if(draggee.classname == "observer")
2523                 return FALSE;
2524         if(draggee.classname == "exteriorweaponentity")
2525                 return FALSE;
2526
2527         return TRUE;
2528 }
2529
2530 float Drag_MayChangeAngles(entity draggee)
2531 {
2532         // TODO add more checks for bad stuff here
2533         if(substring(draggee.model, 0, 1) == "*")
2534                 return FALSE;
2535         return TRUE;
2536 }
2537
2538 void Drag_MoveForward(entity dragger)
2539 {
2540         dragger.dragdistance += dragger.dragspeed;
2541 }
2542
2543 void Drag_SetSpeed(entity dragger, float s)
2544 {
2545         dragger.dragspeed = pow(2, s);
2546 }
2547
2548 void Drag_MoveBackward(entity dragger)
2549 {
2550         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2551 }
2552
2553 void Drag_Update(entity dragger)
2554 {
2555         vector curorigin, neworigin, goodvelocity;
2556         float f;
2557         entity draggee;
2558
2559         draggee = dragger.dragentity;
2560         draggee.flags &~= FL_ONGROUND;
2561
2562         curorigin = gettaginfo(draggee, 0);
2563         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2564         makevectors(dragger.v_angle);
2565         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2566         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2567
2568         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2569                 dragger.draglocalangle += 360;
2570         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2571                 dragger.draglocalangle -= 360;
2572
2573         f = min(frametime * 10, 1);
2574         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2575
2576         if(Drag_MayChangeAngles(draggee))
2577                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2578
2579         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2580
2581         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2582 }
2583
2584 float Drag_CanDrag(entity dragger)
2585 {
2586         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2587 }
2588
2589 float Drag_IsDragging(entity dragger)
2590 {
2591         if(!dragger.dragentity)
2592                 return FALSE;
2593         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2594         {
2595                 dragger.dragentity = world;
2596                 return FALSE;
2597         }
2598         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2599         {
2600                 Drag_Finish(dragger);
2601                 return FALSE;
2602         }
2603         return TRUE;
2604 }
2605
2606 void Drag_MoveDrag(entity from, entity to)
2607 {
2608         if(from.draggedby)
2609         {
2610                 to.draggedby = from.draggedby;
2611                 to.draggedby.dragentity = to;
2612                 from.draggedby = world;
2613         }
2614 }
2615
2616 /*
2617 =============
2618 PlayerPostThink
2619
2620 Called every frame for each client after the physics are run
2621 =============
2622 */
2623 .float idlekick_lasttimeleft;
2624 .float race_penalty;
2625 .float race_penalty_nagged;
2626 .float race_penalty_nagtime;
2627 void PlayerPostThink (void)
2628 {
2629         // Savage: Check for nameless players
2630         if (strlen(self.netname) < 1) {
2631                 self.netname = "Player";
2632                 stuffcmd(self, "seta _cl_name Player\n");
2633         }
2634
2635         if(sv_maxidle && frametime)
2636         {
2637                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2638                 float timeleft;
2639                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2640                 if(timeleft <= 0)
2641                 {
2642                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2643                         announce(self, "announcer/robotic/terminated.wav");
2644                         dropclient(self);
2645                         return;
2646                 }
2647                 else if(timeleft <= 10)
2648                 {
2649                         if(timeleft != self.idlekick_lasttimeleft)
2650                         {
2651                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2652                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2653                         }
2654                 }
2655                 else
2656                 {
2657                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2658                 }
2659                 self.idlekick_lasttimeleft = timeleft;
2660         }
2661
2662         if(sv_cheats)
2663                 if(Drag_CanDrag(self))
2664                         if(self.BUTTON_DRAG)
2665                                 if(!self.dragentity)
2666                                         if(self.cursor_trace_ent)
2667                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2668                                                 {
2669                                                         if(self.cursor_trace_ent.draggedby)
2670                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2671                                                         if(self.cursor_trace_ent.tag_entity)
2672                                                                 detach_sameorigin(self.cursor_trace_ent);
2673                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2674                                                 }
2675
2676         if(Drag_IsDragging(self))
2677         {
2678                 if(self.BUTTON_DRAG)
2679                 {
2680                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2681                         {
2682                                 Drag_MoveForward(self);
2683                                 self.impulse = 0;
2684                         }
2685                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2686                         {
2687                                 Drag_MoveBackward(self);
2688                                 self.impulse = 0;
2689                         }
2690                         else if(self.impulse >= 1 && self.impulse <= 9)
2691                         {
2692                                 Drag_SetSpeed(self, self.impulse - 1);
2693                         }
2694                         else if(self.impulse == 14)
2695                         {
2696                                 Drag_SetSpeed(self, 9);
2697                         }
2698
2699                         if(frametime)
2700                                 Drag_Update(self);
2701                 }
2702                 else
2703                 {
2704                         Drag_Finish(self);
2705                 }
2706         }
2707
2708         if(self.classname == "player") {
2709                 CheckRules_Player();
2710                 UpdateChatBubble();
2711                 UpdateTeamBubble();
2712                 if (self.impulse)
2713                         ImpulseCommands();
2714                 if (intermission_running)
2715                         return;         // intermission or finale
2716
2717                 //if (TetrisPostFrame()) return;
2718
2719                 // restart countdown
2720                         if(time < game_starttime) {
2721                                 if (!cvar("sv_ready_restart_after_countdown"))
2722                                 {
2723                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2724                                         {
2725                                                 if(time < game_starttime - 2)
2726                                                 {
2727                                                         if(!self.race_penalty_nagged)
2728                                                         {
2729                                                                 // TODO better notification for this!
2730                                                                 self.race_penalty_nagtime = 0;
2731                                                                 self.race_penalty_nagged = 1;
2732                                                         }
2733                                                 }
2734                                                 else if(!self.race_penalty)
2735                                                 {
2736                                                         self.race_penalty_nagtime = 0;
2737                                                         self.race_penalty = time + 5;
2738                                                 }
2739                                         }
2740                                         if(time > self.race_penalty_nagtime)
2741                                         {
2742                                                 if(self.race_penalty > time)
2743                                                 {
2744                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2745                                                 }
2746                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2747                                                 {
2748                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2749                                                 }
2750                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2751                                         }
2752                                         self.movetype = MOVETYPE_NONE;
2753                                         self.velocity = '0 0 0';
2754                                         self.avelocity = '0 0 0';
2755                                         self.movement = '0 0 0';
2756                                 }
2757                         }
2758                         else if (time < self.race_penalty)
2759                         {
2760                                 self.movetype = MOVETYPE_NONE;
2761                                 self.velocity = '0 0 0';
2762                                 self.avelocity = '0 0 0';
2763                                 self.movement = '0 0 0';
2764                         }
2765                         else
2766                         {
2767                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2768                                 if (!cvar("sv_ready_restart_after_countdown"))
2769                                 {
2770                                         if(self.movetype == MOVETYPE_NONE)
2771                                         {
2772                                                 self.movetype = MOVETYPE_WALK;
2773                                         }
2774                                         self.race_penalty = 0;
2775                                         self.race_penalty_nagged = 0;
2776                                 }
2777                         }
2778                 GetPressedKeys();
2779         } else if (self.classname == "observer") {
2780                 //do nothing
2781         } else if (self.classname == "spectator") {
2782                 //do nothing
2783         }
2784
2785         /*
2786         float i;
2787         for(i = 0; i < 1000; ++i)
2788         {
2789                 vector end;
2790                 end = self.origin + '0 0 1024' + 512 * randomvec();
2791                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2792                 if(trace_fraction < 1)
2793                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2794                 {
2795                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2796                         break;
2797                 }
2798         }
2799         */
2800
2801         Arena_Warmup();
2802
2803         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2804 }