data/qcsrc/common/mapinfo.qc

   1 // internal toy
   2 void cvar_settemp(string pKey, string pValue)
   3 {
   4         //localcmd(strcat("\nsettemp ", t, " \"", s, "\"\n"));
   5
   6         // duplicate what this alias does:
   7         // alias settemp "settemp_list \"1 $1 $settemp_var $settemp_list\"; set $settemp_var \"${$1}\"; settemp_var ${settemp_var}x; $1 \"$2\""
   8
   9         cvar_set("settemp_list", strcat("1 ", pKey, " ", cvar_string("settemp_var"), " ", cvar_string("settemp_list")));
  10 #ifdef MENUQC
  11         registercvar(cvar_string("settemp_var"), "", 0);
  12 #else
  13         registercvar(cvar_string("settemp_var"), "");
  14 #endif
  15         cvar_set(cvar_string("settemp_var"), cvar_string(pKey));
  16         cvar_set("settemp_var", strcat(cvar_string("settemp_var"), "x"));
  17         cvar_set(pKey, pValue);
  18 }
  19
  20 void cvar_settemp_restore()
  21 {
  22         // undo what cvar_settemp did
  23         float n, i;
  24         n = tokenize(cvar_string("settemp_list"));
  25         for(i = 0; i < n - 3; i += 3)
  26                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
  27         cvar_set("settemp_list", "0");
  28 }
  29
  30 #ifdef HSOI
  31 // HUGE SET - stored in a string
  32 string HugeSetOfIntegers_empty()
  33 {
  34         return "";
  35 }
  36 float HugeSetOfIntegers_get(string pArr, float i)
  37 {
  38         return stof(substring(pArr, i * 4, 4));
  39 }
  40 float HugeSetOfIntegers_length(string pArr)
  41 {
  42         return strlen(pArr) / 4;
  43 }
  44 string HugeSetOfIntegers_concat(string a1, string a2)
  45 {
  46         return strcat(a1, a2);
  47 }
  48 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  49         // special concat function to build up large lists in less time by binary concatenation
  50 {
  51         string s;
  52         s = strcat("    ", ftos(n));
  53         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  54 }
  55 #endif
  56
  57 // generic string stuff
  58 float startsWith(string haystack, string needle)
  59 {
  60         return substring(haystack, 0, strlen(needle)) == needle;
  61 }
  62 float startsWithNocase(string haystack, string needle)
  63 {
  64         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  65 }
  66 string extractRestOfLine(string haystack, string needle)
  67 {
  68         if(startsWith(haystack, needle))
  69                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  70         return string_null;
  71 }
  72 string car(string s)
  73 {
  74         float o;
  75         o = strstrofs(s, " ", 0);
  76         if(o < 0)
  77                 return s;
  78         return substring(s, 0, o);
  79 }
  80 string cdr(string s)
  81 {
  82         float o;
  83         o = strstrofs(s, " ", 0);
  84         if(o < 0)
  85                 return string_null;
  86         return substring(s, o + 1, strlen(s) - (o + 1));
  87 }
  88
  89 float _MapInfo_Cache_Active;
  90 float _MapInfo_Cache_DB_NameToIndex;
  91 float _MapInfo_Cache_Buf_IndexToMapData;
  92
  93 void MapInfo_Cache_Destroy()
  94 {
  95         if(!_MapInfo_Cache_Active)
  96                 return;
  97
  98         db_close(_MapInfo_Cache_DB_NameToIndex);
  99         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
 100         _MapInfo_Cache_Active = 0;
 101 }
 102
 103 void MapInfo_Cache_Create()
 104 {
 105         MapInfo_Cache_Destroy();
 106         _MapInfo_Cache_DB_NameToIndex = db_create();
 107         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
 108         _MapInfo_Cache_Active = 1;
 109 }
 110
 111 void MapInfo_Cache_Invalidate()
 112 {
 113         if(!_MapInfo_Cache_Active)
 114                 return;
 115
 116         MapInfo_Cache_Create();
 117 }
 118
 119 void MapInfo_Cache_Store()
 120 {
 121         float i;
 122         string s;
 123         if(!_MapInfo_Cache_Active)
 124                 return;
 125
 126         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
 127         if(!s) // empty string is NOT valid here!
 128         {
 129                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 130                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 131         }
 132         else
 133                 i = stof(s);
 134
 135         // now store all the stuff
 136         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
 137         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
 138         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
 139         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
 140         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
 141         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
 142 }
 143
 144 float MapInfo_Cache_Retrieve(string map)
 145 {
 146         float i;
 147         string s;
 148         if(!_MapInfo_Cache_Active)
 149                 return 0;
 150
 151         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 152         if(!s)
 153                 return 0;
 154         i = stof(s);
 155
 156         // now retrieve all the stuff
 157         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
 158         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 159         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 160         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 161         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 162         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 163         return 1;
 164 }
 165
 166 // GLOB HANDLING (for all BSP files)
 167 float _MapInfo_globopen;
 168 float _MapInfo_globcount;
 169 float _MapInfo_globhandle;
 170 string _MapInfo_GlobItem(float i)
 171 {
 172         string s;
 173         s = search_getfilename(_MapInfo_globhandle, i);
 174         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 175 }
 176
 177 void MapInfo_Enumerate()
 178 {
 179         if(_MapInfo_globopen)
 180                 search_end(_MapInfo_globhandle);
 181         MapInfo_Cache_Invalidate();
 182         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 183         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 184         _MapInfo_globopen = 1;
 185 }
 186
 187 // filter the info by game type mask (updates MapInfo_count)
 188 //
 189 #ifdef HSOI
 190 string _MapInfo_filtered;
 191 float MapInfo_FilterList_Lookup(float i)
 192 {
 193         return MapInfo_FilterList_Lookup(i);
 194 }
 195
 196 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pBegin, float pEnd, float pAbortOnGenerate)
 197 {
 198         float m, valid;
 199         string l, r;
 200
 201         if(pBegin == pEnd)
 202                 return HugeSetOfIntegers_empty();
 203
 204         m = floor((pBegin + pEnd) / 2);
 205
 206         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 207         if not(l)
 208                 return string_null; // BAIL OUT
 209         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 210                 if(pAbortOnGenerate)
 211                 {
 212                         MapInfo_progress = m / _MapInfo_globcount;
 213                         return string_null; // BAIL OUT
 214                 }
 215         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 216         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, m + 1, pEnd, pAbortOnGenerate);
 217         if not(r)
 218                 return string_null; // BAIL OUT
 219
 220         if(valid)
 221                 return HugeSetOfIntegers_insert(l, m, r);
 222         else
 223                 return HugeSetOfIntegers_concat(l, r);
 224 }
 225
 226 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 227 {
 228         if(_MapInfo_filtered)
 229                 strunzone(_MapInfo_filtered);
 230         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, 0, _MapInfo_globcount, pAbortOnGenerate);
 231         if not(_MapInfo_filtered)
 232         {
 233                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 234                 return 0;
 235         }
 236         _MapInfo_filtered = strzone(_MapInfo_filtered);
 237         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 238         MapInfo_ClearTemps();
 239         return 1;
 240 }
 241
 242 void MapInfo_Filter_Free()
 243 {
 244         if(_MapInfo_filtered)
 245         {
 246                 strunzone(_MapInfo_filtered);
 247                 _MapInfo_filtered = string_null;
 248         }
 249 }
 250 #else
 251 float _MapInfo_filtered;
 252 float _MapInfo_filtered_allocated;
 253 float MapInfo_FilterList_Lookup(float i)
 254 {
 255         return stof(bufstr_get(_MapInfo_filtered, i));
 256 }
 257
 258 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 259 {
 260         float i, j;
 261         if not(_MapInfo_filtered_allocated)
 262         {
 263                 _MapInfo_filtered_allocated = 1;
 264                 _MapInfo_filtered = buf_create();
 265         }
 266         MapInfo_count = 0;
 267         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 268         {
 269                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 270                         if(pAbortOnGenerate)
 271                         {
 272                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 273                                 MapInfo_progress = i / _MapInfo_globcount;
 274                                 return 0;
 275                         }
 276                 if(((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures))
 277                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 278         }
 279         MapInfo_count = j + 1;
 280         MapInfo_ClearTemps();
 281         return 1;
 282 }
 283
 284 void MapInfo_Filter_Free()
 285 {
 286         if(_MapInfo_filtered_allocated)
 287         {
 288                 buf_del(_MapInfo_filtered);
 289                 _MapInfo_filtered_allocated = 0;
 290         }
 291 }
 292 #endif
 293
 294 // load info about the i-th map into the MapInfo_Map_* globals
 295 string MapInfo_BSPName_ByID(float i)
 296 {
 297         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 298 }
 299
 300 string unquote(string s)
 301 {
 302         float i, j, l;
 303         l = strlen(s);
 304         j = -1;
 305         for(i = 0; i < l; ++i)
 306         {
 307                 string ch;
 308                 ch = substring(s, i, 1);
 309                 if(ch != " ") if(ch != "\"")
 310                 {
 311                         for(j = strlen(s) - i - 1; j > 0; --j)
 312                         {
 313                                 ch = substring(s, i+j, 1);
 314                                 if(ch != " ") if(ch != "\"")
 315                                         return substring(s, i, j+1);
 316                         }
 317                         return substring(s, i, 1);
 318                 }
 319         }
 320         return "";
 321 }
 322
 323 float MapInfo_Get_ByID(float i)
 324 {
 325         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 326                 return 1;
 327         return 0;
 328 }
 329
 330 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 331 {
 332         string fn;
 333         float fh;
 334         string s, k, v;
 335         vector o;
 336         float i;
 337         float inWorldspawn;
 338         float r;
 339         float twoBaseModes;
 340         float diameter, spawnpoints;
 341
 342         vector mapMins, mapMaxs;
 343
 344         r = 1;
 345         fn = strcat("maps/", pFilename, ".ent");
 346         fh = fopen(fn, FILE_READ);
 347         if(fh < 0)
 348         {
 349                 r = 2;
 350                 fn = strcat("maps/", pFilename, ".bsp");
 351                 fh = fopen(fn, FILE_READ);
 352         }
 353         if(fh < 0)
 354                 return 0;
 355         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 356
 357         inWorldspawn = 2;
 358         MapInfo_Map_supportedGametypes = 0;
 359         spawnpoints = 0;
 360
 361         for(;;)
 362         {
 363                 if not((s = fgets(fh)))
 364                         break;
 365                 if(inWorldspawn == 1)
 366                         if(startsWith(s, "}"))
 367                                 inWorldspawn = 0;
 368                 k = unquote(car(s));
 369                 v = unquote(cdr(s));
 370                 if(inWorldspawn)
 371                 {
 372                         if(k == "classname" && v == "worldspawn")
 373                                 inWorldspawn = 1;
 374                         else if(k == "author")
 375                                 MapInfo_Map_author = v;
 376                         else if(k == "_description")
 377                                 MapInfo_Map_description = v;
 378                         else if(k == "message")
 379                         {
 380                                 i = strstrofs(v, " by ", 0);
 381                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 382                                 {
 383                                         MapInfo_Map_title = substring(v, 0, i);
 384                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 385                                 }
 386                                 else
 387                                         MapInfo_Map_title = v;
 388                         }
 389                 }
 390                 else
 391                 {
 392                         if(k == "origin")
 393                         {
 394                                 o = stov(strcat("'", v, "'"));
 395                                 mapMins_x = min(mapMins_x, o_x);
 396                                 mapMins_y = min(mapMins_y, o_y);
 397                                 mapMins_z = min(mapMins_z, o_z);
 398                                 mapMaxs_x = max(mapMaxs_x, o_x);
 399                                 mapMaxs_y = max(mapMaxs_y, o_y);
 400                                 mapMaxs_z = max(mapMaxs_z, o_z);
 401                         }
 402                         else if(k == "classname")
 403                         {
 404                                 if(v == "dom_controlpoint")
 405                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 406                                 else if(v == "item_flag_team2")
 407                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 408                                 else if(v == "team_CTF_blueflag")
 409                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 410                                 else if(v == "runematch_spawn_point")
 411                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 412                                 else if(v == "target_assault_roundend")
 413                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 414                                 else if(v == "onslaught_generator")
 415                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 416                                 else if(v == "info_player_team1")
 417                                         ++spawnpoints;
 418                                 else if(v == "info_player_team2")
 419                                         ++spawnpoints;
 420                                 else if(v == "info_player_start")
 421                                         ++spawnpoints;
 422                                 else if(v == "info_player_deathmatch")
 423                                         ++spawnpoints;
 424                                 else if(v == "weapon_nex")
 425                                         { }
 426                                 else if(v == "weapon_railgun")
 427                                         { }
 428                                 else if(startsWith(v, "weapon_"))
 429                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 430                         }
 431                 }
 432         }
 433         if(inWorldspawn)
 434         {
 435                 print(fn, " ended still in worldspawn, BUG\n");
 436                 return 0;
 437         }
 438         diameter = vlen(mapMaxs - mapMins);
 439
 440         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT);
 441         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 442         {
 443                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 444                 // as the map is too symmetric for them.
 445         }
 446         else
 447         {
 448                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 449                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 450
 451                 if(spawnpoints >= 8  && diameter > 4096)
 452                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 453                 if(                     diameter < 4096)
 454                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 455                 if(spawnpoints >= 12 && diameter > 5120)
 456                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 457         }
 458
 459         dprint("-> diameter ",    ftos(diameter));
 460         dprint(";  spawnpoints ", ftos(spawnpoints));
 461         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 462
 463         fclose(fh);
 464
 465         return r;
 466 }
 467
 468 void _MapInfo_Map_Reset()
 469 {
 470         MapInfo_Map_title = "<TITLE>";
 471         MapInfo_Map_description = "<DESCRIPTION>";
 472         MapInfo_Map_author = "<AUTHOR>";
 473         MapInfo_Map_supportedGametypes = 0;
 474         MapInfo_Map_supportedFeatures = 0;
 475 }
 476
 477 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 478 {
 479         string sa;
 480         MapInfo_Map_supportedGametypes |= pThisType;
 481         if(!(pThisType & pWantedType))
 482                 return;
 483
 484         cvar_set("fraglimit", car(s));
 485         s = cdr(s);
 486
 487         cvar_set("timelimit", car(s));
 488         s = cdr(s);
 489
 490         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 491         {
 492                 sa = car(s); if(sa == "") sa = "2";
 493                 cvar_set("g_tdm_teams", sa);
 494                 s = cdr(s);
 495         }
 496
 497         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 498         {
 499                 sa = car(s); if(sa == "") sa = "3";
 500                 cvar_set("g_keyhunt_teams", sa);
 501                 s = cdr(s);
 502         }
 503
 504         if(pWantedType == MAPINFO_TYPE_CTF)
 505         {
 506                 sa = car(s); if(sa == "") sa = "10";
 507                 cvar_set("capturelimit", sa);
 508                 s = cdr(s);
 509         }
 510 }
 511
 512 float MapInfo_Type_FromString(string t)
 513 {
 514         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 515         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 516         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 517         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 518         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 519         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 520         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 521         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 522         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 523         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 524         else if(t == "all")   return MAPINFO_TYPE_ALL;
 525         else                  return 0;
 526 }
 527
 528 // load info about a map by name into the MapInfo_Map_* globals
 529 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 530 {
 531         string fn;
 532         string s, t;
 533         float fh, fh2;
 534         float r, f;
 535
 536         if(pGametypeToSet == 0)
 537                 if(MapInfo_Cache_Retrieve(pFilename))
 538                         return 1;
 539
 540         r = 1;
 541
 542         MapInfo_Map_bspname = pFilename;
 543
 544         // default all generic fields so they have "good" values in case something fails
 545         fn = strcat("maps/", pFilename, ".mapinfo");
 546         fh = fopen(fn, FILE_READ);
 547         if(fh < 0)
 548         {
 549                 if(!pAllowGenerate)
 550                         return 0;
 551                 _MapInfo_Map_Reset();
 552                 r = _MapInfo_Generate(pFilename);
 553                 if(!r)
 554                         return 0;
 555                 fh = fopen(fn, FILE_WRITE);
 556                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 557                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 558                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 559                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 560                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 561                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 562                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 563                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 564                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 565                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 566                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 567                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 568                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 569                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 570
 571                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 572                 if(fh2 >= 0)
 573                 {
 574                         fclose(fh2);
 575                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 576                 }
 577
 578                 fclose(fh);
 579                 r = 2;
 580                 // return r;
 581                 fh = fopen(fn, FILE_READ);
 582                 if(fh < 0)
 583                         error("... but I just wrote it!");
 584         }
 585
 586         _MapInfo_Map_Reset();
 587         for(;;)
 588         {
 589                 if not((s = fgets(fh)))
 590                         break;
 591
 592                 // catch different sorts of comments
 593                 if(s == "")                    // empty lines
 594                         continue;
 595                 if(substring(s, 0, 1) == "#")  // UNIX style
 596                         continue;
 597                 if(substring(s, 0, 2) == "//") // C++ style
 598                         continue;
 599                 if(substring(s, 0, 1) == "_")  // q3map style
 600                         continue;
 601
 602                 t = car(s); s = cdr(s);
 603                 if(t == "title")
 604                         MapInfo_Map_title = s;
 605                 else if(t == "description")
 606                         MapInfo_Map_description = s;
 607                 else if(t == "author")
 608                         MapInfo_Map_author = s;
 609                 else if(t == "has")
 610                 {
 611                         t = car(s); s = cdr(s);
 612                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 613                         else
 614                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 615                 }
 616                 else if(t == "type")
 617                 {
 618                         t = car(s); s = cdr(s);
 619                         f = MapInfo_Type_FromString(t);
 620                         if(f)
 621                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 622                         else
 623                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 624                 }
 625                 else if(t == "settemp_for_type")
 626                 {
 627                         t = car(s); s = cdr(s);
 628                         if((f = MapInfo_Type_FromString(t)))
 629                         {
 630                                 if(f & pGametypeToSet)
 631                                 {
 632                                         t = car(s); s = cdr(s);
 633                                         if(strstrofs(t, "\"", 0) >= 0)
 634                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 635                                         else if(strstrofs(t, "\\", 0) >= 0)
 636                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 637                                         else if(strstrofs(t, ";", 0) >= 0)
 638                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 639                                         else if(strstrofs(s, "\"", 0) >= 0)
 640                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 641                                         else if(strstrofs(s, "\\", 0) >= 0)
 642                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 643                                         else if(strstrofs(s, ";", 0) >= 0)
 644                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 645                                         else
 646                                         {
 647                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 648                                                 cvar_settemp(t, s);
 649                                         }
 650                                 }
 651                         }
 652                         else
 653                         {
 654                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 655                         }
 656                 }
 657                 else
 658                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 659         }
 660         fclose(fh);
 661         if(pGametypeToSet)
 662                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 663                         error("Can't select the requested game type. Bailing out.");
 664         MapInfo_Cache_Store();
 665         if(MapInfo_Map_supportedGametypes != 0)
 666                 return r;
 667         dprint("Map ", pFilename, " supports no game types, ignored\n");
 668         return 0;
 669 }
 670
 671 float MapInfo_FindName(string s)
 672 {
 673         // if there is exactly one map of prefix s, return it
 674         // if not, return the null string
 675         // note that DP sorts glob results... so I can use a binary search
 676         float l, r, m, cmp;
 677         l = 0;
 678         r = MapInfo_count;
 679         // invariants: r is behind s, l-1 is equal or before
 680         while(l != r)
 681         {
 682                 m = floor((l + r) / 2);
 683                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 684                 cmp = strcasecmp(MapInfo_FindName_match, s);
 685                 if(cmp == 0)
 686                         return m; // found and good
 687                 if(cmp < 0)
 688                         l = m + 1; // l-1 is before s
 689                 else
 690                         r = m; // behind s
 691         }
 692         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 693         MapInfo_FindName_firstResult = l;
 694         // r == l, so: l is behind s, l-1 is before
 695         // SO: if there is any, l is the one with the right prefix
 696         //     and l+1 may be one too
 697         if(l == MapInfo_count)
 698         {
 699                 MapInfo_FindName_match = string_null;
 700                 MapInfo_FindName_firstResult = -1;
 701                 return -1; // no MapInfo_FindName_match, behind last item
 702         }
 703         if(!startsWithNocase(MapInfo_FindName_match, s))
 704         {
 705                 MapInfo_FindName_match = string_null;
 706                 MapInfo_FindName_firstResult = -1;
 707                 return -1; // wrong prefix
 708         }
 709         if(l == MapInfo_count - 1)
 710                 return l; // last one, nothing can follow => unique
 711         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 712         {
 713                 MapInfo_FindName_match = string_null;
 714                 return -1; // ambigous MapInfo_FindName_match
 715         }
 716         return l;
 717 }
 718
 719 string MapInfo_FixName(string s)
 720 {
 721         MapInfo_FindName(s);
 722         return MapInfo_FindName_match;
 723 }
 724
 725 float MapInfo_CurrentFeatures()
 726 {
 727         float req;
 728         req = 0;
 729         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena")))
 730                 req |= MAPINFO_FEATURE_WEAPONS;
 731         return req;
 732 }
 733
 734 float MapInfo_CurrentGametype()
 735 {
 736         if(cvar("g_domination"))
 737                 return MAPINFO_TYPE_DOMINATION;
 738         else if(cvar("g_ctf"))
 739                 return MAPINFO_TYPE_CTF;
 740         else if(cvar("g_runematch"))
 741                 return MAPINFO_TYPE_RUNEMATCH;
 742         else if(cvar("g_tdm"))
 743                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 744         else if(cvar("g_assault"))
 745                 return MAPINFO_TYPE_ASSAULT;
 746         else if(cvar("g_lms"))
 747                 return MAPINFO_TYPE_LMS;
 748         else if(cvar("g_arena"))
 749                 return MAPINFO_TYPE_ARENA;
 750         else if(cvar("g_keyhunt"))
 751                 return MAPINFO_TYPE_KEYHUNT;
 752         else if(cvar("g_onslaught"))
 753                 return MAPINFO_TYPE_ONSLAUGHT;
 754         else
 755                 return MAPINFO_TYPE_DEATHMATCH;
 756 }
 757
 758 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 759 {
 760         if(!MapInfo_Get_ByName(s, 1, 0))
 761                 return 0;
 762         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 763                 return 0;
 764         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 765                 return 0;
 766         return 1;
 767 }
 768
 769 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 770 {
 771         float r;
 772         r = _MapInfo_CheckMap(s);
 773         MapInfo_ClearTemps();
 774         return r;
 775 }
 776
 777 void MapInfo_SwitchGameType(float t)
 778 {
 779         cvar_set("gamecfg",      "0");
 780         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 781         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 782         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 783         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 784         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 785         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 786         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 787         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 788         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 789         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 790 }
 791
 792 void MapInfo_LoadMap(string s)
 793 {
 794         MapInfo_Map_supportedGametypes = 0;
 795         if(!MapInfo_CheckMap(s))
 796         {
 797                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 798                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 799         }
 800         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 801 }
 802
 803 string MapInfo_ListAllowedMaps()
 804 {
 805         string out;
 806         float i;
 807
 808         // to make absolutely sure:
 809         MapInfo_Enumerate();
 810         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 811
 812         out = "";
 813         for(i = 0; i < MapInfo_count; ++i)
 814                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 815         return substring(out, 1, strlen(out) - 1);
 816 }
 817
 818 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 819 {
 820         float t;
 821         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 822         {
 823                 if(MapInfo_Map_supportedGametypes <= 0)
 824                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 825
 826                 t = 1;
 827                 while(!(MapInfo_Map_supportedGametypes & 1))
 828                 {
 829                         t *= 2;
 830                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 831                 }
 832                 // t is now a supported mode!
 833                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 834                 MapInfo_SwitchGameType(t);
 835         }
 836         cvar_settemp_restore();
 837         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 838         MapInfo_ClearTemps();
 839 }
 840
 841 void MapInfo_ClearTemps()
 842 {
 843         MapInfo_Map_bspname = string_null;
 844         MapInfo_Map_title = string_null;
 845         MapInfo_Map_description = string_null;
 846         MapInfo_Map_author = string_null;
 847         MapInfo_Map_supportedGametypes = 0;
 848         MapInfo_Map_supportedFeatures = 0;
 849 }
 850
 851 void MapInfo_Shutdown()
 852 {
 853         MapInfo_ClearTemps();
 854         MapInfo_Filter_Free();
 855         MapInfo_Cache_Destroy();
 856         if(_MapInfo_globopen)
 857         {
 858                 search_end(_MapInfo_globhandle);
 859                 _MapInfo_globhandle = -1;
 860                 _MapInfo_globopen = FALSE;
 861         }
 862 }