data/qcsrc/menu/nexuiz/demolist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizDemoList) EXTENDS(NexuizListBox)
   3     METHOD(NexuizDemoList, configureNexuizDemoList, void(entity))
   4     ATTRIB(NexuizDemoList, rowsPerItem, float, 1)
   5     METHOD(NexuizDemoList, resizeNotify, void(entity, vector, vector, vector, vector))
   6     METHOD(NexuizDemoList, drawListBoxItem, void(entity, float, vector, float))
   7     METHOD(NexuizDemoList, getDemos, void(entity))
   8     METHOD(NexuizDemoList, startDemo, void(entity))
   9     METHOD(NexuizDemoList, demoName, string(entity, float))
  10     METHOD(NexuizDemoList, clickListBoxItem, void(entity, float, vector))
  11     METHOD(NexuizDemoList, keyDown, float(entity, float, float, float))
  12     METHOD(NexuizDemoList, destroy, void(entity))
  13     METHOD(NexuizDemoList, showNotify, void(entity))
  14     ATTRIB(NexuizDemoList, listDemo, float, -1)
  15     ATTRIB(NexuizDemoList, realFontSize, vector, '0 0 0')
  16     ATTRIB(NexuizDemoList, columnNameOrigin, float, 0)
  17     ATTRIB(NexuizDemoList, columnNameSize, float, 0)
  18     ATTRIB(NexuizDemoList, realUpperMargin, float, 0)
  19     ATTRIB(NexuizDemoList, origin, vector, '0 0 0')
  20     ATTRIB(NexuizDemoList, itemAbsSize, vector, '0 0 0')
  21     ATTRIB(NexuizDemoList, lastClickedDemo, float, -1)
  22     ATTRIB(NexuizDemoList, lastClickedTime, float, 0)
  23     ATTRIB(NexuizDemoList, filterString, string, string_null)
  24 ENDCLASS(NexuizDemoList)
  25
  26 entity makeNexuizDemoList();
  27 void StartDemo_Click(entity btn, entity me);
  28 void TimeDemo_Click(entity btn, entity me);
  29 void DemoList_Filter_Change(entity box, entity me);
  30 #endif
  31
  32 #ifdef IMPLEMENTATION
  33
  34 entity makeNexuizDemoList()
  35 {
  36     entity me;
  37     me = spawnNexuizDemoList();
  38     me.configureNexuizDemoList(me);
  39     return me;
  40 }
  41
  42 void configureNexuizDemoListNexuizDemoList(entity me)
  43 {
  44     me.configureNexuizListBox(me);
  45     me.getDemos(me);
  46 }
  47
  48 string demoNameNexuizDemoList(entity me, float i )
  49 {
  50     string s;
  51     s = search_getfilename(me.listDemo, i);
  52     s = substring(s, 6, strlen(s) - 6 - 4);  // demos/, .dem
  53     return s;
  54 }
  55
  56
  57 void getDemosNexuizDemoList(entity me)
  58 {
  59     string s;
  60
  61     if(me.filterString)
  62         //subdirectory in filterString allowed
  63         s=strcat("demos/*", me.filterString, "*.dem");
  64     else
  65         s="demos/*.dem";
  66
  67     //dprint("Search demos with the pattern ", s, "\n");
  68     me.listDemo = search_begin(s, FALSE, TRUE);
  69     if(me.listDemo < 0)
  70         me.nItems=0;
  71     else
  72         me.nItems=search_getsize(me.listDemo);
  73 }
  74
  75 void destroyNexuizDemoList(entity me)
  76 {
  77     search_end(me.listDemo);
  78 }
  79
  80 void resizeNotifyNexuizDemoList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  81 {
  82     me.origin = absOrigin;
  83     me.itemAbsSize = '0 0 0';
  84     resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
  85
  86     me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  87     me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  88     me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  89
  90     me.columnNameOrigin = me.realFontSize_x;
  91     me.columnNameSize = 1 - 2 * me.realFontSize_x;
  92 }
  93
  94 void drawListBoxItemNexuizDemoList(entity me, float i, vector absSize, float isSelected)
  95 {
  96     string s;
  97     if(isSelected)
  98         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  99
 100     s = me.demoName(me,i);
 101     s = draw_TextShortenToWidth(s, me.columnNameSize / me.realFontSize_x, 0);
 102     draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 103 }
 104
 105 void showNotifyNexuizDemoList(entity me)
 106 {
 107     me.getDemos(me);
 108 }
 109
 110 void DemoList_Filter_Change(entity box, entity me)
 111 {
 112     if(me.filterString)
 113         strunzone(me.filterString);
 114
 115     if(box.text != "")
 116         me.filterString = strzone(box.text);
 117     else
 118         me.filterString = string_null;
 119
 120     me.getDemos(me);
 121 }
 122
 123 void startDemoNexuizDemoList(entity me)
 124 {
 125     string s;
 126     s = me.demoName(me,me.selectedItem);
 127     localcmd("playdemo demos/", s, ".dem\nwait\ntogglemenu\n");
 128 }
 129
 130 void StartDemo_Click(entity btn, entity me)
 131 {
 132     me.startDemo(me);
 133 }
 134
 135 void TimeDemo_Click(entity btn, entity me)
 136 {
 137     string s;
 138     s = me.demoName(me,me.selectedItem);
 139     localcmd("timedemo demos/", s, ".dem\nwait\ntogglemenu\n");
 140 }
 141
 142 void clickListBoxItemNexuizDemoList(entity me, float i, vector where)
 143 {
 144     if(i == me.lastClickedDemo)
 145         if(time < me.lastClickedTime + 0.3)
 146         {
 147             // DOUBLE CLICK!
 148             me.setSelected(me, i);
 149             me.startDemo(me);
 150         }
 151     me.lastClickedDemo = i;
 152     me.lastClickedTime = time;
 153 }
 154
 155 float keyDownNexuizDemoList(entity me, float scan, float ascii, float shift)
 156 {
 157     if(scan == K_ENTER) {
 158         me.startDemo(me);
 159         return 1;
 160     }
 161     else
 162         return keyDownListBox(me, scan, ascii, shift);
 163 }
 164 #endif
 165