data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         found = 1;
 129                         if(ent.classname == "target_objective")
 130                         {
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 if(self.classname == "player") // spectators may spawn everywhere
 138                                 {
 139                                         if(g_race_qualifying)
 140                                         {
 141                                                 // spawn at first
 142                                                 if(ent.race_checkpoint != 0)
 143                                                         return -1;
 144                                                 if(spot.race_place != race_lowest_place_spawn)
 145                                                         return -1;
 146                                         }
 147                                         else
 148                                         {
 149                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 150                                                         return -1;
 151                                                 float pl;
 152                                                 pl = self.race_place;
 153                                                 if(pl > race_highest_place_spawn)
 154                                                         pl = 0;
 155                                                 if(spot.race_place != pl)
 156                                                         return -1;
 157                                         }
 158                                 }
 159                                 good = 1;
 160                         }
 161                         else
 162                         {
 163                         }
 164                         ent = find(ent, targetname, spot.target);
 165                 }
 166
 167                 if(found && !good)
 168                         return -1;
 169         }
 170
 171         player = playerlist;
 172         shortest = vlen(world.maxs - world.mins);
 173         for(player = playerlist; player; player = player.chain)
 174                 if (player != self)
 175                 {
 176                         thisdist = vlen(player.origin - spot.origin);
 177                         if (thisdist < shortest)
 178                                 shortest = thisdist;
 179                 }
 180         return shortest;
 181 }
 182
 183 float spawn_allbad;
 184 float spawn_allgood;
 185 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 186 {
 187         local entity spot, spotlist, spotlistend;
 188         spawn_allgood = TRUE;
 189         spawn_allbad = TRUE;
 190
 191         spotlist = world;
 192         spotlistend = world;
 193
 194         for(spot = firstspot; spot; spot = spot.chain)
 195         {
 196                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 197
 198                 if(cvar("spawn_debugview"))
 199                 {
 200                         setmodel(spot, "models/runematch/rune.mdl");
 201                         if(spot.SPAWNPOINT_SCORE < mindist)
 202                         {
 203                                 spot.colormod = '1 0 0';
 204                                 spot.scale = 1;
 205                         }
 206                         else
 207                         {
 208                                 spot.colormod = '0 1 0';
 209                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 210                         }
 211                 }
 212
 213                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 214                 {
 215                         if(spot.SPAWNPOINT_SCORE < mindist)
 216                         {
 217                                 // too short distance
 218                                 spawn_allgood = FALSE;
 219                         }
 220                         else
 221                         {
 222                                 // perfect
 223                                 spawn_allbad = FALSE;
 224
 225                                 if(spotlistend)
 226                                         spotlistend.chain = spot;
 227                                 spotlistend = spot;
 228                                 if(!spotlist)
 229                                         spotlist = spot;
 230
 231                                 /*
 232                                 if(teamcheck)
 233                                 if(spot.team != teamcheck)
 234                                         error("invalid spawn added");
 235
 236                                 print("added ", etos(spot), "\n");
 237                                 */
 238                         }
 239                 }
 240         }
 241         if(spotlistend)
 242                 spotlistend.chain = world;
 243
 244         /*
 245                 entity e;
 246                 if(teamcheck)
 247                         for(e = spotlist; e; e = e.chain)
 248                         {
 249                                 print("seen ", etos(e), "\n");
 250                                 if(e.team != teamcheck)
 251                                         error("invalid spawn found");
 252                         }
 253         */
 254
 255         return spotlist;
 256 }
 257
 258 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 259 {
 260         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 261         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 262         local entity spot;
 263
 264         RandomSelection_Init();
 265         for(spot = firstspot; spot; spot = spot.chain)
 266                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 267
 268         return RandomSelection_chosen_ent;
 269 }
 270
 271 /*
 272 =============
 273 SelectSpawnPoint
 274
 275 Finds a point to respawn
 276 =============
 277 */
 278 entity SelectSpawnPoint (float anypoint)
 279 {
 280         local float teamcheck;
 281         local entity firstspot_new;
 282         local entity spot, firstspot, playerlist;
 283
 284         spot = find (world, classname, "testplayerstart");
 285         if (spot)
 286                 return spot;
 287
 288         teamcheck = 0;
 289
 290         if(!anypoint && have_team_spawns)
 291                 teamcheck = self.team;
 292
 293         // get the list of players
 294         playerlist = findchain(classname, "player");
 295         // get the entire list of spots
 296         firstspot = findchain(classname, "info_player_deathmatch");
 297         // filter out the bad ones
 298         // (note this returns the original list if none survived)
 299         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 300         if(!firstspot_new)
 301                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 302         firstspot = firstspot_new;
 303
 304         // there is 50/50 chance of choosing a random spot or the furthest spot
 305         // (this means that roughly every other spawn will be furthest, so you
 306         // usually won't get fragged at spawn twice in a row)
 307         if (arena_roundbased)
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 310                 if(firstspot_new)
 311                         firstspot = firstspot_new;
 312                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 313         }
 314         else if (random() > cvar("g_spawn_furthest"))
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 316         else
 317                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 318
 319         if(cvar("spawn_debugview"))
 320         {
 321                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 322
 323                 entity e;
 324                 if(teamcheck)
 325                         for(e = firstspot; e; e = e.chain)
 326                                 if(e.team != teamcheck)
 327                                         error("invalid spawn found");
 328         }
 329
 330         if (!spot)
 331         {
 332                 if(cvar("spawn_debug"))
 333                         GotoNextMap();
 334                 else
 335                 {
 336                         if(some_spawn_has_been_used)
 337                                 return world; // team can't spawn any more, because of actions of other team
 338                         else
 339                                 error("Cannot find a spawn point - please fix the map!");
 340                 }
 341         }
 342
 343         return spot;
 344 }
 345
 346 /*
 347 =============
 348 CheckPlayerModel
 349
 350 Checks if the argument string can be a valid playermodel.
 351 Returns a valid one in doubt.
 352 =============
 353 */
 354 string FallbackPlayerModel = "models/player/marine.zym";
 355 string CheckPlayerModel(string plyermodel) {
 356         if(strlen(plyermodel) < 4)
 357                 return FallbackPlayerModel;
 358         if( substring(plyermodel,0,14) != "models/player/")
 359                 return FallbackPlayerModel;
 360         else if(cvar("sv_servermodelsonly"))
 361         {
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 364                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 365                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 366                         return FallbackPlayerModel;
 367                 if(plyermodel != strtolower(plyermodel))
 368                         return FallbackPlayerModel;
 369                 if(!fexists(plyermodel))
 370                         return FallbackPlayerModel;
 371         }
 372         return plyermodel;
 373 }
 374
 375 /*
 376 =============
 377 Client_customizeentityforclient
 378
 379 LOD reduction
 380 =============
 381 */
 382 float Client_customizeentityforclient()
 383 {
 384 #ifdef ALLOW_VARIABLE_LOD
 385         // self: me
 386         // other: the player viewing me
 387         float distance;
 388         float f;
 389
 390         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 391                 return TRUE;
 392
 393         if(other.cvar_cl_playerdetailreduction <= 0)
 394         {
 395                 if(other.cvar_cl_playerdetailreduction <= -2)
 396                         self.modelindex = self.modelindex_lod2;
 397                 else if(other.cvar_cl_playerdetailreduction <= -1)
 398                         self.modelindex = self.modelindex_lod1;
 399                 else
 400                         self.modelindex = self.modelindex_lod0;
 401         }
 402         else
 403         {
 404                 distance = vlen(self.origin - other.origin);
 405                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 406                 if(f > 10000)
 407                         self.modelindex = self.modelindex_lod2;
 408                 else if(f > 5000)
 409                         self.modelindex = self.modelindex_lod1;
 410                 else
 411                         self.modelindex = self.modelindex_lod0;
 412         }
 413 #endif
 414
 415         return TRUE;
 416 }
 417
 418 void UpdatePlayerSounds();
 419 void setmodel_lod(entity e, string modelname)
 420 {
 421 #ifdef ALLOW_VARIABLE_LOD
 422         string s;
 423
 424         // FIXME: this only supports 3-letter extensions
 425         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 426         if(fexists(s))
 427         {
 428                 precache_model(s);
 429                 setmodel(e, s); // players have high precision
 430                 self.modelindex_lod1 = self.modelindex;
 431         }
 432         else
 433                 self.modelindex_lod1 = -1;
 434
 435         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 436         if(fexists(s))
 437         {
 438                 precache_model(s);
 439                 setmodel(e, s); // players have high precision
 440                 self.modelindex_lod2 = self.modelindex;
 441         }
 442         else
 443                 self.modelindex_lod2 = -1;
 444
 445         precache_model(modelname);
 446         setmodel(e, modelname); // players have high precision
 447         self.modelindex_lod0 = self.modelindex;
 448
 449         if(self.modelindex_lod1 < 0)
 450                 self.modelindex_lod1 = self.modelindex;
 451
 452         if(self.modelindex_lod2 < 0)
 453                 self.modelindex_lod2 = self.modelindex;
 454 #else
 455         precache_model(modelname);
 456         setmodel(e, modelname); // players have high precision
 457 #endif
 458         player_setupanimsformodel();
 459         UpdatePlayerSounds();
 460 }
 461
 462 /*
 463 =============
 464 PutObserverInServer
 465
 466 putting a client as observer in the server
 467 =============
 468 */
 469 void PutObserverInServer (void)
 470 {
 471         entity  spot;
 472
 473         race_PreSpawnObserver();
 474
 475         spot = SelectSpawnPoint (TRUE);
 476         if(!spot)
 477                 error("No spawnpoints for observers?!?\n");
 478         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 479
 480         if(clienttype(self) == CLIENTTYPE_REAL)
 481         {
 482                 msg_entity = self;
 483                 WriteByte(MSG_ONE, SVC_SETVIEW);
 484                 WriteEntity(MSG_ONE, self);
 485         }
 486
 487         DropAllRunes(self);
 488         kh_Key_DropAll(self, TRUE);
 489
 490         Portal_ClearAll(self);
 491
 492         if(self.flagcarried)
 493                 DropFlag(self.flagcarried, world, world);
 494
 495         WaypointSprite_PlayerDead();
 496
 497         if(self.killcount != -666)
 498         {
 499                 if(g_lms)
 500                 {
 501                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 502                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 503                         else
 504                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 505                 }
 506                 else
 507                         bprint ("^4", self.netname, "^4 is spectating now\n");
 508         }
 509
 510         PlayerScore_Clear(self); // clear scores when needed
 511
 512         self.spectatortime = time;
 513
 514         self.classname = "observer";
 515         self.iscreature = FALSE;
 516         self.health = -666;
 517         self.takedamage = DAMAGE_NO;
 518         self.solid = SOLID_NOT;
 519         self.movetype = MOVETYPE_NOCLIP;
 520         self.flags = FL_CLIENT | FL_NOTARGET;
 521         self.armorvalue = 666;
 522         self.effects = 0;
 523         self.armorvalue = cvar("g_balance_armor_start");
 524         self.pauserotarmor_finished = 0;
 525         self.pauserothealth_finished = 0;
 526         self.pauseregen_finished = 0;
 527         self.damageforcescale = 0;
 528         self.death_time = 0;
 529         self.dead_frame = 0;
 530         self.alpha = 0;
 531         self.scale = 0;
 532         self.fade_time = 0;
 533         self.pain_frame = 0;
 534         self.pain_finished = 0;
 535         self.strength_finished = 0;
 536         self.invincible_finished = 0;
 537         self.pushltime = 0;
 538         self.think = SUB_Null;
 539         self.nextthink = 0;
 540         self.hook_time = 0;
 541         self.runes = 0;
 542         self.deadflag = DEAD_NO;
 543         self.angles = spot.angles;
 544         self.angles_z = 0;
 545         self.fixangle = TRUE;
 546         self.crouch = FALSE;
 547
 548         self.view_ofs = PL_VIEW_OFS;
 549         setorigin (self, spot.origin);
 550         setsize (self, '0 0 0', '0 0 0');
 551         self.oldorigin = self.origin;
 552         self.items = 0;
 553         self.weapons = 0;
 554         self.model = "";
 555         self.modelindex = 0;
 556         self.weapon = 0;
 557         self.weaponmodel = "";
 558         self.weaponentity = world;
 559         self.exteriorweaponentity = world;
 560         self.killcount = -666;
 561         self.velocity = '0 0 0';
 562         self.avelocity = '0 0 0';
 563         self.punchangle = '0 0 0';
 564         self.punchvector = '0 0 0';
 565         self.oldvelocity = self.velocity;
 566         self.customizeentityforclient = Client_customizeentityforclient;
 567
 568         if(g_arena)
 569         {
 570                 if(self.version_mismatch)
 571                 {
 572                         Spawnqueue_Unmark(self);
 573                         Spawnqueue_Remove(self);
 574                 }
 575                 else
 576                 {
 577                         Spawnqueue_Insert(self);
 578                 }
 579         }
 580         else if(g_lms)
 581         {
 582                 // Only if the player cannot play at all
 583                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 584                         self.frags = FRAGS_SPECTATOR;
 585                 else
 586                         self.frags = FRAGS_LMS_LOSER;
 587         }
 588         else
 589                 self.frags = FRAGS_SPECTATOR;
 590 }
 591
 592 float RestrictSkin(float s)
 593 {
 594         if(!teams_matter)
 595                 return s;
 596         if(s == 6)
 597                 return 6;
 598         return mod(s, 3);
 599 }
 600
 601 void FixPlayermodel()
 602 {
 603         local string defaultmodel;
 604         local float defaultskin;
 605         local vector m1, m2;
 606
 607         defaultmodel = "";
 608
 609         if(cvar("sv_defaultcharacter") == 1) {
 610                 defaultskin = 0;
 611
 612                 if(teams_matter)
 613                 {
 614                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 615                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 616                 }
 617
 618                 if(defaultmodel == "")
 619                 {
 620                         defaultmodel = cvar_string("sv_defaultplayermodel");
 621                         defaultskin = cvar("sv_defaultplayerskin");
 622                 }
 623         }
 624
 625         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 626         {
 627                 if(self.model != "")
 628                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 629                 self.model = ""; // force the != checks to return true
 630         }
 631
 632         if(defaultmodel != "")
 633         {
 634                 if (defaultmodel != self.model)
 635                 {
 636                         m1 = self.mins;
 637                         m2 = self.maxs;
 638                         setmodel_lod (self, defaultmodel);
 639                         setsize (self, m1, m2);
 640                 }
 641
 642                 self.skin = defaultskin;
 643         } else {
 644                 if (self.playermodel != self.model)
 645                 {
 646                         self.playermodel = CheckPlayerModel(self.playermodel);
 647                         m1 = self.mins;
 648                         m2 = self.maxs;
 649                         setmodel_lod (self, self.playermodel);
 650                         setsize (self, m1, m2);
 651                 }
 652
 653                 self.skin = RestrictSkin(stof(self.playerskin));
 654         }
 655
 656         if(!teams_matter)
 657                 if(strlen(cvar_string("sv_defaultplayercolors")))
 658                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 659                                 setcolor(self, cvar("sv_defaultplayercolors"));
 660 }
 661
 662 void PlayerTouchExplode(entity p1, entity p2)
 663 {
 664         vector org;
 665         org = (p1.origin + p2.origin) * 0.5;
 666         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 667
 668         te_explosion(org);
 669
 670         entity e;
 671         e = spawn();
 672         setorigin(e, org);
 673         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 674         remove(e);
 675 }
 676
 677 /*
 678 =============
 679 PutClientInServer
 680
 681 Called when a client spawns in the server
 682 =============
 683 */
 684 //void() ctf_playerchanged;
 685 void PutClientInServer (void)
 686 {
 687         if(clienttype(self) == CLIENTTYPE_BOT)
 688         {
 689                 self.classname = "player";
 690         }
 691         else if(clienttype(self) == CLIENTTYPE_REAL)
 692         {
 693                 msg_entity = self;
 694                 WriteByte(MSG_ONE, SVC_SETVIEW);
 695                 WriteEntity(MSG_ONE, self);
 696         }
 697
 698         // player is dead and becomes observer
 699         // FIXME fix LMS scoring for new system
 700         if(g_lms)
 701         {
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 703                         self.classname = "observer";
 704         }
 705
 706         if(g_arena)
 707         if(!self.spawned)
 708                 self.classname = "observer";
 709
 710         if(self.classname == "player") {
 711                 entity spot, oldself;
 712
 713                 race_PreSpawn();
 714
 715                 spot = SelectSpawnPoint (FALSE);
 716                 if(!spot)
 717                 {
 718                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 719                         return; // spawn failed
 720                 }
 721
 722                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 723                 self.campingrifle_bulletcounter = 0;
 724
 725                 self.classname = "player";
 726                 self.wasplayer = TRUE;
 727                 self.iscreature = TRUE;
 728                 self.movetype = MOVETYPE_WALK;
 729                 self.solid = SOLID_SLIDEBOX;
 730                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 731                 self.frags = FRAGS_PLAYER;
 732                 if(independent_players)
 733                         MAKE_INDEPENDENT_PLAYER(self);
 734                 self.flags = FL_CLIENT;
 735                 self.takedamage = DAMAGE_AIM;
 736                 if(g_minstagib)
 737                         self.effects = EF_FULLBRIGHT;
 738                 else
 739                         self.effects = 0;
 740                 self.air_finished = time + 12;
 741                 self.dmg = 2;
 742
 743                 if(inWarmupStage)
 744                 {
 745                         self.ammo_shells = warmup_start_ammo_shells;
 746                         self.ammo_nails = warmup_start_ammo_nails;
 747                         self.ammo_rockets = warmup_start_ammo_rockets;
 748                         self.ammo_cells = warmup_start_ammo_cells;
 749                         self.health = warmup_start_health;
 750                         self.armorvalue = warmup_start_armorvalue;
 751                         self.weapons = warmup_start_weapons;
 752                 }
 753                 else
 754                 {
 755                         self.ammo_shells = start_ammo_shells;
 756                         self.ammo_nails = start_ammo_nails;
 757                         self.ammo_rockets = start_ammo_rockets;
 758                         self.ammo_cells = start_ammo_cells;
 759                         self.health = start_health;
 760                         self.armorvalue = start_armorvalue;
 761                         self.weapons = start_weapons;
 762                 }
 763                 self.items = start_items;
 764                 self.switchweapon = w_getbestweapon(self);
 765                 self.cnt = self.switchweapon;
 766                 self.weapon = 0;
 767                 self.jump_interval = time;
 768
 769                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 770                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 771                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 772                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 773                 //extend the pause of rotting if client was reset at the beginning of the countdown
 774                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 775                         self.spawnshieldtime += game_starttime - time;
 776                         self.pauserotarmor_finished += game_starttime - time;
 777                         self.pauserothealth_finished += game_starttime - time;
 778                         self.pauseregen_finished += game_starttime - time;
 779                 }
 780                 self.damageforcescale = 2;
 781                 self.death_time = 0;
 782                 self.dead_frame = 0;
 783                 self.alpha = 0;
 784                 self.scale = 0;
 785                 self.fade_time = 0;
 786                 self.pain_frame = 0;
 787                 self.pain_finished = 0;
 788                 self.strength_finished = 0;
 789                 self.invincible_finished = 0;
 790                 self.pushltime = 0;
 791                 //self.speed_finished = 0;
 792                 //self.slowmo_finished = 0;
 793                 // players have no think function
 794                 self.think = SUB_Null;
 795                 self.nextthink = 0;
 796                 self.hook_time = 0;
 797                 self.dmg_team = 0;
 798
 799                 self.runes = 0;
 800
 801                 self.deadflag = DEAD_NO;
 802
 803                 self.angles = spot.angles;
 804
 805                 self.angles_z = 0; // never spawn tilted even if the spot says to
 806                 self.fixangle = TRUE; // turn this way immediately
 807                 self.velocity = '0 0 0';
 808                 self.avelocity = '0 0 0';
 809                 self.punchangle = '0 0 0';
 810                 self.punchvector = '0 0 0';
 811                 self.oldvelocity = self.velocity;
 812
 813                 msg_entity = self;
 814                 WRITESPECTATABLE_MSG_ONE({
 815                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 816                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 817                 });
 818
 819                 self.customizeentityforclient = Client_customizeentityforclient;
 820
 821                 self.model = "";
 822                 FixPlayermodel();
 823
 824                 self.crouch = FALSE;
 825                 self.view_ofs = PL_VIEW_OFS;
 826                 setsize (self, PL_MIN, PL_MAX);
 827                 self.spawnorigin = spot.origin;
 828                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 829                 // don't reset back to last position, even if new position is stuck in solid
 830                 self.oldorigin = self.origin;
 831
 832                 if(g_arena)
 833                 {
 834                         Spawnqueue_Remove(self);
 835                         Spawnqueue_Mark(self);
 836                 }
 837
 838                 self.event_damage = PlayerDamage;
 839
 840                 self.bot_attack = TRUE;
 841
 842                 self.statdraintime = time + 5;
 843                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 844
 845                 if(self.killcount == -666) {
 846                         PlayerScore_Clear(self);
 847                         self.killcount = 0;
 848                 }
 849
 850                 self.cnt = WEP_LASER;
 851                 self.nixnex_lastchange_id = -1;
 852
 853                 CL_SpawnWeaponentity();
 854                 self.alpha = default_player_alpha;
 855                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 856                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 857
 858                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 859                 self.lms_traveled_distance = 0;
 860                 self.speedrunning = FALSE;
 861
 862                 race_PostSpawn(spot);
 863
 864                 if(cvar("spawn_debug"))
 865                 {
 866                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 867                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 868                 }
 869
 870                 //stuffcmd(self, "chase_active 0");
 871                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 872
 873                 if (cvar("g_spawnsound"))
 874                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 875
 876                 if(g_assault) {
 877                         if(self.team == assault_attacker_team)
 878                                 centerprint(self, "You are attacking!");
 879                         else
 880                                 centerprint(self, "You are defending!");
 881                 }
 882
 883                 target_voicescript_clear(self);
 884
 885                 oldself = self;
 886                 self = spot;
 887                         activator = oldself;
 888                                 SUB_UseTargets();
 889                         activator = world;
 890                 self = oldself;
 891
 892         } else if(self.classname == "observer") {
 893                 PutObserverInServer ();
 894         }
 895
 896         //if(g_ctf)
 897         //      ctf_playerchanged();
 898 }
 899
 900 float ClientInit_SendEntity(entity to, float sf)
 901 {
 902         float i;
 903         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 904         WriteShort(MSG_ENTITY, CSQC_REVISION);
 905         for(i = 1; i <= 24; ++i)
 906                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 907         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 908         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 909         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 910
 911         if(sv_foginterval && world.fog != "")
 912                 WriteString(MSG_ENTITY, world.fog);
 913         else
 914                 WriteString(MSG_ENTITY, "");
 915
 916         return TRUE;
 917 }
 918
 919 void ClientInit_Spawn()
 920 {
 921         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 922 }
 923
 924 /*
 925 =============
 926 SetNewParms
 927 =============
 928 */
 929 void SetNewParms (void)
 930 {
 931         // initialize parms for a new player
 932         parm1 = -(86400 * 366);
 933 }
 934
 935 /*
 936 =============
 937 SetChangeParms
 938 =============
 939 */
 940 void SetChangeParms (void)
 941 {
 942         // save parms for level change
 943         parm1 = self.parm_idlesince - time;
 944 }
 945
 946 /*
 947 =============
 948 DecodeLevelParms
 949 =============
 950 */
 951 void DecodeLevelParms (void)
 952 {
 953         // load parms
 954         self.parm_idlesince = parm1;
 955         if(self.parm_idlesince == -(86400 * 366))
 956                 self.parm_idlesince = time;
 957
 958         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 959         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 960 }
 961
 962 /*
 963 =============
 964 ClientKill
 965
 966 Called when a client types 'kill' in the console
 967 =============
 968 */
 969
 970 void ClientKill_Now_TeamChange()
 971 {
 972         if(self.killindicator_teamchange == -1)
 973         {
 974                 self.team = -1;
 975                 JoinBestTeam( self, FALSE, FALSE );
 976         }
 977         else
 978         {
 979                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 980         }
 981 }
 982
 983 void ClientKill_Now()
 984 {
 985         if(self.killindicator_teamchange)
 986                 ClientKill_Now_TeamChange();
 987
 988         // in any case:
 989         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 990
 991         if(self.killindicator)
 992         {
 993                 dprint("Cleaned up after a leaked kill indicator.\n");
 994                 remove(self.killindicator);
 995                 self.killindicator = world;
 996         }
 997 }
 998 void KillIndicator_Think()
 999 {
1000         if (!self.owner.modelindex)
1001         {
1002                 self.owner.killindicator = world;
1003                 remove(self);
1004                 return;
1005         }
1006
1007         if(self.cnt <= 0)
1008         {
1009                 self = self.owner;
1010                 ClientKill_Now(); // no oldself needed
1011                 return;
1012         }
1013         else
1014         {
1015                 if(self.cnt <= 10)
1016                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1017                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1018                 {
1019                         if(self.cnt <= 10)
1020                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1021                         if(self.owner.killindicator_teamchange)
1022                         {
1023                                 if(self.owner.killindicator_teamchange == -1)
1024                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1025                                 else
1026                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1027                         }
1028                         else
1029                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1030                 }
1031                 self.nextthink = time + 1;
1032                 self.cnt -= 1;
1033         }
1034 }
1035
1036 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1037 {
1038         float killtime;
1039         entity e;
1040         killtime = cvar("g_balance_kill_delay");
1041
1042         self.killindicator_teamchange = targetteam;
1043
1044         if(!self.killindicator)
1045         {
1046                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1047                 {
1048                         ClientKill_Now();
1049                 }
1050                 else
1051                 {
1052                         self.killindicator = spawn();
1053                         self.killindicator.owner = self;
1054                         self.killindicator.scale = 0.5;
1055                         setattachment(self.killindicator, self, "");
1056                         setorigin(self.killindicator, '0 0 52');
1057                         self.killindicator.think = KillIndicator_Think;
1058                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1059                         self.killindicator.cnt = ceil(killtime);
1060                         self.killindicator.count = bound(0, ceil(killtime), 10);
1061                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1062
1063                         for(e = world; (e = find(e, classname, "body")) != world; )
1064                         {
1065                                 if(e.enemy != self)
1066                                         continue;
1067                                 e.killindicator = spawn();
1068                                 e.killindicator.owner = e;
1069                                 e.killindicator.scale = 0.5;
1070                                 setattachment(e.killindicator, e, "");
1071                                 setorigin(e.killindicator, '0 0 52');
1072                                 e.killindicator.think = KillIndicator_Think;
1073                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1074                                 e.killindicator.cnt = ceil(killtime);
1075                         }
1076                         self.lip = 0;
1077                 }
1078         }
1079         if(self.killindicator)
1080         {
1081                 if(targetteam)
1082                         self.killindicator.colormod = TeamColor(targetteam);
1083                 else
1084                         self.killindicator.colormod = '0 0 0';
1085         }
1086 }
1087
1088 void ClientKill (void)
1089 {
1090         ClientKill_TeamChange(0);
1091 }
1092
1093 void DoTeamChange(float destteam)
1094 {
1095         float t, c0;
1096         if(!teams_matter)
1097         {
1098                 if(destteam >= 0)
1099                         SetPlayerColors(self, destteam);
1100                 return;
1101         }
1102         if(self.classname == "player")
1103         if(destteam == -1)
1104         {
1105                 CheckAllowedTeams(self);
1106                 t = FindSmallestTeam(self, TRUE);
1107                 switch(self.team)
1108                 {
1109                         case COLOR_TEAM1: c0 = c1; break;
1110                         case COLOR_TEAM2: c0 = c2; break;
1111                         case COLOR_TEAM3: c0 = c3; break;
1112                         case COLOR_TEAM4: c0 = c4; break;
1113                         default:          c0 = 999;
1114                 }
1115                 switch(t)
1116                 {
1117                         case 1:
1118                                 if(c0 > c1)
1119                                         destteam = COLOR_TEAM1;
1120                                 break;
1121                         case 2:
1122                                 if(c0 > c2)
1123                                         destteam = COLOR_TEAM2;
1124                                 break;
1125                         case 3:
1126                                 if(c0 > c3)
1127                                         destteam = COLOR_TEAM3;
1128                                 break;
1129                         case 4:
1130                                 if(c0 > c4)
1131                                         destteam = COLOR_TEAM4;
1132                                 break;
1133                 }
1134                 if(destteam == -1)
1135                         return;
1136         }
1137         if(destteam == self.team && !self.killindicator)
1138                 return;
1139         ClientKill_TeamChange(destteam);
1140 }
1141
1142 void FixClientCvars(entity e)
1143 {
1144         // send prediction settings to the client
1145         stuffcmd(e, "\nin_bindmap 0 0\n");
1146         /*
1147          * we no longer need to stuff this. Remove this comment block if you feel
1148          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1149         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1150         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1151         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1152         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1153         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1154         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1155         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1156         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1157         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1158         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1159         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1160         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1161         stuffcmd(e, "cl_movement_edgefriction 1\n");
1162          */
1163 }
1164
1165 /*
1166 =============
1167 ClientConnect
1168
1169 Called when a client connects to the server
1170 =============
1171 */
1172 //void ctf_clientconnect();
1173 string ColoredTeamName(float t);
1174 void DecodeLevelParms (void);
1175 //void dom_player_join_team(entity pl);
1176 void ClientConnect (void)
1177 {
1178         local string s;
1179         float t;
1180
1181         if(self.flags & FL_CLIENT)
1182         {
1183                 print("Warning: ClientConnect, but already connected!\n");
1184                 return;
1185         }
1186
1187         if(Ban_MaybeEnforceBan(self))
1188                 return;
1189
1190         DecodeLevelParms();
1191
1192         self.classname = "player_joining";
1193
1194         self.flags = FL_CLIENT;
1195         self.version_nagtime = time + 10 + random() * 10;
1196
1197         if(player_count<0)
1198         {
1199                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1200                 player_count = 0;
1201         }
1202
1203         PlayerScore_Attach(self);
1204         ClientData_Attach();
1205
1206         bot_clientconnect();
1207
1208         race_PreSpawnObserver();
1209
1210         //if(g_domination)
1211         //      dom_player_join_team(self);
1212
1213         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1214
1215         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1216                 self.classname = "observer";
1217         } else {
1218                 if(teams_matter)
1219                 {
1220                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1221                         {
1222                                 self.classname = "player";
1223                                 campaign_bots_may_start = 1;
1224                         }
1225                         else
1226                         {
1227                                 self.classname = "observer"; // do it anyway
1228                         }
1229                 }
1230                 else
1231                 {
1232                         self.classname = "player";
1233                         campaign_bots_may_start = 1;
1234                 }
1235         }
1236
1237         self.playerid = (playerid_last = playerid_last + 1);
1238         if(cvar("sv_eventlog"))
1239         {
1240                 if(clienttype(self) == CLIENTTYPE_REAL)
1241                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1242                 else
1243                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1244                 s = strcat(":team:", ftos(self.playerid), ":");
1245                 s = strcat(s, ftos(self.team));
1246                 GameLogEcho(s);
1247         }
1248         self.netname_previous = strzone(self.netname);
1249
1250         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1251
1252         bprint ("^4",self.netname);
1253         bprint ("^4 connected");
1254
1255         if(g_domination || g_ctf)
1256         {
1257                 bprint(" and joined the ");
1258                 bprint(ColoredTeamName(self.team));
1259         }
1260
1261         bprint("\n");
1262
1263         self.welcomemessage_time = 0;
1264
1265         stuffcmd(self, strcat(clientstuff, "\n"));
1266         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1267         stuffcmd(self, "cl_particles_reloadeffects\n");
1268
1269         FixClientCvars(self);
1270
1271         // spawnfunc_waypoint sprites
1272         WaypointSprite_InitClient(self);
1273
1274         // Wazat's grappling hook
1275         SetGrappleHookBindings();
1276
1277         // get autoswitch state from player when he toggles it
1278         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1279
1280         // get version info from player
1281         stuffcmd(self, "cmd clientversion $gameversion\n");
1282
1283         // get other cvars from player
1284         GetCvars(0);
1285
1286         // set cvar for team scoreboard
1287         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1288
1289         // notify about available teams
1290         if(teams_matter)
1291         {
1292                 CheckAllowedTeams(self);
1293                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1294                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1295         }
1296         else
1297                 stuffcmd(self, "set _teams_available 0\n");
1298
1299         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1300
1301         if(g_arena)
1302         {
1303                 self.classname = "observer";
1304                 Spawnqueue_Insert(self);
1305         }
1306         /*else if(g_ctf)
1307         {
1308                 ctf_clientconnect();
1309         }*/
1310
1311         if(teams_matter)
1312                 attach_entcs();
1313
1314         bot_relinkplayerlist();
1315
1316         self.spectatortime = time;
1317         if(blockSpectators)
1318         {
1319                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1320         }
1321
1322         self.jointime = time;
1323         self.allowedTimeouts = cvar("sv_timeout_number");
1324
1325         if(clienttype(self) == CLIENTTYPE_REAL)
1326         {
1327                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1328
1329                 if(cvar("g_bugrigs"))
1330                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1331         }
1332
1333         if(g_lms)
1334         {
1335                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1336                 {
1337                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1338                         self.frags = FRAGS_SPECTATOR;
1339                 }
1340         }
1341
1342         if(!sv_foginterval && world.fog != "")
1343                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1344
1345         SoundEntity_Attach(self);
1346 }
1347
1348 /*
1349 =============
1350 ClientDisconnect
1351
1352 Called when a client disconnects from the server
1353 =============
1354 */
1355 .entity chatbubbleentity;
1356 .entity teambubbleentity;
1357 void ReadyCount();
1358 void ClientDisconnect (void)
1359 {
1360         if not(self.flags & FL_CLIENT)
1361         {
1362                 print("Warning: ClientDisconnect without ClientConnect\n");
1363                 return;
1364         }
1365
1366         bot_clientdisconnect();
1367
1368         if(teams_matter)
1369                 detach_entcs();
1370
1371         if(cvar("sv_eventlog"))
1372                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1373         bprint ("^4",self.netname);
1374         bprint ("^4 disconnected\n");
1375
1376         SoundEntity_Detach(self);
1377
1378         DropAllRunes(self);
1379         kh_Key_DropAll(self, TRUE);
1380
1381         Portal_ClearAll(self);
1382
1383         if(self.flagcarried)
1384                 DropFlag(self.flagcarried, world, world);
1385
1386         // Here, everything has been done that requires this player to be a client.
1387
1388         self.flags &~= FL_CLIENT;
1389
1390         if (self.chatbubbleentity)
1391                 remove (self.chatbubbleentity);
1392
1393         if (self.teambubbleentity)
1394                 remove (self.teambubbleentity);
1395
1396         if (self.killindicator)
1397                 remove (self.killindicator);
1398
1399         WaypointSprite_PlayerGone();
1400
1401         bot_relinkplayerlist();
1402
1403         // remove laserdot
1404         if(self.weaponentity)
1405                 if(self.weaponentity.lasertarget)
1406                         remove(self.weaponentity.lasertarget);
1407
1408         if(g_arena)
1409         {
1410                 Spawnqueue_Unmark(self);
1411                 Spawnqueue_Remove(self);
1412         }
1413
1414         ClientData_Detach();
1415         PlayerScore_Detach(self);
1416
1417         if(self.netname_previous)
1418                 strunzone(self.netname_previous);
1419
1420         ClearPlayerSounds();
1421
1422         self.playerid = 0;
1423         ReadyCount();
1424
1425         // free cvars
1426         GetCvars(-1);
1427 }
1428
1429 .float BUTTON_CHAT;
1430 void ChatBubbleThink()
1431 {
1432         self.nextthink = time;
1433         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1434         {
1435                 if(self.owner) // but why can that ever be world?
1436                         self.owner.chatbubbleentity = world;
1437                 remove(self);
1438                 return;
1439         }
1440         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1441                 self.model = self.mdl;
1442         else
1443                 self.model = "";
1444 };
1445
1446 void UpdateChatBubble()
1447 {
1448         if (!self.modelindex)
1449                 return;
1450         // spawn a chatbubble entity if needed
1451         if (!self.chatbubbleentity)
1452         {
1453                 self.chatbubbleentity = spawn();
1454                 self.chatbubbleentity.owner = self;
1455                 self.chatbubbleentity.exteriormodeltoclient = self;
1456                 self.chatbubbleentity.think = ChatBubbleThink;
1457                 self.chatbubbleentity.nextthink = time;
1458                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1459                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1460                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1461                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1462                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1463                 self.chatbubbleentity.model = "";
1464                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1465         }
1466 }
1467
1468
1469 void TeamBubbleThink()
1470 {
1471         self.nextthink = time;
1472         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1473         {
1474                 if(self.owner) // but why can that ever be world?
1475                         self.owner.teambubbleentity = world;
1476                 remove(self);
1477                 return;
1478         }
1479 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1480         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1481                 self.model = "";
1482         else
1483                 self.model = self.mdl;
1484
1485 };
1486
1487 float TeamBubble_customizeentityforclient()
1488 {
1489         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1490 }
1491
1492 void UpdateTeamBubble()
1493 {
1494         if (!self.modelindex || !teams_matter)
1495                 return;
1496         // spawn a teambubble entity if needed
1497         if (!self.teambubbleentity && teams_matter)
1498         {
1499                 self.teambubbleentity = spawn();
1500                 self.teambubbleentity.owner = self;
1501                 self.teambubbleentity.exteriormodeltoclient = self;
1502                 self.teambubbleentity.think = TeamBubbleThink;
1503                 self.teambubbleentity.nextthink = time;
1504                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1505 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1506                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1507                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1508                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1509                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1510                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1511                 self.teambubbleentity.effects = EF_LOWPRECISION;
1512         }
1513 }
1514
1515 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1516 // added to the model skins
1517 /*void UpdateColorModHack()
1518 {
1519         local float c;
1520         c = self.clientcolors & 15;
1521         // LordHavoc: only bothering to support white, green, red, yellow, blue
1522              if (!teams_matter) self.colormod = '0 0 0';
1523         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1524         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1525         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1526         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1527         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1528         else self.colormod = '1 1 1';
1529 };*/
1530
1531 void respawn(void)
1532 {
1533         CopyBody(1);
1534         self.effects |= EF_NODRAW; // prevent another CopyBody
1535         PutClientInServer();
1536 }
1537
1538 /**
1539  * When sv_timeout is used this function returs strings like
1540  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1541  * Called by centerprint functions
1542  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1543  */
1544 string getTimeoutText(float addOneSecond) {
1545         if (!cvar("sv_timeout") || !timeoutStatus)
1546                 return "";
1547
1548         local string retStr;
1549         if (timeoutStatus == 1) {
1550                 if (addOneSecond == 1) {
1551                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1552                 }
1553                 else {
1554                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1555                 }
1556                 return retStr;
1557         }
1558         else if (timeoutStatus == 2) {
1559                 if (addOneSecond) {
1560                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1561                         //don't show messages like "Timeout ends in 0 seconds"...
1562                         if ((remainingTimeoutTime + 1) > 0)
1563                                 return retStr;
1564                         else
1565                                 return "";
1566                 }
1567                 else {
1568                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1569                         //don't show messages like "Timeout ends in 0 seconds"...
1570                         if (remainingTimeoutTime > 0)
1571                                 return retStr;
1572                         else
1573                                 return "";
1574                 }
1575         }
1576         else return "";
1577 }
1578
1579 void player_powerups (void)
1580 {
1581         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1582         {
1583                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, ATTN_IDLE);
1584                 self.modelflags |= MF_ROCKET;
1585         }
1586         else
1587         {
1588                 SoundEntity_StopSound(self, CHAN_PLAYER);
1589                 self.modelflags &~= MF_ROCKET;
1590         }
1591
1592         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1593
1594         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1595                 return;
1596
1597         if (g_minstagib)
1598         {
1599                 if (self.items & IT_STRENGTH)
1600                 {
1601                         if (time > self.strength_finished)
1602                         {
1603                                 self.alpha = default_player_alpha;
1604                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1605                                 self.items &~= IT_STRENGTH;
1606                                 sprint(self, "^3Invisibility has worn off\n");
1607                         }
1608                 }
1609                 else
1610                 {
1611                         if (time < self.strength_finished)
1612                         {
1613                                 self.alpha = g_minstagib_invis_alpha;
1614                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1615                                 self.items |= IT_STRENGTH;
1616                                 sprint(self, "^3You are invisible\n");
1617                         }
1618                 }
1619
1620                 if (self.items & IT_INVINCIBLE)
1621                 {
1622                         if (time > self.invincible_finished)
1623                         {
1624                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1625                                 sprint(self, "^3Speed has worn off\n");
1626                         }
1627                 }
1628                 else
1629                 {
1630                         if (time < self.invincible_finished)
1631                         {
1632                                 self.items = self.items | IT_INVINCIBLE;
1633                                 sprint(self, "^3You are on speed\n");
1634                         }
1635                 }
1636                 return;
1637         }
1638
1639         if (self.items & IT_STRENGTH)
1640         {
1641                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1642                 if (time > self.strength_finished)
1643                 {
1644                         self.items = self.items - (self.items & IT_STRENGTH);
1645                         sprint(self, "^3Strength has worn off\n");
1646                 }
1647         }
1648         else
1649         {
1650                 if (time < self.strength_finished)
1651                 {
1652                         self.items = self.items | IT_STRENGTH;
1653                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1654                 }
1655         }
1656         if (self.items & IT_INVINCIBLE)
1657         {
1658                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1659                 if (time > self.invincible_finished)
1660                 {
1661                         self.items = self.items - (self.items & IT_INVINCIBLE);
1662                         sprint(self, "^3Shield has worn off\n");
1663                 }
1664         }
1665         else
1666         {
1667                 if (time < self.invincible_finished)
1668                 {
1669                         self.items = self.items | IT_INVINCIBLE;
1670                         sprint(self, "^3Shield surrounds you\n");
1671                 }
1672         }
1673
1674         if (cvar("g_fullbrightplayers"))
1675                 self.effects = self.effects | EF_FULLBRIGHT;
1676
1677         // midair gamemode: damage only while in the air
1678         // if in midair mode, being on ground grants temporary invulnerability
1679         // (this is so that multishot weapon don't clear the ground flag on the
1680         // first damage in the frame, leaving the player vulnerable to the
1681         // remaining hits in the same frame)
1682         if (self.flags & FL_ONGROUND)
1683         if (g_midair)
1684                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1685
1686         if (time >= game_starttime)
1687         if (time < self.spawnshieldtime)
1688                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1689 }
1690
1691 float CalcRegen(float current, float stable, float regenfactor)
1692 {
1693         if(current > stable)
1694                 return current;
1695         else if(current > stable - 0.25) // when close enough, "snap"
1696                 return stable;
1697         else
1698                 return min(stable, current + (stable - current) * regenfactor * frametime);
1699 }
1700
1701 void player_regen (void)
1702 {
1703         float maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1704         maxh = cvar("g_balance_health_stable");
1705         maxa = cvar("g_balance_armor_stable");
1706         maxf = cvar("g_balance_fuel_stable");
1707         limith = cvar("g_balance_health_limit");
1708         limita = cvar("g_balance_armor_limit");
1709         limitf = cvar("g_balance_fuel_limit");
1710
1711         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1712                 return;
1713
1714         max_mod = regen_mod = rot_mod = limit_mod = 1;
1715
1716         if (self.runes & RUNE_REGEN)
1717         {
1718                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1719                 {
1720                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1721                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1722                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1723                 }
1724                 else
1725                 {
1726                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1727                         max_mod = cvar("g_balance_rune_regen_hpmod");
1728                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1729                 }
1730         }
1731         else if (self.runes & CURSE_VENOM)
1732         {
1733                 max_mod = cvar("g_balance_curse_venom_hpmod");
1734                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1735                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1736                 else
1737                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1738                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1739                 //if (!self.runes & RUNE_REGEN)
1740                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1741         }
1742         maxh = maxh * max_mod;
1743         //maxa = maxa * max_mod;
1744         //maxf = maxf * max_mod;
1745         limith = limith * limit_mod;
1746         limita = limita * limit_mod;
1747         //limitf = limitf * limit_mod;
1748
1749         if (self.armorvalue > maxa)
1750         {
1751                 if (time > self.pauserotarmor_finished)
1752                 {
1753                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1754                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1755                 }
1756         }
1757         else if (self.armorvalue < maxa)
1758         {
1759                 if (time > self.pauseregen_finished)
1760                 {
1761                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1762                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1763                 }
1764         }
1765         if (self.health > maxh)
1766         {
1767                 if (time > self.pauserothealth_finished)
1768                 {
1769                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1770                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1771                 }
1772         }
1773         else if (self.health < maxh)
1774         {
1775                 if (time > self.pauseregen_finished)
1776                 {
1777                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1778                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1779                 }
1780         }
1781         if (self.ammo_fuel > maxf)
1782         {
1783                 if (time > self.pauserotfuel_finished)
1784                 {
1785                         self.ammo_fuel = max(maxf, self.ammo_fuel + (maxf - self.ammo_fuel) * rot_mod*cvar("g_balance_fuel_rot") * frametime);
1786                         self.ammo_fuel = max(maxf, self.ammo_fuel - rot_mod*cvar("g_balance_fuel_rotlinear") * frametime);
1787                 }
1788         }
1789         else if (self.ammo_fuel < maxf)
1790         {
1791                 if(self.items & IT_FUEL_REGEN)
1792                 {
1793                         if (time > self.pauseregen_finished)
1794                         {
1795                                 self.ammo_fuel = CalcRegen(self.ammo_fuel, maxf, regen_mod * cvar("g_balance_fuel_regen"));
1796                                 self.ammo_fuel = min(maxf, self.ammo_fuel + regen_mod*cvar("g_balance_fuel_regenlinear") * frametime);
1797                         }
1798                 }
1799         }
1800
1801         if (self.health > limith)
1802                 self.health = limith;
1803         if (self.armorvalue > limita)
1804                 self.armorvalue = limita;
1805         if (self.ammo_fuel > limitf)
1806                 self.ammo_fuel = limitf;
1807
1808         // if player rotted to death...  die!
1809         if(self.health < 1)
1810                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1811 }
1812
1813 float zoomstate_set;
1814 void SetZoomState(float z)
1815 {
1816         if(z != self.zoomstate)
1817                 ClientData_Touch(self);
1818         zoomstate_set = 1;
1819 }
1820
1821 void GetPressedKeys(void) {
1822         if (self.movement_x > 0) // get if movement keys are pressed
1823         {       // forward key pressed
1824                 self.pressedkeys |= KEY_FORWARD;
1825                 self.pressedkeys &~= KEY_BACKWARD;
1826         }
1827         else if (self.movement_x < 0)
1828         {       // backward key pressed
1829                 self.pressedkeys |= KEY_BACKWARD;
1830                 self.pressedkeys &~= KEY_FORWARD;
1831         }
1832         else
1833         {       // no x input
1834                 self.pressedkeys &~= KEY_FORWARD;
1835                 self.pressedkeys &~= KEY_BACKWARD;
1836         }
1837
1838         if (self.movement_y > 0)
1839         {       // right key pressed
1840                 self.pressedkeys |= KEY_RIGHT;
1841                 self.pressedkeys &~= KEY_LEFT;
1842         }
1843         else if (self.movement_y < 0)
1844         {       // left key pressed
1845                 self.pressedkeys |= KEY_LEFT;
1846                 self.pressedkeys &~= KEY_RIGHT;
1847         }
1848         else
1849         {       // no y input
1850                 self.pressedkeys &~= KEY_RIGHT;
1851                 self.pressedkeys &~= KEY_LEFT;
1852         }
1853
1854         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1855                 self.pressedkeys |= KEY_JUMP;
1856         else
1857                 self.pressedkeys &~= KEY_JUMP;
1858         if (self.BUTTON_CROUCH)
1859                 self.pressedkeys |= KEY_CROUCH;
1860         else
1861                 self.pressedkeys &~= KEY_CROUCH;
1862 }
1863
1864 /*
1865 ======================
1866 spectate mode routines
1867 ======================
1868 */
1869 void SpectateCopy(entity spectatee) {
1870         self.armortype = spectatee.armortype;
1871         self.armorvalue = spectatee.armorvalue;
1872         self.ammo_cells = spectatee.ammo_cells;
1873         self.ammo_shells = spectatee.ammo_shells;
1874         self.ammo_nails = spectatee.ammo_nails;
1875         self.ammo_rockets = spectatee.ammo_rockets;
1876         self.ammo_fuel = spectatee.ammo_fuel;
1877         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1878         self.health = spectatee.health;
1879         self.impulse = 0;
1880         self.items = spectatee.items;
1881         self.strength_finished = spectatee.strength_finished;
1882         self.invincible_finished = spectatee.invincible_finished;
1883         self.pressedkeys = spectatee.pressedkeys;
1884         self.weapons = spectatee.weapons;
1885         self.switchweapon = spectatee.switchweapon;
1886         self.weapon = spectatee.weapon;
1887         self.punchangle = spectatee.punchangle;
1888         self.view_ofs = spectatee.view_ofs;
1889         self.v_angle = spectatee.v_angle;
1890         self.velocity = spectatee.velocity;
1891         self.dmg_take = spectatee.dmg_take;
1892         self.dmg_save = spectatee.dmg_save;
1893         self.dmg_inflictor = spectatee.dmg_inflictor;
1894         self.angles = spectatee.v_angle;
1895         self.fixangle = TRUE;
1896         setorigin(self, spectatee.origin);
1897         setsize(self, spectatee.mins, spectatee.maxs);
1898         SetZoomState(spectatee.zoomstate);
1899 }
1900
1901 float SpectateUpdate() {
1902         if(!self.enemy)
1903                 return 0;
1904
1905         if (self == self.enemy)
1906                 return 0;
1907
1908         if(self.enemy.flags & FL_NOTARGET)
1909                 return 0;
1910
1911         SpectateCopy(self.enemy);
1912
1913         return 1;
1914 }
1915
1916 float SpectateNext() {
1917         other = find(self.enemy, classname, "player");
1918         if (!other) {
1919                 other = find(other, classname, "player");
1920         }
1921         if (other) {
1922                 self.enemy = other;
1923         }
1924         if(self.enemy.classname == "player") {
1925                 msg_entity = self;
1926                 WriteByte(MSG_ONE, SVC_SETVIEW);
1927                 WriteEntity(MSG_ONE, self.enemy);
1928                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1929                 if(!SpectateUpdate())
1930                         PutObserverInServer();
1931                 return 1;
1932         } else {
1933                 return 0;
1934         }
1935 }
1936
1937 /*
1938 =============
1939 ShowRespawnCountdown()
1940
1941 Update a respawn countdown display.
1942 =============
1943 */
1944 void ShowRespawnCountdown()
1945 {
1946         float number;
1947         if(self.deadflag == DEAD_NO) // just respawned?
1948                 return;
1949         else
1950         {
1951                 number = ceil(self.death_time - time);
1952                 if(number <= 0)
1953                         return;
1954                 if(number <= self.respawn_countdown)
1955                 {
1956                         self.respawn_countdown = number - 1;
1957                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1958                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1959                 }
1960         }
1961 }
1962
1963 void LeaveSpectatorMode()
1964 {
1965         if(isJoinAllowed()) {
1966                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
1967                         self.classname = "player";
1968                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1969                                 JoinBestTeam(self, FALSE, TRUE);
1970                         if(cvar("g_campaign"))
1971                                 campaign_bots_may_start = 1;
1972                         PutClientInServer();
1973                         if(!(self.flags & FL_NOTARGET))
1974                                 bprint ("^4", self.netname, "^4 is playing now\n");
1975                         centerprint(self,"");
1976                         return;
1977                 } else {
1978                         stuffcmd(self,"menu_showteamselect\n");
1979                         return;
1980                 }
1981         }
1982         else {
1983                 //player may not join because of g_maxplayers is set
1984                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1985         }
1986 }
1987
1988 /**
1989  * Determines whether the player is allowed to join. This depends on cvar
1990  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1991  * it checks whether the number of currently playing players exceeds g_maxplayers.
1992  * @return bool TRUE if the player is allowed to join, false otherwise
1993  */
1994 float isJoinAllowed() {
1995         if (!cvar("g_maxplayers"))
1996                 return TRUE;
1997
1998         local entity e;
1999         local float currentlyPlaying;
2000         FOR_EACH_REALPLAYER(e) {
2001                 if(e.classname == "player")
2002                         currentlyPlaying += 1;
2003         }
2004         if(currentlyPlaying < cvar("g_maxplayers"))
2005                 return TRUE;
2006
2007         return FALSE;
2008 }
2009
2010 /**
2011  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2012  * g_maxplayers_spectator_blocktime seconds
2013  */
2014 void checkSpectatorBlock() {
2015         if(self.classname == "spectator" || self.classname == "observer") {
2016                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2017                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2018                         dropclient(self);
2019                 }
2020         }
2021 }
2022
2023 float vercmp_recursive(string v1, string v2)
2024 {
2025         float dot1, dot2;
2026         string s1, s2;
2027         float r;
2028
2029         dot1 = strstrofs(v1, ".", 0);
2030         dot2 = strstrofs(v2, ".", 0);
2031         if(dot1 == -1)
2032                 s1 = v1;
2033         else
2034                 s1 = substring(v1, 0, dot1);
2035         if(dot2 == -1)
2036                 s2 = v2;
2037         else
2038                 s2 = substring(v2, 0, dot2);
2039
2040         r = stof(s1) - stof(s2);
2041         if(r != 0)
2042                 return r;
2043
2044         r = strcasecmp(s1, s2);
2045         if(r != 0)
2046                 return r;
2047
2048         if(dot1 == -1)
2049                 if(dot2 == -1)
2050                         return 0;
2051                 else
2052                         return -1;
2053         else
2054                 if(dot2 == -1)
2055                         return 1;
2056                 else
2057                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2058 }
2059
2060 float vercmp(string v1, string v2)
2061 {
2062         if(strcasecmp(v1, v2) == 0) // early out check
2063                 return 0;
2064         return vercmp_recursive(v1, v2);
2065 }
2066
2067 void ObserverThink()
2068 {
2069         if (self.flags & FL_JUMPRELEASED) {
2070                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2071                         self.welcomemessage_time = 0;
2072                         self.flags &~= FL_JUMPRELEASED;
2073                         self.flags |= FL_SPAWNING;
2074                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2075                         self.welcomemessage_time = 0;
2076                         self.flags &~= FL_JUMPRELEASED;
2077                         if(SpectateNext() == 1) {
2078                                 self.classname = "spectator";
2079                         }
2080                 }
2081         } else {
2082                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2083                         self.flags |= FL_JUMPRELEASED;
2084                         if(self.flags & FL_SPAWNING)
2085                         {
2086                                 self.flags &~= FL_SPAWNING;
2087                                 LeaveSpectatorMode();
2088                                 return;
2089                         }
2090                 }
2091         }
2092         PrintWelcomeMessage(self);
2093 }
2094
2095 void SpectatorThink()
2096 {
2097         if (self.flags & FL_JUMPRELEASED) {
2098                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2099                         self.welcomemessage_time = 0;
2100                         self.flags &~= FL_JUMPRELEASED;
2101                         self.flags |= FL_SPAWNING;
2102                 } else if(self.BUTTON_ATCK) {
2103                         self.welcomemessage_time = 0;
2104                         self.flags &~= FL_JUMPRELEASED;
2105                         if(SpectateNext() == 1) {
2106                                 self.classname = "spectator";
2107                         } else {
2108                                 self.classname = "observer";
2109                                 PutClientInServer();
2110                         }
2111                 } else if (self.BUTTON_ATCK2) {
2112                         self.welcomemessage_time = 0;
2113                         self.flags &~= FL_JUMPRELEASED;
2114                         self.classname = "observer";
2115                         PutClientInServer();
2116                 } else {
2117                         if(!SpectateUpdate())
2118                                 PutObserverInServer();
2119                 }
2120         } else {
2121                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2122                         self.flags |= FL_JUMPRELEASED;
2123                         if(self.flags & FL_SPAWNING)
2124                         {
2125                                 self.flags &~= FL_SPAWNING;
2126                                 LeaveSpectatorMode();
2127                                 return;
2128                         }
2129                 }
2130         }
2131         PrintWelcomeMessage(self);
2132         self.flags |= FL_CLIENT | FL_NOTARGET;
2133 }
2134
2135 .float touchexplode_time;
2136
2137 /*
2138 =============
2139 PlayerPreThink
2140
2141 Called every frame for each client before the physics are run
2142 =============
2143 */
2144 void() ctf_setstatus;
2145 void PlayerPreThink (void)
2146 {
2147         self.stat_sys_ticrate = cvar("sys_ticrate");
2148         self.stat_game_starttime = game_starttime;
2149         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2150
2151         if(blockSpectators && frametime)
2152                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2153                 checkSpectatorBlock();
2154
2155         zoomstate_set = 0;
2156
2157         if(self.netname_previous != self.netname)
2158         {
2159                 if(cvar("sv_eventlog"))
2160                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2161                 if(self.netname_previous)
2162                         strunzone(self.netname_previous);
2163                 self.netname_previous = strzone(self.netname);
2164         }
2165
2166         // version nagging
2167         if(self.version_nagtime)
2168                 if(self.cvar_g_nexuizversion)
2169                         if(time > self.version_nagtime)
2170                         {
2171                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2172                                 {
2173                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2174                                         {
2175                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2176                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2177                                         }
2178                                         else
2179                                         {
2180                                                 float r;
2181                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2182                                                 if(r < 0)
2183                                                 {
2184                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2185                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2186                                                 }
2187                                                 else if(r > 0)
2188                                                 {
2189                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2190                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2191                                                 }
2192                                         }
2193                                 }
2194                                 self.version_nagtime = 0;
2195                         }
2196
2197         // GOD MODE info
2198         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2199         {
2200                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2201                 self.max_armorvalue = 0;
2202         }
2203
2204         if(frametime)
2205                 antilag_record(self);
2206
2207         if(self.classname == "player") {
2208 //              if(self.netname == "Wazat")
2209 //                      bprint(self.classname, "\n");
2210
2211                 CheckRules_Player();
2212
2213                 PrintWelcomeMessage(self);
2214
2215                 if (intermission_running)
2216                 {
2217                         IntermissionThink ();   // otherwise a button could be missed between
2218                         return;                                 // the think tics
2219                 }
2220
2221                 if(self.teleport_time)
2222                 if(time > self.teleport_time)
2223                 {
2224                         self.teleport_time = 0;
2225                         self.effects = self.effects - (self.effects & EF_NODRAW);
2226                 }
2227
2228                 Nixnex_GiveCurrentWeapon();
2229
2230                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2231                         UpdateSelectedPlayer();
2232
2233                 //don't allow the player to turn around while game is paused!
2234                 if(timeoutStatus == 2) {
2235                         self.v_angle = self.lastV_angle;
2236                         self.angles = self.lastV_angle;
2237                         self.fixangle = TRUE;
2238                 }
2239
2240                 player_powerups();
2241
2242                 if (self.deadflag != DEAD_NO)
2243                 {
2244                         float button_pressed, force_respawn;
2245                         if(frametime)
2246                                 player_anim();
2247                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2248                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2249                         if (self.deadflag == DEAD_DYING)
2250                         {
2251                                 if(force_respawn)
2252                                         self.deadflag = DEAD_RESPAWNING;
2253                                 else if(!button_pressed)
2254                                         self.deadflag = DEAD_DEAD;
2255                         }
2256                         else if (self.deadflag == DEAD_DEAD)
2257                         {
2258                                 if(button_pressed)
2259                                         self.deadflag = DEAD_RESPAWNABLE;
2260                         }
2261                         else if (self.deadflag == DEAD_RESPAWNABLE)
2262                         {
2263                                 if(!button_pressed)
2264                                         self.deadflag = DEAD_RESPAWNING;
2265                         }
2266                         else if (self.deadflag == DEAD_RESPAWNING)
2267                         {
2268                                 if(time > self.death_time)
2269                                 {
2270                                         self.death_time = time + 1; // only retry once a second
2271                                         respawn();
2272                                 }
2273                         }
2274                         ShowRespawnCountdown();
2275                         return;
2276                 }
2277
2278                 if(g_touchexplode)
2279                 if(time > self.touchexplode_time)
2280                 if(self.classname == "player")
2281                 if(self.deadflag == DEAD_NO)
2282                 if not(IS_INDEPENDENT_PLAYER(self))
2283                 FOR_EACH_PLAYER(other) if(self != other)
2284                 {
2285                         if(time > other.touchexplode_time)
2286                         if(other.classname == "player")
2287                         if(other.deadflag == DEAD_NO)
2288                         if not(IS_INDEPENDENT_PLAYER(other))
2289                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2290                         {
2291                                 PlayerTouchExplode(self, other);
2292                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2293                         }
2294                 }
2295
2296                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2297                 {
2298                         vector dist;
2299
2300                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2301                         dist = self.oldorigin - self.origin;
2302                         dist_z = 0;
2303                         self.lms_traveled_distance += fabs(vlen(dist));
2304
2305                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2306                         {
2307                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2308                                 self.lms_traveled_distance = 0;
2309                         }
2310
2311                         if(time > self.lms_nextcheck)
2312                         {
2313                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2314                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2315                                 {
2316                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2317                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2318                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2319                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2320                                 }
2321                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2322                                 self.lms_traveled_distance = 0;
2323                         }
2324                 }
2325
2326                 self.oldorigin = self.origin;
2327
2328                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2329                 {
2330                         if (!self.crouch)
2331                         {
2332                                 self.crouch = TRUE;
2333                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2334                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2335                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2336                         }
2337                 }
2338                 else
2339                 {
2340                         if (self.crouch)
2341                         {
2342                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2343                                 if (!trace_startsolid)
2344                                 {
2345                                         self.crouch = FALSE;
2346                                         self.view_ofs = PL_VIEW_OFS;
2347                                         setsize (self, PL_MIN, PL_MAX);
2348                                 }
2349                         }
2350                 }
2351
2352                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2353                 {
2354                         if(self.bloodloss_timer < time)
2355                         {
2356                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2357                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2358                         }
2359                 }
2360
2361                 FixPlayermodel();
2362
2363                 GrapplingHookFrame();
2364
2365                 if(frametime)
2366                 {
2367                         W_WeaponFrame();
2368                         if(self.items & IT_JETPACK)
2369                                 self.items |= IT_FUEL;
2370                 }
2371
2372                 player_regen();
2373                 if(frametime)
2374                         player_anim();
2375
2376                 if (g_minstagib)
2377                         minstagib_ammocheck();
2378
2379                 ctf_setstatus();
2380                 kh_setstatus();
2381
2382                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2383
2384                 //self.angles_y=self.v_angle_y + 90;   // temp
2385
2386                 //if (TetrisPreFrame()) return;
2387         } else if(gameover) {
2388                 if (intermission_running)
2389                         IntermissionThink ();   // otherwise a button could be missed between
2390                 return;
2391         } else if(self.classname == "observer") {
2392                 ObserverThink();
2393         } else if(self.classname == "spectator") {
2394                 SpectatorThink();
2395         }
2396
2397         if(!zoomstate_set)
2398                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2399
2400         float oldspectatee_status;
2401         oldspectatee_status = self.spectatee_status;
2402         if(self.classname == "spectator")
2403                 self.spectatee_status = num_for_edict(self.enemy);
2404         else if(self.classname == "observer")
2405                 self.spectatee_status = num_for_edict(self);
2406         else
2407                 self.spectatee_status = 0;
2408         if(self.spectatee_status != oldspectatee_status)
2409         {
2410                 ClientData_Touch(self);
2411                 if(g_race)
2412                         race_InitSpectator();
2413         }
2414
2415         if(self.teamkill_soundtime)
2416         if(time > self.teamkill_soundtime)
2417         {
2418                 self.teamkill_soundtime = 0;
2419
2420                 entity oldpusher, oldself;
2421
2422                 oldself = self; self = self.teamkill_soundsource;
2423                 oldpusher = self.pusher; self.pusher = oldself;
2424
2425                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2426
2427                 self.pusher = oldpusher;
2428                 self = oldself;
2429         }
2430
2431         if(self.taunt_soundtime)
2432         if(time > self.taunt_soundtime)
2433         {
2434                 self.taunt_soundtime = 0;
2435                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2436         }
2437
2438         target_voicescript_next(self);
2439 }
2440
2441 // on dragger:
2442 .entity dragentity;
2443 .float draggravity;
2444 .float dragspeed; // speed of mouse wheel action
2445 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
2446 .vector draglocalvector; // local attachment vector of the dragentity
2447 .float draglocalangle;
2448 // on draggee:
2449 .entity draggedby;
2450 .float dragmovetype;
2451 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
2452 {
2453         float tagscale;
2454
2455         draggee.dragmovetype = draggee.movetype;
2456         draggee.draggravity = draggee.gravity;
2457         draggee.movetype = MOVETYPE_WALK;
2458         draggee.gravity = 0.00001;
2459         draggee.flags &~= FL_ONGROUND;
2460         draggee.draggedby = dragger;
2461
2462         dragger.dragentity = draggee;
2463
2464         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
2465         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
2466         touchpoint = touchpoint - gettaginfo(draggee, 0);
2467         tagscale = pow(vlen(v_forward), -2);
2468         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
2469         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
2470         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
2471
2472         dragger.dragspeed = 64;
2473 }
2474
2475 void Drag_Finish(entity dragger)
2476 {
2477         entity draggee;
2478         draggee = dragger.dragentity;
2479         if(dragger)
2480                 dragger.dragentity = world;
2481         draggee.draggedby = world;
2482         draggee.movetype = draggee.dragmovetype;
2483         draggee.gravity = draggee.draggravity;
2484
2485         switch(draggee.movetype)
2486         {
2487                 case MOVETYPE_TOSS:
2488                 case MOVETYPE_WALK:
2489                 case MOVETYPE_STEP:
2490                 case MOVETYPE_FLYMISSILE:
2491                 case MOVETYPE_BOUNCE:
2492                 case MOVETYPE_BOUNCEMISSILE:
2493                         break;
2494                 default:
2495                         draggee.velocity = '0 0 0';
2496                         break;
2497         }
2498
2499         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
2500         {
2501                 draggee.velocity = '0 0 0';
2502                 draggee.flags |= FL_ONGROUND; // floating items are FUN
2503         }
2504 }
2505
2506 float Drag_IsDraggable(entity draggee)
2507 {
2508         // TODO add more checks for bad stuff here
2509         if(draggee.classname == "func_bobbing")
2510                 return FALSE;
2511         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
2512                 return FALSE;
2513         if(draggee.classname == "plat")
2514                 return FALSE;
2515         if(draggee.classname == "func_button")
2516                 return FALSE;
2517         if(draggee.model == "")
2518                 return FALSE;
2519         if(draggee.classname == "spectator")
2520                 return FALSE;
2521         if(draggee.classname == "observer")
2522                 return FALSE;
2523         if(draggee.classname == "exteriorweaponentity")
2524                 return FALSE;
2525
2526         return TRUE;
2527 }
2528
2529 float Drag_MayChangeAngles(entity draggee)
2530 {
2531         // TODO add more checks for bad stuff here
2532         if(substring(draggee.model, 0, 1) == "*")
2533                 return FALSE;
2534         return TRUE;
2535 }
2536
2537 void Drag_MoveForward(entity dragger)
2538 {
2539         dragger.dragdistance += dragger.dragspeed;
2540 }
2541
2542 void Drag_SetSpeed(entity dragger, float s)
2543 {
2544         dragger.dragspeed = pow(2, s);
2545 }
2546
2547 void Drag_MoveBackward(entity dragger)
2548 {
2549         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
2550 }
2551
2552 void Drag_Update(entity dragger)
2553 {
2554         vector curorigin, neworigin, goodvelocity;
2555         float f;
2556         entity draggee;
2557
2558         draggee = dragger.dragentity;
2559         draggee.flags &~= FL_ONGROUND;
2560
2561         curorigin = gettaginfo(draggee, 0);
2562         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
2563         makevectors(dragger.v_angle);
2564         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
2565         goodvelocity = (neworigin - curorigin) * (1 / frametime);
2566
2567         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
2568                 dragger.draglocalangle += 360;
2569         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
2570                 dragger.draglocalangle -= 360;
2571
2572         f = min(frametime * 10, 1);
2573         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
2574
2575         if(Drag_MayChangeAngles(draggee))
2576                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
2577
2578         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
2579
2580         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
2581 }
2582
2583 float Drag_CanDrag(entity dragger)
2584 {
2585         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
2586 }
2587
2588 float Drag_IsDragging(entity dragger)
2589 {
2590         if(!dragger.dragentity)
2591                 return FALSE;
2592         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
2593         {
2594                 dragger.dragentity = world;
2595                 return FALSE;
2596         }
2597         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
2598         {
2599                 Drag_Finish(dragger);
2600                 return FALSE;
2601         }
2602         return TRUE;
2603 }
2604
2605 void Drag_MoveDrag(entity from, entity to)
2606 {
2607         if(from.draggedby)
2608         {
2609                 to.draggedby = from.draggedby;
2610                 to.draggedby.dragentity = to;
2611                 from.draggedby = world;
2612         }
2613 }
2614
2615 /*
2616 =============
2617 PlayerPostThink
2618
2619 Called every frame for each client after the physics are run
2620 =============
2621 */
2622 .float idlekick_lasttimeleft;
2623 .float race_penalty;
2624 .float race_penalty_nagged;
2625 .float race_penalty_nagtime;
2626 void PlayerPostThink (void)
2627 {
2628         // Savage: Check for nameless players
2629         if (strlen(self.netname) < 1) {
2630                 self.netname = "Player";
2631                 stuffcmd(self, "seta _cl_name Player\n");
2632         }
2633
2634         if(sv_maxidle && frametime)
2635         {
2636                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2637                 float timeleft;
2638                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2639                 if(timeleft <= 0)
2640                 {
2641                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2642                         announce(self, "announcer/robotic/terminated.wav");
2643                         dropclient(self);
2644                         return;
2645                 }
2646                 else if(timeleft <= 10)
2647                 {
2648                         if(timeleft != self.idlekick_lasttimeleft)
2649                         {
2650                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2651                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2652                         }
2653                 }
2654                 else
2655                 {
2656                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2657                 }
2658                 self.idlekick_lasttimeleft = timeleft;
2659         }
2660
2661         if(sv_cheats)
2662                 if(Drag_CanDrag(self))
2663                         if(self.BUTTON_DRAG)
2664                                 if(!self.dragentity)
2665                                         if(self.cursor_trace_ent)
2666                                                 if(Drag_IsDraggable(self.cursor_trace_ent))
2667                                                 {
2668                                                         if(self.cursor_trace_ent.draggedby)
2669                                                                 Drag_Finish(self.cursor_trace_ent.draggedby);
2670                                                         if(self.cursor_trace_ent.tag_entity)
2671                                                                 detach_sameorigin(self.cursor_trace_ent);
2672                                                         Drag_Begin(self, self.cursor_trace_ent, self.cursor_trace_endpos);
2673                                                 }
2674
2675         if(Drag_IsDragging(self))
2676         {
2677                 if(self.BUTTON_DRAG)
2678                 {
2679                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
2680                         {
2681                                 Drag_MoveForward(self);
2682                                 self.impulse = 0;
2683                         }
2684                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
2685                         {
2686                                 Drag_MoveBackward(self);
2687                                 self.impulse = 0;
2688                         }
2689                         else if(self.impulse >= 1 && self.impulse <= 9)
2690                         {
2691                                 Drag_SetSpeed(self, self.impulse - 1);
2692                         }
2693                         else if(self.impulse == 14)
2694                         {
2695                                 Drag_SetSpeed(self, 9);
2696                         }
2697
2698                         if(frametime)
2699                                 Drag_Update(self);
2700                 }
2701                 else
2702                 {
2703                         Drag_Finish(self);
2704                 }
2705         }
2706
2707         if(self.classname == "player") {
2708                 CheckRules_Player();
2709                 UpdateChatBubble();
2710                 UpdateTeamBubble();
2711                 if (self.impulse)
2712                         ImpulseCommands();
2713                 if (intermission_running)
2714                         return;         // intermission or finale
2715
2716                 //if (TetrisPostFrame()) return;
2717
2718                 // restart countdown
2719                         if(time < game_starttime) {
2720                                 if (!cvar("sv_ready_restart_after_countdown"))
2721                                 {
2722                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2723                                         {
2724                                                 if(time < game_starttime - 2)
2725                                                 {
2726                                                         if(!self.race_penalty_nagged)
2727                                                         {
2728                                                                 // TODO better notification for this!
2729                                                                 self.race_penalty_nagtime = 0;
2730                                                                 self.race_penalty_nagged = 1;
2731                                                         }
2732                                                 }
2733                                                 else if(!self.race_penalty)
2734                                                 {
2735                                                         self.race_penalty_nagtime = 0;
2736                                                         self.race_penalty = time + 5;
2737                                                 }
2738                                         }
2739                                         if(time > self.race_penalty_nagtime)
2740                                         {
2741                                                 if(self.race_penalty > time)
2742                                                 {
2743                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2744                                                 }
2745                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2746                                                 {
2747                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2748                                                 }
2749                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2750                                         }
2751                                         self.movetype = MOVETYPE_NONE;
2752                                         self.velocity = '0 0 0';
2753                                         self.avelocity = '0 0 0';
2754                                         self.movement = '0 0 0';
2755                                 }
2756                         }
2757                         else if (time < self.race_penalty)
2758                         {
2759                                 self.movetype = MOVETYPE_NONE;
2760                                 self.velocity = '0 0 0';
2761                                 self.avelocity = '0 0 0';
2762                                 self.movement = '0 0 0';
2763                         }
2764                         else
2765                         {
2766                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2767                                 if (!cvar("sv_ready_restart_after_countdown"))
2768                                 {
2769                                         if(self.movetype == MOVETYPE_NONE)
2770                                         {
2771                                                 self.movetype = MOVETYPE_WALK;
2772                                         }
2773                                         self.race_penalty = 0;
2774                                         self.race_penalty_nagged = 0;
2775                                 }
2776                         }
2777                 GetPressedKeys();
2778         } else if (self.classname == "observer") {
2779                 //do nothing
2780         } else if (self.classname == "spectator") {
2781                 //do nothing
2782         }
2783
2784         /*
2785         float i;
2786         for(i = 0; i < 1000; ++i)
2787         {
2788                 vector end;
2789                 end = self.origin + '0 0 1024' + 512 * randomvec();
2790                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2791                 if(trace_fraction < 1)
2792                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2793                 {
2794                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2795                         break;
2796                 }
2797         }
2798         */
2799
2800         Arena_Warmup();
2801
2802         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2803 }