data/qcsrc/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 float spawn_goodspots, spawn_badspots;
  11 entity Spawn_ClassifyPoints(entity firstspot, entity playerlist, float mindist, float goodspotnum, float badspotnum)
  12 {
  13         local entity spot, player;
  14         local float pcount;
  15         spawn_goodspots = 0;
  16         spawn_badspots = 0;
  17         spot = firstspot;
  18         while (spot)
  19         {
  20                 pcount = 0;
  21                 player = playerlist;
  22                 while (player)
  23                 {
  24                         if (player != self)
  25                         if (vlen(player.origin - spot.origin) < 100)
  26                                 pcount = pcount + 1;
  27                         player = player.chain;
  28                 }
  29                 if (pcount)
  30                 {
  31                         if (spawn_goodspots >= badspotnum)
  32                                 return spot;
  33                         spawn_badspots = spawn_badspots + 1;
  34                 }
  35                 else
  36                 {
  37                         if (spawn_goodspots >= goodspotnum)
  38                                 return spot;
  39                         spawn_goodspots = spawn_goodspots + 1;
  40                 }
  41                 spot = find(spot, classname, "info_player_deathmatch");
  42         }
  43         return firstspot;
  44 }
  45
  46 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  47 {
  48         local entity best, spot, player;
  49         local float bestrating, rating;
  50         best = world;
  51         bestrating = -1000000;
  52         spot = firstspot;
  53         while (spot)
  54         {
  55                 rating = 1000000000;
  56                 player = playerlist;
  57                 while (player)
  58                 {
  59                         if (player != self)
  60                                 rating = min(rating, vlen(player.origin - spot.origin));
  61                         player = player.chain;
  62                 }
  63                 rating = rating + random() * 16;
  64                 if (bestrating < rating)
  65                 {
  66                         best = spot;
  67                         bestrating = rating;
  68                 }
  69                 spot = find(spot, classname, "info_player_deathmatch");
  70         }
  71         return best;
  72 }
  73
  74 /*
  75 =============
  76 SelectSpawnPoint
  77
  78 Finds a point to respawn
  79 =============
  80 */
  81 entity SelectSpawnPoint (float anypoint)
  82 {
  83         local entity spot, firstspot, playerlist;
  84         string spotname;
  85
  86         spot = find (world, classname, "testplayerstart");
  87         if (spot)
  88                 return spot;
  89
  90         spotname = "info_player_deathmatch";
  91
  92         if(!anypoint && cvar("g_ctf") )
  93         {
  94                 if(self.team == 5)//4)
  95                         spotname = "info_player_team1";
  96                 if(self.team == 14)//13)
  97                         spotname = "info_player_team2";
  98                 if(self.team == 4)//3)
  99                         spotname = "info_player_team3";
 100                 if(self.team == 13)//12)
 101                         spotname = "info_player_team4";
 102         }
 103
 104         playerlist = findchain(classname, "player");
 105         firstspot = find(world, classname, spotname);
 106         Spawn_ClassifyPoints(firstspot, playerlist, 100, 1000000, 1000000);
 107         // first check if there are ANY good spots
 108         if (spawn_goodspots > 0)
 109         {
 110                 // good spots exist, there is 50/50 chance of choosing a random good
 111                 // spot or the furthest spot
 112                 // (this means that roughly every other spawn will be furthest, so you
 113                 // usually won't get fragged at spawn twice in a row)
 114                 if (random() > 0.5)
 115                         spot = Spawn_ClassifyPoints(firstspot, playerlist, 100, min(floor(random() * spawn_goodspots), spawn_goodspots - 1), 1000000);
 116                 else
 117                         spot = Spawn_FurthestPoint(firstspot, playerlist);
 118         }
 119         else
 120         {
 121                 // no good spots exist, pick a random bad spot
 122                 spot = Spawn_ClassifyPoints(firstspot, playerlist, 100, 1000000, min(floor(random() * spawn_badspots), spawn_badspots - 1));
 123         }
 124
 125         if (!spot)
 126         {
 127                 if(anypoint)
 128                         error ("PutClientInServer: no start points on level");
 129                 else // try again with deathmatch spots
 130                         spot = SelectSpawnPoint(TRUE);
 131         }
 132
 133         return spot;
 134 }
 135
 136 /*
 137 =============
 138 CheckPlayerModel
 139
 140 Checks if the argument string can be a valid playermodel.
 141 Returns a valid one in doubt.
 142 =============
 143 */
 144 string CheckPlayerModel(string plyermodel) {
 145         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 146
 147         /* Possible Fixme: Check if server can open the model?
 148            This would kill custom models, however. */
 149
 150         return plyermodel;
 151 }
 152
 153 /*
 154 =============
 155 PutObserverInServer
 156
 157 putting a client as observer in the server
 158 =============
 159 */
 160 void PutObserverInServer (void)
 161 {
 162         entity  spot;
 163         spot = SelectSpawnPoint (FALSE);
 164         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 165
 166         if(self.frags == 0 && cvar("g_lms"))
 167                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 168         else if(self.killcount != -666)
 169                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 170
 171         self.classname = "observer";
 172         self.health = 666;
 173         self.takedamage = DAMAGE_NO;
 174         self.solid = SOLID_NOT;
 175         self.movetype = MOVETYPE_NOCLIP;
 176         self.armorvalue = 666;
 177         self.effects = 0;
 178         self.armorvalue = cvar("g_balance_armor_start");
 179         self.pauserotarmor_finished = 0;
 180         self.pauserothealth_finished = 0;
 181         self.pauseregen_finished = 0;
 182         self.damageforcescale = 0;
 183         self.death_time = 0;
 184         self.dead_time = 0;
 185         self.dead_frame = 0;
 186         self.die_frame = 0;
 187         self.alpha = 0;
 188         self.scale = 0;
 189         self.fade_time = 0;
 190         self.pain_frame = 0;
 191         self.pain_finished = 0;
 192         self.strength_finished = 0;
 193         self.invincible_finished = 0;
 194         self.pushltime = 0;
 195         self.vote_finished = 0;
 196         self.think = SUB_Null;
 197         self.nextthink = 0;
 198         self.hook_time = 0;
 199         self.runes = 0;
 200         self.deadflag = DEAD_NO;
 201         self.angles = spot.angles;
 202         self.angles_z = 0;
 203         self.fixangle = TRUE;
 204         self.crouch = FALSE;
 205         self.view_ofs = PL_VIEW_OFS;
 206         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 207         self.oldorigin = self.origin;
 208         self.items = 0;
 209         self.model = "";
 210         self.modelindex = 0;
 211         self.weapon = 0;
 212         self.weaponmodel = "";
 213         self.weaponframe = 0;
 214         self.weaponentity = world;
 215         self.killcount = -666;
 216         if(!cvar("g_lms"))
 217                 self.frags = -666;
 218         //stuffcmd(self, "set viewsize 120 \n");
 219 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 220 }
 221
 222
 223 /*
 224 =============
 225 PutClientInServer
 226
 227 Called when a client spawns in the server
 228 =============
 229 */
 230 void PutClientInServer (void)
 231 {
 232         if(clienttype(self) ==  CLIENTTYPE_BOT)
 233         {
 234                 self.classname = "player";
 235         }
 236
 237         // player is dead and becomes observer
 238         if(cvar("g_lms") && self.frags < 1)
 239                 self.classname = "observer";
 240
 241         if(self.classname == "player") {
 242                 entity  spot;
 243
 244                 spot = SelectSpawnPoint (FALSE);
 245
 246                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 247
 248                 self.classname = "player";
 249                 self.iscreature = TRUE;
 250                 self.movetype = MOVETYPE_WALK;
 251                 self.solid = SOLID_SLIDEBOX;
 252                 self.flags = FL_CLIENT;
 253                 self.takedamage = DAMAGE_AIM;
 254                 self.effects = 0;
 255                 self.health = cvar("g_balance_health_start");
 256                 self.armorvalue = cvar("g_balance_armor_start");
 257                 self.pauserotarmor_finished = time + 10;
 258                 self.pauserothealth_finished = time + 10;
 259                 self.pauseregen_finished = 0;
 260                 self.damageforcescale = 2;
 261                 self.death_time = 0;
 262                 self.dead_time = 0;
 263                 self.dead_frame = 0;
 264                 self.die_frame = 0;
 265                 self.alpha = 0;
 266                 self.scale = 0;
 267                 self.fade_time = 0;
 268                 self.pain_frame = 0;
 269                 self.pain_finished = 0;
 270                 self.strength_finished = 0;
 271                 self.invincible_finished = 0;
 272                 self.pushltime = 0;
 273                 //self.speed_finished = 0;
 274                 //self.slowmo_finished = 0;
 275                 self.vote_finished = 0;
 276                 // players have no think function
 277                 self.think = SUB_Null;
 278                 self.nextthink = 0;
 279
 280                 self.hook_time = 0;
 281
 282                 self.runes = 0;
 283
 284                 self.deadflag = DEAD_NO;
 285
 286                 self.angles = spot.angles;
 287
 288                 self.angles_z = 0; // never spawn tilted even if the spot says to
 289                 self.fixangle = TRUE; // turn this way immediately
 290                 self.velocity = '0 0 0';
 291                 self.avelocity = '0 0 0';
 292                 self.punchangle = '0 0 0';
 293                 self.punchvector = '0 0 0';
 294                 self.oldvelocity = self.velocity;
 295
 296                 self.viewzoom = 0.6;
 297
 298                 if(cvar("sv_defaultcharacter") == 1) {
 299                         local string defaultmodel;
 300                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 301
 302                         precache_model (defaultmodel);
 303                         setmodel (self, defaultmodel);
 304                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 305                 } else {
 306                         self.playermodel = CheckPlayerModel(self.playermodel);
 307
 308                         precache_model (self.playermodel);
 309                         setmodel (self, self.playermodel);
 310                         self.skin = stof(self.playerskin);
 311
 312                 }
 313
 314                 self.crouch = FALSE;
 315                 self.view_ofs = PL_VIEW_OFS;
 316                 setsize (self, PL_MIN, PL_MAX);
 317                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 318                 // don't reset back to last position, even if new position is stuck in solid
 319                 self.oldorigin = self.origin;
 320
 321                 if(cvar("g_lms"))
 322                 {
 323                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 324                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 325                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 326                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 327                 }
 328                 else if (cvar("g_use_ammunition")) {
 329                         self.ammo_shells = cvar("g_start_ammo_shells");
 330                         self.ammo_nails = cvar("g_start_ammo_nails");
 331                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 332                         self.ammo_cells = cvar("g_start_ammo_cells");
 333                 } else {
 334                         self.ammo_shells = 999;
 335                         self.ammo_nails = 999;
 336                         self.ammo_rockets = 999;
 337                         self.ammo_cells = 999;
 338                 }
 339
 340                 self.items = 0;
 341                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 342                 {
 343                         self.items = self.items | IT_LASER;
 344                         self.switchweapon = WEP_LASER;
 345                 }
 346                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 347                 {
 348                         self.items = self.items | IT_SHOTGUN;
 349                         self.switchweapon = WEP_SHOTGUN;
 350                 }
 351                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 352                 {
 353                         self.items = self.items | IT_UZI;
 354                         self.switchweapon = WEP_UZI;
 355                 }
 356                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 357                 {
 358                         self.items = self.items | IT_GRENADE_LAUNCHER;
 359                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 360                 }
 361                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 362                 {
 363                         self.items = self.items | IT_ELECTRO;
 364                         self.switchweapon = WEP_ELECTRO;
 365                 }
 366                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 367                 {
 368                         self.items = self.items | IT_CRYLINK;
 369                         self.switchweapon = WEP_CRYLINK;
 370                 }
 371                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 372                 {
 373                         self.items = self.items | IT_NEX;
 374                         self.switchweapon = WEP_NEX;
 375                 }
 376                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 377                 {
 378                         self.items = self.items | IT_HAGAR;
 379                         self.switchweapon = WEP_HAGAR;
 380                 }
 381                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 382                 {
 383                         self.items = self.items | IT_ROCKET_LAUNCHER;
 384                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 385                 }
 386
 387                 if(cvar("g_instagib"))
 388                 {
 389                         self.items = IT_NEX;
 390                         self.switchweapon = WEP_NEX;
 391                         self.ammo_cells = 999;
 392                 }
 393
 394                 if(cvar("g_rocketarena"))
 395                 {
 396                         self.items = IT_ROCKET_LAUNCHER;
 397                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 398                         self.ammo_rockets = 999;
 399                 }
 400
 401                 if(cvar("g_minstagib"))
 402                 {
 403                         self.health = 100;
 404                         self.armorvalue = 0;
 405                         self.items = IT_NEX;
 406                         self.switchweapon = WEP_NEX;
 407                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 408                         self.extralives = 0;
 409                         self.jump_interval = time;
 410                 }
 411
 412                 self.event_damage = PlayerDamage;
 413
 414                 self.statdraintime = time + 5;
 415                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 416
 417                 if(self.killcount == -666) {
 418                         self.killcount = 0;
 419                         self.frags = 0;
 420                 }
 421
 422                 /*
 423                 W_UpdateWeapon();
 424                 W_UpdateAmmo();
 425                 */
 426                 CL_SpawnWeaponentity();
 427
 428                 //stuffcmd(self, "chase_active 0");
 429                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 430         } else if(self.classname == "observer") {
 431                 PutObserverInServer ();
 432         }
 433 }
 434
 435 /*
 436 =============
 437 SetNewParms
 438 =============
 439 */
 440 void SetNewParms (void)
 441 {
 442
 443 }
 444
 445 /*
 446 =============
 447 SetChangeParms
 448 =============
 449 */
 450 void SetChangeParms (void)
 451 {
 452
 453 }
 454
 455 /*
 456 =============
 457 ClientKill
 458
 459 Called when a client types 'kill' in the console
 460 =============
 461 */
 462 void ClientKill (void)
 463 {
 464         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 465 }
 466
 467 /*
 468 =============
 469 ClientConnect
 470
 471 Called when a client connects to the server
 472 =============
 473 */
 474 string ColoredTeamName(float t);
 475 //void dom_player_join_team(entity pl);
 476 void ClientConnect (void)
 477 {
 478         self.classname = "player_joining";
 479
 480         //if(cvar("g_domination"))
 481         //      dom_player_join_team(self);
 482
 483         //JoinBestTeam(self, FALSE);
 484         if(cvar("teamplay") && self.version == cvar("g_nexuizversion_major")) stuffcmd(self,"menu_showteamselect\n");
 485
 486
 487         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 488                 self.classname = "observer";
 489         } else {
 490                 self.classname = "player";
 491         }
 492
 493         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 494
 495         bprint ("^4",self.netname);
 496         bprint ("^4 connected");
 497
 498         if(cvar("g_domination") || cvar("g_ctf"))
 499         {
 500                 bprint(" and joined the ");
 501                 bprint(ColoredTeamName(self.team));
 502         }
 503
 504         bprint("\n");
 505
 506         self.welcomemessage_time = time + cvar("welcome_message_time");
 507         self.welcomemessage_time2 = 0;
 508
 509         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 510         // send prediction settings to the client
 511         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 512         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 513         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 514         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 515         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 516         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 517         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 518         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 519         // Wazat's grappling hook
 520         SetGrappleHookBindings();
 521
 522         // get autoswitch state from player
 523         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 524         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 525
 526         // get version info from player
 527         stuffcmd(self, "cmd clientversion $g_nexuizversion_major\n");
 528
 529         // set cvar for team scoreboard
 530         if(teams_matter)
 531                 stuffcmd(self, "set teamplay 1\n");
 532         else
 533                 stuffcmd(self, "set teamplay 0\n");
 534
 535         if(cvar("g_lms"))
 536         {
 537                 self.frags = cvar("fraglimit");
 538                 // no fraglimit was set, so player gets 999 lives
 539                 if(self.frags < 1)
 540                         self.frags = 999;
 541
 542                 // disallow player to join after the worst player has lost g_lms_last_join lives
 543                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 544                 if((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime"))
 545                 {
 546                         self.frags = -1;
 547                         lms_dead_count += 1;
 548                 }
 549                 else if(cvar("fraglimit") > lms_lowest_lives)
 550                 {
 551                         self.frags = lms_lowest_lives;
 552                 }
 553         }
 554
 555         if(clienttype(self) !=  CLIENTTYPE_BOT)
 556                 player_count += 1;
 557 }
 558
 559 /*
 560 =============
 561 ClientDisconnect
 562
 563 Called when a client disconnects from the server
 564 =============
 565 */
 566 .entity chatbubbleentity;
 567 .entity teambubbleentity;
 568 void ClientDisconnect (void)
 569 {
 570         bprint ("^4",self.netname);
 571         bprint ("^4 disconnected\n");
 572
 573         if (self.chatbubbleentity)
 574         {
 575                 remove (self.chatbubbleentity);
 576                 self.chatbubbleentity = world;
 577         }
 578
 579         if (self.teambubbleentity)
 580         {
 581                 remove (self.teambubbleentity);
 582                 self.teambubbleentity = world;
 583         }
 584
 585         DropAllRunes(self);
 586         // decrease player count for lms
 587         if(clienttype(self) !=  CLIENTTYPE_BOT)
 588                 player_count -= 1;
 589         // player was dead, decrease dead count
 590         if(cvar("g_lms") && self.frags < 1)
 591                 lms_dead_count -= 1;
 592         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 593 }
 594
 595 .float buttonchat;
 596 void() ChatBubbleThink =
 597 {
 598         self.nextthink = time;
 599         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 600         {
 601                 remove(self);
 602                 return;
 603         }
 604         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 605         if (self.owner.buttonchat && !self.owner.deadflag)
 606                 self.model = self.mdl;
 607         else
 608                 self.model = "";
 609 };
 610
 611 void() UpdateChatBubble =
 612 {
 613         if (!self.modelindex)
 614                 return;
 615         // spawn a chatbubble entity if needed
 616         if (!self.chatbubbleentity)
 617         {
 618                 self.chatbubbleentity = spawn();
 619                 self.chatbubbleentity.owner = self;
 620                 self.chatbubbleentity.exteriormodeltoclient = self;
 621                 self.chatbubbleentity.think = ChatBubbleThink;
 622                 self.chatbubbleentity.nextthink = time;
 623                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 624                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 625                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 626                 self.chatbubbleentity.model = "";
 627         }
 628 }
 629
 630
 631 void() TeamBubbleThink =
 632 {
 633         self.nextthink = time;
 634         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 635         {
 636                 remove(self);
 637                 return;
 638         }
 639         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 640         if (self.owner.buttonchat || self.owner.deadflag)
 641                 self.model = "";
 642         else
 643                 self.model = self.mdl;
 644
 645 };
 646
 647 .float() customizeentityforclient;
 648 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 649
 650 void() UpdateTeamBubble =
 651 {
 652         if (!self.modelindex || !cvar("teamplay"))
 653                 return;
 654         // spawn a teambubble entity if needed
 655         if (!self.teambubbleentity && cvar("teamplay"))
 656         {
 657                 self.teambubbleentity = spawn();
 658                 self.teambubbleentity.owner = self;
 659                 self.teambubbleentity.exteriormodeltoclient = self;
 660                 self.teambubbleentity.think = TeamBubbleThink;
 661                 self.teambubbleentity.nextthink = time;
 662                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 663                 setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 664                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 665                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 666                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 667         }
 668 }
 669
 670 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 671 // added to the model skins
 672 /*void() UpdateColorModHack =
 673 {
 674         local float c;
 675         c = self.clientcolors & 15;
 676         // LordHavoc: only bothering to support white, green, red, yellow, blue
 677              if (teamplay == 0) self.colormod = '0 0 0';
 678         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 679         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 680         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 681         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 682         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 683         else self.colormod = '1 1 1';
 684 };*/
 685
 686 void UpdatePlayerColors () {
 687         if(self.weaponentity) {
 688                 self.weaponentity.colormap = self.colormap;
 689                 self.exteriorweaponentity.colormap = self.colormap;
 690         }
 691 }
 692 /*
 693 =============
 694 PlayerJump
 695
 696 When you press the jump key
 697 =============
 698 */
 699 void PlayerJump (void)
 700 {
 701         float mjumpheight;
 702
 703         mjumpheight = cvar("g_balance_jumpheight");
 704         if (self.waterlevel >= 2)
 705         {
 706                 if (self.watertype == CONTENT_WATER)
 707                         self.velocity_z = 200;
 708                 else if (self.watertype == CONTENT_SLIME)
 709                         self.velocity_z = 80;
 710                 else
 711                         self.velocity_z = 50;
 712
 713                 return;
 714         }
 715
 716
 717         if (!(self.flags & FL_ONGROUND))
 718                 return;
 719
 720         if (!(self.flags & FL_JUMPRELEASED))
 721                 return;
 722
 723         if(cvar("g_runematch"))
 724         {
 725                 if(self.runes & RUNE_SPEED)
 726                 {
 727                         if(self.runes & CURSE_SLOW)
 728                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 729                         else
 730                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 731                 }
 732                 else if(self.runes & CURSE_SLOW)
 733                 {
 734                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 735                 }
 736         }
 737
 738         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 739         {
 740                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 741         }
 742
 743         self.velocity_z = self.velocity_z + mjumpheight;
 744         self.oldvelocity_z = self.velocity_z;
 745
 746         self.flags = self.flags - FL_ONGROUND;
 747         self.flags = self.flags - FL_JUMPRELEASED;
 748 }
 749
 750 void() CheckWaterJump =
 751 {
 752         local vector start, end;
 753
 754 // check for a jump-out-of-water
 755         makevectors (self.angles);
 756         start = self.origin;
 757         start_z = start_z + 8;
 758         v_forward_z = 0;
 759         normalize(v_forward);
 760         end = start + v_forward*24;
 761         traceline (start, end, TRUE, self);
 762         if (trace_fraction < 1)
 763         {       // solid at waist
 764                 start_z = start_z + self.maxs_z - 8;
 765                 end = start + v_forward*24;
 766                 self.movedir = trace_plane_normal * -50;
 767                 traceline (start, end, TRUE, self);
 768                 if (trace_fraction == 1)
 769                 {       // open at eye level
 770                         self.flags = self.flags | FL_WATERJUMP;
 771                         self.velocity_z = 225;
 772                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 773                         self.teleport_time = time + 2;  // safety net
 774                         return;
 775                 }
 776         }
 777 };
 778
 779
 780 void respawn(void)
 781 {
 782         CopyBody(1);
 783         PutClientInServer();
 784 }
 785
 786 void player_powerups (void)
 787 {
 788         if (cvar("g_minstagib"))
 789         {
 790                 self.effects = EF_FULLBRIGHT;
 791                 if (self.items & IT_STRENGTH)
 792                 {
 793                         self.effects = EF_NODRAW;
 794                         if (time > self.strength_finished)
 795                         {
 796                                 self.items = self.items - (self.items & IT_STRENGTH);
 797                                 sprint(self, "^3Invisibility has worn off\n");
 798                         }
 799                 }
 800                 else
 801                 {
 802                         if (time < self.strength_finished)
 803                         {
 804                                 self.items = self.items | IT_STRENGTH;
 805                                 sprint(self, "^3You are invisible\n");
 806                         }
 807                 }
 808
 809                 if (self.items & IT_INVINCIBLE)
 810                 {
 811                         if (time > self.invincible_finished)
 812                         {
 813                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 814                                 sprint(self, "^3Speed has worn off\n");
 815                         }
 816                 }
 817                 else
 818                 {
 819                         if (time < self.invincible_finished)
 820                         {
 821                                 self.items = self.items | IT_INVINCIBLE;
 822                                 sprint(self, "^3You are on speed\n");
 823                         }
 824                 }
 825                 return;
 826         }
 827
 828         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 829         if (self.items & IT_STRENGTH)
 830         {
 831                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 832                 if (time > self.strength_finished)
 833                 {
 834                         self.items = self.items - (self.items & IT_STRENGTH);
 835                         sprint(self, "^3Strength has worn off\n");
 836                 }
 837         }
 838         else
 839         {
 840                 if (time < self.strength_finished)
 841                 {
 842                         self.items = self.items | IT_STRENGTH;
 843                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 844                 }
 845         }
 846         if (self.items & IT_INVINCIBLE)
 847         {
 848                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 849                 if (time > self.invincible_finished)
 850                 {
 851                         self.items = self.items - (self.items & IT_INVINCIBLE);
 852                         sprint(self, "^3Shield has worn off\n");
 853                 }
 854         }
 855         else
 856         {
 857                 if (time < self.invincible_finished)
 858                 {
 859                         self.items = self.items | IT_INVINCIBLE;
 860                         sprint(self, "^3Shield surrounds you\n");
 861                 }
 862         }
 863
 864         if (cvar("g_fullbrightplayers"))
 865                 self.effects = EF_FULLBRIGHT;
 866
 867 }
 868
 869 void player_regen (void)
 870 {
 871         float maxh, maxa, max_mod, regen_mod, rot_mod;
 872         maxh = cvar("g_balance_health_stable");
 873         maxa = cvar("g_balance_armor_stable");
 874
 875         if (cvar("g_minstagib"))
 876         {
 877                 maxh = 100;
 878                 maxa = 0;
 879                 return;
 880         }
 881
 882         if(cvar("g_runematch"))
 883         {
 884                 max_mod = regen_mod = rot_mod = 1;
 885                 if (self.runes & RUNE_REGEN)
 886                 {
 887                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 888                         {
 889                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 890                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 891                         }
 892                         else
 893                         {
 894                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 895                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 896                         }
 897                 }
 898                 else if (self.runes & CURSE_VENOM)
 899                 {
 900                         max_mod = cvar("g_balance_curse_venom_hpmod");
 901                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 902                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 903                         else
 904                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 905                         //if (!self.runes & RUNE_REGEN)
 906                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 907                 }
 908                 maxh = maxh * max_mod;
 909                 //maxa = maxa * max_mod;
 910
 911                 if (time > self.pauserotarmor_finished)
 912                 {
 913                         if (self.armorvalue > maxa)
 914                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 915                 }
 916                 if (time > self.pauserothealth_finished)
 917                 {
 918                         if (self.health > maxh)
 919                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 920                 }
 921                 if (time > self.pauseregen_finished)
 922                 {
 923                         if (self.health < maxh)
 924                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 925                         if (self.armorvalue < maxa)
 926                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 927                 }
 928         }
 929         else
 930         {
 931                 if (time > self.pauserothealth_finished)
 932                 if (self.health > maxh)
 933                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 934                 if (time > self.pauserotarmor_finished)
 935                 if (self.armorvalue > maxa)
 936                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 937                 if (time > self.pauseregen_finished)
 938                 {
 939                         if (self.health < maxh)
 940                                 self.health = bound(0, self.health + (maxh- self.health) * cvar("g_balance_health_regen") * frametime, 1000);
 941                         if (self.armorvalue < maxa)
 942                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 943                 }
 944         }
 945 }
 946
 947 /*
 948 ======================
 949 spectate mode routines
 950 ======================
 951 */
 952 void SpectateCopy(entity spectatee) {
 953         self.armortype = spectatee.armortype;
 954         self.armorvalue = spectatee.armorvalue;
 955         self.currentammo = spectatee.currentammo;
 956         self.effects = spectatee.effects;
 957         self.health = spectatee.health;
 958         self.impulse = 0;
 959         self.items = spectatee.items;
 960         self.punchangle = spectatee.punchangle;
 961         self.view_ofs = spectatee.view_ofs;
 962         self.v_angle = spectatee.v_angle;
 963         self.viewzoom = spectatee.viewzoom;
 964         setorigin(self, spectatee.origin);
 965         setsize(self, spectatee.mins, spectatee.maxs);
 966 }
 967
 968 void SpectateUpdate() {
 969         if (self != self.enemy) {
 970                 SpectateCopy(self.enemy);
 971                 msg_entity = self;
 972                 WriteByte(MSG_ONE, SVC_SETANGLE);
 973                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
 974                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
 975                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
 976         }
 977 }
 978
 979 float SpectateNext() {
 980         other = find(self.enemy, classname, "player");
 981         if (!other) {
 982                 other = find(other, classname, "player");
 983         }
 984         if (other) {
 985                 self.enemy = other;
 986         }
 987         if(self.enemy.classname == "player") {
 988                 msg_entity = self;
 989                 WriteByte(MSG_ONE, SVC_SETVIEW);
 990                 WriteEntity(MSG_ONE, self.enemy);
 991                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 992                 SpectateUpdate();
 993                 return 1;
 994         } else {
 995                 return 0;
 996         }
 997 }
 998
 999 /*
1000 =============
1001 PlayerPreThink
1002
1003 Called every frame for each client before the physics are run
1004 =============
1005 */
1006 void PlayerPreThink (void)
1007 {
1008         if(self.classname == "player") {
1009                 local vector m1, m2;
1010
1011 //              MauveBot_AI();
1012
1013 //              if(self.netname == "Wazat")
1014 //                      bprint(strcat(self.classname, "\n"));
1015
1016                 CheckRules_Player();
1017
1018                 if (intermission_running)
1019                 {
1020                         IntermissionThink ();   // otherwise a button could be missed between
1021                         return;                                 // the think tics
1022                 }
1023
1024                 if (self.deadflag != DEAD_NO)
1025                 {
1026                         player_anim();
1027                         weapon_freeze();
1028                         if (self.deadflag == DEAD_DYING)
1029                         {
1030                                 if (time > self.dead_time)
1031                                         self.deadflag = DEAD_DEAD;
1032                         }
1033                         else if (self.deadflag == DEAD_DEAD)
1034                         {
1035                                 if (!self.button0 && !self.button2 && !self.button3)
1036                                         self.deadflag = DEAD_RESPAWNABLE;
1037                         }
1038                         else if (self.deadflag == DEAD_RESPAWNABLE)
1039                         {
1040                                 if (self.button0  ||
1041                                     self.button2  ||
1042                                     self.button3  ||
1043                                     self.button4  ||
1044                                     cvar("g_lms") ||
1045                                     cvar("g_forced_respawn"))
1046                                         respawn();
1047                         }
1048                         return;
1049                 }
1050
1051                 if (self.button5)
1052                 {
1053                         if (!self.crouch)
1054                         {
1055                                 self.crouch = TRUE;
1056                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1057                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1058                         }
1059                 }
1060                 else
1061                 {
1062                         if (self.crouch)
1063                         {
1064                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1065                                 if (!trace_startsolid)
1066                                 {
1067                                         self.crouch = FALSE;
1068                                         self.view_ofs = PL_VIEW_OFS;
1069                                         setsize (self, PL_MIN, PL_MAX);
1070                                 }
1071                         }
1072                 }
1073
1074                 if(cvar("sv_defaultcharacter") == 1) {
1075                         local string defaultmodel;
1076                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1077
1078                         if (defaultmodel != self.model)
1079                         {
1080                                 m1 = self.mins;
1081                                 m2 = self.maxs;
1082                                 precache_model (defaultmodel);
1083                                 setmodel (self, defaultmodel);
1084                                 setsize (self, m1, m2);
1085                         }
1086
1087                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1088                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1089                 } else {
1090                         if (self.playermodel != self.model)
1091                         {
1092                                 self.playermodel = CheckPlayerModel(self.playermodel);
1093                                 m1 = self.mins;
1094                                 m2 = self.maxs;
1095                                 precache_model (self.playermodel);
1096                                 setmodel (self, self.playermodel);
1097                                 setsize (self, m1, m2);
1098                         }
1099
1100                         if (self.skin != stof(self.playerskin))
1101                                 self.skin = stof(self.playerskin);
1102                 }
1103                 // Savage: Check for nameless players
1104                 if (strlen(self.netname) < 1) {
1105                         self.netname = "Player";
1106                         stuffcmd(self, "name Player\n");
1107                 }
1108
1109                 GrapplingHookFrame();
1110
1111                 W_WeaponFrame();
1112
1113                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1114                 {
1115                         if (cvar("g_minstagib") && self.button3)
1116                         {
1117                                 if (self.jump_interval <= (time + 0.1))
1118                                 {
1119                                         self.jump_interval = time + 1;
1120                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1121                                 }
1122                         }
1123                         else if (self.viewzoom > 0.4)
1124                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1125                 }
1126                 else if (self.viewzoom < 1.0)
1127                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1128
1129
1130                 if (self.button2)
1131                         PlayerJump ();
1132                 else
1133                         self.flags = self.flags | FL_JUMPRELEASED;
1134
1135                 player_powerups();
1136                 player_regen();
1137                 player_anim();
1138
1139                 //self.angles_y=self.v_angle_y + 90;   // temp
1140
1141                 if (self.waterlevel == 2)
1142                         CheckWaterJump ();
1143
1144                 //if (TetrisPreFrame()) return;
1145         } else if(self.classname == "observer") {
1146
1147                 if (self.flags & FL_JUMPRELEASED) {
1148                         if (self.button2 && self.version == cvar("g_nexuizversion_major")) {
1149                                 if(!cvar("teamplay")) {
1150                                         self.flags = self.flags & !FL_JUMPRELEASED;
1151                                         self.classname = "player";
1152                                         if(!cvar("g_lms"))
1153                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1154                                         PutClientInServer();
1155                                         centerprint(self,"");
1156                                         return;
1157                                 } else {
1158                                         self.flags = self.flags & !FL_JUMPRELEASED;
1159                                         stuffcmd(self,"menu_showteamselect\n");
1160                                         return;
1161                                 }
1162                         } else if(self.button0 && self.version == cvar("g_nexuizversion_major")) {
1163                                 self.flags = self.flags & !FL_JUMPRELEASED;
1164                                 if(SpectateNext() == 1) {
1165                                         self.classname = "spectator";
1166                                 }
1167                         }
1168                 } else {
1169                         if (!(self.button0 || self.button2)) {
1170                                 self.flags = self.flags | FL_JUMPRELEASED;
1171                         }
1172                 }
1173                 if(cvar("g_lms") && self.frags == 0)
1174                         centerprint(self, "\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1175                 else if(cvar("g_lms") && self.frags == -1)
1176                         centerprint(self, "\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1177                 else
1178                         PrintWelcomeMessage(self);
1179                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1180         } else if(self.classname == "spectator") {
1181
1182                 if (self.flags & FL_JUMPRELEASED) {
1183                         if(self.button0) {
1184                                 self.flags = self.flags & !FL_JUMPRELEASED;
1185                                 if(SpectateNext() == 1) {
1186                                         self.classname = "spectator";
1187                                 } else {
1188                                         self.classname = "observer";
1189                                         msg_entity = self;
1190                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1191                                         WriteEntity(MSG_ONE, self);
1192                                         PutClientInServer();
1193                                 }
1194                         } else if (self.button3) {
1195                                 self.flags = self.flags & !FL_JUMPRELEASED;
1196                                 self.classname = "observer";
1197                                 msg_entity = self;
1198                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1199                                 WriteEntity(MSG_ONE, self);
1200                                 PutClientInServer();
1201                         } else {
1202                                 SpectateUpdate();
1203                         }
1204         } else {
1205                 if (!(self.button0 || self.button3)) {
1206                         self.flags = self.flags | FL_JUMPRELEASED;
1207                 }
1208                 }
1209                 centerprint(self, strcat("spectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1210
1211         }
1212         VoteThink();
1213 }
1214
1215 /*
1216 =============
1217 PlayerPostThink
1218
1219 Called every frame for each client after the physics are run
1220 =============
1221 */
1222 void PlayerPostThink (void)
1223 {
1224         if(self.classname == "player") {
1225                 CheckRules_Player();
1226                 UpdateChatBubble();
1227                 UpdateTeamBubble();
1228                 UpdatePlayerColors();
1229                 if (self.deadflag == DEAD_NO)
1230                 if (self.impulse)
1231                         ImpulseCommands ();
1232                 if (intermission_running)
1233                         return;         // intermission or finale
1234
1235                 //PrintWelcomeMessage(self);
1236                 //if (TetrisPostFrame()) return;
1237         } else if (self.classname == "observer") {
1238                 //do nothing
1239         } else if (self.classname == "spectator") {
1240                 //do nothing
1241         }
1242 }