data/qcsrc/menu/nexuiz/campaign.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizCampaignList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizCampaignList, configureNexuizCampaignList, void(entity))
   4         ATTRIB(NexuizCampaignList, rowsPerItem, float, 10)
   5         METHOD(NexuizCampaignList, draw, void(entity))
   6         METHOD(NexuizCampaignList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizCampaignList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizCampaignList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizCampaignList, setSelected, void(entity, float))
  10         METHOD(NexuizCampaignList, keyDown, float(entity, float, float, float))
  11         METHOD(NexuizCampaignList, campaignGo, void(entity, float))
  12
  13         ATTRIB(NexuizCampaignList, campaignGlob, float, 0)
  14         ATTRIB(NexuizCampaignList, realFontSize, vector, '0 0 0')
  15         ATTRIB(NexuizCampaignList, columnPreviewOrigin, float, 0)
  16         ATTRIB(NexuizCampaignList, columnPreviewSize, float, 0)
  17         ATTRIB(NexuizCampaignList, columnNameOrigin, float, 0)
  18         ATTRIB(NexuizCampaignList, columnNameSize, float, 0)
  19         ATTRIB(NexuizCampaignList, columnCheckMarkOrigin, float, 0)
  20         ATTRIB(NexuizCampaignList, columnCheckMarkSize, float, 0)
  21         ATTRIB(NexuizCampaignList, checkMarkOrigin, vector, '0 0 0')
  22         ATTRIB(NexuizCampaignList, checkMarkSize, vector, '0 0 0')
  23         ATTRIB(NexuizCampaignList, realUpperMargin1, float, 0)
  24         ATTRIB(NexuizCampaignList, realUpperMargin2, float, 0)
  25
  26         ATTRIB(NexuizCampaignList, lastClickedMap, float, -1)
  27         ATTRIB(NexuizCampaignList, lastClickedTime, float, 0)
  28
  29         ATTRIB(NexuizCampaignList, origin, vector, '0 0 0')
  30         ATTRIB(NexuizCampaignList, itemAbsSize, vector, '0 0 0')
  31         ATTRIB(NexuizCampaignList, emptyLineHeight, float, 0.5)
  32
  33         ATTRIB(NexuizCampaignList, campaignIndex, float, 0)
  34         ATTRIB(NexuizCampaignList, cvarName, string, string_null)
  35         METHOD(NexuizCampaignList, loadCvars, void(entity))
  36         METHOD(NexuizCampaignList, saveCvars, void(entity))
  37
  38         ATTRIB(NexuizCampaignList, buttonNext, entity, NULL)
  39         ATTRIB(NexuizCampaignList, buttonPrev, entity, NULL)
  40         ATTRIB(NexuizCampaignList, labelTitle, entity, NULL)
  41 ENDCLASS(NexuizCampaignList)
  42 entity makeNexuizCampaignList();
  43 void CampaignList_LoadMap(entity btn, entity me);
  44 void MultiCampaign_Next(entity btn, entity me);
  45 void MultiCampaign_Prev(entity btn, entity me);
  46 #endif
  47
  48 #ifdef IMPLEMENTATION
  49 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
  50
  51 void rewrapCampaign(float w, float l0, float emptyheight)
  52 {
  53         float i, j;
  54         float n, take, cantake, l;
  55         string r, s;
  56         for(i = 0; i < campaign_entries; ++i)
  57         {
  58                 l = l0;
  59                 if(campaign_longdesc_wrapped[i])
  60                         strunzone(campaign_longdesc_wrapped[i]);
  61                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  62                 r = "";
  63                 for(j = 0; j < n; ++j)
  64                 {
  65                         s = argv(j);
  66                         if(s == "")
  67                         {
  68                                 l -= emptyheight;
  69                                 r = strcat(r, "\n");
  70                                 continue;
  71                         }
  72                         for(;;)
  73                         {
  74                                 cantake = draw_TextLengthUpToWidth(s, w, 0);
  75                                 if(cantake > 0 && cantake < strlen(s))
  76                                 {
  77                                         take = cantake - 1;
  78                                         while(take > 0 && substring(s, take, 1) != " ")
  79                                                 --take;
  80                                         if(take == 0)
  81                                         {
  82                                                 if(--l < 0) goto toolong;
  83                                                 r = strcat(r, substring(s, 0, cantake), "\n");
  84                                                 s = substring(s, cantake, strlen(s) - cantake);
  85                                         }
  86                                         else
  87                                         {
  88                                                 if(--l < 0) goto toolong;
  89                                                 r = strcat(r, substring(s, 0, take), "\n");
  90                                                 s = substring(s, take + 1, strlen(s) - take);
  91                                         }
  92                                 }
  93                                 else
  94                                 {
  95                                         if(--l < 0) goto toolong;
  96                                         r = strcat(r, s, "\n");
  97                                         break;
  98                                 }
  99                         }
 100                 }
 101                 goto nottoolong;
 102 :toolong
 103                 while(substring(r, strlen(r) - 1, 1) == "\n")
 104                         r = substring(r, 0, strlen(r) - 1);
 105                 r = strcat(r, "...\n");
 106 :nottoolong
 107                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
 108         }
 109 }
 110
 111 entity makeNexuizCampaignList()
 112 {
 113         entity me;
 114         me = spawnNexuizCampaignList();
 115         me.configureNexuizCampaignList(me);
 116         return me;
 117 }
 118 void configureNexuizCampaignListNexuizCampaignList(entity me)
 119 {
 120         me.configureNexuizListBox(me);
 121         me.campaignGlob = search_begin("maps/campaign*.txt", TRUE, TRUE);
 122         me.loadCvars(me);
 123         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
 124 }
 125
 126 void loadCvarsNexuizCampaignList(entity me)
 127 {
 128         // read campaign cvars
 129         if(campaign_name)
 130                 strunzone(campaign_name);
 131         if(me.cvarName)
 132                 strunzone(me.cvarName);
 133         campaign_name = strzone(cvar_string("g_campaign_name"));
 134         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
 135         registercvar(me.cvarName, "", 0); // saved by server QC anyway
 136         CampaignFile_Unload();
 137         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
 138         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
 139         cvar_set(me.cvarName, ftos(me.campaignIndex));
 140         if(me.columnNameSize)
 141                 rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 142         me.nItems = min(me.campaignIndex + 2, campaign_entries);
 143         me.selectedItem = min(me.campaignIndex, me.nItems - 1);
 144         me.scrollPos = me.nItems * me.itemHeight - 1;
 145         if(me.labelTitle)
 146                 me.labelTitle.setText(me.labelTitle, campaign_title);
 147 }
 148
 149 void saveCvarsNexuizCampaignList(entity me)
 150 {
 151         // write campaign cvars
 152         // no reason to do this!
 153         // cvar_set("g_campaign_name", campaign_name);
 154         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 155 }
 156
 157 void campaignGoNexuizCampaignList(entity me, float step)
 158 {
 159         float canNext, canPrev;
 160         string s;
 161         float i, j, n;
 162
 163         canNext = canPrev = 0;
 164
 165         if(me.campaignGlob >= 0)
 166         {
 167                 n = search_getsize(me.campaignGlob);
 168                 if(n > 0)
 169                 {
 170                         j = -1;
 171                         s = strcat("maps/campaign", campaign_name, ".txt");
 172                         for(i = 0; i < n; ++i)
 173                         {
 174                                 if(search_getfilename(me.campaignGlob, i) == s)
 175                                         j = i;
 176                         }
 177                         if(j < 0)
 178                         {
 179                                 if(step >= 0)
 180                                         j = 0;
 181                                 else
 182                                         j = n - 1;
 183                         }
 184                         else
 185                                 j = mod(j + step, n);
 186                         s = search_getfilename(me.campaignGlob, j);
 187                         print(s, "\n");
 188                         s = substring(s, 13, strlen(s) - 17);
 189                         cvar_set("g_campaign_name", s);
 190                         me.loadCvars(me);
 191                         canNext = (j != n - 1);
 192                         canPrev = (j != 0);
 193                 }
 194         }
 195
 196         if(me.buttonNext)
 197                 me.buttonNext.disabled = !canNext;
 198         if(me.buttonPrev)
 199                 me.buttonPrev.disabled = !canPrev;
 200 }
 201
 202 void MultiCampaign_Next(entity btn, entity me)
 203 {
 204         me.campaignGo(me, +1);
 205 }
 206 void MultiCampaign_Prev(entity btn, entity me)
 207 {
 208         me.campaignGo(me, -1);
 209 }
 210
 211 void drawNexuizCampaignList(entity me)
 212 {
 213         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 214                 me.loadCvars(me);
 215         drawListBox(me);
 216 }
 217
 218 void resizeNotifyNexuizCampaignList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 219 {
 220         me.origin = absOrigin;
 221         me.itemAbsSize = '0 0 0';
 222         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 223
 224         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 225         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 226         me.realUpperMargin1 = 0.5 * me.realFontSize_y;
 227         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize_y;
 228
 229         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 230
 231         me.columnPreviewOrigin = 0;
 232         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 233         me.columnCheckMarkSize = me.checkMarkSize_x;
 234         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize_x;
 235         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 236         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize_x * 2;
 237
 238         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 239
 240         rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 241 }
 242 void clickListBoxItemNexuizCampaignList(entity me, float i, vector where)
 243 {
 244         if(i == me.lastClickedMap)
 245                 if(time < me.lastClickedTime + 0.3)
 246                 {
 247                         // DOUBLE CLICK!
 248                         // start game
 249                         CampaignList_LoadMap(me, me);
 250                         return;
 251                 }
 252         me.lastClickedMap = i;
 253         me.lastClickedTime = time;
 254 }
 255 void drawListBoxItemNexuizCampaignList(entity me, float i, vector absSize, float isSelected)
 256 {
 257         string s;
 258         float p;
 259         vector theColor;
 260         float theAlpha;
 261         float j, n;
 262         vector o;
 263
 264         if(i < me.campaignIndex)
 265         {
 266                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 267                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 268         }
 269         else if(i == me.campaignIndex)
 270         {
 271                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 272                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 273         }
 274         else
 275         {
 276                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 277                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 278         }
 279
 280         if(isSelected)
 281                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 282
 283         s = ftos(p);
 284         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 285         if(i < me.campaignIndex)
 286                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 287         if(i <= me.campaignIndex)
 288                 s = campaign_shortdesc[i]; // fteqcc sucks
 289         else
 290                 s = "???";
 291         s = draw_TextShortenToWidth(strcat("Level ", ftos(i + 1), ": ", s), me.columnNameSize / me.realFontSize_x, 0);
 292         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 293
 294         if(i <= me.campaignIndex)
 295         {
 296                 s = campaign_longdesc_wrapped[i];
 297                 n = tokenizebyseparator(s, "\n");
 298                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 299                 for(j = 0; j < n; ++j)
 300                         if(argv(j) != "")
 301                         {
 302                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 303                                 o_y += me.realFontSize_y;
 304                         }
 305                         else
 306                                 o_y += me.realFontSize_y * me.emptyLineHeight;
 307         }
 308 }
 309 void CampaignList_LoadMap(entity btn, entity me)
 310 {
 311         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 312                 return;
 313         CampaignSetup(me.selectedItem);
 314 }
 315
 316 void setSelectedNexuizCampaignList(entity me, float i)
 317 {
 318         // prevent too late items from being played
 319         setSelectedListBox(me, min(i, me.campaignIndex));
 320 }
 321
 322 float keyDownNexuizCampaignList(entity me, float scan, float ascii, float shift)
 323 {
 324         if(scan == K_ENTER || scan == K_SPACE)
 325                 CampaignList_LoadMap(me, me);
 326         else
 327                 return keyDownListBox(me, scan, ascii, shift);
 328         return 1;
 329 }
 330 #endif