data/qcsrc/server/cl_client.qc

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121
 122         spot = find (world, classname, "testplayerstart");
 123         if (spot)
 124                 return spot;
 125
 126         teamcheck = 0;
 127
 128         if(!anypoint && cvar("g_ctf") )
 129                 teamcheck = self.team;
 130
 131         // get the list of players
 132         playerlist = findchain(classname, "player");
 133         // get the entire list of spots
 134         firstspot = findchain(classname, "info_player_deathmatch");
 135         // filter out the bad ones
 136         // (note this returns the original list if none survived)
 137         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 138
 139         // there is 50/50 chance of choosing a random spot or the furthest spot
 140         // (this means that roughly every other spawn will be furthest, so you
 141         // usually won't get fragged at spawn twice in a row)
 142         if (arena_roundbased)
 143         {
 144                 firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 145                 spot = Spawn_RandomPoint(firstspot);
 146         }
 147         else if (random() > 0.5 || spawn_allbad || spawn_allgood)
 148                 spot = Spawn_RandomPoint(firstspot);
 149         else
 150                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 151
 152         if (!spot)
 153         {
 154                 if(cvar("spawn_debug"))
 155                         GotoNextMap();
 156                 else
 157                         error ("PutClientInServer: no start points on level");
 158         }
 159
 160         return spot;
 161 }
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel = "models/player/marine.zym";
 172 string CheckPlayerModel(string plyermodel) {
 173         if(strlen(plyermodel) < 4)
 174                 return FallbackPlayerModel;
 175         if( substring(plyermodel,0,14) != "models/player/")
 176                 return FallbackPlayerModel;
 177         else if(cvar("sv_servermodelsonly"))
 178         {
 179                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 180                         return FallbackPlayerModel;
 181                 if(!fexists(plyermodel))
 182                         return FallbackPlayerModel;
 183         }
 184         return plyermodel;
 185 }
 186
 187 /*
 188 =============
 189 Client_customizeentityforclient
 190
 191 LOD reduction
 192 =============
 193 */
 194 float Client_customizeentityforclient()
 195 {
 196 #ifdef ALLOW_VARIABLE_LOD
 197         // self: me
 198         // other: the player viewing me
 199         float distance;
 200         float f;
 201
 202         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 203                 return TRUE;
 204
 205         if(other.cvar_cl_playerdetailreduction <= 0)
 206         {
 207                 if(other.cvar_cl_playerdetailreduction <= -2)
 208                         self.modelindex = self.modelindex_lod2;
 209                 else if(other.cvar_cl_playerdetailreduction <= -1)
 210                         self.modelindex = self.modelindex_lod1;
 211                 else
 212                         self.modelindex = self.modelindex_lod0;
 213         }
 214         else
 215         {
 216                 distance = vlen(self.origin - other.origin);
 217                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 218                 if(f > 10000)
 219                         self.modelindex = self.modelindex_lod2;
 220                 else if(f > 5000)
 221                         self.modelindex = self.modelindex_lod1;
 222                 else
 223                         self.modelindex = self.modelindex_lod0;
 224         }
 225 #endif
 226
 227         return TRUE;
 228 }
 229
 230 void setmodel_lod(entity e, string modelname)
 231 {
 232 #ifdef ALLOW_VARIABLE_LOD
 233         string s;
 234
 235         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 236         if(fexists(s))
 237         {
 238                 precache_model(s);
 239                 setmodel(e, s);
 240                 self.modelindex_lod1 = self.modelindex;
 241         }
 242         else
 243                 self.modelindex_lod1 = -1;
 244
 245         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 246         if(fexists(s))
 247         {
 248                 precache_model(s);
 249                 setmodel(e, s);
 250                 self.modelindex_lod2 = self.modelindex;
 251         }
 252         else
 253                 self.modelindex_lod2 = -1;
 254
 255         precache_model(modelname);
 256         setmodel(e, modelname);
 257         self.modelindex_lod0 = self.modelindex;
 258
 259         if(self.modelindex_lod1 < 0)
 260                 self.modelindex_lod1 = self.modelindex;
 261
 262         if(self.modelindex_lod2 < 0)
 263                 self.modelindex_lod2 = self.modelindex;
 264 #else
 265         precache_model(modelname);
 266         setmodel(e, modelname);
 267 #endif
 268 }
 269
 270 /*
 271 =============
 272 PutObserverInServer
 273
 274 putting a client as observer in the server
 275 =============
 276 */
 277 void PutObserverInServer (void)
 278 {
 279         entity  spot;
 280         spot = SelectSpawnPoint (FALSE);
 281         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 282
 283         if(clienttype(self) == CLIENTTYPE_REAL)
 284         {
 285                 msg_entity = self;
 286                 WriteByte(MSG_ONE, SVC_SETVIEW);
 287                 WriteEntity(MSG_ONE, self);
 288         }
 289
 290         if (cvar("g_runematch"))
 291                 DropAllRunes(self);
 292
 293         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 294                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 295         else if(self.killcount != -666)
 296                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 297
 298         self.classname = "observer";
 299         self.health = -666;
 300         self.takedamage = DAMAGE_NO;
 301         self.solid = SOLID_NOT;
 302         self.movetype = MOVETYPE_NOCLIP;
 303         self.flags = FL_CLIENT | FL_NOTARGET;
 304         self.armorvalue = 666;
 305         self.effects = 0;
 306         self.armorvalue = cvar("g_balance_armor_start");
 307         self.pauserotarmor_finished = 0;
 308         self.pauserothealth_finished = 0;
 309         self.pauseregen_finished = 0;
 310         self.damageforcescale = 0;
 311         self.death_time = 0;
 312         self.dead_time = 0;
 313         self.dead_frame = 0;
 314         self.die_frame = 0;
 315         self.deaths = 0;
 316         self.alpha = 0;
 317         self.scale = 0;
 318         self.fade_time = 0;
 319         self.pain_frame = 0;
 320         self.pain_finished = 0;
 321         self.strength_finished = 0;
 322         self.invincible_finished = 0;
 323         self.pushltime = 0;
 324         self.think = SUB_Null;
 325         self.nextthink = 0;
 326         self.hook_time = 0;
 327         self.runes = 0;
 328         self.deadflag = DEAD_NO;
 329         self.angles = spot.angles;
 330         self.angles_z = 0;
 331         self.fixangle = TRUE;
 332         self.crouch = FALSE;
 333
 334         self.view_ofs = PL_VIEW_OFS;
 335         setorigin (self, spot.origin);
 336         setsize (self, '0 0 0', '0 0 0');
 337         self.oldorigin = self.origin;
 338         self.items = 0;
 339         self.model = "";
 340         self.modelindex = 0;
 341         self.weapon = 0;
 342         self.weaponmodel = "";
 343         self.weaponentity = world;
 344         self.killcount = -666;
 345         self.velocity = '0 0 0';
 346         self.avelocity = '0 0 0';
 347         self.punchangle = '0 0 0';
 348         self.punchvector = '0 0 0';
 349         self.oldvelocity = self.velocity;
 350         self.customizeentityforclient = Client_customizeentityforclient;
 351
 352         if(cvar("g_arena"))
 353         {
 354                 if(self.frags != -2)
 355                 {
 356                         Spawnqueue_Insert(self);
 357                 }
 358                 else
 359                 {
 360                         Spawnqueue_Unmark(self);
 361                         Spawnqueue_Remove(self);
 362                 }
 363         }
 364         else if(!cvar("g_lms"))
 365                 self.frags = -666;
 366 }
 367
 368
 369 /*
 370 =============
 371 PutClientInServer
 372
 373 Called when a client spawns in the server
 374 =============
 375 */
 376 void PutClientInServer (void)
 377 {
 378         if(clienttype(self) == CLIENTTYPE_BOT)
 379         {
 380                 self.classname = "player";
 381         }
 382         else if(clienttype(self) == CLIENTTYPE_REAL)
 383         {
 384                 msg_entity = self;
 385                 WriteByte(MSG_ONE, SVC_SETVIEW);
 386                 WriteEntity(MSG_ONE, self);
 387         }
 388
 389         // player is dead and becomes observer
 390         if(cvar("g_lms") && self.frags < 1)
 391                 self.classname = "observer";
 392
 393         if(cvar("g_arena"))
 394         if(!self.spawned)
 395                 self.classname = "observer";
 396
 397         if(self.classname == "player") {
 398                 entity  spot;
 399
 400                 spot = SelectSpawnPoint (FALSE);
 401
 402                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 403
 404                 self.classname = "player";
 405                 self.iscreature = TRUE;
 406                 self.movetype = MOVETYPE_WALK;
 407                 self.solid = SOLID_SLIDEBOX;
 408                 self.flags = FL_CLIENT;
 409                 self.takedamage = DAMAGE_AIM;
 410                 self.effects = 0;
 411                 self.health = cvar("g_balance_health_start");
 412                 self.armorvalue = cvar("g_balance_armor_start");
 413                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 414                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 415                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 416                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 417                 self.damageforcescale = 2;
 418                 self.death_time = 0;
 419                 self.dead_time = 0;
 420                 self.dead_frame = 0;
 421                 self.die_frame = 0;
 422                 self.alpha = 0;
 423                 self.scale = 0;
 424                 self.fade_time = 0;
 425                 self.pain_frame = 0;
 426                 self.pain_finished = 0;
 427                 self.strength_finished = 0;
 428                 self.invincible_finished = 0;
 429                 self.pushltime = 0;
 430                 //self.speed_finished = 0;
 431                 //self.slowmo_finished = 0;
 432                 // players have no think function
 433                 self.think = SUB_Null;
 434                 self.nextthink = 0;
 435                 self.weapon = 0;
 436                 self.switchweapon = 0;
 437                 self.hook_time = 0;
 438
 439                 self.runes = 0;
 440
 441                 self.deadflag = DEAD_NO;
 442
 443                 self.angles = spot.angles;
 444
 445                 self.angles_z = 0; // never spawn tilted even if the spot says to
 446                 self.fixangle = TRUE; // turn this way immediately
 447                 self.velocity = '0 0 0';
 448                 self.avelocity = '0 0 0';
 449                 self.punchangle = '0 0 0';
 450                 self.punchvector = '0 0 0';
 451                 self.oldvelocity = self.velocity;
 452
 453                 self.viewzoom = 0.6;
 454
 455                 self.customizeentityforclient = Client_customizeentityforclient;
 456
 457                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
 458                         local string defaultmodel;
 459                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 460                         setmodel_lod (self, defaultmodel);
 461                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 462                 } else {
 463                         self.playermodel = CheckPlayerModel(self.playermodel);
 464                         setmodel_lod (self, self.playermodel);
 465                         self.skin = stof(self.playerskin);
 466
 467                 }
 468
 469                 self.crouch = FALSE;
 470                 self.view_ofs = PL_VIEW_OFS;
 471                 setsize (self, PL_MIN, PL_MAX);
 472                 self.spawnorigin = spot.origin;
 473                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 474                 // don't reset back to last position, even if new position is stuck in solid
 475                 self.oldorigin = self.origin;
 476
 477                 if(cvar("g_lms"))
 478                 {
 479                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 480                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 481                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 482                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 483                         self.health = cvar("g_lms_start_health");
 484                         self.armorvalue = cvar("g_lms_start_armor");
 485                 }
 486                 else if (cvar("g_use_ammunition")) {
 487                         self.ammo_shells = cvar("g_start_ammo_shells");
 488                         self.ammo_nails = cvar("g_start_ammo_nails");
 489                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 490                         self.ammo_cells = cvar("g_start_ammo_cells");
 491                 } else {
 492                         self.ammo_shells = 999;
 493                         self.ammo_nails = 999;
 494                         self.ammo_rockets = 999;
 495                         self.ammo_cells = 999;
 496                 }
 497
 498                 self.items = 0;
 499                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 500                 {
 501                         self.items = self.items | IT_LASER;
 502                         self.switchweapon = WEP_LASER;
 503                 }
 504                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 505                 {
 506                         self.items = self.items | IT_SHOTGUN;
 507                         self.switchweapon = WEP_SHOTGUN;
 508                 }
 509                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 510                 {
 511                         self.items = self.items | IT_UZI;
 512                         self.switchweapon = WEP_UZI;
 513                 }
 514                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 515                 {
 516                         self.items = self.items | IT_GRENADE_LAUNCHER;
 517                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 518                 }
 519                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 520                 {
 521                         self.items = self.items | IT_ELECTRO;
 522                         self.switchweapon = WEP_ELECTRO;
 523                 }
 524                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 525                 {
 526                         self.items = self.items | IT_CRYLINK;
 527                         self.switchweapon = WEP_CRYLINK;
 528                 }
 529                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 530                 {
 531                         self.items = self.items | IT_NEX;
 532                         self.switchweapon = WEP_NEX;
 533                 }
 534                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 535                 {
 536                         self.items = self.items | IT_HAGAR;
 537                         self.switchweapon = WEP_HAGAR;
 538                 }
 539                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 540                 {
 541                         self.items = self.items | IT_ROCKET_LAUNCHER;
 542                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 543                 }
 544
 545                 if(cvar("g_instagib"))
 546                 {
 547                         self.items = IT_NEX;
 548                         self.switchweapon = WEP_NEX;
 549                         self.ammo_cells = 999;
 550                 }
 551
 552                 if(cvar("g_rocketarena"))
 553                 {
 554                         self.items = IT_ROCKET_LAUNCHER;
 555                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 556                         self.ammo_rockets = 999;
 557                 }
 558
 559                 if(cvar("g_nixnex"))
 560                 {
 561                         self.items = 0;
 562                         // will be done later
 563                 }
 564
 565                 if(cvar("g_minstagib"))
 566                 {
 567                         self.health = 100;
 568                         self.armorvalue = 0;
 569                         self.items = IT_NEX;
 570                         self.switchweapon = WEP_NEX;
 571                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 572                         self.extralives = 0;
 573                         self.jump_interval = time;
 574                 }
 575
 576                 if(cvar("g_arena"))
 577                 {
 578                         Spawnqueue_Remove(self);
 579                         Spawnqueue_Mark(self);
 580                 }
 581
 582                 self.event_damage = PlayerDamage;
 583
 584                 self.bot_attack = TRUE;
 585
 586                 self.statdraintime = time + 5;
 587                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 588
 589                 if(self.killcount == -666) {
 590                         self.killcount = 0;
 591                         if(!cvar("g_arena"))
 592                         if(!cvar("g_lms"))
 593                                 self.frags = 0;
 594                 }
 595
 596                 self.cnt = WEP_LASER;
 597                 self.nixnex_lastchange_id = -1;
 598
 599                 CL_SpawnWeaponentity();
 600                 self.alpha = default_player_alpha;
 601                 self.exteriorweaponentity.alpha = default_player_alpha;
 602
 603                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 604                 self.lms_traveled_distance = 0;
 605
 606                 if(cvar("spawn_debug"))
 607                 {
 608                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 609                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 610                 }
 611
 612                 //stuffcmd(self, "chase_active 0");
 613                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 614         } else if(self.classname == "observer") {
 615                 PutObserverInServer ();
 616         }
 617 }
 618
 619 /*
 620 =============
 621 SetNewParms
 622 =============
 623 */
 624 void SetNewParms (void)
 625 {
 626
 627 }
 628
 629 /*
 630 =============
 631 SetChangeParms
 632 =============
 633 */
 634 void SetChangeParms (void)
 635 {
 636
 637 }
 638
 639 /*
 640 =============
 641 ClientKill
 642
 643 Called when a client types 'kill' in the console
 644 =============
 645 */
 646 void ClientKill (void)
 647 {
 648         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 649 }
 650
 651 /*
 652 =============
 653 ClientConnect
 654
 655 Called when a client connects to the server
 656 =============
 657 */
 658 string ColoredTeamName(float t);
 659 //void dom_player_join_team(entity pl);
 660 void ClientConnect (void)
 661 {
 662         self.classname = "player_joining";
 663         self.flags = self.flags | FL_CLIENT;
 664
 665         if(player_count<0) player_count = 0;
 666
 667         bot_clientconnect();
 668
 669         //if(cvar("g_domination"))
 670         //      dom_player_join_team(self);
 671
 672         //JoinBestTeam(self, FALSE);
 673
 674         if((cvar("sv_spectate") == 1 && !cvar("g_lms")) || cvar("g_campaign")) {
 675                 self.classname = "observer";
 676         } else {
 677                 self.classname = "player";
 678                 campaign_bots_may_start = 1;
 679         }
 680
 681         self.playerid = (playerid_last = playerid_last + 1);
 682         if(cvar("sv_eventlog"))
 683         {
 684                 string s;
 685                 if(clienttype(self) == CLIENTTYPE_REAL)
 686                         s = "player";
 687                 else
 688                         s = "bot";
 689                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 690                 s = strcat(":team:", ftos(self.playerid), ":");
 691                 s = strcat(s, ftos(self.team));
 692                 GameLogEcho(s, FALSE);
 693         }
 694
 695         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 696
 697         bprint ("^4",self.netname);
 698         bprint ("^4 connected");
 699
 700         if(cvar("g_domination") || cvar("g_ctf"))
 701         {
 702                 bprint(" and joined the ");
 703                 bprint(ColoredTeamName(self.team));
 704         }
 705
 706         bprint("\n");
 707
 708         self.welcomemessage_time = time + cvar("welcome_message_time");
 709         self.welcomemessage_time2 = 0;
 710
 711         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 712         // send prediction settings to the client
 713         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 714         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 715         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 716         stuffcmd(self, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
 717         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 718         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 719         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 720         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 721         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 722         stuffcmd(self, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
 723         stuffcmd(self, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
 724         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 725         // Wazat's grappling hook
 726         SetGrappleHookBindings();
 727
 728         // get autoswitch state from player
 729         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 730         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 731
 732         // get version info from player
 733         stuffcmd(self, "cmd clientversion $gameversion\n");
 734
 735         // get other cvars from player
 736         GetCvars(0);
 737
 738         // set cvar for team scoreboard
 739         if (teams_matter)
 740         {
 741                 local float t;
 742                 t = cvar("teamplay");
 743                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
 744                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
 745         }
 746         else
 747                 stuffcmd(self, strcat("set teamplay 0\n"));
 748
 749         if(cvar("g_lms"))
 750         {
 751                 self.frags = cvar("fraglimit");
 752                 // no fraglimit was set, so player gets 999 lives
 753                 if(self.frags < 1)
 754                         self.frags = 999;
 755
 756                 // disallow player to join after the worst player has lost g_lms_last_join lives
 757                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 758                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 759                 {
 760                         self.frags = -666;
 761                         lms_dead_count += 1;
 762                 }
 763                 else if(cvar("fraglimit") > lms_lowest_lives)
 764                 {
 765                         self.frags = lms_lowest_lives;
 766                 }
 767         }
 768         else if(cvar("g_arena"))
 769         {
 770                 self.classname = "observer";
 771                 Spawnqueue_Insert(self);
 772         }
 773
 774         bot_relinkplayerlist();
 775
 776         self.jointime = time;
 777 }
 778
 779 /*
 780 =============
 781 ClientDisconnect
 782
 783 Called when a client disconnects from the server
 784 =============
 785 */
 786 void(entity e) DropFlag;
 787 .entity chatbubbleentity;
 788 .entity teambubbleentity;
 789 void ClientDisconnect (void)
 790 {
 791         float save;
 792         if(cvar("sv_eventlog"))
 793                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 794         bprint ("^4",self.netname);
 795         bprint ("^4 disconnected\n");
 796
 797         if (self.chatbubbleentity)
 798         {
 799                 remove (self.chatbubbleentity);
 800                 self.chatbubbleentity = world;
 801         }
 802
 803         if (self.teambubbleentity)
 804         {
 805                 remove (self.teambubbleentity);
 806                 self.teambubbleentity = world;
 807         }
 808
 809         DropAllRunes(self);
 810
 811         if(self.flagcarried)
 812                 DropFlag(self.flagcarried);
 813
 814         save = self.flags;
 815         self.flags = self.flags - (self.flags & FL_CLIENT);
 816         bot_relinkplayerlist();
 817         self.flags = save;
 818
 819         // player was dead, decrease dead count
 820         if(cvar("g_lms") && self.frags < 1)
 821                 lms_dead_count -= 1;
 822         else if(cvar("g_arena"))
 823         {
 824                 Spawnqueue_Unmark(self);
 825                 Spawnqueue_Remove(self);
 826         }
 827 }
 828
 829 .float buttonchat;
 830 void() ChatBubbleThink =
 831 {
 832         self.nextthink = time;
 833         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 834         {
 835                 self.owner.chatbubbleentity = world;
 836                 remove(self);
 837                 return;
 838         }
 839         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 840         if (self.owner.buttonchat && !self.owner.deadflag)
 841                 self.model = self.mdl;
 842         else
 843                 self.model = "";
 844 };
 845
 846 void() UpdateChatBubble =
 847 {
 848         if (!self.modelindex)
 849                 return;
 850         // spawn a chatbubble entity if needed
 851         if (!self.chatbubbleentity)
 852         {
 853                 self.chatbubbleentity = spawn();
 854                 self.chatbubbleentity.owner = self;
 855                 self.chatbubbleentity.exteriormodeltoclient = self;
 856                 self.chatbubbleentity.think = ChatBubbleThink;
 857                 self.chatbubbleentity.nextthink = time;
 858                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 859                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 860                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 861                 self.chatbubbleentity.model = "";
 862         }
 863 }
 864
 865
 866 void() TeamBubbleThink =
 867 {
 868         self.nextthink = time;
 869         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 870         {
 871                 self.owner.teambubbleentity = world;
 872                 remove(self);
 873                 return;
 874         }
 875 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 876         if (self.owner.buttonchat || self.owner.deadflag)
 877                 self.model = "";
 878         else
 879                 self.model = self.mdl;
 880
 881 };
 882
 883 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 884
 885 void() UpdateTeamBubble =
 886 {
 887         if (!self.modelindex || !cvar("teamplay"))
 888                 return;
 889         // spawn a teambubble entity if needed
 890         if (!self.teambubbleentity && cvar("teamplay"))
 891         {
 892                 self.teambubbleentity = spawn();
 893                 self.teambubbleentity.owner = self;
 894                 self.teambubbleentity.exteriormodeltoclient = self;
 895                 self.teambubbleentity.think = TeamBubbleThink;
 896                 self.teambubbleentity.nextthink = time;
 897                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 898 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 899                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 900                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 901                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 902                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 903                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 904         }
 905 }
 906
 907 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 908 // added to the model skins
 909 /*void() UpdateColorModHack =
 910 {
 911         local float c;
 912         c = self.clientcolors & 15;
 913         // LordHavoc: only bothering to support white, green, red, yellow, blue
 914              if (teamplay == 0) self.colormod = '0 0 0';
 915         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 916         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 917         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 918         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 919         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 920         else self.colormod = '1 1 1';
 921 };*/
 922
 923 /*
 924 =============
 925 PlayerJump
 926
 927 When you press the jump key
 928 =============
 929 */
 930 void PlayerJump (void)
 931 {
 932         float mjumpheight;
 933
 934         mjumpheight = cvar("g_balance_jumpheight");
 935         if (self.waterlevel >= 2)
 936         {
 937                 if (self.watertype == CONTENT_WATER)
 938                         self.velocity_z = 200;
 939                 else if (self.watertype == CONTENT_SLIME)
 940                         self.velocity_z = 80;
 941                 else
 942                         self.velocity_z = 50;
 943
 944                 return;
 945         }
 946
 947
 948         if (!(self.flags & FL_ONGROUND))
 949                 return;
 950
 951         if (!(self.flags & FL_JUMPRELEASED))
 952                 return;
 953
 954         if(cvar("g_runematch"))
 955         {
 956                 if(self.runes & RUNE_SPEED)
 957                 {
 958                         if(self.runes & CURSE_SLOW)
 959                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 960                         else
 961                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 962                 }
 963                 else if(self.runes & CURSE_SLOW)
 964                 {
 965                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 966                 }
 967         }
 968
 969         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 970         {
 971                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 972         }
 973
 974         self.velocity_z = self.velocity_z + mjumpheight;
 975         self.oldvelocity_z = self.velocity_z;
 976
 977         self.flags = self.flags - FL_ONGROUND;
 978         self.flags = self.flags - FL_JUMPRELEASED;
 979 }
 980
 981 void() CheckWaterJump =
 982 {
 983         local vector start, end;
 984
 985 // check for a jump-out-of-water
 986         makevectors (self.angles);
 987         start = self.origin;
 988         start_z = start_z + 8;
 989         v_forward_z = 0;
 990         normalize(v_forward);
 991         end = start + v_forward*24;
 992         traceline (start, end, TRUE, self);
 993         if (trace_fraction < 1)
 994         {       // solid at waist
 995                 start_z = start_z + self.maxs_z - 8;
 996                 end = start + v_forward*24;
 997                 self.movedir = trace_plane_normal * -50;
 998                 traceline (start, end, TRUE, self);
 999                 if (trace_fraction == 1)
1000                 {       // open at eye level
1001                         self.flags = self.flags | FL_WATERJUMP;
1002                         self.velocity_z = 225;
1003                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
1004                         self.teleport_time = time + 2;  // safety net
1005                         return;
1006                 }
1007         }
1008 };
1009
1010
1011 void respawn(void)
1012 {
1013         CopyBody(1);
1014         PutClientInServer();
1015 }
1016
1017 void player_powerups (void)
1018 {
1019         if (cvar("g_minstagib"))
1020         {
1021                 self.effects = EF_FULLBRIGHT;
1022                 if (self.items & IT_STRENGTH)
1023                 {
1024                         if (time > self.strength_finished)
1025                         {
1026                                 self.alpha = default_player_alpha;
1027                                 self.exteriorweaponentity.alpha = default_player_alpha;
1028                                 self.items = self.items - (self.items & IT_STRENGTH);
1029                                 sprint(self, "^3Invisibility has worn off\n");
1030                         }
1031                 }
1032                 else
1033                 {
1034                         if (time < self.strength_finished)
1035                         {
1036                                 self.alpha = cvar("g_minstagib_invis_alpha");
1037                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1038                                 self.items = self.items | IT_STRENGTH;
1039                                 sprint(self, "^3You are invisible\n");
1040                         }
1041                 }
1042
1043                 if (self.items & IT_INVINCIBLE)
1044                 {
1045                         if (time > self.invincible_finished)
1046                         {
1047                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1048                                 sprint(self, "^3Speed has worn off\n");
1049                         }
1050                 }
1051                 else
1052                 {
1053                         if (time < self.invincible_finished)
1054                         {
1055                                 self.items = self.items | IT_INVINCIBLE;
1056                                 sprint(self, "^3You are on speed\n");
1057                         }
1058                 }
1059                 return;
1060         }
1061
1062         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1063         if (self.items & IT_STRENGTH)
1064         {
1065                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1066                 if (time > self.strength_finished)
1067                 {
1068                         self.items = self.items - (self.items & IT_STRENGTH);
1069                         sprint(self, "^3Strength has worn off\n");
1070                 }
1071         }
1072         else
1073         {
1074                 if (time < self.strength_finished)
1075                 {
1076                         self.items = self.items | IT_STRENGTH;
1077                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1078                 }
1079         }
1080         if (self.items & IT_INVINCIBLE)
1081         {
1082                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1083                 if (time > self.invincible_finished)
1084                 {
1085                         self.items = self.items - (self.items & IT_INVINCIBLE);
1086                         sprint(self, "^3Shield has worn off\n");
1087                 }
1088         }
1089         else
1090         {
1091                 if (time < self.invincible_finished)
1092                 {
1093                         self.items = self.items | IT_INVINCIBLE;
1094                         sprint(self, "^3Shield surrounds you\n");
1095                 }
1096         }
1097
1098         if (cvar("g_fullbrightplayers"))
1099                 self.effects = self.effects | EF_FULLBRIGHT;
1100
1101         // midair gamemode: damage only while in the air
1102         // if in midair mode, being on ground grants temporary invulnerability
1103         // (this is so that multishot weapon don't clear the ground flag on the
1104         // first damage in the frame, leaving the player vulnerable to the
1105         // remaining hits in the same frame)
1106         if (self.flags & FL_ONGROUND)
1107         if (cvar("g_midair"))
1108                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1109
1110         if (time < self.spawnshieldtime)
1111                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1112 }
1113
1114 void player_regen (void)
1115 {
1116         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1117         maxh = cvar("g_balance_health_stable");
1118         maxa = cvar("g_balance_armor_stable");
1119         limith = cvar("g_balance_health_limit");
1120         limita = cvar("g_balance_armor_limit");
1121
1122         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1123                 return;
1124
1125         if(cvar("g_runematch"))
1126         {
1127                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1128                 if (self.runes & RUNE_REGEN)
1129                 {
1130                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1131                         {
1132                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1133                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1134                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1135                         }
1136                         else
1137                         {
1138                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1139                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1140                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1141                         }
1142                 }
1143                 else if (self.runes & CURSE_VENOM)
1144                 {
1145                         max_mod = cvar("g_balance_curse_venom_hpmod");
1146                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1147                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1148                         else
1149                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1150                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1151                         //if (!self.runes & RUNE_REGEN)
1152                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1153                 }
1154                 maxh = maxh * max_mod;
1155                 //maxa = maxa * max_mod;
1156
1157                 if (time > self.pauserotarmor_finished)
1158                 {
1159                         if (self.armorvalue > maxa)
1160                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1161                 }
1162                 if (time > self.pauserothealth_finished)
1163                 {
1164                         if (self.health > maxh)
1165                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1166                 }
1167                 if (time > self.pauseregen_finished)
1168                 {
1169                         if (self.health < maxh)
1170                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1171                         if (self.armorvalue < maxa)
1172                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1173                 }
1174         }
1175         else
1176         {
1177                 if (time > self.pauserothealth_finished)
1178                 if (self.health > maxh)
1179                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1180                 if (time > self.pauserotarmor_finished)
1181                 if (self.armorvalue > maxa)
1182                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1183                 if (time > self.pauseregen_finished)
1184                 {
1185                         if (self.health < maxh)
1186                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1187                         if (self.armorvalue < maxa)
1188                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1189                 }
1190         }
1191
1192         if (self.health > limith)
1193                 self.health = limith;
1194         if(self.health < 1)
1195                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1196         if (self.armorvalue > limita)
1197                 self.armorvalue = limita;
1198 }
1199
1200 /*
1201 ======================
1202 spectate mode routines
1203 ======================
1204 */
1205 void SpectateCopy(entity spectatee) {
1206         self.armortype = spectatee.armortype;
1207         self.armorvalue = spectatee.armorvalue;
1208         self.currentammo = spectatee.currentammo;
1209         self.effects = spectatee.effects;
1210         self.health = spectatee.health;
1211         self.impulse = 0;
1212         self.items = spectatee.items;
1213         self.punchangle = spectatee.punchangle;
1214         self.view_ofs = spectatee.view_ofs;
1215         self.v_angle = spectatee.v_angle;
1216         self.viewzoom = spectatee.viewzoom;
1217         setorigin(self, spectatee.origin);
1218         setsize(self, spectatee.mins, spectatee.maxs);
1219 }
1220
1221 void SpectateUpdate() {
1222         if(!self.enemy)
1223                         PutObserverInServer();
1224
1225         if (self != self.enemy) {
1226                 if(self.enemy.flags & FL_NOTARGET)
1227                         PutObserverInServer();
1228                 SpectateCopy(self.enemy);
1229                 self.dmg_take = self.enemy.dmg_take;
1230                 self.dmg_save = self.enemy.dmg_save;
1231                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1232                 self.fixangle = TRUE;
1233                 self.angles = self.enemy.v_angle;
1234                 //msg_entity = self;
1235                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1236                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1237                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1238                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1239         }
1240 }
1241
1242 float SpectateNext() {
1243         other = find(self.enemy, classname, "player");
1244         if (!other) {
1245                 other = find(other, classname, "player");
1246         }
1247         if (other) {
1248                 self.enemy = other;
1249         }
1250         if(self.enemy.classname == "player") {
1251                 msg_entity = self;
1252                 WriteByte(MSG_ONE, SVC_SETVIEW);
1253                 WriteEntity(MSG_ONE, self.enemy);
1254                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1255                 SpectateUpdate();
1256                 return 1;
1257         } else {
1258                 return 0;
1259         }
1260 }
1261
1262 /*
1263 =============
1264 PlayerPreThink
1265
1266 Called every frame for each client before the physics are run
1267 =============
1268 */
1269 void PlayerPreThink (void)
1270 {
1271         if(self.classname == "player") {
1272                 local vector m1, m2;
1273
1274 //              if(self.netname == "Wazat")
1275 //                      bprint(strcat(self.classname, "\n"));
1276
1277                 CheckRules_Player();
1278
1279                 Nixnex_GiveCurrentWeapon();
1280
1281                 if(self.button7)
1282                         PrintWelcomeMessage(self);
1283
1284                 if(cvar("g_lms") || !cvar("sv_spectate"))
1285                 if((time - self.jointime) <= cvar("welcome_message_time"))
1286                         PrintWelcomeMessage(self);
1287
1288                 if (intermission_running)
1289                 {
1290                         IntermissionThink ();   // otherwise a button could be missed between
1291                         return;                                 // the think tics
1292                 }
1293
1294                 if (self.deadflag != DEAD_NO)
1295                 {
1296                         player_anim();
1297                         if (self.deadflag == DEAD_DYING)
1298                         {
1299                                 if (time > self.dead_time)
1300                                         self.deadflag = DEAD_DEAD;
1301                         }
1302                         else if (self.deadflag == DEAD_DEAD)
1303                         {
1304                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1305                                         self.deadflag = DEAD_RESPAWNABLE;
1306                                 else if (!self.button0 && !self.button2 && !self.button3)
1307                                         self.deadflag = DEAD_RESPAWNABLE;
1308                         }
1309                         else if (self.deadflag == DEAD_RESPAWNABLE)
1310                         {
1311                                 if (self.button0  ||
1312                                     self.button2  ||
1313                                     self.button3  ||
1314                                     self.button4  ||
1315                                     self.button5  ||
1316                                     self.button6  ||
1317                                     self.button7  ||
1318                                     self.button8  ||
1319                                     self.buttonuse ||
1320                                     cvar("g_lms") ||
1321                                     cvar("g_forced_respawn"))
1322                                         respawn();
1323                         }
1324                         return;
1325                 }
1326
1327                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1328                 {
1329                         vector dist;
1330
1331                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1332                         dist = self.oldorigin - self.origin;
1333                         dist_z = 0;
1334                         self.lms_traveled_distance += fabs(vlen(dist));
1335
1336                         if(cvar("g_campaign"))
1337                         if(!campaign_bots_may_start)
1338                         {
1339                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1340                                 self.lms_traveled_distance = 0;
1341                         }
1342
1343                         if(time > self.lms_nextcheck)
1344                         {
1345                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1346                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1347                                 {
1348                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1349                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1350                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1351                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1352                                 }
1353                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1354                                 self.lms_traveled_distance = 0;
1355                         }
1356                 }
1357
1358                 if (self.button5 && !self.hook.state)
1359                 {
1360                         if (!self.crouch)
1361                         {
1362                                 self.crouch = TRUE;
1363                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1364                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1365                         }
1366                 }
1367                 else
1368                 {
1369                         if (self.crouch)
1370                         {
1371                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1372                                 if (!trace_startsolid)
1373                                 {
1374                                         self.crouch = FALSE;
1375                                         self.view_ofs = PL_VIEW_OFS;
1376                                         setsize (self, PL_MIN, PL_MAX);
1377                                 }
1378                         }
1379                 }
1380
1381                 if(cvar("sv_defaultcharacter") == 1 && !teams_matter) {
1382                         local string defaultmodel;
1383                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1384
1385                         if (defaultmodel != self.model)
1386                         {
1387                                 m1 = self.mins;
1388                                 m2 = self.maxs;
1389                                 setmodel_lod (self, defaultmodel);
1390                                 setsize (self, m1, m2);
1391                         }
1392
1393                         if (self.skin != cvar("sv_defaultplayerskin"))
1394                                 self.skin = cvar("sv_defaultplayerskin");
1395                 } else {
1396                         if (self.playermodel != self.model)
1397                         {
1398                                 self.playermodel = CheckPlayerModel(self.playermodel);
1399                                 m1 = self.mins;
1400                                 m2 = self.maxs;
1401                                 setmodel_lod (self, self.playermodel);
1402                                 setsize (self, m1, m2);
1403                         }
1404
1405                         if (self.skin != stof(self.playerskin))
1406                                 self.skin = stof(self.playerskin);
1407                 }
1408                 // Savage: Check for nameless players
1409                 if (strlen(self.netname) < 1) {
1410                         self.netname = "Player";
1411                         stuffcmd(self, "name Player\n");
1412                 }
1413
1414                 GrapplingHookFrame();
1415
1416                 W_WeaponFrame();
1417
1418                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1419                 {
1420                         if (cvar("g_minstagib") && self.button3)
1421                         {
1422                                 if (self.jump_interval <= (time + 0.1))
1423                                 {
1424                                         self.jump_interval = time + 1;
1425                                         W_Laser_Attack();
1426                                 }
1427                         }
1428                         else if (self.viewzoom > 0.4)
1429                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1430                 }
1431                 else if (self.viewzoom < 1.0)
1432                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1433
1434
1435                 if (self.button2)
1436                         PlayerJump ();
1437                 else
1438                         self.flags = self.flags | FL_JUMPRELEASED;
1439
1440                 player_powerups();
1441                 player_regen();
1442                 player_anim();
1443
1444                 if (cvar("g_minstagib"))
1445                         minstagib_ammocheck();
1446
1447                 //self.angles_y=self.v_angle_y + 90;   // temp
1448
1449                 if (self.waterlevel == 2)
1450                         CheckWaterJump ();
1451
1452                 //if (TetrisPreFrame()) return;
1453         } else if(gameover) {
1454                 if (intermission_running)
1455                         IntermissionThink ();   // otherwise a button could be missed between
1456                 return;
1457         } else if(self.classname == "observer") {
1458
1459                 if (self.flags & FL_JUMPRELEASED) {
1460                         if (self.button2 && self.version == cvar("gameversion")) {
1461                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1462                                         self.flags = self.flags & !FL_JUMPRELEASED;
1463                                         self.classname = "player";
1464                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1465                                                 JoinBestTeam(self, 0);
1466                                         if(cvar("g_campaign"))
1467                                                 campaign_bots_may_start = 1;
1468                                         PutClientInServer();
1469                                         if(self.flags & !FL_NOTARGET)
1470                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1471                                         centerprint(self,"");
1472                                         return;
1473                                 } else {
1474                                         self.flags = self.flags & !FL_JUMPRELEASED;
1475                                         stuffcmd(self,"menu_showteamselect\n");
1476                                         return;
1477                                 }
1478                         } else if(self.button0 && self.version == cvar("gameversion")) {
1479                                 self.flags = self.flags & !FL_JUMPRELEASED;
1480                                 if(SpectateNext() == 1) {
1481                                         self.classname = "spectator";
1482                                 }
1483                         }
1484                 } else {
1485                         if (!(self.button0 || self.button2)) {
1486                                 self.flags = self.flags | FL_JUMPRELEASED;
1487                         }
1488                 }
1489                 PrintWelcomeMessage(self);
1490         } else if(self.classname == "spectator") {
1491                 if (self.flags & FL_JUMPRELEASED) {
1492                         if (self.button2 && self.version == cvar("gameversion")) {
1493                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1494                                         self.flags = self.flags & !FL_JUMPRELEASED;
1495                                         self.classname = "player";
1496                                         if(!cvar("g_lms"))
1497                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1498
1499                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1500                                                 JoinBestTeam(self, 0);
1501                                         if(cvar("g_campaign"))
1502                                                 campaign_bots_may_start = 1;
1503                                         PutClientInServer();
1504                                         centerprint(self,"");
1505                                         return;
1506                                 } else {
1507                                         self.flags = self.flags & !FL_JUMPRELEASED;
1508                                         stuffcmd(self,"menu_showteamselect\n");
1509                                         return;
1510                                 }
1511                         } else if(self.button0) {
1512                                 self.flags = self.flags & !FL_JUMPRELEASED;
1513                                 if(SpectateNext() == 1) {
1514                                         self.classname = "spectator";
1515                                 } else {
1516                                         self.classname = "observer";
1517                                         PutClientInServer();
1518                                 }
1519                         } else if (self.button3) {
1520                                 self.flags = self.flags & !FL_JUMPRELEASED;
1521                                 self.classname = "observer";
1522                                 PutClientInServer();
1523                         } else {
1524                                 SpectateUpdate();
1525                         }
1526                 } else {
1527                         if (!(self.button0 || self.button3)) {
1528                                 self.flags = self.flags | FL_JUMPRELEASED;
1529                         }
1530                 }
1531                 PrintWelcomeMessage(self);
1532                 self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
1533         }
1534 }
1535
1536
1537 /*
1538 =============
1539 PlayerPostThink
1540
1541 Called every frame for each client after the physics are run
1542 =============
1543 */
1544 void PlayerPostThink (void)
1545 {
1546         if(self.classname == "player") {
1547                 CheckRules_Player();
1548                 UpdateChatBubble();
1549                 UpdateTeamBubble();
1550                 if (self.deadflag == DEAD_NO)
1551                 if (self.impulse)
1552                         ImpulseCommands ();
1553                 if (intermission_running)
1554                         return;         // intermission or finale
1555
1556                 //PrintWelcomeMessage(self);
1557                 //if (TetrisPostFrame()) return;
1558         } else if (self.classname == "observer") {
1559                 //do nothing
1560         } else if (self.classname == "spectator") {
1561                 //do nothing
1562         }
1563         Arena_Warmup();
1564 }