data/qcsrc/menu-div0test/item/label.c

   1 #ifdef INTERFACE
   2 CLASS(Label) EXTENDS(Item)
   3         METHOD(Label, configureLabel, void(entity, string, float, float))
   4         METHOD(Label, draw, void(entity))
   5         METHOD(Label, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(Label, setText, void(entity, string))
   7         ATTRIB(Label, text, string, "Big Red Button")
   8         ATTRIB(Label, fontSize, float, 8)
   9         ATTRIB(Label, align, float, 0.5)
  10         ATTRIB(Label, keepspaceLeft, float, 0) // for use by subclasses (radiobuttons for example)
  11         ATTRIB(Label, keepspaceRight, float, 0)
  12         ATTRIB(Label, realFontSize, vector, '0 0 0')
  13         ATTRIB(Label, realOrigin, vector, '0 0 0')
  14         ATTRIB(Label, alpha, float, 0.7)
  15 ENDCLASS(Label)
  16 #endif
  17
  18 #ifdef IMPLEMENTATION
  19 void setTextLabel(entity me, string txt)
  20 {
  21         me.text = txt;
  22         me.realOrigin_x = me.align * (1 - me.realFontSize_x * draw_TextWidth(me.text));
  23 }
  24 void resizeNotifyLabel(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  25 {
  26         // absSize_y is height of label
  27         me.realFontSize_y = me.fontSize / absSize_y;
  28         me.realFontSize_x = me.fontSize / absSize_x;
  29         me.realOrigin_x = me.align * (1 - me.keepspaceLeft - me.keepspaceRight - me.realFontSize_x * draw_TextWidth(me.text)) + me.keepspaceLeft;
  30         me.realOrigin_y = 0.5 * (1 - me.realFontSize_y);
  31 }
  32 void configureLabelLabel(entity me, string txt, float sz, float algn)
  33 {
  34         me.fontSize = sz;
  35         me.align = algn;
  36         me.setText(me, txt);
  37 }
  38 void drawLabel(entity me)
  39 {
  40         if(me.text)
  41                 draw_Text(me.realOrigin, me.text, me.realFontSize, '1 1 1', me.alpha);
  42 }
  43 #endif