data/qcsrc/server/bots.qc

   1 // rough simulation of walking from one point to another to test if a path
   2 // can be traveled, used by havocbot
   3
   4
   5 vector stepheightvec;
   6 float navigation_testtracewalk;
   7 float(entity e, vector start, vector m1, vector m2, vector end) tracewalk =
   8 {
   9         local vector org;
  10         local vector move;
  11         local vector dir;
  12         local float dist;
  13         local float totaldist;
  14         local float stepdist;
  15         local float yaw;
  16         local float ignorehazards;
  17         if (navigation_testtracewalk)
  18         {
  19                 if (navigation_testtracewalk > 1)
  20                         dprint("tracewalk: ");
  21                 //te_wizspike(start);
  22                 //te_knightspike(end);
  23                 //te_lightning2(world, start, end);
  24         }
  25         move = end - start;
  26         move_z = 0;
  27         org = start;
  28         dist = totaldist = vlen(move);
  29         dir = normalize(move);
  30         stepdist = 32;
  31         ignorehazards = FALSE;
  32         //self.angles = vectoangles(dir);
  33         traceline(start, start, FALSE, e);
  34         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  35                 ignorehazards = TRUE;
  36         tracebox(start, m1, m2, start, TRUE, e);
  37         if (trace_startsolid)
  38         {
  39                 // failed - bad start
  40                 if (navigation_testtracewalk)
  41                 {
  42                         if (navigation_testtracewalk > 1)
  43                                 dprint("bad-start\n");
  44                         te_knightspike(start);
  45                 }
  46                 return 0;
  47         }
  48         yaw = vectoyaw(move);
  49         move = end - org;
  50         while (1)
  51         {
  52                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  53                 {
  54                         if (navigation_testtracewalk)
  55                         {
  56                                 if (navigation_testtracewalk > 1)
  57                                         dprint("success\n");
  58                                 te_wizspike(org);
  59                         }
  60                         // succeeded
  61                         return 1;
  62                 }
  63                 if (dist <= 0)
  64                         break;
  65                 if (navigation_testtracewalk)
  66                 {
  67                         //dprint("trying ");
  68                         //te_gunshot(org);
  69                         particle(org, '0 0 0', 104, 8);
  70                 }
  71                 if (stepdist > dist)
  72                         stepdist = dist;
  73                 dist = dist - stepdist;
  74                 traceline(org, org, FALSE, e);
  75                 if (!ignorehazards)
  76                 {
  77                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  78                         {
  79                                 if (navigation_testtracewalk)
  80                                 {
  81                                         if (navigation_testtracewalk > 1)
  82                                                 dprint("hazard\n");
  83                                         te_gunshot(org);
  84                                 }
  85                                 // hazards blocking path
  86                                 return 0;
  87                         }
  88                 }
  89                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  90                 {
  91                         move = normalize(end - org);
  92                         tracebox(org, m1, m2, org + move * stepdist, MOVE_WORLDONLY, e);
  93                         if (trace_fraction < 1)
  94                         {
  95                                 if (navigation_testtracewalk)
  96                                 {
  97                                         if (navigation_testtracewalk > 1)
  98                                                 dprint("swimming-hit-something\n");
  99                                         //particle(org, move * 64, 104, 4);
 100                                         te_gunshot(org);
 101                                 }
 102                                 // failed
 103                                 return 0;
 104                         }
 105                         org = trace_endpos;
 106                 }
 107                 else
 108                 {
 109                         move = dir * stepdist + org;
 110                         tracebox(org, m1, m2, move, MOVE_WORLDONLY, e);
 111                         if (trace_fraction < 1)
 112                         {
 113                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, MOVE_WORLDONLY, e);
 114                                 if (trace_fraction < 1 || trace_startsolid)
 115                                 {
 116                                         if (navigation_testtracewalk)
 117                                         {
 118                                                 if (navigation_testtracewalk > 1)
 119                                                         dprint("hit-something\n");
 120                                                 //move = normalize(end - org);
 121                                                 //particle(org, move * 64, 104, 4);
 122                                                 te_gunshot(org);
 123                                         }
 124                                         // failed
 125                                         return 0;
 126                                 }
 127                         }
 128                         move = trace_endpos;
 129                         tracebox(move, m1, m2, move + '0 0 -65536', FALSE, e);
 130                         /*
 131                         // trace down from stepheight as far as possible and move there,
 132                         // if this starts in solid we try again without the stepup, and
 133                         // if that also fails we assume it is a wall
 134                         // (this is the same logic as the Quake walkmove function used)
 135                         tracebox(move + '0 0 18', m1, m2, move + '0 0 -65536', FALSE, e);
 136                         if (trace_startsolid)
 137                         {
 138                                 tracebox(move, m1, m2, move + '0 0 -65536', FALSE, e);
 139                                 if (trace_startsolid)
 140                                 {
 141                                         if (navigation_testtracewalk)
 142                                         {
 143                                                 if (navigation_testtracewalk > 1)
 144                                                         dprint("hit-something\n");
 145                                                 //move = normalize(end - org);
 146                                                 //particle(org, move * 64, 104, 4);
 147                                                 te_knightspike(org);
 148                                         }
 149                                         // failed
 150                                         return 0;
 151                                 }
 152                         }
 153                         */
 154                         // moved successfully
 155                         if (navigation_testtracewalk > 1)
 156                                 dprint("moved ");
 157                         org = trace_endpos;
 158                 }
 159         }
 160         if (navigation_testtracewalk)
 161         {
 162                 if (navigation_testtracewalk > 1)
 163                         dprint("wrong-place\n");
 164                 te_knightspike(org);
 165                 //te_gunshot(end);
 166         }
 167         // moved but didn't arrive at the intended destination
 168         return 0;
 169 };
 170
 171
 172 // grenade tracing to decide the best pitch to fire at
 173
 174 entity tracetossent;
 175 entity tracetossfaketarget;
 176
 177 // traces multiple trajectories to find one that will impact the target
 178 // 'end' vector is the place it aims for,
 179 // returns TRUE only if it hit targ (don't target non-solid entities)
 180 vector findtrajectory_velocity;
 181 float(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore) findtrajectorywithleading =
 182 {
 183         local float c, savesolid, shottime;
 184         local vector dir, end, v;
 185         if (shotspeed < 1)
 186                 return FALSE; // could cause division by zero if calculated
 187         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
 188                 return FALSE; // could never hit it
 189         if (!tracetossent)
 190                 tracetossent = spawn();
 191         tracetossent.owner = ignore;
 192         setsize(tracetossent, m1, m2);
 193         savesolid = targ.solid;
 194         targ.solid = SOLID_NOT;
 195         shottime = ((vlen(targ.origin - org) / shotspeed) + shotdelay);
 196         v = targ.velocity * shottime + targ.origin;
 197         tracebox(targ.origin, targ.mins, targ.maxs, v, FALSE, targ);
 198         v = trace_endpos;
 199         end = v + (targ.mins + targ.maxs) * 0.5;
 200         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
 201         {
 202                 // out of range
 203                 targ.solid = savesolid;
 204                 return FALSE;
 205         }
 206
 207         if (!tracetossfaketarget)
 208                 tracetossfaketarget = spawn();
 209         tracetossfaketarget.solid = savesolid;
 210         tracetossfaketarget.movetype = targ.movetype;
 211         setmodel(tracetossfaketarget, targ.model); // no low precision
 212         tracetossfaketarget.model = targ.model;
 213         tracetossfaketarget.modelindex = targ.modelindex;
 214         setsize(tracetossfaketarget, targ.mins, targ.maxs);
 215         setorigin(tracetossfaketarget, v);
 216
 217         c = 0;
 218         dir = normalize(end - org);
 219         while (c < 10) // 10 traces
 220         {
 221                 setorigin(tracetossent, org); // reset
 222                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
 223                 tracetoss(tracetossent, ignore); // love builtin functions...
 224                 if (trace_ent == tracetossfaketarget) // done
 225                 {
 226                         targ.solid = savesolid;
 227
 228                         // make it disappear
 229                         tracetossfaketarget.solid = SOLID_NOT;
 230                         tracetossfaketarget.movetype = MOVETYPE_NONE;
 231                         tracetossfaketarget.model = "";
 232                         tracetossfaketarget.modelindex = 0;
 233                         // relink to remove it from physics considerations
 234                         setorigin(tracetossfaketarget, v);
 235
 236                         return TRUE;
 237                 }
 238                 dir_z = dir_z + 0.1; // aim up a little more
 239                 c = c + 1;
 240         }
 241         targ.solid = savesolid;
 242
 243         // make it disappear
 244         tracetossfaketarget.solid = SOLID_NOT;
 245         tracetossfaketarget.movetype = MOVETYPE_NONE;
 246         tracetossfaketarget.model = "";
 247         tracetossfaketarget.modelindex = 0;
 248         // relink to remove it from physics considerations
 249         setorigin(tracetossfaketarget, v);
 250
 251         // leave a valid one even if it won't reach
 252         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
 253         return FALSE;
 254 };
 255
 256
 257
 258 // lag simulation
 259
 260 .void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_func;
 261
 262 // upto 5 queued messages
 263 .float lag1_time;
 264 .float lag1_float1;
 265 .float lag1_float2;
 266 .entity lag1_entity1;
 267 .vector lag1_vec1;
 268 .vector lag1_vec2;
 269 .vector lag1_vec3;
 270 .vector lag1_vec4;
 271
 272 .float lag2_time;
 273 .float lag2_float1;
 274 .float lag2_float2;
 275 .entity lag2_entity1;
 276 .vector lag2_vec1;
 277 .vector lag2_vec2;
 278 .vector lag2_vec3;
 279 .vector lag2_vec4;
 280
 281 .float lag3_time;
 282 .float lag3_float1;
 283 .float lag3_float2;
 284 .entity lag3_entity1;
 285 .vector lag3_vec1;
 286 .vector lag3_vec2;
 287 .vector lag3_vec3;
 288 .vector lag3_vec4;
 289
 290 .float lag4_time;
 291 .float lag4_float1;
 292 .float lag4_float2;
 293 .entity lag4_entity1;
 294 .vector lag4_vec1;
 295 .vector lag4_vec2;
 296 .vector lag4_vec3;
 297 .vector lag4_vec4;
 298
 299 .float lag5_time;
 300 .float lag5_float1;
 301 .float lag5_float2;
 302 .entity lag5_entity1;
 303 .vector lag5_vec1;
 304 .vector lag5_vec2;
 305 .vector lag5_vec3;
 306 .vector lag5_vec4;
 307
 308 void() lag_update =
 309 {
 310         if (self.lag1_time) if (time > self.lag1_time) {self.lag_func(self.lag1_time, self.lag1_float1, self.lag1_float2, self.lag1_entity1, self.lag1_vec1, self.lag1_vec2, self.lag1_vec3, self.lag1_vec4);self.lag1_time = 0;}
 311         if (self.lag2_time) if (time > self.lag2_time) {self.lag_func(self.lag2_time, self.lag2_float1, self.lag2_float2, self.lag2_entity1, self.lag2_vec1, self.lag2_vec2, self.lag2_vec3, self.lag2_vec4);self.lag2_time = 0;}
 312         if (self.lag3_time) if (time > self.lag3_time) {self.lag_func(self.lag3_time, self.lag3_float1, self.lag3_float2, self.lag3_entity1, self.lag3_vec1, self.lag3_vec2, self.lag3_vec3, self.lag3_vec4);self.lag3_time = 0;}
 313         if (self.lag4_time) if (time > self.lag4_time) {self.lag_func(self.lag4_time, self.lag4_float1, self.lag4_float2, self.lag4_entity1, self.lag4_vec1, self.lag4_vec2, self.lag4_vec3, self.lag4_vec4);self.lag4_time = 0;}
 314         if (self.lag5_time) if (time > self.lag5_time) {self.lag_func(self.lag5_time, self.lag5_float1, self.lag5_float2, self.lag5_entity1, self.lag5_vec1, self.lag5_vec2, self.lag5_vec3, self.lag5_vec4);self.lag5_time = 0;}
 315 };
 316
 317 float(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) lag_additem =
 318 {
 319         if (self.lag1_time == 0) {self.lag1_time = t;self.lag1_float1 = f1;self.lag1_float2 = f2;self.lag1_entity1 = e1;self.lag1_vec1 = v1;self.lag1_vec2 = v2;self.lag1_vec3 = v3;self.lag1_vec4 = v4;return TRUE;}
 320         if (self.lag2_time == 0) {self.lag2_time = t;self.lag2_float1 = f1;self.lag2_float2 = f2;self.lag2_entity1 = e1;self.lag2_vec1 = v1;self.lag2_vec2 = v2;self.lag2_vec3 = v3;self.lag2_vec4 = v4;return TRUE;}
 321         if (self.lag3_time == 0) {self.lag3_time = t;self.lag3_float1 = f1;self.lag3_float2 = f2;self.lag3_entity1 = e1;self.lag3_vec1 = v1;self.lag3_vec2 = v2;self.lag3_vec3 = v3;self.lag3_vec4 = v4;return TRUE;}
 322         if (self.lag4_time == 0) {self.lag4_time = t;self.lag4_float1 = f1;self.lag4_float2 = f2;self.lag4_entity1 = e1;self.lag4_vec1 = v1;self.lag4_vec2 = v2;self.lag4_vec3 = v3;self.lag4_vec4 = v4;return TRUE;}
 323         if (self.lag5_time == 0) {self.lag5_time = t;self.lag5_float1 = f1;self.lag5_float2 = f2;self.lag5_entity1 = e1;self.lag5_vec1 = v1;self.lag5_vec2 = v2;self.lag5_vec3 = v3;self.lag5_vec4 = v4;return TRUE;}
 324         // no room for it (what is the best thing to do here??)
 325         return FALSE;
 326 };
 327
 328
 329 // Random skill system
 330 .float bot_thinkskill;
 331 .float bot_mouseskill;
 332 .float bot_predictionskill;
 333 .float bot_offsetskill;
 334
 335
 336 // waypoint navigation system
 337
 338 // itemscore = (howmuchmoreIwant / howmuchIcanwant) / itemdistance
 339 // waypointscore = 0.7 / waypointdistance
 340
 341 .entity wp00, wp01, wp02, wp03, wp04, wp05, wp06, wp07;
 342 .entity wp08, wp09, wp10, wp11, wp12, wp13, wp14, wp15;
 343 .entity wp16, wp17, wp18, wp19, wp20, wp21, wp22, wp23, wp24, wp25, wp26, wp27, wp28, wp29, wp30, wp31;
 344 .float wp00mincost, wp01mincost, wp02mincost, wp03mincost, wp04mincost, wp05mincost, wp06mincost, wp07mincost;
 345 .float wp08mincost, wp09mincost, wp10mincost, wp11mincost, wp12mincost, wp13mincost, wp14mincost, wp15mincost;
 346 .float wp16mincost, wp17mincost, wp18mincost, wp19mincost, wp20mincost, wp21mincost, wp22mincost, wp23mincost, wp24mincost, wp25mincost, wp26mincost, wp27mincost, wp28mincost, wp29mincost, wp30mincost, wp31mincost;
 347 .float wpfire, wpcost;
 348 .float wpisbox;
 349 .float wpflags;
 350 .vector wpnearestpoint;
 351
 352 // stack of current goals (the last one of which may be an item or other
 353 // desirable object, the rest are typically waypoints to reach it)
 354 .entity goalcurrent, goalstack01, goalstack02, goalstack03;
 355 .entity goalstack04, goalstack05, goalstack06, goalstack07;
 356 .entity goalstack08, goalstack09, goalstack10, goalstack11;
 357 .entity goalstack12, goalstack13, goalstack14, goalstack15;
 358 .entity goalstack16, goalstack17, goalstack18, goalstack19;
 359 .entity goalstack20, goalstack21, goalstack22, goalstack23;
 360 .entity goalstack24, goalstack25, goalstack26, goalstack27;
 361 .entity goalstack28, goalstack29, goalstack30, goalstack31;
 362
 363 .entity nearestwaypoint;
 364 .float nearestwaypointtimeout;
 365
 366 // used during navigation_goalrating_begin/end sessions
 367 float navigation_bestrating;
 368 entity navigation_bestgoal;
 369
 370
 371
 372
 373
 374 /////////////////////////////////////////////////////////////////////////////
 375 // waypoint management
 376 /////////////////////////////////////////////////////////////////////////////
 377
 378 // waypoints with this flag are not saved, they are automatically generated
 379 // waypoints like jump pads, teleporters, and items
 380 float WAYPOINTFLAG_GENERATED = 8388608;
 381 float WAYPOINTFLAG_ITEM = 4194304;
 382 float WAYPOINTFLAG_TELEPORT = 2097152;
 383 float WAYPOINTFLAG_NORELINK = 1048576;
 384
 385 // add a new link to the waypoint, replacing the furthest link it already has
 386 void(entity from, entity to) waypoint_addlink =
 387 {
 388         local float c;
 389
 390         if (from == to)
 391                 return;
 392         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 393                 return;
 394
 395         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
 396         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
 397         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
 398         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
 399         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 400         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 401         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 402         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 403
 404         if (to.wpisbox || from.wpisbox)
 405         {
 406                 // if either is a box we have to find the nearest points on them to
 407                 // calculate the distance properly
 408                 local vector v1, v2, m1, m2;
 409                 v1 = from.origin;
 410                 m1 = to.absmin;
 411                 m2 = to.absmax;
 412                 v1_x = bound(m1_x, v1_x, m2_x);
 413                 v1_y = bound(m1_y, v1_y, m2_y);
 414                 v1_z = bound(m1_z, v1_z, m2_z);
 415                 v2 = to.origin;
 416                 m1 = from.absmin;
 417                 m2 = from.absmax;
 418                 v2_x = bound(m1_x, v2_x, m2_x);
 419                 v2_y = bound(m1_y, v2_y, m2_y);
 420                 v2_z = bound(m1_z, v2_z, m2_z);
 421                 v2 = to.origin;
 422                 c = vlen(v2 - v1);
 423         }
 424         else
 425                 c = vlen(to.origin - from.origin);
 426
 427         if (from.wp31mincost < c) return;
 428         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 429         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 430         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 431         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 432         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 433         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 434         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 435         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 436         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 437         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 438         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 439         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 440         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 441         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 442         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 443         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 444         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 445         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 446         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 447         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 448         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 449         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 450         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 451         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 452         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 453         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 454         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 455         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 456         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 457         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 458         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 459         from.wp00 = to;from.wp00mincost = c;return;
 460 };
 461
 462 // relink this waypoint
 463 // (precompile a list of all reachable waypoints from this waypoint)
 464 // (SLOW!)
 465 void() waypoint_think =
 466 {
 467         local entity e;
 468         local vector sv, sm1, sm2, ev, em1, em2;
 469         //dprint("waypoint_think wpisbox = ", ftos(self.wpisbox), "\n");
 470         sm1 = self.origin + self.mins;
 471         sm2 = self.origin + self.maxs;
 472         e = find(world, classname, "waypoint");
 473         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 474         while (e)
 475         {
 476                 if (boxesoverlap(self.absmin, self.absmax, e.absmin, e.absmax))
 477                 {
 478                         waypoint_addlink(self, e);
 479                         waypoint_addlink(e, self);
 480                 }
 481                 else
 482                 {
 483                         sv = e.origin;
 484                         sv_x = bound(sm1_x, sv_x, sm2_x);
 485                         sv_y = bound(sm1_y, sv_y, sm2_y);
 486                         sv_z = bound(sm1_z, sv_z, sm2_z);
 487                         ev = self.origin;
 488                         em1 = e.origin + e.mins;
 489                         em2 = e.origin + e.maxs;
 490                         ev_x = bound(em1_x, ev_x, em2_x);
 491                         ev_y = bound(em1_y, ev_y, em2_y);
 492                         ev_z = bound(em1_z, ev_z, em2_z);
 493                         if (vlen(ev - sv) < self.wp31mincost)
 494                         {
 495                                 navigation_testtracewalk = 0;
 496                                 if (!self.wpisbox)
 497                                 {
 498                                         tracebox(sv - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, sv, FALSE, self);
 499                                         if (!trace_startsolid)
 500                                         {
 501                                                 //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 502                                                 sv = trace_endpos + '0 0 1';
 503                                         }
 504                                 }
 505                                 if (!e.wpisbox)
 506                                 {
 507                                         tracebox(ev - PL_MIN_z * '0 0 1', PL_MIN, PL_MAX, ev, FALSE, e);
 508                                         if (!trace_startsolid)
 509                                         {
 510                                                 //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 511                                                 ev = trace_endpos + '0 0 1';
 512                                         }
 513                                 }
 514                                 //traceline(self.origin, e.origin, FALSE, world);
 515                                 //if (trace_fraction == 1)
 516                                 if (!self.wpisbox)
 517                                 if (tracewalk(self, sv, PL_MIN, PL_MAX, ev))
 518                                         waypoint_addlink(self, e);
 519                                 if (!e.wpisbox)
 520                                 if (tracewalk(e, ev, PL_MIN, PL_MAX, sv))
 521                                         waypoint_addlink(e, self);
 522                         }
 523                 }
 524                 e = find(e, classname, "waypoint");
 525         }
 526         navigation_testtracewalk = 0;
 527 };
 528
 529 void(entity wp) waypoint_clearlinks =
 530 {
 531         // clear links to other waypoints
 532         local float f;
 533         f = 1050; // maximum search range for other waypoints
 534         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = world;wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 535         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = world;wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 536         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = world;wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 537         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = world;wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 538 };
 539
 540 // tell a waypoint to relink
 541 void(entity wp) waypoint_schedulerelink =
 542 {
 543         if (wp == world)
 544                 return;
 545         // TODO: add some sort of visible box in edit mode for box waypoints
 546         if (cvar("g_waypointeditor"))
 547         {
 548                 local vector m1, m2;
 549                 m1 = wp.mins;
 550                 m2 = wp.maxs;
 551                 setmodel(wp, "models/runematch/rune.mdl"); wp.effects = EF_LOWPRECISION;
 552                 setsize(wp, m1, m2);
 553         }
 554         else
 555                 wp.model = "";
 556         wp.wpisbox = vlen(wp.size) > 0;
 557         wp.enemy = world;
 558         wp.owner = world;
 559         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 560                 waypoint_clearlinks(wp);
 561         // schedule an actual relink on next frame
 562         wp.think = waypoint_think;
 563         wp.nextthink = time;
 564         wp.effects = EF_LOWPRECISION;
 565 }
 566
 567 // create a new waypoint and automatically link it to other waypoints, and link
 568 // them back to it as well
 569 // (suitable for waypoint editor)
 570 entity(vector m1, vector m2, float f) waypoint_spawn =
 571 {
 572         local entity w, oldself;
 573         local vector org;
 574         org = (m1 + m2) * 0.5;
 575         m1 = m1 - org;
 576         m2 = m2 - org;
 577         w = find(world, classname, "waypoint");
 578         while (w)
 579         {
 580                 // if a matching waypoint already exists, don't add a duplicate
 581                 if (w.origin == org && w.mins == m1 && w.maxs == m2)
 582                         return w;
 583                 w = find(w, classname, "waypoint");
 584         }
 585         w = spawn();
 586         w.classname = "waypoint";
 587         w.wpflags = f;
 588         setorigin(w, org);
 589         setsize(w, PL_MIN + m1, PL_MAX + m2);
 590         move_out_of_solid(w);
 591         oldself = self;
 592         self = w;
 593         droptofloor();
 594         self = oldself;
 595         setsize(w, m1, m2);
 596
 597         waypoint_clearlinks(w);
 598         //waypoint_schedulerelink(w);
 599         return w;
 600 };
 601
 602 // waypoint map entity
 603 void() waypoint =
 604 {
 605         setorigin(self, self.origin);
 606         // schedule a relink after other waypoints have had a chance to spawn
 607         waypoint_clearlinks(self);
 608         //waypoint_schedulerelink(self);
 609 };
 610
 611 // remove a waypoint, and schedule all neighbors to relink
 612 void(entity e) waypoint_remove =
 613 {
 614         // tell all linked waypoints that they need to relink
 615         waypoint_schedulerelink(e.wp00);
 616         waypoint_schedulerelink(e.wp01);
 617         waypoint_schedulerelink(e.wp02);
 618         waypoint_schedulerelink(e.wp03);
 619         waypoint_schedulerelink(e.wp04);
 620         waypoint_schedulerelink(e.wp05);
 621         waypoint_schedulerelink(e.wp06);
 622         waypoint_schedulerelink(e.wp07);
 623         waypoint_schedulerelink(e.wp08);
 624         waypoint_schedulerelink(e.wp09);
 625         waypoint_schedulerelink(e.wp10);
 626         waypoint_schedulerelink(e.wp11);
 627         waypoint_schedulerelink(e.wp12);
 628         waypoint_schedulerelink(e.wp13);
 629         waypoint_schedulerelink(e.wp14);
 630         waypoint_schedulerelink(e.wp15);
 631         waypoint_schedulerelink(e.wp16);
 632         waypoint_schedulerelink(e.wp17);
 633         waypoint_schedulerelink(e.wp18);
 634         waypoint_schedulerelink(e.wp19);
 635         waypoint_schedulerelink(e.wp20);
 636         waypoint_schedulerelink(e.wp21);
 637         waypoint_schedulerelink(e.wp22);
 638         waypoint_schedulerelink(e.wp23);
 639         waypoint_schedulerelink(e.wp24);
 640         waypoint_schedulerelink(e.wp25);
 641         waypoint_schedulerelink(e.wp26);
 642         waypoint_schedulerelink(e.wp27);
 643         waypoint_schedulerelink(e.wp28);
 644         waypoint_schedulerelink(e.wp29);
 645         waypoint_schedulerelink(e.wp30);
 646         waypoint_schedulerelink(e.wp31);
 647         // and now remove the waypoint
 648         remove(e);
 649 };
 650
 651 // empties the map of waypoints
 652 void() waypoint_removeall =
 653 {
 654         local entity head, next;
 655         head = findchain(classname, "waypoint");
 656         while (head)
 657         {
 658                 next = head.chain;
 659                 remove(head);
 660                 head = next;
 661         }
 662 };
 663
 664 // tell all waypoints to relink
 665 // (is this useful at all?)
 666 void() waypoint_schedulerelinkall =
 667 {
 668         local entity head;
 669         head = findchain(classname, "waypoint");
 670         while (head)
 671         {
 672                 waypoint_schedulerelink(head);
 673                 head = head.chain;
 674         }
 675 };
 676
 677 // save waypoints to gamedir/data/maps/mapname.waypoints
 678 // TODO: support saving wayboxes
 679 void() waypoint_saveall =
 680 {
 681         local string filename, s;
 682         local float file, c;
 683         local entity w;
 684         filename = strcat("maps/", mapname);
 685         filename = strcat(filename, ".waypoints");
 686         file = fopen(filename, FILE_WRITE);
 687         if (file >= 0)
 688         {
 689                 c = 0;
 690                 w = findchain(classname, "waypoint");
 691                 while (w)
 692                 {
 693                         if (!(w.wpflags & WAYPOINTFLAG_GENERATED))
 694                         {
 695                                 s = strcat(vtos(w.origin + w.mins), "\n");
 696                                 s = strcat(s, vtos(w.origin + w.maxs));
 697                                 s = strcat(s, "\n");
 698                                 s = strcat(s, ftos(w.wpflags));
 699                                 s = strcat(s, "\n");
 700                                 fputs(file, s);
 701                                 c = c + 1;
 702                         }
 703                         w = w.chain;
 704                 }
 705                 fclose(file);
 706                 bprint("saved ");
 707                 bprint(ftos(c));
 708                 bprint(" waypoints to maps/");
 709                 bprint(mapname);
 710                 bprint(".waypoints\n");
 711         }
 712         else
 713         {
 714                 bprint("waypoint save to ");
 715                 bprint(filename);
 716                 bprint(" failed\n");
 717         }
 718 };
 719
 720 // load waypoints from file
 721 float() waypoint_loadall =
 722 {
 723         local string filename, s;
 724         local float file, cwp, cwb, fl;
 725         local vector m1, m2;
 726         cwp = 0;
 727         cwb = 0;
 728         filename = strcat("maps/", mapname);
 729         filename = strcat(filename, ".waypoints");
 730         file = fopen(filename, FILE_READ);
 731         if (file >= 0)
 732         {
 733                 while (1)
 734                 {
 735                         s = fgets(file);
 736                         if (!s)
 737                                 break;
 738                         m1 = stov(s);
 739                         s = fgets(file);
 740                         if (!s)
 741                                 break;
 742                         m2 = stov(s);
 743                         s = fgets(file);
 744                         if (!s)
 745                                 break;
 746                         fl = stof(s);
 747                         waypoint_spawn(m1, m2, fl);
 748                         if (m1 == m2)
 749                                 cwp = cwp + 1;
 750                         else
 751                                 cwb = cwb + 1;
 752                 }
 753                 fclose(file);
 754                 dprint("loaded ");
 755                 dprint(ftos(cwp));
 756                 dprint(" waypoints and ");
 757                 dprint(ftos(cwb));
 758                 dprint(" wayboxes from maps/");
 759                 dprint(mapname);
 760                 dprint(".waypoints\n");
 761         }
 762         else
 763         {
 764                 dprint("waypoint load from ");
 765                 dprint(filename);
 766                 dprint(" failed\n");
 767         }
 768         return cwp + cwb;
 769 };
 770
 771 void(entity e) waypoint_spawnforitem =
 772 {
 773         local entity w;
 774         local vector org;
 775
 776         if(!bot_waypoints_for_items)
 777                 return;
 778
 779         org = e.origin + (e.mins + e.maxs) * 0.5;
 780         org_z = e.origin_z + e.mins_z - PL_MIN_z + 1;
 781         e.nearestwaypointtimeout = time + 1000000000;
 782         // don't spawn an item waypoint if it already exists
 783         w = findchain(classname, "waypoint");
 784         while (w)
 785         {
 786                 if (vlen(w.size) > 1)
 787                 {
 788                         if (boxesoverlap(org, org, w.absmin, w.absmax))
 789                         {
 790                                 e.nearestwaypoint = w;
 791                                 return;
 792                         }
 793                 }
 794                 else
 795                 {
 796                         if (vlen(w.origin - org) < 16)
 797                         {
 798                                 e.nearestwaypoint = w;
 799                                 return;
 800                         }
 801                 }
 802                 w = w.chain;
 803         }
 804         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 805 };
 806
 807 void(entity e, vector destination, float timetaken) waypoint_spawnforteleporter =
 808 {
 809         local entity w;
 810         local entity dw;
 811         w = waypoint_spawn(e.absmin, e.absmax, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 812         dw = waypoint_spawn(destination, destination, WAYPOINTFLAG_GENERATED);
 813         // one way link to the destination
 814         w.wp00 = dw;
 815         w.wp00mincost = timetaken; // this is just for jump pads
 816         // the teleporter's nearest waypoint is this one
 817         // (teleporters are not goals, so this is probably useless)
 818         e.nearestwaypoint = w;
 819         e.nearestwaypointtimeout = time + 1000000000;
 820 };
 821
 822
 823
 824
 825
 826 /////////////////////////////////////////////////////////////////////////////
 827 // goal stack
 828 /////////////////////////////////////////////////////////////////////////////
 829
 830 // completely empty the goal stack, used when deciding where to go
 831 void() navigation_clearroute =
 832 {
 833         self.goalcurrent = world;
 834         self.goalstack01 = world;
 835         self.goalstack02 = world;
 836         self.goalstack03 = world;
 837         self.goalstack04 = world;
 838         self.goalstack05 = world;
 839         self.goalstack06 = world;
 840         self.goalstack07 = world;
 841         self.goalstack08 = world;
 842         self.goalstack09 = world;
 843         self.goalstack10 = world;
 844         self.goalstack11 = world;
 845         self.goalstack12 = world;
 846         self.goalstack13 = world;
 847         self.goalstack14 = world;
 848         self.goalstack15 = world;
 849         self.goalstack16 = world;
 850         self.goalstack17 = world;
 851         self.goalstack18 = world;
 852         self.goalstack19 = world;
 853         self.goalstack20 = world;
 854         self.goalstack21 = world;
 855         self.goalstack22 = world;
 856         self.goalstack23 = world;
 857         self.goalstack24 = world;
 858         self.goalstack25 = world;
 859         self.goalstack26 = world;
 860         self.goalstack27 = world;
 861         self.goalstack28 = world;
 862         self.goalstack29 = world;
 863         self.goalstack30 = world;
 864         self.goalstack31 = world;
 865 };
 866
 867 // add a new goal at the beginning of the stack
 868 // (in other words: add a new prerequisite before going to the later goals)
 869 void(entity e) navigation_pushroute =
 870 {
 871         self.goalstack31 = self.goalstack30;
 872         self.goalstack30 = self.goalstack29;
 873         self.goalstack29 = self.goalstack28;
 874         self.goalstack28 = self.goalstack27;
 875         self.goalstack27 = self.goalstack26;
 876         self.goalstack26 = self.goalstack25;
 877         self.goalstack25 = self.goalstack24;
 878         self.goalstack24 = self.goalstack23;
 879         self.goalstack23 = self.goalstack22;
 880         self.goalstack22 = self.goalstack21;
 881         self.goalstack21 = self.goalstack20;
 882         self.goalstack20 = self.goalstack19;
 883         self.goalstack19 = self.goalstack18;
 884         self.goalstack18 = self.goalstack17;
 885         self.goalstack17 = self.goalstack16;
 886         self.goalstack16 = self.goalstack15;
 887         self.goalstack15 = self.goalstack14;
 888         self.goalstack14 = self.goalstack13;
 889         self.goalstack13 = self.goalstack12;
 890         self.goalstack12 = self.goalstack11;
 891         self.goalstack11 = self.goalstack10;
 892         self.goalstack10 = self.goalstack09;
 893         self.goalstack09 = self.goalstack08;
 894         self.goalstack08 = self.goalstack07;
 895         self.goalstack07 = self.goalstack06;
 896         self.goalstack06 = self.goalstack05;
 897         self.goalstack05 = self.goalstack04;
 898         self.goalstack04 = self.goalstack03;
 899         self.goalstack03 = self.goalstack02;
 900         self.goalstack02 = self.goalstack01;
 901         self.goalstack01 = self.goalcurrent;
 902         self.goalcurrent = e;
 903 };
 904
 905 // remove first goal from stack
 906 // (in other words: remove a prerequisite for reaching the later goals)
 907 // (used when a waypoint is reached)
 908 void() navigation_poproute =
 909 {
 910         self.goalcurrent = self.goalstack01;
 911         self.goalstack01 = self.goalstack02;
 912         self.goalstack02 = self.goalstack03;
 913         self.goalstack03 = self.goalstack04;
 914         self.goalstack04 = self.goalstack05;
 915         self.goalstack05 = self.goalstack06;
 916         self.goalstack06 = self.goalstack07;
 917         self.goalstack07 = self.goalstack08;
 918         self.goalstack08 = self.goalstack09;
 919         self.goalstack09 = self.goalstack10;
 920         self.goalstack10 = self.goalstack11;
 921         self.goalstack11 = self.goalstack12;
 922         self.goalstack12 = self.goalstack13;
 923         self.goalstack13 = self.goalstack14;
 924         self.goalstack14 = self.goalstack15;
 925         self.goalstack15 = self.goalstack16;
 926         self.goalstack16 = self.goalstack17;
 927         self.goalstack17 = self.goalstack18;
 928         self.goalstack18 = self.goalstack19;
 929         self.goalstack19 = self.goalstack20;
 930         self.goalstack20 = self.goalstack21;
 931         self.goalstack21 = self.goalstack22;
 932         self.goalstack22 = self.goalstack23;
 933         self.goalstack23 = self.goalstack24;
 934         self.goalstack24 = self.goalstack25;
 935         self.goalstack25 = self.goalstack26;
 936         self.goalstack26 = self.goalstack27;
 937         self.goalstack27 = self.goalstack28;
 938         self.goalstack28 = self.goalstack29;
 939         self.goalstack29 = self.goalstack30;
 940         self.goalstack30 = self.goalstack31;
 941         self.goalstack31 = world;
 942 };
 943
 944 // find the waypoint near a dynamic goal such as a dropped weapon
 945 entity(entity player, float walkfromwp) navigation_findnearestwaypoint =
 946 {
 947         local entity waylist, w, best;
 948         local float dist, bestdist;
 949         local vector v, org;
 950         org = player.origin + (player.mins_z - PL_MIN_z) * '0 0 1';
 951         if(player.tag_entity)
 952                 org = org + player.tag_entity.origin;
 953         if (navigation_testtracewalk)
 954                 te_plasmaburn(org);
 955         best = world;
 956         bestdist = 1000;
 957         waylist = findchain(classname, "waypoint");
 958         // do two scans, because box test is cheaper
 959         w = waylist;
 960         while (w)
 961         {
 962                 // if object is touching waypoint
 963                 if (boxesoverlap(org, org, w.absmin, w.absmax))
 964                         return w;
 965                 w = w.chain;
 966         }
 967         // box check failed, try walk
 968         w = waylist;
 969         while (w)
 970         {
 971                 // if object can walk from waypoint
 972                 if (w.wpisbox)
 973                 {
 974                         local vector wm1, wm2;
 975                         wm1 = w.origin + w.mins;
 976                         wm2 = w.origin + w.maxs;
 977                         v_x = bound(wm1_x, org_x, wm2_x);
 978                         v_y = bound(wm1_y, org_y, wm2_y);
 979                         v_z = bound(wm1_z, org_z, wm2_z);
 980                 }
 981                 else
 982                         v = w.origin;
 983                 dist = vlen(v - org);
 984                 if (bestdist > dist)
 985                 {
 986                         if (walkfromwp)
 987                         {
 988                                 traceline(v, org, TRUE, player);
 989                                 if (trace_fraction == 1)
 990                                 if (tracewalk(player, v, PL_MIN, PL_MAX, org))
 991                                 {
 992                                         bestdist = dist;
 993                                         best = w;
 994                                 }
 995                         }
 996                         else
 997                         {
 998                                 traceline(v, org, TRUE, player);
 999                                 if (trace_fraction == 1)
1000                                 if (tracewalk(player, org, PL_MIN, PL_MAX, v))
1001                                 {
1002                                         bestdist = dist;
1003                                         best = w;
1004                                 }
1005                         }
1006                 }
1007                 w = w.chain;
1008         }
1009         return best;
1010 }
1011
1012 // finds the waypoints near the bot initiating a navigation query
1013 void() navigation_markroutes_nearestwaypoints =
1014 {
1015         local entity head;
1016         local float dist;
1017         local vector v, m1, m2;
1018         //navigation_testtracewalk = TRUE;
1019         head = findchain(classname, "waypoint");
1020         while (head)
1021         {
1022                 m1 = head.origin + head.mins;
1023                 m2 = head.origin + head.maxs;
1024                 v = self.origin;
1025                 v_x = bound(m1_x, v_x, m2_x);
1026                 v_y = bound(m1_y, v_y, m2_y);
1027                 v_z = bound(m1_z, v_z, m2_z);
1028                 dist = vlen(v - self.origin);
1029                 if (dist < 1000)
1030                 {
1031                         if (dist < 4)
1032                         {
1033                                 // if bot is very near a waypoint don't bother doing a trace
1034                                 head.wpnearestpoint = v;
1035                                 head.wpcost = dist + head.dmg;
1036                                 head.wpfire = 1;
1037                                 head.enemy = world;
1038                         }
1039                         else
1040                         {
1041                                 tracebox(self.origin, '-16 -16 0', '16 16 0', v, TRUE, self);
1042                                 if (trace_fraction == 1)
1043                                 {
1044                                         if (tracewalk(self, self.origin, self.mins, self.maxs, v))
1045                                         {
1046                                                 head.wpnearestpoint = v;
1047                                                 head.wpcost = dist + head.dmg;
1048                                                 head.wpfire = 1;
1049                                                 head.enemy = world;
1050                                         }
1051                                 }
1052                         }
1053                 }
1054                 head = head.chain;
1055         }
1056         //navigation_testtracewalk = FALSE;
1057 }
1058
1059 // updates a path link if a waypoint link is better than the current one
1060 void(entity w, entity wp, float cost2, vector p) navigation_markroutes_checkwaypoint =
1061 {
1062         local vector m1;
1063         local vector m2;
1064         local vector v;
1065         if (wp.wpisbox)
1066         {
1067                 m1 = wp.absmin;
1068                 m2 = wp.absmax;
1069                 v_x = bound(m1_x, p_x, m2_x);
1070                 v_y = bound(m1_y, p_y, m2_y);
1071                 v_z = bound(m1_z, p_z, m2_z);
1072         }
1073         else
1074                 v = wp.origin;
1075         cost2 = cost2 + vlen(v);
1076         if (wp.wpcost > cost2)
1077         {
1078                 wp.wpcost = cost2;
1079                 wp.enemy = w;
1080                 wp.wpfire = 1;
1081                 wp.wpnearestpoint = v;
1082         }
1083 };
1084
1085 // queries the entire waypoint network for pathes leading away from the bot
1086 void() navigation_markroutes =
1087 {
1088         local entity w, wp, waylist;
1089         local float searching, cost, cost2;
1090         local vector p;
1091         w = waylist = findchain(classname, "waypoint");
1092         while (w)
1093         {
1094                 w.wpnearestpoint = '0 0 0';
1095                 w.wpcost = 10000000;
1096                 w.wpfire = 0;
1097                 w.enemy = world;
1098                 w = w.chain;
1099         }
1100         navigation_markroutes_nearestwaypoints();
1101         searching = TRUE;
1102         while (searching)
1103         {
1104                 searching = FALSE;
1105                 w = waylist;
1106                 while (w)
1107                 {
1108                         if (w.wpfire)
1109                         {
1110                                 searching = TRUE;
1111                                 w.wpfire = 0;
1112                                 cost = w.wpcost;
1113                                 p = w.wpnearestpoint;
1114                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1115                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1116                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1117                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1118                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1119                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1120                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1121                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1122                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1123                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1124                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1125                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1126                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1127                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1128                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1129                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1130                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1131                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1132                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1133                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1134                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1135                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1136                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1137                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1138                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1139                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1140                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1141                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1142                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1143                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1144                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1145                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + wp.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
1146                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
1147                         }
1148                         w = w.chain;
1149                 }
1150         }
1151 };
1152
1153 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1154 void(entity e, float f) navigation_routerating =
1155 {
1156         if (!e)
1157                 return;
1158         //te_wizspike(e.origin);
1159         //bprint(etos(e));
1160         //bprint("\n");
1161         // update the cached waypoint link on a dynamic item entity
1162         if (time > e.nearestwaypointtimeout)
1163         {
1164                 e.nearestwaypoint = navigation_findnearestwaypoint(e, TRUE);
1165                 e.nearestwaypointtimeout = time + random() * 3 + 5;
1166         }
1167         if (e.nearestwaypoint)
1168         if (e.nearestwaypoint.wpcost < 10000000)
1169         {
1170                 //te_wizspike(e.nearestwaypoint.wpnearestpoint);
1171                 f = f / ((e.nearestwaypoint.wpcost + vlen(e.origin - e.nearestwaypoint.wpnearestpoint)) * 0.001 + 1);
1172                 if (navigation_bestrating < f)
1173                 {
1174                         navigation_bestrating = f;
1175                         navigation_bestgoal = e;
1176                 }
1177         }
1178 };
1179
1180 // replaces the goal stack with the path to a given item
1181 void(entity e) navigation_routetogoal =
1182 {
1183         // if already going to this goal, don't stop
1184         //if (self.goalentity == e)
1185         //      return;
1186         // clear the route and add the new one
1187         navigation_clearroute();
1188         self.goalentity = e;
1189         // if there is no goal, just exit
1190         if (!e)
1191                 return;
1192         // put the entity on the goal stack as the only item
1193         navigation_pushroute(e);
1194         //te_smallflash((e.absmin + e.absmax) * 0.5);
1195         //bprint("navigation_routetogoal(");
1196         //bprint(etos(e));
1197         //bprint(") : ");
1198         //bprint(etos(e));
1199         tracebox(self.origin, '-16 -16 0', '16 16 0', e.origin, TRUE, self);
1200         if (trace_fraction == 1)
1201         if (tracewalk(self, self.origin, PL_MIN, PL_MAX, e.origin))
1202                 return;
1203         // see if there are waypoints describing a path to the item
1204         e = e.nearestwaypoint;
1205         while (e != world)
1206         {
1207                 //bprint(" ");
1208                 //bprint(etos(e));
1209                 //te_smallflash((e.absmin + e.absmax) * 0.5);
1210                 //tracebox(self.origin, '-16 -16 0', '16 16 0', e.origin, TRUE, self);
1211                 //if (trace_fraction == 1)
1212                 //if (tracewalk(self, self.origin, PL_MIN, PL_MAX, e.origin))
1213                 //      break;
1214                 // add the waypoint to the path
1215                 navigation_pushroute(e);
1216                 e = e.enemy;
1217         }
1218         //bprint("\n");
1219 };
1220
1221 // removes any currently touching waypoints from the goal stack
1222 // (this is how bots detect if they have reached a goal)
1223 void() navigation_poptouchedgoals =
1224 {
1225         local vector org, m1, m2;
1226         org = self.origin;// + self.velocity * 0.1;
1227         m1 = org + self.mins;
1228         m2 = org + self.maxs;
1229         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
1230                 navigation_poproute();
1231 }
1232
1233 // begin a goal selection session (queries waypoint network)
1234 void() navigation_goalrating_start =
1235 {
1236         navigation_bestrating = -1;
1237         navigation_bestgoal = world;
1238         navigation_markroutes();
1239 };
1240
1241 // ends a goal selection session (updates goal stack to the best goal)
1242 void() navigation_goalrating_end =
1243 {
1244         navigation_routetogoal(navigation_bestgoal);
1245 };
1246
1247
1248
1249
1250
1251 //////////////////////////////////////////////////////////////////////////////
1252 // general bot functions
1253 //////////////////////////////////////////////////////////////////////////////
1254
1255 .float isbot; // true if this client is actually a bot
1256
1257 float skill;
1258 entity bot_list;
1259 .entity nextbot;
1260
1261 float sv_maxspeed;
1262 .float createdtime;
1263
1264 .float bot_attack;
1265 .float bot_dodge;
1266 .float bot_dodgerating;
1267
1268 //.float bot_painintensity;
1269 .float bot_firetimer;
1270 //.float bot_oldhealth;
1271 .void() bot_ai;
1272
1273 .entity bot_aimtarg;
1274 .float bot_aimlatency;
1275 .vector bot_aimselforigin;
1276 .vector bot_aimselfvelocity;
1277 .vector bot_aimtargorigin;
1278 .vector bot_aimtargvelocity;
1279
1280 .float bot_pickup;
1281 .float(entity player, entity item) bot_pickupevalfunc;
1282 .float bot_pickupbasevalue;
1283 .float bot_canfire;
1284
1285 // used for aiming currently
1286 // FIXME: make the weapon code use these and then replace the calculations here with a call to the weapon code
1287 vector shotorg;
1288 vector shotdir;
1289
1290 const float BOTSKINS = 19;
1291 const float BOTNAMES = 32;
1292 string(float r) bot_namefornumber =
1293 {
1294         if (r <  1) return "Thunderstorm";
1295         if (r <  2) return "Darkness";
1296         if (r <  3) return "Scorcher";
1297         if (r <  4) return "Paranoia";
1298         if (r <  5) return "Eureka";
1299         if (r <  6) return "Mystery";
1300         if (r <  7) return "Toxic";
1301         if (r <  8) return "Dominion";
1302         if (r <  9) return "Pegasus";
1303         if (r < 10) return "Sensible";
1304         if (r < 11) return "Gator";
1305         if (r < 12) return "Kangaroo";
1306         if (r < 13) return "Deadline";
1307         if (r < 14) return "Frosty";
1308         if (r < 15) return "Roadkill";
1309         if (r < 16) return "Death";
1310         if (r < 17) return "Panic";
1311         if (r < 18) return "Discovery";
1312         if (r < 19) return "Shadow";
1313         if (r < 20) return "Acidic";
1314         if (r < 21) return "Dominator";
1315         if (r < 22) return "Hellfire";
1316         if (r < 23) return "Necrotic";
1317         if (r < 24) return "Newbie";
1318         if (r < 25) return "Spellbinder";
1319         if (r < 26) return "Lion";
1320         if (r < 27) return "Controlled";
1321         if (r < 28) return "Airhead";
1322         if (r < 29) return "Delirium";
1323         if (r < 30) return "Resurrection";
1324         if (r < 31) return "Danger";
1325         return "Flatline";
1326 };
1327
1328 string(float r) bot_skinfornumber =
1329 {
1330              if (r <  1) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "0";return "Carni"          ;}
1331         else if (r <  2) {self.playermodel = "models/player/carni.zym"          ;self.playerskin = "1";return "Armored Carni"  ;}
1332         else if (r <  3) {self.playermodel = "models/player/crash.zym"          ;self.playerskin = "0";return "Quark"          ;}
1333         else if (r <  4) {self.playermodel = "models/player/grunt.zym"          ;self.playerskin = "0";return "Grunt"          ;}
1334         else if (r <  5) {self.playermodel = "models/player/headhunter.zym"     ;self.playerskin = "0";return "HeadHunter"     ;}
1335         else if (r <  6) {self.playermodel = "models/player/insurrectionist.zym";self.playerskin = "0";return "Insurrectionist";}
1336         else if (r <  7) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "0";return "Lurk"           ;}
1337         else if (r <  8) {self.playermodel = "models/player/lurk.zym"           ;self.playerskin = "1";return "Reptile"        ;}
1338         else if (r <  9) {self.playermodel = "models/player/lycanthrope.zym"    ;self.playerskin = "0";return "Lycanthrope"    ;}
1339         else if (r < 10) {self.playermodel = "models/player/marine.zym"         ;self.playerskin = "0";return "Marine"         ;}
1340         else if (r < 11) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "0";return "Nexus"          ;}
1341         else if (r < 12) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "1";return "Mulder"         ;}
1342         else if (r < 13) {self.playermodel = "models/player/nexus.zym"          ;self.playerskin = "2";return "Xolar"          ;}
1343         else if (r < 14) {self.playermodel = "models/player/pyria.zym"          ;self.playerskin = "0";return "Pyria"          ;}
1344         else if (r < 15) {self.playermodel = "models/player/shock.zym"          ;self.playerskin = "0";return "Shock"          ;}
1345         else if (r < 16) {self.playermodel = "models/player/skadi.zym"          ;self.playerskin = "0";return "Skadi"          ;}
1346         else if (r < 17) {self.playermodel = "models/player/specop.zym"         ;self.playerskin = "0";return "Specop"         ;}
1347         else             {self.playermodel = "models/player/visitant.zym"       ;self.playerskin = "0";return "Fricka"         ;}
1348 };
1349
1350 void() bot_setnameandstuff =
1351 {
1352         local string name, prefix, suffix;
1353         local float r, b, shirt, pants;
1354
1355         prefix = cvar_string("bot_prefix");
1356         suffix = cvar_string("bot_suffix");
1357
1358         // this is really only a default, JoinBestTeam is called later
1359         pants = bound(0, floor(random() * 13), 13);
1360         //shirt = bound(0, floor(random() * 16), 15);
1361         shirt = pants;
1362         self.clientcolors = shirt * 16 + pants;
1363         self.team = pants + 1;
1364
1365         // now pick a name...
1366
1367         if (cvar("bot_usemodelnames"))
1368         {
1369                 // first see if all skins are taken
1370                 b = 0;
1371                 do
1372                 {
1373                         name = bot_skinfornumber(b);
1374                         b = b + 1;
1375                 }
1376                 while (b < BOTSKINS && find(world, netname, name));
1377
1378                 // randomly pick a skin, if it's taken either repeat until we find one,
1379                 // or give up if we already know all skins are taken
1380                 do
1381                 {
1382                         r = floor(random() * BOTSKINS);
1383                         name = bot_skinfornumber(r);
1384                 }
1385                 while (b < BOTSKINS && find(world, netname, name));
1386         }
1387         else
1388         {
1389                 // first see if all names are taken
1390                 b = 0;
1391                 do
1392                 {
1393                         name = bot_namefornumber(b);
1394                         b = b + 1;
1395                 }
1396                 while (b < BOTNAMES && find(world, netname, name));
1397
1398                 // randomly pick a name, if it's taken either repeat until we find one,
1399                 // or give up if we already know all names are taken
1400                 do
1401                 {
1402                         r = floor(random() * BOTNAMES);
1403                         name = bot_namefornumber(r);
1404                 }
1405                 while (b < BOTNAMES && find(world, netname, name));
1406
1407                 // randomly pick a skin
1408                 bot_skinfornumber(floor(random() * BOTSKINS));
1409         }
1410         if(!cvar("g_campaign"))
1411                 self.netname = strzone(strcat(prefix, name, suffix));
1412         else
1413                 self.netname = name;
1414 };
1415
1416 float bot_ignore_bots; // let bots not attack other bots (only works in non-teamplay)
1417 float(entity e) bot_shouldattack =
1418 {
1419         if (e.team == self.team)
1420         {
1421                 if (e == self)
1422                         return FALSE;
1423                 if (teamplay)
1424                 if (e.team != 0)
1425                         return FALSE;
1426         }
1427         if(!teamplay)
1428                 if(bot_ignore_bots)
1429                         if(clienttype(e) == CLIENTTYPE_BOT)
1430                                 return FALSE;
1431         if (!e.takedamage)
1432                 return FALSE;
1433         if (e.deadflag)
1434                 return FALSE;
1435         if (e.buttonchat)
1436                 return FALSE;
1437         return TRUE;
1438 };
1439
1440 void(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4) bot_lagfunc =
1441 {
1442         self.bot_aimtarg = e1;
1443         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
1444         self.bot_aimselforigin = v1;
1445         self.bot_aimselfvelocity = v2;
1446         self.bot_aimtargorigin = v3;
1447         self.bot_aimtargvelocity = v4;
1448         if(skill <= 0)
1449                 self.bot_canfire = (random() < 0.8);
1450         else if(skill <= 1)
1451                 self.bot_canfire = (random() < 0.9);
1452         else if(skill <= 2)
1453                 self.bot_canfire = (random() < 0.95);
1454         else
1455                 self.bot_canfire = 1;
1456 };
1457
1458 .float bot_badaimtime;
1459 .float bot_aimthinktime;
1460 .vector bot_mouseaim;
1461 .vector bot_badaimoffset;
1462 .vector bot_1st_order_aimfilter;
1463 .vector bot_2nd_order_aimfilter;
1464 .vector bot_3th_order_aimfilter;
1465 .vector bot_4th_order_aimfilter;
1466 .vector bot_5th_order_aimfilter;
1467 .vector bot_olddesiredang;
1468 float(vector v, float maxfiredeviation) bot_aimdir =
1469 {
1470 /*
1471         local float snapcos;
1472         local vector olddir, newdir, desireddir;
1473
1474         makevectors(self.v_angle);
1475         olddir = newdir = v_forward;
1476         desireddir = normalize(v);
1477         snapcos = cos(cvar("bot_ai_aimskill_snapangle") * frametime * (skill + 1) * 0.5);
1478         if (desireddir * olddir < v_forward_x)
1479                 newdir = desireddir;
1480         else
1481         {
1482                 local float blendrate;
1483                 blendrate = cvar("bot_ai_aimskill_blendrate") * frametime * (skill + 1) * 0.5;
1484                 newdir = olddir + (desireddir - olddir) * bound(0, blendrate, 1);
1485         }
1486
1487         // decide whether to fire this time
1488         if ((desireddir * newdir) >= cos(maxfiredeviation))
1489                 self.bot_firetimer = time + 0.3;
1490
1491         self.v_angle = vectoangles(newdir);
1492         self.v_angle_x = self.v_angle_x * -1;
1493
1494         makevectors(self.v_angle);
1495         shotorg = self.origin + self.view_ofs;
1496         shotdir = newdir;
1497
1498         return time < self.bot_firetimer;
1499 */
1500
1501         local float dist;
1502         local vector desiredang, diffang;
1503
1504         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
1505         // make sure v_angle is sane first
1506         //self.v_angle_x = bound(-180, self.v_angle_x, 180);
1507         //while (self.v_angle_x < -180) self.v_angle_x = self.v_angle_x + 360;
1508         //while (self.v_angle_x >= 180) self.v_angle_x = self.v_angle_x - 360;
1509         while (self.v_angle_y < -180) self.v_angle_y = self.v_angle_y + 360;
1510         while (self.v_angle_y >= 180) self.v_angle_y = self.v_angle_y - 360;
1511         //while (self.v_angle_z < -180) self.v_angle_z = self.v_angle_z + 360;
1512         //while (self.v_angle_z >= 180) self.v_angle_z = self.v_angle_z - 360;
1513         self.v_angle_z = 0;
1514
1515         // get the desired angles to aim at
1516         //dprint(" at:", vtos(v));
1517         v = normalize(v);
1518         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
1519         if (time >= self.bot_badaimtime)
1520         {
1521                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
1522                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5);
1523         }
1524         desiredang = vectoangles(v) + self.bot_badaimoffset*cvar("bot_ai_aimskill_offset");
1525         //dprint(" desired:", vtos(desiredang));
1526         if (desiredang_x >= 180)
1527                 desiredang_x = desiredang_x - 360;
1528         desiredang_x = 0 - desiredang_x;
1529         desiredang_z = self.v_angle_z;
1530         desiredang_x = bound(-90, desiredang_x, 90);
1531         //dprint(" / ", vtos(desiredang));
1532
1533         //// pain throws off aim
1534         //if (self.bot_painintensity)
1535         //{
1536         //      // shake from pain
1537         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
1538         //}
1539
1540         // calculate turn angles
1541         diffang = (desiredang - self.bot_olddesiredang)*(1/frametime);
1542         self.bot_olddesiredang = desiredang;
1543         //dprint(" diff:", vtos(diffang));
1544
1545         // wrap yaw turn
1546         while (diffang_y < -180)
1547                 diffang_y = diffang_y + 360;
1548         while (diffang_y >  180)
1549                 diffang_y = diffang_y - 360;
1550
1551         // Here we will try to anticipate the comming aiming direction
1552         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
1553                 + (diffang                      - self.bot_1st_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_1st"),1);
1554         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
1555                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_2nd"),1);
1556         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
1557                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_3th"),1);
1558         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
1559                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_4th"),1);
1560         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
1561                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, cvar("bot_ai_aimskill_order_filter_5th"),1);
1562
1563         local float blend;
1564         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
1565         blend = bound(0,skill,10)*0.1;
1566         desiredang = desiredang + blend *
1567         (
1568                   self.bot_1st_order_aimfilter * cvar("bot_ai_aimskill_order_mix_1st")
1569                 + self.bot_2nd_order_aimfilter * cvar("bot_ai_aimskill_order_mix_2nd")
1570                 + self.bot_3th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_3th")
1571                 + self.bot_4th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_4th")
1572                 + self.bot_5th_order_aimfilter * cvar("bot_ai_aimskill_order_mix_5th")
1573         );
1574         while (desiredang_z < -180)
1575                 desiredang_z = desiredang_z + 360;
1576         while (desiredang_z >  180)
1577                 desiredang_z = desiredang_z - 360;
1578         // calculate turn angles
1579         diffang = desiredang - self.bot_mouseaim;
1580         //dprint(" diff:", vtos(diffang));
1581
1582         // wrap yaw turn
1583         while (diffang_y < -180)
1584                 diffang_y = diffang_y + 360;
1585         while (diffang_y >  180)
1586                 diffang_y = diffang_y - 360;
1587
1588         if (time >= self.bot_aimthinktime)
1589         {
1590                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
1591                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-skill,10));
1592         }
1593
1594         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
1595
1596         desiredang = self.bot_mouseaim*bound(0,cvar("bot_ai_aimskill_think"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_think")),1);
1597
1598         // calculate turn angles
1599         diffang = desiredang - self.v_angle;
1600         //dprint(" diff:", vtos(diffang));
1601
1602         // wrap yaw turn
1603         while (diffang_y < -180)
1604                 diffang_y = diffang_y + 360;
1605         while (diffang_y >  180)
1606                 diffang_y = diffang_y - 360;
1607         // calculate turn angles
1608         diffang = desiredang - self.v_angle;
1609         //dprint(" diff:", vtos(diffang));
1610
1611         // wrap yaw turn
1612         while (diffang_y < -180)
1613                 diffang_y = diffang_y + 360;
1614         while (diffang_y >  180)
1615                 diffang_y = diffang_y - 360;
1616
1617         // jitter tracking
1618         dist = vlen(diffang);
1619         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
1620
1621         // turn
1622         local float r, fixedrate, blendrate;
1623         fixedrate = cvar("bot_ai_aimskill_fixedrate") / bound(1,dist,1000);
1624         blendrate = cvar("bot_ai_aimskill_blendrate");
1625         r = max(fixedrate, blendrate);
1626         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
1627         self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
1628         self.v_angle = self.v_angle * bound(0,cvar("bot_ai_aimskill_mouse"),1) + desiredang * bound(0,(1-cvar("bot_ai_aimskill_mouse")),1);
1629         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
1630         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
1631         self.v_angle_z = 0;
1632         while (self.v_angle_y < -180)
1633                 self.v_angle_y = self.v_angle_y + 360;
1634         while (self.v_angle_y >= 180)
1635                 self.v_angle_y = self.v_angle_y - 360;
1636         //dprint(" turn:", vtos(self.v_angle));
1637
1638         makevectors(self.v_angle);
1639         shotorg = self.origin + self.view_ofs;
1640         shotdir = v_forward;
1641
1642         //dprint(" dir:", vtos(v_forward));
1643         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
1644
1645         // calculate turn angles again
1646         diffang = desiredang - self.v_angle;
1647         while (diffang_y < -180)
1648                 diffang_y = diffang_y + 360;
1649         while (diffang_y >  180)
1650                 diffang_y = diffang_y - 360;
1651
1652         //bprint("e ");bprintvector(diffang);bprint(" < ");bprintfloat(maxfiredeviation);bprint("\n");
1653
1654         // decide whether to fire this time
1655         // note the maxfiredeviation is in degrees so this has to convert to radians first
1656         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
1657         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
1658                         self.bot_firetimer = time + 0.3/bound(1,skill*0.3,3);
1659         traceline(shotorg,shotorg+shotdir*1000,FALSE,world);
1660         if ( vlen(trace_endpos-shotorg)>bound(0,skill*20,20) && random()<bound(0,skill*0.5,10)*frametime*2 )
1661                 self.bot_canfire = 0;
1662         //dprint(ftos(maxfiredeviation),"\n");
1663         //dprint(" diff:", vtos(diffang), "\n");
1664
1665         return self.bot_canfire && (time < self.bot_firetimer);
1666 };
1667
1668 vector(vector targorigin, vector targvelocity, float shotspeed, float shotdelay) bot_shotlead =
1669 {
1670         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
1671         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
1672 };
1673
1674 float(float shotspeed, float shotspeedupward, float maxshottime, float applygravity) bot_aim =
1675 {
1676         local float f, r;
1677         local vector v;
1678         /*
1679         eprint(self);
1680         dprint("bot_aim(", ftos(shotspeed));
1681         dprint(", ", ftos(shotspeedupward));
1682         dprint(", ", ftos(maxshottime));
1683         dprint(", ", ftos(applygravity));
1684         dprint(");\n");
1685         */
1686         if (!shotspeed)
1687         {
1688                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " shotspeed is zero!\n");
1689                 shotspeed = 1000000;
1690         }
1691         if (!maxshottime)
1692         {
1693                 dprint("bot_aim: WARNING: weapon ", W_Name(self.weapon), " maxshottime is zero!\n");
1694                 maxshottime = 1;
1695         }
1696         makevectors(self.v_angle);
1697         shotorg = self.origin + self.view_ofs;
1698         shotdir = v_forward;
1699         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
1700         local float distanceratio;
1701         distanceratio =sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/cvar("bot_ai_aimskill_firetolerance_distdegrees");
1702         distanceratio = bound(0,distanceratio,1);
1703         r =  (cvar("bot_ai_aimskill_firetolerance_maxdegrees")-cvar("bot_ai_aimskill_firetolerance_mindegrees"))
1704                 * (1-distanceratio) + cvar("bot_ai_aimskill_firetolerance_mindegrees");
1705         if (applygravity && self.bot_aimtarg)
1706         {
1707                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
1708                         return FALSE;
1709                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
1710         }
1711         else
1712         {
1713                 f = bot_aimdir(v - shotorg, r);
1714                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
1715                 traceline(shotorg, shotorg + shotdir * 10000, FALSE, self);
1716                 if (trace_ent.takedamage)
1717                 if (trace_fraction < 1)
1718                 if (!bot_shouldattack(trace_ent))
1719                         return FALSE;
1720                 traceline(shotorg, self.bot_aimtargorigin, FALSE, self);
1721                 if (trace_fraction < 1)
1722                 if (trace_ent != self.enemy)
1723                 if (!bot_shouldattack(trace_ent))
1724                         return FALSE;
1725         }
1726         if (r > maxshottime * shotspeed)
1727                 return FALSE;
1728         return f;
1729 };
1730
1731 // TODO: move this painintensity code to the player damage code
1732 void() bot_think =
1733 {
1734         //if (self.bot_painintensity > 0)
1735         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
1736
1737         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
1738         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
1739
1740         if(cvar("g_campaign") && !campaign_bots_may_start)
1741         {
1742                 self.nextthink = time + 0.5;
1743                 return;
1744         }
1745
1746         if (self.fixangle)
1747         {
1748                 self.v_angle = self.angles;
1749                 self.v_angle_z = 0;
1750                 self.fixangle = FALSE;
1751         }
1752
1753         self.dmg_take = 0;
1754         self.dmg_save = 0;
1755         self.dmg_inflictor = world;
1756
1757         // calculate an aiming latency based on the skill setting
1758         // (simulated network latency + naturally delayed reflexes)
1759         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
1760         // minimum ping 20+10 random
1761         self.ping = bound(0,0.07 - bound(0, skill * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
1762         // skill 10 = ping 0.2 (adrenaline)
1763         // skill 0 = ping 0.7 (slightly drunk)
1764
1765         // clear buttons
1766         self.button0 = 0;
1767         self.button1 = 0;
1768         self.button2 = 0;
1769         self.button3 = 0;
1770         self.button4 = 0;
1771         self.button5 = 0;
1772         self.button6 = 0;
1773         self.button7 = 0;
1774         self.button8 = 0;
1775         self.buttonchat = 0;
1776         self.buttonuse = 0;
1777
1778         // if dead, just wait until we can respawn
1779         if (self.deadflag)
1780         {
1781                 if (self.deadflag == DEAD_DEAD)
1782                         self.button2 = 1; // press jump to respawn
1783                 return;
1784         }
1785
1786         // now call the current bot AI (havocbot for example)
1787         self.bot_ai();
1788 };
1789
1790 entity bot_strategytoken;
1791 entity player_list;
1792 .entity nextplayer;
1793 void() bot_relinkplayerlist =
1794 {
1795         local entity e;
1796         local entity prevbot;
1797         player_count = 0;
1798         currentbots = 0;
1799         player_list = e = findchainflags(flags, FL_CLIENT);
1800         bot_list = world;
1801         prevbot = world;
1802         while (e)
1803         {
1804                 player_count = player_count + 1;
1805                 e.nextplayer = e.chain;
1806                 if (clienttype(e) == CLIENTTYPE_BOT)
1807                 {
1808                         if (prevbot)
1809                                 prevbot.nextbot = e;
1810                         else
1811                                 bot_list = e;
1812                         prevbot = e;
1813                         currentbots = currentbots + 1;
1814                 }
1815                 e = e.chain;
1816         }
1817         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
1818         bot_strategytoken = bot_list;
1819 };
1820
1821 void() havocbot_setupbot;
1822 float JoinBestTeam(entity pl, float only_return_best);
1823
1824 void() bot_clientconnect =
1825 {
1826         if (clienttype(self) != CLIENTTYPE_BOT)
1827                 return;
1828         self.lag_func = bot_lagfunc;
1829         self.isbot = TRUE;
1830         self.createdtime = self.nextthink;
1831         JoinBestTeam(self, FALSE);
1832         havocbot_setupbot();
1833         self.bot_mouseskill=random()-0.5;
1834         self.bot_thinkskill=random()-0.5;
1835         self.bot_predictionskill=random()-0.5;
1836         self.bot_offsetskill=random()-0.5;
1837 };
1838
1839 entity() bot_spawn =
1840 {
1841         local entity oldself, bot;
1842         bot = spawnclient();
1843         if (bot)
1844         {
1845                 currentbots = currentbots + 1;
1846                 oldself = self;
1847                 self = bot;
1848                 bot_setnameandstuff();
1849                 ClientConnect();
1850                 PutClientInServer();
1851                 self = oldself;
1852         }
1853         return bot;
1854 };
1855
1856 void() bot_removenewest =
1857 {
1858         local float besttime;
1859         local entity best, head;
1860         head = findchainfloat(isbot, TRUE);
1861         if (!head)
1862                 return;
1863         best = head;
1864         besttime = head.createdtime;
1865         while (head)
1866         {
1867                 if (besttime < head.createdtime)
1868                 {
1869                         besttime = head.createdtime;
1870                         best = head;
1871                 }
1872                 head = head.chain;
1873         }
1874         currentbots = currentbots - 1;
1875         dropclient(best);
1876 };
1877
1878 float botframe_waypointeditorlightningtime;
1879 void() botframe_showwaypointlinks =
1880 {
1881         local entity player, head, w;
1882         if (time < botframe_waypointeditorlightningtime)
1883                 return;
1884         botframe_waypointeditorlightningtime = time + 0.5;
1885         player = find(world, classname, "player");
1886         while (player)
1887         {
1888                 if (!player.isbot)
1889                 if (player.flags & FL_ONGROUND)
1890                 {
1891                         //navigation_testtracewalk = TRUE;
1892                         head = navigation_findnearestwaypoint(player, FALSE);
1893                         //navigation_testtracewalk = FALSE;
1894                         if (head)
1895                         {
1896                                 w = head     ;if (w) te_lightning2(world, w.origin, player.origin);
1897                                 w = head.wp00;if (w) te_lightning2(world, w.origin, head.origin);
1898                                 w = head.wp01;if (w) te_lightning2(world, w.origin, head.origin);
1899                                 w = head.wp02;if (w) te_lightning2(world, w.origin, head.origin);
1900                                 w = head.wp03;if (w) te_lightning2(world, w.origin, head.origin);
1901                                 w = head.wp04;if (w) te_lightning2(world, w.origin, head.origin);
1902                                 w = head.wp05;if (w) te_lightning2(world, w.origin, head.origin);
1903                                 w = head.wp06;if (w) te_lightning2(world, w.origin, head.origin);
1904                                 w = head.wp07;if (w) te_lightning2(world, w.origin, head.origin);
1905                                 w = head.wp08;if (w) te_lightning2(world, w.origin, head.origin);
1906                                 w = head.wp09;if (w) te_lightning2(world, w.origin, head.origin);
1907                                 w = head.wp10;if (w) te_lightning2(world, w.origin, head.origin);
1908                                 w = head.wp11;if (w) te_lightning2(world, w.origin, head.origin);
1909                                 w = head.wp12;if (w) te_lightning2(world, w.origin, head.origin);
1910                                 w = head.wp13;if (w) te_lightning2(world, w.origin, head.origin);
1911                                 w = head.wp14;if (w) te_lightning2(world, w.origin, head.origin);
1912                                 w = head.wp15;if (w) te_lightning2(world, w.origin, head.origin);
1913                                 w = head.wp16;if (w) te_lightning2(world, w.origin, head.origin);
1914                                 w = head.wp17;if (w) te_lightning2(world, w.origin, head.origin);
1915                                 w = head.wp18;if (w) te_lightning2(world, w.origin, head.origin);
1916                                 w = head.wp19;if (w) te_lightning2(world, w.origin, head.origin);
1917                                 w = head.wp20;if (w) te_lightning2(world, w.origin, head.origin);
1918                                 w = head.wp21;if (w) te_lightning2(world, w.origin, head.origin);
1919                                 w = head.wp22;if (w) te_lightning2(world, w.origin, head.origin);
1920                                 w = head.wp23;if (w) te_lightning2(world, w.origin, head.origin);
1921                                 w = head.wp24;if (w) te_lightning2(world, w.origin, head.origin);
1922                                 w = head.wp25;if (w) te_lightning2(world, w.origin, head.origin);
1923                                 w = head.wp26;if (w) te_lightning2(world, w.origin, head.origin);
1924                                 w = head.wp27;if (w) te_lightning2(world, w.origin, head.origin);
1925                                 w = head.wp28;if (w) te_lightning2(world, w.origin, head.origin);
1926                                 w = head.wp29;if (w) te_lightning2(world, w.origin, head.origin);
1927                                 w = head.wp30;if (w) te_lightning2(world, w.origin, head.origin);
1928                                 w = head.wp31;if (w) te_lightning2(world, w.origin, head.origin);
1929                         }
1930                 }
1931                 player = find(player, classname, "player");
1932         }
1933 };
1934
1935 entity botframe_dangerwaypoint;
1936 void() botframe_updatedangerousobjects =
1937 {
1938         local entity head, bot_dodgelist;
1939         local vector m1, m2, v;
1940         local float c, d, danger;
1941         c = 0;
1942         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
1943         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
1944         while (botframe_dangerwaypoint != world)
1945         {
1946                 danger = 0;
1947                 m1 = botframe_dangerwaypoint.mins;
1948                 m2 = botframe_dangerwaypoint.maxs;
1949                 head = bot_dodgelist;
1950                 while (head)
1951                 {
1952                         v = head.origin;
1953                         v_x = bound(m1_x, v_x, m2_x);
1954                         v_y = bound(m1_y, v_y, m2_y);
1955                         v_z = bound(m1_z, v_z, m2_z);
1956                         d = head.bot_dodgerating - vlen(head.origin - v);
1957                         if (d > 0)
1958                         {
1959                                 traceline(head.origin, v, TRUE, world);
1960                                 if (trace_fraction == 1)
1961                                         danger = danger + d;
1962                         }
1963                         head = head.chain;
1964                 }
1965                 botframe_dangerwaypoint.dmg = danger;
1966                 c = c + 1;
1967                 if (c >= 256)
1968                         break;
1969                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
1970         }
1971 };
1972
1973
1974 float botframe_spawnedwaypoints;
1975 void() bot_serverframe =
1976 {
1977         float realplayers, bots;
1978
1979         if (intermission_running)
1980                 return;
1981
1982         if (time < 2)
1983                 return;
1984
1985         realplayers = player_count - currentbots;
1986
1987         // add/remove bots if needed to make sure there are at least
1988         // minplayers+bot_number, or remove all bots if no one is playing
1989         // But don't remove bots immediately on level change, as the real players
1990         // usually haven't rejoined yet
1991         if (realplayers || cvar("bot_join_empty") || (currentbots > 0 && time < 5))
1992         {
1993                 float realminplayers, minplayers;
1994                 realminplayers = cvar("minplayers");
1995                 minplayers = bound(0, floor(realminplayers), maxclients - 1);
1996                 if (realminplayers != minplayers)
1997                         cvar_set("minplayers", ftos(minplayers));
1998
1999                 float realminbots, minbots;
2000                 realminbots = cvar("bot_number");
2001                 minbots = bound(0, floor(realminbots), maxclients - 1);
2002                 if (realminbots != minbots)
2003                         cvar_set("bot_number", ftos(minbots));
2004
2005                 bots = bound(minbots, minplayers - realplayers, maxclients);
2006         }
2007         else
2008         {
2009                 // if there are no players, remove bots
2010                 bots = 0;
2011         }
2012
2013         bot_ignore_bots = cvar("bot_ignore_bots");
2014
2015         // only add one bot per frame to avoid utter chaos
2016         while (currentbots < bots)
2017         {
2018                 if (bot_spawn() == world)
2019                 {
2020                         bprint("Can not add bot, server full.\n");
2021                         cvar_set("bot_number", ftos(currentbots));
2022                         bots = currentbots;
2023                         break;
2024                 }
2025         }
2026         while (currentbots > bots)
2027                 bot_removenewest();
2028
2029         if(botframe_spawnedwaypoints)
2030         {
2031                 if(cvar("waypoint_benchmark"))
2032                         localcmd("quit\n");
2033         }
2034
2035         if (bots > 0 || cvar("g_waypointeditor"))
2036         if (!botframe_spawnedwaypoints)
2037         {
2038                 botframe_spawnedwaypoints = TRUE;
2039                 waypoint_loadall();
2040                 waypoint_schedulerelinkall();
2041         }
2042
2043         if (bot_list)
2044         {
2045                 // cycle the goal token from one bot to the next each frame
2046                 // (this prevents them from all doing waypoint searches on the same
2047                 //  frame, which causes choppy framerates)
2048                 if (bot_strategytoken)
2049                         bot_strategytoken = bot_strategytoken.nextbot;
2050                 if (!bot_strategytoken)
2051                         bot_strategytoken = bot_list;
2052
2053                 botframe_updatedangerousobjects();
2054         }
2055
2056         if (cvar("g_waypointeditor"))
2057                 botframe_showwaypointlinks();
2058 };