data/qcsrc/server/arena.qc

   1 float maxspawned;
   2 float numspawned;
   3 float arena_roundbased;
   4 .float spawned;
   5 .entity spawnqueue_next;
   6 .entity spawnqueue_prev;
   7 .float spawnqueue_in;
   8 entity spawnqueue_first;
   9 entity spawnqueue_last;
  10 entity champion;
  11 float warmup;
  12
  13 void PutObserverInServer();
  14 void PutClientInServer();
  15 void(entity e) DropFlag;
  16 void(entity e) ReturnFlag;
  17 void(entity e) removedecor;
  18 void dom_controlpoint_setup();
  19
  20 void reset_map()
  21 {
  22         if(g_arena)
  23         if(cvar("g_arena_warmup"))
  24                 warmup = time + cvar("g_arena_warmup");
  25
  26         lms_lowest_lives = 999;
  27         lms_next_place = player_count;
  28
  29         self = nextent(world);
  30         while(self)
  31         {
  32                 if(self.flags & FL_CLIENT)                              // reset all players
  33                 {
  34                         if(time < restart_countdown)
  35                         {
  36                                 self.frags = (g_lms)?LMS_NewPlayerLives():0;
  37                                 self.deaths = 0;
  38                                 self.killcount = 0;
  39                                 self.classname = "player";
  40                                 PutClientInServer();
  41                         }
  42                         else if(g_arena)
  43                         {
  44                                 if(self.spawned)
  45                                         PutClientInServer();
  46                                 else
  47                                         PutObserverInServer();
  48                         }
  49                 }
  50                 else if(self.classname == STR_ITEM_KH_KEY)
  51                 {
  52                         kh_Key_AssignTo(self, world);
  53                         //if(self.owner)
  54                         //      kh_Key_DropAll(self.owner, TRUE);
  55                         kh_Key_Remove(self);
  56                 }
  57                 else if(self.classname == "droppedweapon"               // cleanup
  58                                 || self.classname == "gib"
  59                                 || self.classname == "body")
  60                 {
  61                         remove(self);
  62                 }
  63                 else if(self.items & (IT_KEY1 | IT_KEY2))
  64                 {
  65                         DropFlag(self);
  66                         ReturnFlag(self);
  67                 }
  68                 else if(self.classname == "rune")
  69                 {
  70                         if(self.owner)
  71                         if(self.owner.classname != "runematch_spawn_point")
  72                                 DropAllRunes(self.owner);
  73                         rune_respawn();
  74                 }
  75                 else if(self.classname == "sprite_waypoint")
  76                 {
  77                         if(self.health | g_keyhunt)
  78                                 WaypointSprite_Kill(self);
  79                 }
  80                 else if(self.classname == "dom_controlpoint")
  81                 {
  82                         dom_controlpoint_setup();
  83                 }
  84                 else if(self.flags & FL_ITEM)                   // reset items
  85                 {
  86                         self.model = self.mdl;
  87                         self.solid = SOLID_TRIGGER;
  88                         setorigin (self, self.origin);
  89                         self.think = SUB_Null;
  90                         self.nextthink = 0;
  91                         self.effects = self.effects - (self.effects & EF_STARDUST);
  92                 }
  93                 else if(self.flags & FL_PROJECTILE)             // remove any projectiles left
  94                 {
  95                         sound(self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  96                         remove(self);
  97                 }
  98                 else if(self.isdecor)
  99                 {
 100                         removedecor(self);
 101                 }
 102                 self = nextent(self);
 103         }
 104
 105         if(g_keyhunt)
 106                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round")+RESTART_COUNTDOWN, "", kh_StartRound);
 107
 108         if(g_arena)
 109         if(champion)
 110                 UpdateFrags(champion, +1);
 111 }
 112
 113 void Spawnqueue_Insert(entity e)
 114 {
 115         if(e.spawnqueue_in)
 116                 return;
 117         dprint(strcat("Into queue: ", e.netname, "\n"));
 118         e.spawnqueue_in = TRUE;
 119         e.spawnqueue_prev = spawnqueue_last;
 120         e.spawnqueue_next = world;
 121         if(spawnqueue_last)
 122                 spawnqueue_last.spawnqueue_next = e;
 123         spawnqueue_last = e;
 124         if(!spawnqueue_first)
 125                 spawnqueue_first = e;
 126 }
 127
 128 void Spawnqueue_Remove(entity e)
 129 {
 130         if(!e.spawnqueue_in)
 131                 return;
 132         dprint(strcat("Out of queue: ", e.netname, "\n"));
 133         e.spawnqueue_in = FALSE;
 134         if(e == spawnqueue_first)
 135                 spawnqueue_first = e.spawnqueue_next;
 136         if(e == spawnqueue_last)
 137                 spawnqueue_last = e.spawnqueue_prev;
 138         if(e.spawnqueue_prev)
 139                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
 140         if(e.spawnqueue_next)
 141                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
 142         e.spawnqueue_next = world;
 143         e.spawnqueue_prev = world;
 144 }
 145
 146 void Spawnqueue_Unmark(entity e)
 147 {
 148         if(!e.spawned)
 149                 return;
 150         e.spawned = FALSE;
 151         numspawned = numspawned - 1;
 152 }
 153
 154 void Spawnqueue_Mark(entity e)
 155 {
 156         if(e.spawned)
 157                 return;
 158         e.spawned = TRUE;
 159         numspawned = numspawned + 1;
 160 }
 161
 162 void Arena_Warmup()
 163 {
 164         float f;
 165         string msg;
 166
 167         if(!g_arena || !arena_roundbased || (time < restart_countdown))
 168                 return;
 169
 170         f = rint(warmup - time);
 171
 172         msg = NEWLINES;
 173         if(time < warmup && self.spawned)
 174         {
 175                 if(champion)
 176                         msg = strcat(msg, "The Champion is ", champion.netname, "^7\n\n\n");
 177
 178                 if(f)
 179                         msg = strcat(msg, "Round will start in ", ftos(f));
 180                 else
 181                 {
 182                         if(self.spawned)
 183                                 msg = strcat(msg, "^1Fight!");
 184                 }
 185
 186                 centerprint(self, msg);
 187
 188                 if(self.spawned)
 189                         self.movetype = MOVETYPE_NONE;
 190
 191                 self.velocity = '0 0 0';
 192                 self.avelocity = '0 0 0';
 193                 self.movement = '0 0 0';
 194                 //self.fixangle = TRUE;
 195         }
 196         else if(self.movetype == MOVETYPE_NONE)
 197         {
 198                 self.movetype = MOVETYPE_WALK;
 199                 centerprint(self, "\n");
 200         }
 201
 202 }
 203
 204 float next_round;
 205 void Spawnqueue_Check()
 206 {
 207         if(time < warmup + 1)
 208                 return;
 209
 210         if(!next_round)
 211         if(numspawned < 2)
 212                 next_round = time + 3;
 213
 214         if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
 215         {
 216                 next_round = 0;
 217
 218                 if(arena_roundbased)
 219                 {
 220                         champion = find(world, classname, "player");
 221                         while(champion && champion.deadflag)
 222                                 champion = find(champion, classname, "player");
 223                         reset_map();
 224                 }
 225
 226                 while(numspawned < maxspawned && spawnqueue_first)
 227                 {
 228                         self = spawnqueue_first;
 229
 230                         bprint ("^4", self.netname, "^4 is the next challenger\n");
 231
 232                         Spawnqueue_Remove(self);
 233                         Spawnqueue_Mark(self);
 234
 235                         self.classname = "player";
 236                         PutClientInServer();
 237                 }
 238         }
 239 }