data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float activeweapon;
   4 float weapontime;
   5
   6 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   7
   8 vector sbar;
   9 vector sbar_fontsize;
  10 float sbar_alpha_fg;
  11 float sbar_hudselector;
  12 /*
  13 entity sortedPlayers;
  14 entity sortedTeams;
  15
  16 .float sb_frags;
  17 .float sb_team;
  18 .float sb_player;
  19 .float sb_caps;
  20 */
  21 float ps_primary, ps_secondary;
  22 float ts_primary, ts_secondary;
  23
  24 entity team1, team2, team3, team4, teamspec;
  25
  26 void CSQC_kh_hud();
  27 void CSQC_ctf_hud();
  28 void MapVote_Draw();
  29 void Sbar_FinaleOverlay()
  30 {
  31         /*vector pos;
  32         pos_x = (vid_conwidth - 1)/2;
  33         pos_y = 16;
  34         pos_z = 0;*/
  35
  36         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  37
  38         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  39         MapVote_Draw();
  40 }
  41
  42 void Sbar_DrawWeapon(float nr, float fade, float active)
  43 {
  44         vector pos, vsize, color;
  45         float value;
  46
  47         value = (active) ? 1 : 0.6;
  48         color_x = color_y = color_z = value;
  49
  50         if(sbar_hudselector == 1)
  51         {
  52                 // width = 300, height = 100
  53                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  54
  55                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * nr;
  56                 pos_y = (vid_conheight - w_height);
  57                 pos_z = 0;
  58                 vsize_x = w_width;
  59                 vsize_y = w_height;
  60                 vsize_z = 0;
  61                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  62                 pos_x += w_space;
  63                 pos_y += w_space;
  64                 vsize_x = font_size;
  65                 vsize_y = font_size;
  66                 vsize_z = 0;
  67                 drawstring(pos, ftos(nr+1), vsize, '1 1 0', sbar_alpha_fg, 0);
  68
  69         }
  70         else
  71         {
  72                 // width = 300, height = 100
  73                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  74                 const float w2_scale = 0.4;
  75
  76                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale;
  77                 pos_y = (w2_height + w2_space) * w2_scale * nr + w2_space;
  78                 pos_z = 0;
  79                 vsize_x = w2_width * w2_scale;
  80                 vsize_y = w2_height * w2_scale;
  81                 vsize_z = 0;
  82
  83                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  84         }
  85 }
  86 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
  87 {
  88         float l, i;
  89         string str, tmp;
  90         float minus;
  91         vector vsize;
  92
  93         vsize_x = vsize_y = lettersize;
  94         vsize_z = 0;
  95
  96         if(num < 0)
  97         {
  98                 minus = true;
  99                 num = -num;
 100                 pos_x -= lettersize;
 101         } else
 102                 minus = false;
 103
 104         if(digits < 0)
 105         {
 106                 tmp = ftos(num);
 107                 digits = -digits;
 108                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 109         } else
 110                 str = ftos(num);
 111
 112         l = strlen(str);
 113
 114         if(l > digits)
 115         {
 116                 str = substring(str, l-digits, 999);
 117                 l = strlen(str);
 118         } else if(l < digits)
 119                 pos_x += (digits-l) * lettersize;
 120
 121         if(minus)
 122         {
 123                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 124                 pos_x += lettersize;
 125         }
 126
 127         for(i = 0; i < l; ++i)
 128         {
 129                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 130                 pos_x += lettersize;
 131         }
 132 }
 133
 134 void Cmd_Sbar_SetFields(float argc);
 135 void Sbar_InitScores()
 136 {
 137         float i, f, primary_prio, secondary_prio;
 138
 139         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 140         for(i = 0; i < MAX_SCORE; ++i)
 141         {
 142                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 143                 if(f == SFL_SORT_PRIO_PRIMARY)
 144                         ps_primary = i;
 145                 if(f == SFL_SORT_PRIO_SECONDARY)
 146                         ps_secondary = i;
 147         }
 148         if(ps_secondary == -1)
 149                 ps_secondary = ps_primary;
 150
 151         for(i = 0; i < MAX_TEAMSCORE; ++i)
 152         {
 153                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 154                 if(f == SFL_SORT_PRIO_PRIMARY)
 155                         ts_primary = i;
 156                 if(f == SFL_SORT_PRIO_SECONDARY)
 157                         ts_secondary = i;
 158         }
 159         if(ts_secondary == -1)
 160                 ts_secondary = ts_primary;
 161
 162         Cmd_Sbar_SetFields(0);
 163 }
 164
 165 void Sbar_UpdatePlayerPos(entity pl);
 166 void Sbar_UpdatePlayerTeams()
 167 {
 168         float Team;
 169         entity pl, tmp;
 170         float num;
 171
 172         num = 0;
 173         for(pl = players.sort_next; pl; pl = pl.sort_next)
 174         {
 175                 num += 1;
 176                 Team = GetPlayerColor(pl.sv_entnum);
 177                 if(pl.team != Team)
 178                 {
 179                         tmp = GetTeam(pl.team, false);
 180                         tmp.team_size -= 1;
 181                         tmp = GetTeam(Team, true);
 182                         tmp.team_size += 1;
 183
 184                         pl.team = Team;
 185
 186                         tmp = pl.sort_prev;
 187                         Sbar_UpdatePlayerPos(pl);
 188                         if(tmp)
 189                                 pl = tmp;
 190                         else
 191                                 pl = players.sort_next;
 192                 }
 193         }
 194         //print(strcat("PNUM: ", ftos(num), "\n"));
 195 }
 196
 197 float Sbar_ComparePlayerScores(entity left, entity right)
 198 {
 199         float vl, vr;
 200         vl = GetPlayerColor(left.sv_entnum);
 201         vr = GetPlayerColor(right.sv_entnum);
 202
 203         if(vl > vr)
 204                 return true;
 205         if(vl < vr)
 206                 return false;
 207
 208         vl = left.scores[ps_primary];
 209         vr = right.scores[ps_primary];
 210         if(vl > vr)
 211                 return IS_INCREASING(scores_flags[ps_primary]);
 212         if(vl < vr)
 213                 return IS_DECREASING(scores_flags[ps_primary]);
 214
 215         vl = left.scores[ps_secondary];
 216         vr = right.scores[ps_secondary];
 217         if(vl > vr)
 218                 return IS_INCREASING(scores_flags[ps_secondary]);
 219         if(vl < vr)
 220                 return IS_DECREASING(scores_flags[ps_secondary]);
 221
 222         return false;
 223 }
 224
 225 void Sbar_UpdatePlayerPos(entity player)
 226 {
 227         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 228         {
 229                 SORT_SWAP(player, other);
 230         }
 231         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 232         {
 233                 SORT_SWAP(other, player);
 234         }
 235 }
 236
 237 float Sbar_CompareTeamScores(entity left, entity right)
 238 {
 239         float vl, vr;
 240
 241         if(left.team == COLOR_SPECTATOR)
 242                 return 1;
 243         if(right.team == COLOR_SPECTATOR)
 244                 return 0;
 245
 246         vl = left.teamscores[ts_primary];
 247         vr = right.teamscores[ts_primary];
 248         if(vl > vr)
 249                 return IS_INCREASING(teamscores_flags[ts_primary]);
 250         if(vl < vr)
 251                 return IS_DECREASING(teamscores_flags[ts_primary]);
 252
 253         vl = left.teamscores[ts_secondary];
 254         vr = right.teamscores[ts_secondary];
 255         if(vl > vr)
 256                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 257         if(vl < vr)
 258                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 259
 260         return false;
 261 }
 262
 263 void Sbar_UpdateTeamPos(entity Team)
 264 {
 265         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 266         {
 267                 SORT_SWAP(Team, other);
 268         }
 269         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 270         {
 271                 SORT_SWAP(other, Team);
 272         }
 273 }
 274
 275 void Cmd_Sbar_Help(float argc)
 276 {
 277         print("You can modify the scoreboard using the\n");
 278         print("^3|---------------------------------------------------------------|\n");
 279         print("^1 TO BE DONE\n");
 280         print("Usage:\n");
 281         print("^2sbar_columns_set default\n");
 282         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 283         print("The following field names are recognized (case INsensitive):\n");
 284         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 285
 286         print("^3name^7 or ^3nick^7             Name of a player\n");
 287         print("^3ping^7                     Ping time\n\n");
 288         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 289         print("                         The kill-death ratio\n");
 290
 291         print("Before a field you can put a + or - sign, then a comma separated list\n");
 292         print("of game types, then a slash, to make the field show up only in these\n");
 293         print("or in all but these game types.\n");
 294
 295         local float i;
 296         print("Additional columns:\n");
 297         for(i = 0; i < MAX_SCORE; ++i)
 298         {
 299                 if(scores_label[i] != "")
 300                         print(strcat(scores_label[i], "\n"));
 301         }
 302 }
 303
 304 #define MIN_NAMELEN 24
 305 #define MAX_NAMELEN 24
 306
 307 string Sbar_DefaultColumnLayout()
 308 {
 309         return "ping name | -ctf,kh/kills -ctf,kh/deaths +lms/lives +lms/rank +kh,ctf/caps +kh/pushes +kh/destroyed -lms/score";
 310 }
 311
 312 void Cmd_Sbar_SetFields(float argc)
 313 {
 314         float i, j, slash;
 315         string str, pattern, subpattern;
 316         float digit;
 317         float have_name, have_primary, have_secondary, have_separator;
 318         float missing;
 319
 320         // TODO: re enable with gametype dependant cvars?
 321         if(argc < 2) // no arguments provided
 322                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 323
 324         if(argc < 2)
 325                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 326
 327         if(argc == 2)
 328         {
 329                 if(argv(1) == "default")
 330                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 331                 else if(argv(1) == "all")
 332                 {
 333                         string s;
 334                         s = "ping name |";
 335                         for(i = 0; i < MAX_SCORE; ++i)
 336                         {
 337                                 if(i != ps_primary)
 338                                 if(i != ps_secondary)
 339                                 if(scores_label[i] != "")
 340                                         s = strcat(s, " ", scores_label[i]);
 341                         }
 342                         if(ps_secondary != ps_primary)
 343                                 s = strcat(s, " ", scores_label[ps_secondary]);
 344                         s = strcat(s, " ", scores_label[ps_primary]);
 345                         argc = tokenizebyseparator(strcat("x ", s), " ");
 346                 }
 347         }
 348
 349
 350         argc = min(MAX_SBAR_FIELDS, argc);
 351         sbar_num_fields = 0;
 352
 353         drawfont = sbar_font;
 354         digit = stringwidth("0123456789", FALSE) / 10;
 355
 356         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 357
 358         argc = min(argc-1, MAX_SBAR_FIELDS-1);
 359         for(i = 0; i < argc; ++i)
 360         {
 361                 str = argv(i+1);
 362
 363                 slash = strstrofs(str, "/", 0);
 364                 if(slash >= 0)
 365                 {
 366                         pattern = substring(str, 0, slash);
 367                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 368
 369                         if(substring(pattern, 0, 1) == "-")
 370                         {
 371                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 372                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 373                                         continue;
 374                         }
 375                         else
 376                         {
 377                                 if(substring(pattern, 0, 1) == "+")
 378                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 379                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 380                                         continue;
 381                         }
 382                 }
 383
 384                 strunzone(sbar_title[sbar_num_fields]);
 385                 sbar_title[sbar_num_fields] = strzone(str);
 386                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 387                 str = strtolower(str);
 388
 389                 if(str == "ping") {
 390                         sbar_field[sbar_num_fields] = SP_PING;
 391                 } else if(str == "name" || str == "nick") {
 392                         sbar_field[sbar_num_fields] = SP_NAME;
 393                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 394                         have_name = 1;
 395                 } else if(str == "|") {
 396                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 397                         have_separator = 1;
 398                 } else {
 399                         for(j = 0; j < MAX_SCORE; ++j)
 400                                 if(str == strtolower(scores_label[j]))
 401                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 402 :notfound
 403                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 404                         continue;
 405 :found
 406                         sbar_field[sbar_num_fields] = j;
 407                         if(j == ps_primary)
 408                                 have_primary = 1;
 409                         if(j == ps_secondary)
 410                                 have_secondary = 1;
 411                 }
 412                 ++sbar_num_fields;
 413         }
 414
 415         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 416                 have_primary = 1;
 417         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 418                 have_secondary = 1;
 419         if(ps_primary == ps_secondary)
 420                 have_secondary = 1;
 421         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 422
 423         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 424         {
 425                 if(!have_name)
 426                 {
 427                         strunzone(sbar_title[sbar_num_fields]);
 428                         for(i = sbar_num_fields; i > 0; --i)
 429                         {
 430                                 sbar_title[i] = sbar_title[i-1];
 431                                 sbar_size[i] = sbar_size[i-1];
 432                                 sbar_field[i] = sbar_field[i-1];
 433                         }
 434                         sbar_title[0] = strzone("name");
 435                         sbar_field[0] = SP_NAME;
 436                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 437                         ++sbar_num_fields;
 438                         print("fixed missing field 'name'\n");
 439
 440                         if(!have_separator)
 441                         {
 442                                 strunzone(sbar_title[sbar_num_fields]);
 443                                 for(i = sbar_num_fields; i > 1; --i)
 444                                 {
 445                                         sbar_title[i] = sbar_title[i-1];
 446                                         sbar_size[i] = sbar_size[i-1];
 447                                         sbar_field[i] = sbar_field[i-1];
 448                                 }
 449                                 sbar_title[1] = strzone("|");
 450                                 sbar_field[1] = SP_SEPARATOR;
 451                                 sbar_size[1] = stringwidth("|", FALSE);
 452                                 ++sbar_num_fields;
 453                                 print("fixed missing field '|'\n");
 454                         }
 455                 }
 456                 else if(!have_separator)
 457                 {
 458                         strunzone(sbar_title[sbar_num_fields]);
 459                         sbar_title[sbar_num_fields] = strzone("|");
 460                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 461                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 462                         ++sbar_num_fields;
 463                         print("fixed missing field '|'\n");
 464                 }
 465
 466                 if(!have_secondary)
 467                 {
 468                         strunzone(sbar_title[sbar_num_fields]);
 469                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 470                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 471                         sbar_field[sbar_num_fields] = ps_secondary;
 472                         ++sbar_num_fields;
 473                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 474                 }
 475
 476                 if(!have_primary)
 477                 {
 478                         strunzone(sbar_title[sbar_num_fields]);
 479                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 480                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 481                         sbar_field[sbar_num_fields] = ps_primary;
 482                         ++sbar_num_fields;
 483                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 484                 }
 485         }
 486
 487         sbar_field[sbar_num_fields] = SP_END;
 488 }
 489
 490 // MOVEUP::
 491 vector sbar_field_rgb;
 492 string Sbar_GetField(entity pl, float field)
 493 {
 494         float tmp, num, denom, f;
 495         string str;
 496         sbar_field_rgb = '1 1 1';
 497         switch(field)
 498         {
 499                 case SP_PING:
 500                         str = bufstr_get(databuf, DATABUF_PING + pl.sv_entnum);
 501                         tmp = max(0, min(220, stof(str)-80)) / 220;
 502                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 503                         return str;
 504
 505                 case SP_NAME:
 506                         return getplayerkey(pl.sv_entnum, "name");
 507
 508                 case SP_KDRATIO:
 509                         num = pl.(scores[SP_KILLS]);
 510                         denom = pl.(scores[SP_DEATHS]);
 511
 512                         if(denom == 0) {
 513                                 sbar_field_rgb = '0 1 0';
 514                                 str = ftos(num);
 515                         } else if(num <= 0) {
 516                                 sbar_field_rgb = '1 0 0';
 517                                 str = ftos(num/denom);
 518                         } else
 519                                 str = ftos(num/denom);
 520
 521                         tmp = strstrofs(str, ".", 0);
 522                         if(tmp > 0)
 523                                 str = substring(str, 0, tmp+2);
 524                         return str;
 525
 526                 default:
 527                         tmp = pl.(scores[field]);
 528                         f = scores_flags[field];
 529                         if(field == ps_primary)
 530                                 sbar_field_rgb = '1 1 0';
 531                         else if(field == ps_secondary)
 532                                 sbar_field_rgb = '0 1 1';
 533                         else
 534                                 sbar_field_rgb = '1 1 1';
 535                         if(!tmp)
 536                                 if(f & SFL_HIDE_ZERO)
 537                                         return "";
 538                         return ftos(tmp);
 539         }
 540         //return "error";
 541 }
 542
 543 // shamelessly stolen from menu QC :P <- as if I would steal YOUR code pfft ;)
 544 float textLengthUpToWidth(string theText, float maxWidth, float handleColors)
 545 {
 546         // STOP.
 547         // The following function is SLOW.
 548         // For your safety and for the protection of those around you...
 549         // DO NOT CALL THIS AT HOME.
 550         // No really, don't.
 551         if(stringwidth(theText, handleColors) <= maxWidth)
 552                 return strlen(theText); // yeah!
 553
 554         // binary search for right place to cut string
 555         float left, right, middle; // this always works
 556         left = 0;
 557         right = strlen(theText); // this always fails
 558         do
 559         {
 560                 middle = floor((left + right) / 2);
 561                 if(stringwidth(substring(theText, 0, middle), handleColors) <= maxWidth)
 562                         left = middle;
 563                 else
 564                         right = middle;
 565         }
 566         while(left < right - 1);
 567
 568         // NOTE: when color codes are involved, this binary search is,
 569         // mathematically, BROKEN. However, it is obviously guaranteed to
 570         // terminate, as the range still halves each time - but nevertheless, it is
 571         // guaranteed that it finds ONE valid cutoff place (where "left" is in
 572         // range, and "right" is outside).
 573
 574         return left;
 575 }
 576 string textShortenToWidth(string theText, float maxWidth, float handleColors)
 577 {
 578         if(stringwidth(theText, handleColors) <= maxWidth)
 579                 return theText;
 580         else
 581                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - stringwidth("...", handleColors), handleColors)), "...");
 582 }
 583
 584 float xmin, xmax, ymin, ymax, sbwidth, sbheight;
 585
 586 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 587 {
 588         vector tmp;
 589         string str;
 590         float i, field, len;
 591         float is_spec;
 592         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 593
 594         // Layout:
 595         tmp_z = 0;
 596         if(is_self)
 597         {
 598                 tmp_x = sbwidth;
 599                 tmp_y = sbar_fontsize_y;
 600                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 601         }
 602         tmp_y = 0;
 603
 604         for(i = 0; i < sbar_num_fields; ++i)
 605         {
 606                 field = sbar_field[i];
 607                 if(field == SP_SEPARATOR)
 608                         break;
 609
 610                 if(is_spec && field != SP_NAME && field != SP_PING) {
 611                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 612                         continue;
 613                 }
 614                 str = Sbar_GetField(pl, field);
 615
 616                 if(field == SP_NAME)
 617                 {
 618                         float realsize;
 619                         float j;
 620                         realsize = sbar_size[i];
 621                         if(i+1 < sbar_num_fields)
 622                                 if(sbar_field[i+1] == SP_SEPARATOR)
 623                                 {
 624                                         realsize = (xmax - xmin) / sbar_fontsize_x;
 625                                         for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 626                                                 realsize -= sbar_size[j] + 1;
 627                                         realsize += 1;
 628                                 }
 629                         str = textShortenToWidth(str, realsize, TRUE);
 630                 }
 631                 len = stringwidth(str, TRUE);
 632
 633                 if(sbar_size[i] < len)
 634                         sbar_size[i] = len;
 635
 636                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 637
 638                 if(field == SP_NAME) {
 639                         tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 640                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 641                 } else {
 642                         tmp_x = len*sbar_fontsize_x + sbar_fontsize_x;
 643                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 644                 }
 645         }
 646
 647         if(sbar_field[i] == SP_SEPARATOR)
 648         {
 649                 pos_x = xmax;
 650                 for(i = sbar_num_fields-1; i > 0; --i)
 651                 {
 652                         field = sbar_field[i];
 653                         if(field == SP_SEPARATOR)
 654                                 break;
 655
 656                         if(is_spec && field != SP_NAME && field != SP_PING) {
 657                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 658                                 continue;
 659                         }
 660
 661                         str = Sbar_GetField(pl, field);
 662
 663                         if(field == SP_NAME)
 664                                 str = textShortenToWidth(str, sbar_size[i], TRUE);
 665                         len = stringwidth(str, TRUE);
 666
 667                         if(sbar_size[i] < len)
 668                                 sbar_size[i] = len;
 669
 670                         if(field == SP_NAME) {
 671                                 tmp_x = sbar_fontsize_x*len; // left or right aligned? let's put it right...
 672                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 673                         } else {
 674                                 tmp_x = sbar_fontsize_x*len; //strlen(str);
 675                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 676                         }
 677                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 678                 }
 679         }
 680 }
 681
 682 void Sbar_DrawScoreboard()
 683 {
 684         //float xmin, ymin, xmax, ymax;
 685         vector rgb, pos, tmp, sbar_save;
 686         entity pl, tm;
 687         float specs, i;
 688         float center_x;
 689
 690         sbar_fontsize = Sbar_GetFontsize();
 691         if(sbar_fontsize_x == 0)
 692                 sbar_fontsize = '8 8 0';
 693         if(sbar_fontsize_y == 0)
 694                 sbar_fontsize_y = sbar_fontsize_x;
 695
 696         xmin = vid_conwidth / 5;
 697         ymin = 20;
 698
 699         xmax = vid_conwidth - xmin;
 700         ymax = vid_conheight - 0.2*vid_conheight;
 701
 702         sbwidth = xmax - xmin;
 703         sbheight = ymax - ymin;
 704
 705         center_x = xmin + 0.5*sbwidth;
 706
 707         //Sbar_UpdateFields();
 708
 709         // Initializes position
 710         //pos_x = xmin;
 711         pos_y = ymin;
 712         pos_z = 0;
 713
 714         // Heading
 715         drawfont = sbar_bigfont;
 716         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 717         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 718         pos_x = xmin;
 719         pos_y += 24 + 4;
 720
 721         // Titlebar background:
 722         tmp_x = sbwidth;
 723         tmp_y = sbar_fontsize_y;
 724         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 725
 726         drawfont = sbar_font;
 727
 728         for(i = 0; i < sbar_num_fields; ++i)
 729         {
 730                 if(sbar_field[i] == SP_SEPARATOR)
 731                         break;
 732                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 733                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 734         }
 735
 736         if(sbar_field[i] == SP_SEPARATOR)
 737         {
 738                 pos_x = xmax + sbar_fontsize_x;
 739                 tmp_y = tmp_z = 0;
 740                 for(i = sbar_num_fields-1; i > 0; --i)
 741                 {
 742                         if(sbar_field[i] == SP_SEPARATOR)
 743                                 break;
 744
 745                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 746                         /**
 747                          * FTEQCC BUG!
 748                          * Using the following line will fuck it all up:
 749                          **
 750                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 751                          */
 752                         tmp_x = sbar_fontsize_x*sbar_size[i];
 753                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 754                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 755                 }
 756         }
 757
 758         pos_x = xmin;
 759         pos_y += 1.5 * sbar_fontsize_y;
 760
 761         sbar_save = sbar;
 762         sbar = '0 0 0';
 763
 764         if(teamplay)
 765         {
 766                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 767                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 768                 {
 769                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 770                                 continue;
 771
 772                         rgb = GetTeamRGB(tm.team);
 773
 774                         pos_x = xmin;
 775
 776                         Sbar_DrawXNum(
 777                                 pos - '6.5 0 0' * sbar_fontsize_y,
 778                                 tm.(teamscores[ts_primary]),
 779                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 780
 781                         if(ts_primary != ts_secondary)
 782                         Sbar_DrawXNum(
 783                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 784                                 tm.(teamscores[ts_secondary]),
 785                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 786
 787                         specs = tm.team_size;
 788
 789                         if(specs < 2)
 790                                 specs = 2;
 791
 792                         tmp_x = sbwidth;
 793                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 794                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 795
 796                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 797                         {
 798                                 if(pl.team != tm.team)
 799                                         continue;
 800                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 801                                 pos_y += 1.25 * sbar_fontsize_y;
 802                                 tmp_y -= 1.25 * sbar_fontsize_y;
 803                         }
 804                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 805                 }
 806                 // rgb := tempvector :)
 807                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 808                 pos_y += 3 * sbar_fontsize_y;
 809                 specs = 0;
 810                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 811                 {
 812                         if(pl.team != COLOR_SPECTATOR)
 813                                 continue;
 814                         //drawcolorcodedstring(pos, getplayerkey(pl.sb_player, "name"), '8 8 0', 1, 0);
 815                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 816                         pos += '0 1.25 0' * sbar_fontsize_y;
 817                         ++specs;
 818                 }
 819
 820                 if(specs)
 821                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 822         } else {
 823                 pos_x = xmin;
 824                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 825                 {
 826                         if(pl.team == COLOR_SPECTATOR)
 827                                 continue;
 828                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 829                         pos_y += 1.25 * sbar_fontsize_y;
 830                         tmp_y -= 1.25 * sbar_fontsize_y;
 831                 }
 832
 833                 // rgb := tempvector :)
 834                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 835                 pos_y += 3 * sbar_fontsize_y;
 836                 specs = 0;
 837                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 838                 {
 839                         if(pl.team != COLOR_SPECTATOR)
 840                                 continue;
 841                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 842                         pos += '0 1.25 0' * sbar_fontsize_y;
 843                         ++specs;
 844                 }
 845
 846                 if(specs)
 847                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 848         }
 849
 850         string str;
 851         float tl, fl;
 852         str = strcat("playing on ^2", shortmapname, "^7");
 853         tl = getstatf(STAT_TIMELIMIT);
 854         fl = getstatf(STAT_FRAGLIMIT);
 855         if(gametype == GAME_LMS)
 856         {
 857                 if(tl > 0)
 858                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
 859         }
 860         else
 861         {
 862                 if(tl > 0)
 863                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
 864                 if(fl > 0)
 865                 {
 866                         if(tl > 0)
 867                                 str = strcat(str, " or");
 868                         str = strcat(str, " until ^3", ftos(fl));
 869                         if(scores_label[ps_primary] == "score")
 870                                 str = strcat(str, " points^7");
 871                         else
 872                                 str = strcat(str, " ", scores_label[ps_primary]);
 873                 }
 874         }
 875
 876         pos_y += 1.5 * sbar_fontsize_y;
 877         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
 878
 879         sbar = sbar_save;
 880 }
 881
 882 void Sbar_Score(float margin)
 883 {
 884         float timelimit, timeleft, minutes, seconds, distribution, myplace, score;
 885         vector sbar_save, place;
 886         entity tm, pl, me;
 887         sbar_save = sbar;
 888
 889         myteam = GetPlayerColor(player_localentnum - 1);
 890
 891         sbar_y = vid_conheight - (32+12);
 892         sbar_x -= margin;
 893
 894         place = '-48 -12 0';
 895         if(teamplay)
 896         {
 897                 // Layout:
 898                 //
 899                 //   team1 team3 team4
 900                 //
 901                 //         TEAM2
 902                 //for(i = 0; i < 4; ++i)
 903                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 904                 {
 905                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
 906                                 continue;
 907                         // -32*4 = -128
 908                         score = tm.(teamscores[ts_primary]);
 909                         if(tm.team == myteam)
 910                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
 911                         else
 912                         {
 913                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
 914                                 place_x -= 4*12;
 915                         }
 916                 }
 917         } else {
 918                 // me vector := [team/connected frags id]
 919                 myplace = 0;
 920                 for(me = players.sort_next; me; me = me.sort_next)
 921                 {
 922                         if(me.team != COLOR_SPECTATOR)
 923                                 ++myplace;
 924                         if(me.sv_entnum == player_localentnum - 1)
 925                                 break;
 926                 }
 927                 pl = players;
 928                 if(pl == me)
 929                         pl = pl.sort_next;
 930
 931                 if(pl) {
 932                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
 933                 } else
 934                         distribution = 0;
 935
 936                 if(myplace == 1)
 937                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 938                 else if(myplace == 2)
 939                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
 940                 else
 941                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
 942
 943                 score = me.(scores[ps_primary]);
 944                 if(distribution >= 0)
 945                 {
 946                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
 947                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
 948                 } else if(distribution >= -5)
 949                 {
 950                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
 951                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
 952                 } else {
 953                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
 954                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
 955                 }
 956         }
 957         timelimit = getstatf(STAT_TIMELIMIT);
 958         if(timelimit)
 959         {
 960                 timeleft = max(0, timelimit * 60 - time);
 961                 minutes = floor(timeleft / 60);
 962                 seconds = floor(timeleft - minutes*60);
 963                 if(minutes >= 5)
 964                 {
 965                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 966                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
 967                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 968                 } else if(minutes >= 1)
 969                 {
 970                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
 971                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 0', sbar_alpha_fg, 0);
 972                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
 973                 } else {
 974                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
 975                 }
 976         } else {
 977                 minutes = floor(time / 60);
 978                 seconds = floor(time - minutes*60);
 979                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 980                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
 981                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
 982         }
 983         sbar = sbar_save;
 984 }
 985
 986 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
 987 {
 988         float x, score;
 989         pos_x += 72;
 990
 991         if(teamplay)
 992                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
 993         else
 994                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 995         x = pos_x;
 996         pos_x += 5*8;
 997         score = pl.(scores[ps_primary]);
 998         pos_x -= stringwidth(ftos(score), FALSE)*8;
 999         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1000         pos_x = x;
1001         if(is_self)
1002         {
1003                 pos_x += 48;
1004                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1005                 pos_x += 8;
1006         } else
1007                 pos_x += 56;
1008         drawcolorcodedstring(pos, getplayerkey(pl.sv_entnum, "name"), '8 8 0', 1, 0);
1009 }
1010
1011 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1012 {
1013         float x;
1014         pos_x += 72;
1015
1016         if(teamplay)
1017                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1018         else
1019                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1020         x = pos_x;
1021         pos_x += 5*8;
1022         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1023         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1024         pos_x = x;
1025         if(is_self)
1026         {
1027                 pos_x += 48;
1028                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1029                 pos_x += 8;
1030         } else
1031                 pos_x += 56;
1032         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1033 }
1034
1035 void Sbar_MiniDeathmatchOverlay(vector pos)
1036 {
1037         float numlines, up, down, score;
1038         entity me, tm, pl;
1039         float miniscoreboard_size;
1040         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1041
1042         if(miniscoreboard_size == 0)
1043                 return;
1044         pos_y = vid_conheight - 8;
1045
1046         if(miniscoreboard_size < 0)
1047                 numlines = (vid_conheight - sbar_y + 7) / 8;
1048         else
1049                 numlines = miniscoreboard_size;
1050
1051         // give up if there isn't enough room
1052         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1053                 return;
1054
1055         // me vector := [team/connected frags id]
1056         for(me = players.sort_next; me; me = me.sort_next)
1057         {
1058                 if(me.sv_entnum == player_localentnum - 1)
1059                         break;
1060         }
1061
1062         if(teamplay)
1063                 numlines -= numteams;
1064
1065         // figure out how many players above and below we can show
1066         up = floor(numlines/2);
1067         down = up;
1068         if((up + down) > numlines)
1069                 down = numlines - up;
1070
1071         // render bottom-up
1072         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1073         {
1074                 if(pl.team == COLOR_SPECTATOR)
1075                         continue;
1076                 Sbar_MiniscoreItem(pos, pl, false);
1077                 pos_y -= 9;
1078                 --down;
1079         }
1080         Sbar_MiniscoreItem(pos, me, true);
1081         pos_y -= 9;
1082         up += down; // if there weren't enough lines below... add them
1083         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1084         {
1085                 if(pl.team == COLOR_SPECTATOR)
1086                         continue;
1087                 Sbar_MiniscoreItem(pos, pl, false);
1088                 pos_y -= 9;
1089                 --up;
1090         }
1091
1092         if(teamplay)
1093         {
1094                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1095                 for(; tm; tm = tm.sort_prev)
1096                 {
1097                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1098                                 continue;
1099                         score = tm.(teamscores[ts_primary]);
1100                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1101                         pos_y -= 9;
1102                 }
1103         }
1104 }
1105
1106 float Sbar_WouldDrawScoreboard ()
1107 {
1108         if (sb_showscores)
1109                 return 1;
1110         else if (intermission == 1)
1111                 return 1;
1112         else if (intermission == 2)
1113                 return 1;
1114         return 0;
1115 }
1116
1117 void Sbar_Draw (void)
1118 {
1119         float i;
1120         float x, fade;
1121         float stat_items;
1122
1123         //Sbar_SortFrags();
1124         Sbar_UpdatePlayerTeams();
1125
1126         sb_lines = 24;
1127
1128         if (sb_showscores)
1129                 Sbar_DrawScoreboard();
1130         else if (intermission == 1)
1131         {
1132                 Sbar_DrawScoreboard();
1133                 return;
1134         }
1135         else if (intermission == 2)
1136                 Sbar_FinaleOverlay();
1137         else
1138         {
1139                 if (sb_showscores || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1140                 {
1141                         sbar_x = (vid_conwidth - 640.0)*0.5;
1142                         sbar_y = vid_conheight - 47;
1143                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1144                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1145                         Sbar_DrawScoreboard ();
1146                 }
1147                 else
1148                 {
1149                         if (sb_lines && sbar_hudselector == 1)
1150                         {
1151                                 stat_items = getstati(STAT_ITEMS);
1152
1153                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1154                                 sbar_y = vid_conheight - 24.0 - 16.0;
1155                                 sbar_z = 0;
1156
1157                                 fade = 3.2 - 2 * (time - weapontime);
1158                                 fade = bound(0.7, fade, 1);
1159
1160                                 x = 1.0;
1161                                 for(i = 0; i < 8; ++i)
1162                                 {
1163                                         if(stat_items & x)
1164                                         {
1165                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1166                                         }
1167                                         x *= 2;
1168                                 }
1169                                 x *= 2*2*2*2;
1170                                 if(stat_items & x)
1171                                 {
1172                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1173                                 }
1174
1175                                 // armor
1176                                 x = getstati(STAT_ARMOR);
1177                                 if (x > 0)
1178                                 {
1179                                         // "gfx/sb_armor"
1180                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1181                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1182                                         if(x > 200)
1183                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1184                                         else if(x > 100)
1185                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1186                                         else if(x > 50)
1187                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1188                                         else if(x > 25)
1189                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1190                                         else
1191                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1192                                 }
1193
1194                                 // health
1195                                 x = getstati(STAT_HEALTH);
1196                                 if (x != 0)
1197                                 {
1198                                         // "gfx/sb_health"
1199                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1200                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1201                                         if(x > 200)
1202                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1203                                         else if(x > 100)
1204                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1205                                         else if(x > 50)
1206                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1207                                         else if(x > 25)
1208                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1209                                         else
1210                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1211                                 }
1212
1213                                 // ammo
1214                                 x = getstati(STAT_AMMO);
1215                                 if ((stat_items & (NEX_IT_SHELLS | NEX_IT_BULLETS | NEX_IT_ROCKETS | NEX_IT_CELLS)) || x != 0)
1216                                 {
1217                                         if (stat_items & NEX_IT_SHELLS)
1218                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1219                                         else if (stat_items & NEX_IT_BULLETS)
1220                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1221                                         else if (stat_items & NEX_IT_ROCKETS)
1222                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1223                                         else if (stat_items & NEX_IT_CELLS)
1224                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1225                                         if(x > 10)
1226                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1227                                         else
1228                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1229                                 }
1230
1231                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1232                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1233                                 if (sbar_x > 0)
1234                                         Sbar_Score(16);
1235                                 // The margin can be at most 8 to support 640x480 console size:
1236                                 //   320 + 2 * (144 + 16) = 640
1237                         }
1238                         else if (sb_lines)
1239                         {
1240
1241                                 stat_items = getstati(STAT_ITEMS);
1242
1243                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1244                                 sbar_y = vid_conheight - 47;
1245                                 sbar_z = 0;
1246
1247                                 fade = 3 - 2 * (time - weapontime);
1248
1249                                 x = 1.0;
1250                                 for(i = 0; i < 8; ++i)
1251                                 {
1252                                         if(stat_items & x)
1253                                         {
1254                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1255                                         }
1256                                         x *= 2;
1257                                 }
1258                                 x *= 2*2*2*2;
1259                                 if(stat_items & x)
1260                                 {
1261                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1262                                 }
1263
1264                                 if (sb_lines > 24)
1265                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1266                                 else
1267                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1268
1269                                 // armor
1270                                 // (340-3*24) = 268
1271                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1272
1273                                 // health
1274                                 // (154-3*24) = 82
1275                                 x = getstati(STAT_HEALTH);
1276                                 if(x > 100)
1277                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1278                                 else if(x <= 25 && time - floor(time) > 0.5)
1279                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1280                                 else
1281                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1282
1283                                 // AK dont draw ammo for the laser
1284                                 x = getstati(STAT_AMMO);
1285                                 if(activeweapon != 12)
1286                                 {
1287                                         // (519-3*24) = 447
1288                                         if (stat_items & NEX_IT_SHELLS)
1289                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1290                                         else if (stat_items & NEX_IT_BULLETS)
1291                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1292                                         else if (stat_items & NEX_IT_ROCKETS)
1293                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1294                                         else if (stat_items & NEX_IT_CELLS)
1295                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1296                                         if(x > 10)
1297                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1298                                         else
1299                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1300                                 }
1301
1302                                 if (sb_lines > 24)
1303                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
1304
1305                                 if (sbar_x + 600 + 160 <= vid_conwidth)
1306                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
1307
1308                                 if (sbar_x > 0)
1309                                         Sbar_Score(-16);
1310                                 // Because:
1311                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
1312                                 //   pixels when there are four teams...
1313                                 //   Nexuiz by default sets vid_conwidth to 800... makes
1314                                 //   sbar_x == 80...
1315                                 //   so we need to shift it by 64 pixels to the right to fit
1316                                 //   BUT: then it overlaps with the image that gets drawn
1317                                 //   for viewsize 100! Therefore, just account for 3 teams,
1318                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
1319                                 //   to the right!
1320                         }
1321
1322
1323                         if(gametype == GAME_KEYHUNT)
1324                         {
1325                                 CSQC_kh_hud();
1326                         } else if(gametype == GAME_CTF)
1327                         {
1328                                 CSQC_ctf_hud();
1329                         }
1330                 }
1331         }
1332 }
1333
1334 void CSQC_ctf_hud(void)
1335 {
1336         // cvar("sbar_flagstatus_right") move the flag icons right
1337         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
1338         float redflag, blueflag;
1339         float stat_items;
1340         vector pos;
1341
1342         stat_items = getstati(STAT_ITEMS);
1343         redflag = (stat_items/32768) & 3;
1344         blueflag = (stat_items/131072) & 3;
1345
1346         /**
1347          * FTEQCC BUG!
1348          * For some reason now not even THAT works there...
1349          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
1350          **
1351          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
1352          ** Should try those later:
1353          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
1354          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
1355          */
1356
1357         if(cvar("sbar_flagstatus_right"))
1358                 pos_x = vid_conwidth - 10 - sbar_x - 64;
1359         else
1360                 pos_x = 10 - sbar_x;
1361
1362         pos_z = 0;
1363
1364         if(sbar_hudselector == 1)
1365                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
1366         else
1367                 pos_y = -117;
1368
1369         pos += sbar;
1370
1371         switch(redflag)
1372         {
1373         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1374         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1375         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1376         }
1377
1378         pos_y -= 64;
1379
1380         switch(blueflag)
1381         {
1382         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '0 0 0', '1 1 1', 1, 0); break;
1383         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '0 0 0', '1 1 1', 1, 0); break;
1384         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '0 0 0', '1 1 1', 1, 0); break;
1385         }
1386 }