Docs/server/rcon2irc/rcon2irc.pl

   1 #!/usr/bin/perl
   2
   3 our $VERSION = '0.4.2 svn $Revision$';
   4
   5 # Copyright (c) 2008 Rudolf "divVerent" Polzer
   6 #
   7 # Permission is hereby granted, free of charge, to any person
   8 # obtaining a copy of this software and associated documentation
   9 # files (the "Software"), to deal in the Software without
  10 # restriction, including without limitation the rights to use,
  11 # copy, modify, merge, publish, distribute, sublicense, and/or sell
  12 # copies of the Software, and to permit persons to whom the
  13 # Software is furnished to do so, subject to the following
  14 # conditions:
  15 #
  16 # The above copyright notice and this permission notice shall be
  17 # included in all copies or substantial portions of the Software.
  18 #
  19 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  21 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  22 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  23 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  24 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  26 # OTHER DEALINGS IN THE SOFTWARE.
  27
  28 # MISC STRING UTILITY ROUTINES to convert between DarkPlaces and IRC conventions
  29
  30 # convert mIRC color codes to DP color codes
  31 our @color_irc2dp_table = (7, 0, 4, 2, 1, 1, 6, 1, 3, 2, 5, 5, 4, 6, 7, 7);
  32 our @color_dp2irc_table = (-1, 4, 9, 8, 12, 11, 13, -1, -1, -1); # not accurate, but legible
  33 our @color_dp2ansi_table = ("m", "1;31m", "1;32m", "1;33m", "1;34m", "1;36m", "1;35m", "m", "1m", "1m"); # not accurate, but legible
  34 our %color_team2dp_table = (5 => 1, 14 => 4, 13 => 3, 10 => 6);
  35 our %color_team2irc_table = (5 => 4, 14 => 12, 13 => 8, 10 => 13);
  36 sub color_irc2dp($)
  37 {
  38         my ($message) = @_;
  39         $message =~ s/\^/^^/g;
  40         my $color = 7;
  41         $message =~ s{\003(\d\d?)(?:,(\d?\d?))?|(\017)}{
  42                 # $1 is FG, $2 is BG, but let's ignore BG
  43                 my $oldcolor = $color;
  44                 if($3)
  45                 {
  46                         $color = 7;
  47                 }
  48                 else
  49                 {
  50                         $color = $color_irc2dp_table[$1];
  51                         $color = $oldcolor if not defined $color;
  52                 }
  53                 ($color == $oldcolor) ? '' : '^' . $color;
  54         }esg;
  55         $message =~ s{[\000-\037]}{}gs; # kill bold etc. for now
  56         return $message;
  57 }
  58
  59 our @text_qfont_table = ( # ripped from DP console.c qfont_table
  60     "\0", '#',  '#',  '#',  '#',  '.',  '#',  '#',
  61     '#',  9,    10,   '#',  ' ',  13,   '.',  '.',
  62     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  63     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  64     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  65     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  66     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  67     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  68     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  69     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  70     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  71     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  72     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  73     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  74     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  75     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<',
  76     '<',  '=',  '>',  '#',  '#',  '.',  '#',  '#',
  77     '#',  '#',  ' ',  '#',  ' ',  '>',  '.',  '.',
  78     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  79     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  80     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  81     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  82     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  83     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  84     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  85     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  86     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  87     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  88     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  89     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  90     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  91     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<'
  92 );
  93 sub text_dp2ascii($)
  94 {
  95         my ($message) = @_;
  96         $message = join '', map { $text_qfont_table[ord $_] } split //, $message;
  97 }
  98
  99 sub color_dp_transform(&$)
 100 {
 101         my ($block, $message) = @_;
 102
 103         $message =~ s{(?:(\^\^)|\^x([0-9a-fA-F])([0-9a-fA-F])([0-9a-fA-F])|\^([0-9])|(.))(?=([0-9,]?))}{
 104                 defined $1 ? $block->(char => '^', $7) :
 105                 defined $2 ? $block->(rgb => [hex $2, hex $3, hex $4], $7) :
 106                 defined $5 ? $block->(color => $5, $7) :
 107                 defined $6 ? $block->(char => $6, $7) :
 108                         die "Invalid match";
 109         }esg;
 110
 111         return $message;
 112 }
 113
 114 sub color_dp2none($)
 115 {
 116         my ($message) = @_;
 117
 118         return color_dp_transform
 119         {
 120                 my ($type, $data, $next) = @_;
 121                 print "$type $data\n";
 122                 $type eq 'char'
 123                         ? $text_qfont_table[ord $data]
 124                         : "";
 125         }
 126         $message;
 127 }
 128
 129 sub color_rgb2basic($)
 130 {
 131         my ($data) = @_;
 132         my ($r, $g, $b) = @$data;
 133         my $min = [sort ($r, $g, $b)]->[0];
 134         my $max = [sort ($r, $g, $b)]->[-1];
 135
 136         my $v = $max / 15;
 137         my $s = ($max == $min) ? 0 : 1 - $min/$max;
 138
 139         if($s < 0.2)
 140         {
 141                 return 0 if $v < 0.5;
 142                 return 7;
 143         }
 144
 145         my $h;
 146         if($max == $min)
 147         {
 148                 $h = 0;
 149         }
 150         elsif($max == $r)
 151         {
 152                 $h = (60 * ($g - $b) / ($max - $min)) % 360;
 153         }
 154         elsif($max == $g)
 155         {
 156                 $h = (60 * ($b - $r) / ($max - $min)) + 120;
 157         }
 158         elsif($max == $b)
 159         {
 160                 $h = (60 * ($r - $g) / ($max - $min)) + 240;
 161         }
 162
 163         return 1 if $h < 36;
 164         return 3 if $h < 80;
 165         return 2 if $h < 150;
 166         return 5 if $h < 200;
 167         return 4 if $h < 270;
 168         return 6 if $h < 330;
 169         return 1;
 170 }
 171
 172 sub color_dp_rgb2basic($)
 173 {
 174         my ($message) = @_;
 175         return color_dp_transform
 176         {
 177                 my ($type, $data, $next) = @_;
 178                 print "$type $data\n";
 179                 $type eq 'char'  ? ($data eq '^' ? '^^' : $data) :
 180                 $type eq 'color' ? "^$data" :
 181                 $type eq 'rgb'   ? "^" . color_rgb2basic $data :
 182                         die "Invalid type";
 183         }
 184         $message;
 185 }
 186
 187 sub color_dp2irc($)
 188 {
 189         my ($message) = @_;
 190         my $color = -1;
 191         return color_dp_transform
 192         {
 193                 my ($type, $data, $next) = @_;
 194
 195                 if($type eq 'rgb')
 196                 {
 197                         $type = 'color';
 198                         $data = color_rgb2basic $data;
 199                 }
 200
 201                 $type eq 'char'  ? $text_qfont_table[ord $data] :
 202                 $type eq 'color' ? do {
 203                         my $oldcolor = $color;
 204                         $color = $color_dp2irc_table[$data];
 205
 206                         $color == $oldcolor ? '' :
 207                         $color < 0          ? "\017" :
 208                         $next eq ','        ? "\003$color\002\002" :
 209                                               sprintf "\003%02d", $color;
 210                 } :
 211                         die "Invalid type";
 212         }
 213         $message;
 214 }
 215
 216 sub color_dp2ansi($)
 217 {
 218         my ($message) = @_;
 219         my $color = -1;
 220         return color_dp_transform
 221         {
 222                 my ($type, $data, $next) = @_;
 223
 224                 if($type eq 'rgb')
 225                 {
 226                         $type = 'color';
 227                         $data = color_rgb2basic $data;
 228                 }
 229
 230                 $type eq 'char'  ? $text_qfont_table[ord $data] :
 231                 $type eq 'color' ? do {
 232                         my $oldcolor = $color;
 233                         $color = $color_dp2ansi_table[$data];
 234
 235                         $color eq $oldcolor ? '' :
 236                                               "\033[${color}"
 237                 } :
 238                         die "Invalid type";
 239         }
 240         $message;
 241 }
 242
 243 sub color_dpfix($)
 244 {
 245         my ($message) = @_;
 246         # if the message ends with an odd number of ^, kill one
 247         chop $message if $message =~ /(?:^|[^\^])\^(\^\^)*$/;
 248         return $message;
 249 }
 250
 251
 252
 253
 254 # Interfaces:
 255 #   Connection:
 256 #     $conn->sockname() returns a connection type specific representation
 257 #       string of the local address, or undef if not applicable.
 258 #     $conn->send("string") sends something over the connection.
 259 #     $conn->recv() receives a string from the connection, or returns "" if no
 260 #       data is available.
 261 #     $conn->fds() returns all file descriptors used by the connection, so one
 262 #       can use select() on them.
 263 #   Channel:
 264 #     Usually wraps around a connection and implements a command based
 265 #     structure over it. It usually is constructed using new
 266 #     ChannelType($connection, someparameters...)
 267 #     @cmds = $chan->join_commands(@cmds) joins multiple commands to a single
 268 #       command string if the protocol supports it, or does nothing and leaves
 269 #       @cmds unchanged if the protocol does not support that usage (this is
 270 #       meant to save send() invocations).
 271 #     $chan->send($command, $nothrottle) sends a command over the channel. If
 272 #       $nothrottle is sent, the command must not be left out even if the channel
 273 #       is saturated (for example, because of IRC's flood control mechanism).
 274 #     $chan->quote($str) returns a string in a quoted form so it can safely be
 275 #       inserted as a substring into a command, or returns $str as is if not
 276 #       applicable. It is assumed that the result of the quote method is used
 277 #       as part of a quoted string, if the protocol supports that.
 278 #     $chan->recv() returns a list of received commands from the channel, or
 279 #       the empty list if none are available.
 280 #     $conn->fds() returns all file descriptors used by the channel's
 281 #       connections, so one can use select() on them.
 282
 283
 284
 285
 286
 287
 288
 289 # Socket connection.
 290 # Represents a connection over a socket.
 291 # Mainly used to wrap a channel around it for, in this case, line based or rcon-like operation.
 292 package Connection::Socket;
 293 use strict;
 294 use warnings;
 295 use IO::Socket::INET;
 296 use IO::Handle;
 297
 298 # Constructor:
 299 #   my $conn = new Connection::Socket(tcp => "localaddress" => "remoteaddress" => 6667);
 300 # If the remote address does not contain a port number, the numeric port is
 301 # used (it serves as a default port).
 302 sub new($$)
 303 {
 304         my ($class, $proto, $local, $remote, $defaultport) = @_;
 305         my $sock = IO::Socket::INET->new(
 306                 Proto => $proto,
 307                 (length($local) ? (LocalAddr => $local) : ()),
 308                 PeerAddr => $remote,
 309                 PeerPort => $defaultport
 310         ) or die "socket $proto/$local/$remote: $!";
 311         $sock->blocking(0);
 312         my $you = {
 313                 # Mortal fool! Release me from this wretched tomb! I must be set free
 314                 # or I will haunt you forever! I will hide your keys beneath the
 315                 # cushions of your upholstered furniture... and NEVERMORE will you be
 316                 # able to find socks that match!
 317                 sock => $sock,
 318                 # My demonic powers have made me OMNIPOTENT! Bwahahahahahahaha!
 319         };
 320         return
 321                 bless $you, 'Connection::Socket';
 322 }
 323
 324 # $sock->sockname() returns the local address of the socket.
 325 sub sockname($)
 326 {
 327         my ($self) = @_;
 328         my ($port, $addr) = sockaddr_in $self->{sock}->sockname();
 329         return "@{[inet_ntoa $addr]}:$port";
 330 }
 331
 332 # $sock->send($data) sends some data over the socket; on success, 1 is returned.
 333 sub send($$)
 334 {
 335         my ($self, $data) = @_;
 336         return 1
 337                 if not length $data;
 338         if(not eval { $self->{sock}->send($data); })
 339         {
 340                 warn "$@";
 341                 return 0;
 342         }
 343         return 1;
 344 }
 345
 346 # $sock->recv() receives as much as possible from the socket (or at most 32k). Returns "" if no data is available.
 347 sub recv($)
 348 {
 349         my ($self) = @_;
 350         my $data = "";
 351         if(defined $self->{sock}->recv($data, 32768, 0))
 352         {
 353                 return $data;
 354         }
 355         elsif($!{EAGAIN})
 356         {
 357                 return "";
 358         }
 359         else
 360         {
 361                 return undef;
 362         }
 363 }
 364
 365 # $sock->fds() returns the socket file descriptor.
 366 sub fds($)
 367 {
 368         my ($self) = @_;
 369         return fileno $self->{sock};
 370 }
 371
 372
 373
 374
 375
 376
 377
 378 # Line-based buffered connectionless FIFO channel.
 379 # Whatever is sent to it using send() is echoed back when using recv().
 380 package Channel::FIFO;
 381 use strict;
 382 use warnings;
 383
 384 # Constructor:
 385 #   my $chan = new Channel::FIFO();
 386 sub new($)
 387 {
 388         my ($class) = @_;
 389         my $you = {
 390                 buffer => []
 391         };
 392         return
 393                 bless $you, 'Channel::FIFO';
 394 }
 395
 396 sub join_commands($@)
 397 {
 398         my ($self, @data) = @_;
 399         return @data;
 400 }
 401
 402 sub send($$$)
 403 {
 404         my ($self, $line, $nothrottle) = @_;
 405         push @{$self->{buffer}}, $line;
 406 }
 407
 408 sub quote($$)
 409 {
 410         my ($self, $data) = @_;
 411         return $data;
 412 }
 413
 414 sub recv($)
 415 {
 416         my ($self) = @_;
 417         my $r = $self->{buffer};
 418         $self->{buffer} = [];
 419         return @$r;
 420 }
 421
 422 sub fds($)
 423 {
 424         my ($self) = @_;
 425         return ();
 426 }
 427
 428
 429
 430
 431
 432
 433
 434 # QW rcon protocol channel.
 435 # Wraps around a UDP based Connection and sends commands as rcon commands as
 436 # well as receives rcon replies. The quote and join_commands methods are using
 437 # DarkPlaces engine specific rcon protocol extensions.
 438 package Channel::QW;
 439 use strict;
 440 use warnings;
 441
 442 # Constructor:
 443 #   my $chan = new Channel::QW($connection, "password");
 444 sub new($$)
 445 {
 446         my ($class, $conn, $password) = @_;
 447         my $you = {
 448                 connector => $conn,
 449                 password => $password,
 450                 recvbuf => "",
 451         };
 452         return
 453                 bless $you, 'Channel::QW';
 454 }
 455
 456 # Note: multiple commands in one rcon packet is a DarkPlaces extension.
 457 sub join_commands($@)
 458 {
 459         my ($self, @data) = @_;
 460         return join "\0", @data;
 461 }
 462
 463 sub send($$$)
 464 {
 465         my ($self, $line, $nothrottle) = @_;
 466         return $self->{connector}->send("\377\377\377\377rcon $self->{password} $line");
 467 }
 468
 469 # Note: backslash and quotation mark escaping is a DarkPlaces extension.
 470 sub quote($$)
 471 {
 472         my ($self, $data) = @_;
 473         $data =~ s/[\000-\037]//g;
 474         $data =~ s/([\\"])/\\$1/g;
 475         $data =~ s/\$/\$\$/g;
 476         return $data;
 477 }
 478
 479 sub recv($)
 480 {
 481         my ($self) = @_;
 482         for(;;)
 483         {
 484                 my $s = $self->{connector}->recv();
 485                 die "read error\n"
 486                         if not defined $s;
 487                 length $s
 488                         or last;
 489                 next
 490                         if $s !~ /^\377\377\377\377n(.*)$/s;
 491                 $self->{recvbuf} .= $1;
 492         }
 493         my @out = ();
 494         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 495         {
 496                 push @out, $1;
 497         }
 498         return @out;
 499 }
 500
 501 sub fds($)
 502 {
 503         my ($self) = @_;
 504         return $self->{connector}->fds();
 505 }
 506
 507
 508
 509
 510
 511
 512
 513 # Line based protocol channel.
 514 # Wraps around a TCP based Connection and sends commands as text lines
 515 # (separated by CRLF). When reading responses from the Connection, any type of
 516 # line ending is accepted.
 517 # A flood control mechanism is implemented.
 518 package Channel::Line;
 519 use strict;
 520 use warnings;
 521 use Time::HiRes qw/time/;
 522
 523 # Constructor:
 524 #   my $chan = new Channel::Line($connection);
 525 sub new($$)
 526 {
 527         my ($class, $conn) = @_;
 528         my $you = {
 529                 connector => $conn,
 530                 recvbuf => "",
 531                 capacity => undef,
 532                 linepersec => undef,
 533                 maxlines => undef,
 534                 lastsend => time()
 535         };
 536         return
 537                 bless $you, 'Channel::Line';
 538 }
 539
 540 sub join_commands($@)
 541 {
 542         my ($self, @data) = @_;
 543         return @data;
 544 }
 545
 546 # Sets new flood control parameters:
 547 #   $chan->throttle(maximum lines per second, maximum burst length allowed to
 548 #     exceed the lines per second limit);
 549 #   RFC 1459 describes these parameters to be 0.5 and 5 for the IRC protocol.
 550 #   If the $nothrottle flag is set while sending, the line is sent anyway even
 551 #   if flooding would take place.
 552 sub throttle($$$)
 553 {
 554         my ($self, $linepersec, $maxlines) = @_;
 555         $self->{linepersec} = $linepersec;
 556         $self->{maxlines} = $maxlines;
 557         $self->{capacity} = $maxlines;
 558 }
 559
 560 sub send($$$)
 561 {
 562         my ($self, $line, $nothrottle) = @_;
 563         my $t = time();
 564         if(defined $self->{capacity})
 565         {
 566                 $self->{capacity} += ($t - $self->{lastsend}) * $self->{linepersec};
 567                 $self->{lastsend} = $t;
 568                 $self->{capacity} = $self->{maxlines}
 569                         if $self->{capacity} > $self->{maxlines};
 570                 if(!$nothrottle)
 571                 {
 572                         return -1
 573                                 if $self->{capacity} < 0;
 574                 }
 575                 $self->{capacity} -= 1;
 576         }
 577         $line =~ s/\r|\n//g;
 578         return $self->{connector}->send("$line\r\n");
 579 }
 580
 581 sub quote($$)
 582 {
 583         my ($self, $data) = @_;
 584         $data =~ s/\r\n?/\n/g;
 585         $data =~ s/\n/*/g;
 586         return $data;
 587 }
 588
 589 sub recv($)
 590 {
 591         my ($self) = @_;
 592         for(;;)
 593         {
 594                 my $s = $self->{connector}->recv();
 595                 die "read error\n"
 596                         if not defined $s;
 597                 length $s
 598                         or last;
 599                 $self->{recvbuf} .= $s;
 600         }
 601         my @out = ();
 602         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 603         {
 604                 push @out, $1;
 605         }
 606         return @out;
 607 }
 608
 609 sub fds($)
 610 {
 611         my ($self) = @_;
 612         return $self->{connector}->fds();
 613 }
 614
 615
 616
 617
 618
 619
 620 # main program... a gateway between IRC and DarkPlaces servers
 621 package main;
 622
 623 use strict;
 624 use warnings;
 625 use IO::Select;
 626 use Digest::MD5;
 627 use Time::HiRes qw/time/;
 628
 629 our @handlers = (); # list of [channel, expression, sub to handle result]
 630 our @tasks = (); # list of [time, sub]
 631 our %channels = ();
 632 our %store = (
 633         irc_nick => "",
 634         playernick_0 => "(console)",
 635 );
 636 our %config = (
 637         irc_server => undef,
 638         irc_nick => undef,
 639         irc_user => undef,
 640         irc_channel => undef,
 641         irc_ping_delay => 120,
 642         irc_trigger => "",
 643
 644         irc_nickserv_password => "",
 645         irc_nickserv_identify => 'PRIVMSG NickServ :IDENTIFY %2$s',
 646         irc_nickserv_ghost => 'PRIVMSG NickServ :GHOST %1$s %2$s',
 647         irc_nickserv_ghost_attempts => 3,
 648
 649         irc_quakenet_authname => "",
 650         irc_quakenet_password => "",
 651         irc_quakenet_getchallenge => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGE',
 652         irc_quakenet_challengeauth => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGEAUTH',
 653         irc_quakenet_challengeprefix => ':Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :CHALLENGE',
 654
 655         dp_server => undef,
 656         dp_listen => "",
 657         dp_password => undef,
 658         dp_status_delay => 30,
 659         dp_server_from_wan => "",
 660         irc_local => "",
 661
 662         irc_admin_password => "",
 663         irc_admin_timeout => 3600,
 664
 665         plugins => "",
 666 );
 667
 668
 669
 670 # Nexuiz specific parsing of some server messages
 671
 672 sub nex_is_teamplay($)
 673 {
 674         my ($map) = @_;
 675         return $map =~ /^(?:kh|ctf|tdm|dom)_/;
 676 }
 677
 678 sub nex_slotsstring()
 679 {
 680         my $slotsstr = "";
 681         if(defined $store{slots_max})
 682         {
 683                 my $slots = $store{slots_max} - $store{slots_active};
 684                 my $slots_s = ($slots == 1) ? '' : 's';
 685                 $slotsstr = " ($slots free slot$slots_s)";
 686                 my $s = $config{dp_server_from_wan} || $config{dp_server};
 687                 $slotsstr .= "; join now: \002nexuiz +connect $s"
 688                         if $slots >= 1 and not $store{lms_blocked};
 689         }
 690         return $slotsstr;
 691 }
 692
 693
 694
 695 # Do we have a config file? If yes, read and parse it (syntax: key = value
 696 # pairs, separated by newlines), if not, complain.
 697 die "Usage: $0 configfile\n"
 698         unless @ARGV == 1;
 699
 700 open my $fh, "<", $ARGV[0]
 701         or die "open $ARGV[0]: $!";
 702 while(<$fh>)
 703 {
 704         chomp;
 705         /^#/ and next;
 706         /^(.*?)\s*=(?:\s*(.*))?$/ or next;
 707         warn "Undefined config item: $1"
 708                 unless exists $config{$1};
 709         $config{$1} = defined $2 ? $2 : "";
 710 }
 711 close $fh;
 712 my @missing = grep { !defined $config{$_} } keys %config;
 713 die "The following config items are missing: @missing"
 714         if @missing;
 715
 716
 717
 718 # Create a channel for error messages and other internal status messages...
 719
 720 $channels{system} = new Channel::FIFO();
 721
 722 # for example, quit messages caused by signals (if SIGTERM or SIGINT is first
 723 # received, try to shut down cleanly, and if such a signal is received a second
 724 # time, just exit)
 725 my $quitting = 0;
 726 $SIG{INT} = sub {
 727         exit 1 if $quitting++;
 728         $channels{system}->send("quit SIGINT");
 729 };
 730 $SIG{TERM} = sub {
 731         exit 1 if $quitting++;
 732         $channels{system}->send("quit SIGTERM");
 733 };
 734
 735
 736
 737 # Create the two channels to gateway between...
 738
 739 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
 740 $channels{dp} = new Channel::QW(my $dpsock = new Connection::Socket(udp => $config{dp_listen} => $config{dp_server} => 26000), $config{dp_password});
 741 $config{dp_listen} = $dpsock->sockname();
 742 print "Listening on $config{dp_listen}\n";
 743
 744 $channels{irc}->throttle(0.5, 5);
 745
 746
 747 # Utility routine to write to a channel by name, also outputting what's been written and some status
 748 sub out($$@)
 749 {
 750         my $chanstr = shift;
 751         my $nothrottle = shift;
 752         my $chan = $channels{$chanstr};
 753         if(!$chan)
 754         {
 755                 print "UNDEFINED: $chanstr, ignoring message\n";
 756                 return;
 757         }
 758         @_ = $chan->join_commands(@_);
 759         for(@_)
 760         {
 761                 my $result = $chan->send($_, $nothrottle);
 762                 if($result > 0)
 763                 {
 764                         print "           $chanstr << $_\n";
 765                 }
 766                 elsif($result < 0)
 767                 {
 768                         print "FLOOD:     $chanstr << $_\n";
 769                 }
 770                 else
 771                 {
 772                         print "ERROR:     $chanstr << $_\n";
 773                         $channels{system}->send("error $chanstr", 0);
 774                 }
 775         }
 776 }
 777
 778
 779
 780 # Schedule a task for later execution by the main loop; usage: schedule sub {
 781 # task... }, $time; When a scheduled task is run, a reference to the task's own
 782 # sub is passed as first argument; that way, the task is able to re-schedule
 783 # itself so it gets periodically executed.
 784 sub schedule($$)
 785 {
 786         my ($sub, $time) = @_;
 787         push @tasks, [time() + $time, $sub];
 788 }
 789
 790 # On IRC error, delete some data store variables of the connection, and
 791 # reconnect to the IRC server soon (but only if someone is actually playing)
 792 sub irc_error()
 793 {
 794         # prevent multiple instances of this timer
 795         return if $store{irc_error_active};
 796         $store{irc_error_active} = 1;
 797
 798         delete $channels{irc};
 799         schedule sub {
 800                 my ($timer) = @_;
 801                 if(!defined $store{slots_full})
 802                 {
 803                         # DP is not running, then delay IRC reconnecting
 804                         #use Data::Dumper; print Dumper \$timer;
 805                         schedule $timer => 1;;
 806                         return;
 807                         # this will keep irc_error_active
 808                 }
 809                 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => "" => $config{irc_server}));
 810                 delete $store{$_} for grep { /^irc_/ } keys %store;
 811                 $store{irc_nick} = "";
 812                 schedule sub {
 813                         my ($timer) = @_;
 814                         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp';
 815                         $store{status_waiting} = -1;
 816                 } => 1;
 817                 # this will clear irc_error_active
 818         } => 30;
 819         return 0;
 820 }
 821
 822 # IRC joining (if this is called as response to a nick name collision, $is433 is set);
 823 # among other stuff, it performs NickServ or Quakenet authentication. This is to be called
 824 # until the channel has been joined for every message that may be "interesting" (basically,
 825 # IRC 001 hello messages, 443 nick collision messages and some notices by services).
 826 sub irc_joinstage($)
 827 {
 828         my($is433) = @_;
 829
 830         return 0
 831                 if $store{irc_joined_channel};
 832
 833                 #use Data::Dumper; print Dumper \%store;
 834
 835         if($is433)
 836         {
 837                 if(length $store{irc_nick})
 838                 {
 839                         # we already have another nick, but couldn't change to the new one
 840                         # try ghosting and then get the nick again
 841                         if(length $config{irc_nickserv_password})
 842                         {
 843                                 if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 844                                 {
 845                                         $store{irc_nick_requested} = $config{irc_nick};
 846                                         out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 847                                         schedule sub {
 848                                                 out irc => 1, "NICK $config{irc_nick}";
 849                                         } => 1;
 850                                         return; # we'll get here again for the NICK success message, or for a 433 failure
 851                                 }
 852                                 # otherwise, we failed to ghost and will continue with the wrong
 853                                 # nick... also, no need to try to identify here
 854                         }
 855                         # otherwise, we can't handle this and will continue with our wrong nick
 856                 }
 857                 else
 858                 {
 859                         # we failed to get an initial nickname
 860                         # change ours a bit and try again
 861                         if(length $store{irc_nick_requested} < 9)
 862                         {
 863                                 $store{irc_nick_requested} .= '_';
 864                         }
 865                         else
 866                         {
 867                                 substr $store{irc_nick_requested}, int(rand length $store{irc_nick_requested}), 1, chr(97 + int rand 26);
 868                         }
 869                         out irc => 1, "NICK $store{irc_nick_requested}";
 870                         return; # when it fails, we'll get here again, and when it succeeds, we will continue
 871                 }
 872         }
 873
 874         # we got a 001 or a NICK message, so $store{irc_nick} has been updated
 875         if(length $config{irc_nickserv_password})
 876         {
 877                 if($store{irc_nick} eq $config{irc_nick})
 878                 {
 879                         # identify
 880                         out irc => 1, sprintf($config{irc_nickserv_identify}, $config{irc_nick}, $config{irc_nickserv_password});
 881                 }
 882                 else
 883                 {
 884                         # ghost
 885                         if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 886                         {
 887                                 $store{irc_nick_requested} = $config{irc_nick};
 888                                 out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 889                                 schedule sub {
 890                                         out irc => 1, "NICK $config{irc_nick}";
 891                                 } => 1;
 892                                 return; # we'll get here again for the NICK success message, or for a 433 failure
 893                         }
 894                         # otherwise, we failed to ghost and will continue with the wrong
 895                         # nick... also, no need to try to identify here
 896                 }
 897         }
 898
 899         # we are on Quakenet. Try to authenticate.
 900         if(length $config{irc_quakenet_password} and length $config{irc_quakenet_authname})
 901         {
 902                 if(defined $store{irc_quakenet_challenge})
 903                 {
 904                         if($store{irc_quakenet_challenge} =~ /^MD5 (.*)/)
 905                         {
 906                                 out irc => 1, "$config{irc_quakenet_challengeauth} $config{irc_quakenet_authname} " . Digest::MD5::md5_hex("$config{irc_quakenet_password} $1");
 907                         }
 908                 }
 909                 else
 910                 {
 911                         out irc => 1, $config{irc_quakenet_getchallenge};
 912                         return;
 913                         # we get here again when Q asks us
 914                 }
 915         }
 916
 917         # if we get here, we are on IRC
 918         $store{irc_joined_channel} = 1;
 919         schedule sub {
 920                 out irc => 1, "JOIN $config{irc_channel}";
 921         } => 1;
 922         return 0;
 923 }
 924
 925 my $RE_FAIL = qr/$ $/;
 926 my $RE_SUCCEED = qr//;
 927 sub cond($)
 928 {
 929         return $_[0] ? $RE_FAIL : $RE_SUCCEED;
 930 }
 931
 932
 933 # List of all handlers on the various sockets. Additional handlers can be added by a plugin.
 934 @handlers = (
 935         # detect a server restart and set it up again
 936         [ dp => q{ *(?:Warning: Could not expand \$|Unknown command ")(?:rcon2irc_[a-z0-9_]*)[" ]*} => sub {
 937                 out dp => 0,
 938                         'alias rcon2irc_eval "$*"',
 939                         'log_dest_udp',
 940                         'sv_logscores_console 0',
 941                         'sv_logscores_bots 1',
 942                         'sv_eventlog 1',
 943                         'sv_eventlog_console 1',
 944                         'alias rcon2irc_say_as "set say_as_restorenick \"$sv_adminnick\"; sv_adminnick \"$1^3\"; say \"^7$2\"; rcon2irc_say_as_restore"',
 945                         'alias rcon2irc_say_as_restore "set sv_adminnick \"$say_as_restorenick\""',
 946                         'alias rcon2irc_quit "echo \"quitting rcon2irc $1: log_dest_udp is $log_dest_udp\""'; # note: \\\\\\" ->perl \\\" ->console \"
 947                 return 0;
 948         } ],
 949
 950         # detect missing entry in log_dest_udp and fix it
 951         [ dp => q{"log_dest_udp" is "([^"]*)" \["[^"]*"\]} => sub {
 952                 my ($dest) = @_;
 953                 my @dests = split ' ', $dest;
 954                 return 0 if grep { $_ eq $config{dp_listen} } @dests;
 955                 out dp => 0, 'log_dest_udp "' . join(" ", @dests, $config{dp_listen}) . '"';
 956                 return 0;
 957         } ],
 958
 959         # retrieve list of banned hosts
 960         [ dp => q{#(\d+): (\S+) is still banned for (\S+) seconds} => sub {
 961                 return 0 unless $store{status_waiting} < 0;
 962                 my ($id, $ip, $time) = @_;
 963                 $store{bans_new} = [] if $id == 0;
 964                 $store{bans_new}[$id] = { ip => $ip, 'time' => $time };
 965                 return 0;
 966         } ],
 967
 968         # retrieve hostname from status replies
 969         [ dp => q{host:     (.*)} => sub {
 970                 return 0 unless $store{status_waiting} < 0;
 971                 my ($name) = @_;
 972                 $store{dp_hostname} = $name;
 973                 $store{bans} = $store{bans_new};
 974                 return 0;
 975         } ],
 976
 977         # retrieve version from status replies
 978         [ dp => q{version:  (.*)} => sub {
 979                 return 0 unless $store{status_waiting} < 0;
 980                 my ($version) = @_;
 981                 $store{dp_version} = $version;
 982                 return 0;
 983         } ],
 984
 985         # retrieve player names
 986         [ dp => q{players:  (\d+) active \((\d+) max\)} => sub {
 987                 return 0 unless $store{status_waiting} < 0;
 988                 my ($active, $max) = @_;
 989                 my $full = ($active >= $max);
 990                 $store{slots_max} = $max;
 991                 $store{slots_active} = $active;
 992                 $store{status_waiting} = $active;
 993                 $store{playerslots_active_new} = [];
 994                 if($full != ($store{slots_full} || 0))
 995                 {
 996                         $store{slots_full} = $full;
 997                         return 0
 998                                 if $store{lms_blocked};
 999                         if($full)
1000                         {
1001                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION is full!\001";
1002                         }
1003                         else
1004                         {
1005                                 my $slotsstr = nex_slotsstring();
1006                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can be joined again$slotsstr!\001";
1007                         }
1008                 }
1009                 return 0;
1010         } ],
1011
1012         # retrieve player names
1013         [ dp => q{\^\d(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+(-?\d+)\s+\#(\d+)\s+\^\d(.*)} => sub {
1014                 return 0 unless $store{status_waiting} > 0;
1015                 my ($ip, $pl, $ping, $time, $frags, $no, $name) = ($1, $2, $3, $4, $5, $6, $7);
1016                 $store{"playerslot_$no"} = { ip => $ip, pl => $pl, ping => $ping, 'time' => $time, frags => $frags, no => $no, name => $name };
1017                 push @{$store{playerslots_active_new}}, $no;
1018                 if(--$store{status_waiting} == 0)
1019                 {
1020                         $store{playerslots_active} = $store{playerslots_active_new};
1021                 }
1022                 return 0;
1023         } ],
1024
1025         # IRC admin commands
1026         [ irc => q{:(([^! ]*)![^ ]*) (?i:PRIVMSG) [^&#%]\S* :(.*)} => sub {
1027                 return 0 unless $config{irc_admin_password} ne '';
1028
1029                 my ($hostmask, $nick, $command) = @_;
1030                 my $dpnick = color_dpfix $nick;
1031
1032                 if($command eq "login $config{irc_admin_password}")
1033                 {
1034                         $store{logins}{$hostmask} = time() + $config{irc_admin_timeout};
1035                         out irc => 0, "PRIVMSG $nick :my wish is your command";
1036                         return -1;
1037                 }
1038
1039                 if($command =~ /^login /)
1040                 {
1041                         out irc => 0, "PRIVMSG $nick :invalid password";
1042                         return -1;
1043                 }
1044
1045                 if(($store{logins}{$hostmask} || 0) < time())
1046                 {
1047                         out irc => 0, "PRIVMSG $nick :authentication required";
1048                         return -1;
1049                 }
1050
1051                 if($command =~ /^status(?: (.*))?$/)
1052                 {
1053                         my ($match) = $1;
1054                         my $found = 0;
1055                         my $foundany = 0;
1056                         for my $slot(@{$store{playerslots_active} || []})
1057                         {
1058                                 my $s = $store{"playerslot_$slot"};
1059                                 next unless $s;
1060                                 if(not defined $match or index(color_dp2none($s->{name}), $match) >= 0)
1061                                 {
1062                                         out irc => 0, sprintf 'PRIVMSG %s :%-21s %2i %4i %8s %4i #%-3u %s', $nick, $s->{ip}, $s->{pl}, $s->{ping}, $s->{time}, $s->{frags}, $slot, color_dp2irc $s->{name};
1063                                         ++$found;
1064                                 }
1065                                 ++$foundany;
1066                         }
1067                         if(!$found)
1068                         {
1069                                 if(!$foundany)
1070                                 {
1071                                         out irc => 0, "PRIVMSG $nick :the server is empty";
1072                                 }
1073                                 else
1074                                 {
1075                                         out irc => 0, "PRIVMSG $nick :no nicknames match";
1076                                 }
1077                         }
1078                         return 0;
1079                 }
1080
1081                 if($command =~ /^kick # (\d+) (.*)$/)
1082                 {
1083                         my ($id, $reason) = ($1, $2);
1084                         my $dpreason = color_irc2dp $reason;
1085                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1086                         $dpreason =~ s/(["\\])/\\$1/g;
1087                         out dp => 0, "kick # $id $dpreason";
1088                         my $slotnik = "playerslot_$id";
1089                         out irc => 0, "PRIVMSG $nick :kicked #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}) ($reason)";
1090                         return 0;
1091                 }
1092
1093                 if($command =~ /^kickban # (\d+) (\d+) (\d+) (.*)$/)
1094                 {
1095                         my ($id, $bantime, $mask, $reason) = ($1, $2, $3, $4);
1096                         my $dpreason = color_irc2dp $reason;
1097                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1098                         $dpreason =~ s/(["\\])/\\$1/g;
1099                         out dp => 0, "kickban # $id $bantime $mask $dpreason";
1100                         my $slotnik = "playerslot_$id";
1101                         out irc => 0, "PRIVMSG $nick :kickbanned #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}), netmask $mask, for $bantime seconds ($reason)";
1102                         return 0;
1103                 }
1104
1105                 if($command eq "bans")
1106                 {
1107                         my $banlist =
1108                                 join ", ",
1109                                 map { "$_ ($store{bans}[$_]{ip}, $store{bans}[$_]{time}s)" }
1110                                 0..@{$store{bans} || []}-1;
1111                         $banlist = "no bans"
1112                                 if $banlist eq "";
1113                         out irc => 0, "PRIVMSG $nick :$banlist";
1114                         return 0;
1115                 }
1116
1117                 if($command =~ /^unban (\d+)$/)
1118                 {
1119                         my ($id) = ($1);
1120                         out dp => 0, "unban $id";
1121                         out irc => 0, "PRIVMSG $nick :removed ban $id ($store{bans}[$id]{ip})";
1122                         return 0;
1123                 }
1124
1125                 out irc => 0, "PRIVMSG $nick :unknown command (supported: status [substring], kick # id reason, kickban # id bantime mask reason, bans, unban banid)";
1126
1127                 return -1;
1128         } ],
1129
1130         # LMS: detect "no more lives" message
1131         [ dp => q{\^4.*\^4 has no more lives left} => sub {
1132                 if(!$store{lms_blocked})
1133                 {
1134                         $store{lms_blocked} = 1;
1135                         if(!$store{slots_full})
1136                         {
1137                                 schedule sub {
1138                                         if($store{lms_blocked})
1139                                         {
1140                                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can't be joined until next round (a player has no more lives left)\001";
1141                                         }
1142                                 } => 1;
1143                         }
1144                 }
1145         } ],
1146
1147         # detect IRC errors and reconnect
1148         [ irc => q{ERROR .*} => \&irc_error ],
1149         [ system => q{error irc} => \&irc_error ],
1150
1151         # IRC nick in use
1152         [ irc => q{:[^ ]* 433 .*} => sub {
1153                 return irc_joinstage(433);
1154         } ],
1155
1156         # IRC welcome
1157         [ irc => q{:[^ ]* 001 .*} => sub {
1158                 $store{irc_seen_welcome} = 1;
1159                 $store{irc_nick} = $store{irc_nick_requested};
1160                 return irc_joinstage(0);
1161         } ],
1162
1163         # IRC my nickname changed
1164         [ irc => q{:(?i:(??{$store{irc_nick}}))![^ ]* (?i:NICK) :(.*)} => sub {
1165                 my ($n) = @_;
1166                 $store{irc_nick} = $n;
1167                 return irc_joinstage(0);
1168         } ],
1169
1170         # Quakenet: challenge from Q
1171         [ irc => q{(??{$config{irc_quakenet_challengeprefix}}) (.*)} => sub {
1172                 $store{irc_quakenet_challenge} = $1;
1173                 return irc_joinstage(0);
1174         } ],
1175
1176         # shut down everything on SIGINT
1177         [ system => q{quit (.*)} => sub {
1178                 my ($cause) = @_;
1179                 out irc => 1, "QUIT :$cause";
1180                 $store{quitcookie} = int rand 1000000000;
1181                 out dp => 0, "rcon2irc_quit $store{quitcookie}";
1182         } ],
1183
1184         # remove myself from the log destinations and exit everything
1185         [ dp => q{quitting rcon2irc (??{$store{quitcookie}}): log_dest_udp is (.*) *} => sub {
1186                 my ($dest) = @_;
1187                 my @dests = grep { $_ ne $config{dp_listen} } split ' ', $dest;
1188                 out dp => 0, 'log_dest_udp "' . join(" ", @dests) . '"';
1189                 exit 0;
1190                 return 0;
1191         } ],
1192
1193         # IRC PING
1194         [ irc => q{PING (.*)} => sub {
1195                 my ($data) = @_;
1196                 out irc => 1, "PONG $data";
1197                 return 1;
1198         } ],
1199
1200         # IRC PONG
1201         [ irc => q{:[^ ]* PONG .* :(.*)} => sub {
1202                 my ($data) = @_;
1203                 return 0
1204                         if not defined $store{irc_pingtime};
1205                 return 0
1206                         if $data ne $store{irc_pingtime};
1207                 print "* measured IRC line delay: @{[time() - $store{irc_pingtime}]}\n";
1208                 undef $store{irc_pingtime};
1209                 return 0;
1210         } ],
1211
1212         # detect channel join message and note hostname length to get the maximum allowed line length
1213         [ irc => q{(:(?i:(??{$store{irc_nick}}))![^ ]* )(?i:JOIN) :(?i:(??{$config{irc_channel}}))} => sub {
1214                 $store{irc_maxlen} = 510 - length($1);
1215                 $store{irc_joined_channel} = 1;
1216                 print "* detected maximum line length for channel messages: $store{irc_maxlen}\n";
1217                 return 0;
1218         } ],
1219
1220         # chat: Nexuiz server -> IRC channel
1221         [ dp => q{\001(.*?)\^7: (.*)} => sub {
1222                 my ($nick, $message) = map { color_dp2irc $_ } @_;
1223                 out irc => 0, "PRIVMSG $config{irc_channel} :<$nick\017> $message";
1224                 return 0;
1225         } ],
1226
1227         # chat: Nexuiz server -> IRC channel, nick set
1228         [ dp => q{:join:(\d+):(\d+):([^:]*):(.*)} => sub {
1229                 my ($id, $slot, $ip, $nick) = @_;
1230                 $nick = color_dp2irc $nick;
1231                 $store{"playernick_$id"} = $nick;
1232                 $store{"playerslot_$id"} = $slot;
1233                 $store{"playerip_$id"} = $ip;
1234                 return 0;
1235         } ],
1236
1237         # chat: Nexuiz server -> IRC channel, nick change/set
1238         [ dp => q{:name:(\d+):(.*)} => sub {
1239                 my ($id, $nick) = @_;
1240                 $nick = color_dp2irc $nick;
1241                 my $oldnick = $store{"playernick_$id"};
1242                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 is now known as $nick";
1243                 $store{"playernick_$id"} = $nick;
1244                 return 0;
1245         } ],
1246
1247         # chat: Nexuiz server -> IRC channel, vote call
1248         [ dp => q{:vote:vcall:(\d+):(.*)} => sub {
1249                 my ($id, $command) = @_;
1250                 $command = color_dp2irc $command;
1251                 my $oldnick = $id ? $store{"playernick_$id"} : "(console)";
1252                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 calls a vote for \"$command\017\"";
1253                 return 0;
1254         } ],
1255
1256         # chat: Nexuiz server -> IRC channel, vote stop
1257         [ dp => q{:vote:vstop:(\d+)} => sub {
1258                 my ($id) = @_;
1259                 my $oldnick = $id ? $store{"playernick_$id"} : "(console)";
1260                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 stopped the vote";
1261                 return 0;
1262         } ],
1263
1264         # chat: Nexuiz server -> IRC channel, master login
1265         [ dp => q{:vote:vlogin:(\d+)} => sub {
1266                 my ($id) = @_;
1267                 my $oldnick = $id ? $store{"playernick_$id"} : "(console)";
1268                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 logged in as master";
1269                 return 0;
1270         } ],
1271
1272         # chat: Nexuiz server -> IRC channel, master do
1273         [ dp => q{:vote:vdo:(\d+):(.*)} => sub {
1274                 my ($id, $command) = @_;
1275                 $command = color_dp2irc $command;
1276                 my $oldnick = $id ? $store{"playernick_$id"} : "(console)";
1277                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 used his master status to do \"$command\017\"";
1278                 return 0;
1279         } ],
1280
1281         # chat: Nexuiz server -> IRC channel, result
1282         [ dp => q{:vote:v(yes|no|timeout):(\d+):(\d+):(\d+):(\d+):(-?\d+)} => sub {
1283                 my ($result, $yes, $no, $abstain, $not, $min) = @_;
1284                 my $spam = "$yes:$no" . (($min >= 0) ? " ($min needed)" : "") . ", $abstain didn't care, $not didn't vote";
1285                 out irc => 0, "PRIVMSG $config{irc_channel} :* the vote ended with $result: $spam";
1286                 return 0;
1287         } ],
1288
1289         # chat: IRC channel -> Nexuiz server
1290         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$store{irc_nick}}))(?: |: ?|, ?)(.*)} => sub {
1291                 my ($nick, $message) = @_;
1292                 $nick = color_dpfix $nick;
1293                         # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1294                 $message = color_irc2dp $message;
1295                 $message =~ s/(["\\])/\\$1/g;
1296                 out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1297                 return 0;
1298         } ],
1299
1300         (
1301                 length $config{irc_trigger}
1302                         ?
1303                                 [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$config{irc_trigger}}))(?: |: ?|, ?)(.*)} => sub {
1304                                         my ($nick, $message) = @_;
1305                                         $nick = color_dpfix $nick;
1306                                                 # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1307                                         $message = color_irc2dp $message;
1308                                         $message =~ s/(["\\])/\\$1/g;
1309                                         out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1310                                         return 0;
1311                                 } ]
1312                         :
1313                                 ()
1314         ),
1315
1316         # irc: CTCP VERSION reply
1317         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$store{irc_nick}})) :\001VERSION( .*)?\001} => sub {
1318                 my ($nick) = @_;
1319                 my $ver = $store{dp_version} or return 0;
1320                 $ver .= ", rcon2irc $VERSION";
1321                 out irc => 0, "NOTICE $nick :\001VERSION $ver\001";
1322         } ],
1323
1324         # on game start, notify the channel
1325         [ dp => q{:gamestart:(.*):[0-9.]*} => sub {
1326                 my ($map) = @_;
1327                 $store{playing} = 1;
1328                 $store{map} = $map;
1329                 $store{map_starttime} = time();
1330                 my $slotsstr = nex_slotsstring();
1331                 out irc => 0, "PRIVMSG $config{irc_channel} :\00304" . $map . "\017 has begun$slotsstr";
1332                 delete $store{lms_blocked};
1333                 return 0;
1334         } ],
1335
1336         # on game over, clear the current map
1337         [ dp => q{:gameover} => sub {
1338                 $store{playing} = 0;
1339                 return 0;
1340         } ],
1341
1342         # scores: Nexuiz server -> IRC channel (start)
1343         [ dp => q{:scores:(.*):(\d+)} => sub {
1344                 my ($map, $time) = @_;
1345                 $store{scores} = {};
1346                 $store{scores}{map} = $map;
1347                 $store{scores}{time} = $time;
1348                 $store{scores}{players} = [];
1349                 delete $store{lms_blocked};
1350                 return 0;
1351         } ],
1352
1353         # scores: Nexuiz server -> IRC channel, legacy format
1354         [ dp => q{:player:(-?\d+):(\d+):(\d+):(\d+):(\d+):(.*)} => sub {
1355                 my ($frags, $deaths, $time, $team, $id, $name) = @_;
1356                 return if not exists $store{scores};
1357                 push @{$store{scores}{players}}, [$frags, $team, $name]
1358                         unless $frags <= -666; # no spectators
1359                 return 0;
1360         } ],
1361
1362         # scores: Nexuiz server -> IRC channel (CTF), legacy format
1363         [ dp => q{:teamscores:(\d+:-?\d*(?::\d+:-?\d*)*)} => sub {
1364                 my ($teams) = @_;
1365                 return if not exists $store{scores};
1366                 $store{scores}{teams} = {split /:/, $teams};
1367                 return 0;
1368         } ],
1369
1370         # scores: Nexuiz server -> IRC channel, new format
1371         [ dp => q{:player:see-labels:(\d+)[-0-9,]*:(\d+):(\d+):(\d+):(.*)} => sub {
1372                 my ($frags, $time, $team, $id, $name) = @_;
1373                 return if not exists $store{scores};
1374                 push @{$store{scores}{players}}, [$frags, $team, $name];
1375                 return 0;
1376         } ],
1377
1378         # scores: Nexuiz server -> IRC channel (CTF), new format
1379         [ dp => q{:teamscores:see-labels:(\d+)[-0-9,]*:(\d+)} => sub {
1380                 my ($frags, $team) = @_;
1381                 return if not exists $store{scores};
1382                 $store{scores}{teams}{$team} = $frags;
1383                 return 0;
1384         } ],
1385
1386         # scores: Nexuiz server -> IRC channel
1387         [ dp => q{:end} => sub {
1388                 return if not exists $store{scores};
1389                 my $s = $store{scores};
1390                 delete $store{scores};
1391                 my $teams_matter = nex_is_teamplay($s->{map});
1392
1393                 my @t = ();
1394                 my @p = ();
1395
1396                 if($teams_matter)
1397                 {
1398                         # put players into teams
1399                         my %t = ();
1400                         for(@{$s->{players}})
1401                         {
1402                                 my $thisteam = ($t{$_->[1]} ||= {score => 0, team => $_->[1], players => []});
1403                                 push @{$thisteam->{players}}, [$_->[0], $_->[1], $_->[2]];
1404                                 if($s->{teams})
1405                                 {
1406                                         $thisteam->{score} = $s->{teams}{$_->[1]};
1407                                 }
1408                                 else
1409                                 {
1410                                         $thisteam->{score} += $_->[0];
1411                                 }
1412                         }
1413
1414                         # sort by team score
1415                         @t = sort { $b->{score} <=> $a->{score} } values %t;
1416
1417                         # sort by player score
1418                         @p = ();
1419                         for(@t)
1420                         {
1421                                 @{$_->{players}} = sort { $b->[0] <=> $a->[0] } @{$_->{players}};
1422                                 push @p, @{$_->{players}};
1423                         }
1424                 }
1425                 else
1426                 {
1427                         @p = sort { $b->[0] <=> $a->[0] } @{$s->{players}};
1428                 }
1429
1430                 # no display for empty server
1431                 return 0
1432                         if !@p;
1433
1434                 # make message fit somehow
1435                 for my $maxnamelen(reverse 3..64)
1436                 {
1437                         my $scores_string = "PRIVMSG $config{irc_channel} :\00304" . $s->{map} . "\017 ended:";
1438                         if($teams_matter)
1439                         {
1440                                 my $sep = ' ';
1441                                 for(@t)
1442                                 {
1443                                         $scores_string .= $sep . sprintf "\003%02d\%d\017", $color_team2irc_table{$_->{team}}, $_->{score};
1444                                         $sep = ':';
1445                                 }
1446                         }
1447                         my $sep = '';
1448                         for(@p)
1449                         {
1450                                 my ($frags, $team, $name) = @$_;
1451                                 $name = color_dpfix substr($name, 0, $maxnamelen);
1452                                 if($teams_matter)
1453                                 {
1454                                         $name = "\003" . $color_team2irc_table{$team} . " " . color_dp2none $name;
1455                                 }
1456                                 else
1457                                 {
1458                                         $name = " " . color_dp2irc $name;
1459                                 }
1460                                 $scores_string .= "$sep$name\017 $frags";
1461                                 $sep = ',';
1462                         }
1463                         if(length($scores_string) <= ($store{irc_maxlen} || 256))
1464                         {
1465                                 out irc => 0, $scores_string;
1466                                 return 0;
1467                         }
1468                 }
1469                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION would have LIKED to put the scores here, but they wouldn't fit :(\001";
1470                 return 0;
1471         } ],
1472
1473         # complain when system load gets too high
1474         [ dp => q{timing:   (([0-9.]*)% CPU, ([0-9.]*)% lost, offset avg ([0-9.]*)ms, max ([0-9.]*)ms, sdev ([0-9.]*)ms)} => sub {
1475                 my ($all, $cpu, $lost, $avg, $max, $sdev) = @_;
1476                 return 0 # don't complain when just on the voting screen
1477                         if !$store{playing};
1478                 return 0 # don't complain if it was less than 0.5%
1479                         if $lost < 0.5;
1480                 return 0 # don't complain if nobody is looking
1481                         if $store{slots_active} == 0;
1482                 return 0 # don't complain in the first two minutes
1483                         if time() - $store{map_starttime} < 120;
1484                 return 0 # don't complain if it was already at least half as bad in this round
1485                         if $store{map_starttime} == $store{timingerror_map_starttime} and $lost <= 2 * $store{timingerror_lost};
1486                 $store{timingerror_map_starttime} = $store{map_starttime};
1487                 $store{timingerror_lost} = $lost;
1488                 out dp => 0, 'rcon2irc_say_as server "There are currently some severe system load problems. The admins have been notified."';
1489                 out irc => 1, "PRIVMSG $config{irc_channel} :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1490                 #out irc => 1, "PRIVMSG OpBaI :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1491                 return 0;
1492         } ],
1493 );
1494
1495
1496
1497 # Load plugins and add them to the handler list in the front.
1498 for my $p(split ' ', $config{plugins})
1499 {
1500         my @h = eval { do $p; }
1501                 or die "Invalid plugin $p: $@";
1502         for(reverse @h)
1503         {
1504                 ref $_ eq 'ARRAY' or die "Invalid plugin $p: did not return a list of arrays";
1505                 @$_ == 3 or die "Invalid plugin $p: did not return a list of three-element arrays";
1506                 !ref $_->[0] && !ref $_->[1] && ref $_->[2] eq 'CODE' or die "Invalid plugin $p: did not return a list of string-string-sub arrays";
1507                 unshift @handlers, $_;
1508         }
1509 }
1510
1511
1512
1513 # verify that the server is up by letting it echo back a string that causes
1514 # re-initialization of the required aliases
1515 out dp => 0, 'echo "Unknown command \"rcon2irc_eval\""'; # assume the server has been restarted
1516
1517
1518
1519 # regularily, query the server status and if it still is connected to us using
1520 # the log_dest_udp feature. If not, we will detect the response to this rcon
1521 # command and re-initialize the server's connection to us (either by log_dest_udp
1522 # not containing our own IP:port, or by rcon2irc_eval not being a defined command).
1523 schedule sub {
1524         my ($timer) = @_;
1525         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp', 'rcon2irc_eval set dummy 1';
1526         $store{status_waiting} = -1;
1527         schedule $timer => (exists $store{dp_hostname} ? $config{dp_status_delay} : 1);;
1528 } => 1;
1529
1530
1531
1532 # Continue with connecting to IRC as soon as we get our first status reply from
1533 # the DP server (which contains the server's hostname that we'll use as
1534 # realname for IRC).
1535 schedule sub {
1536         my ($timer) = @_;
1537
1538         # log on to IRC when needed
1539         if(exists $store{dp_hostname} && !exists $store{irc_logged_in})
1540         {
1541                 $store{irc_nick_requested} = $config{irc_nick};
1542                 out irc => 1, "NICK $config{irc_nick}", "USER $config{irc_user} localhost localhost :$store{dp_hostname}";
1543                 $store{irc_logged_in} = 1;
1544                 undef $store{irc_maxlen};
1545                 undef $store{irc_pingtime};
1546         }
1547
1548         schedule $timer => 1;;
1549 } => 1;
1550
1551
1552
1553 # Regularily ping the IRC server to detect if the connection is down. If it is,
1554 # schedule an IRC error that will cause reconnection later.
1555 schedule sub {
1556         my ($timer) = @_;
1557
1558         if($store{irc_logged_in})
1559         {
1560                 if(defined $store{irc_pingtime})
1561                 {
1562                         # IRC connection apparently broke
1563                         # so... KILL IT WITH FIRE
1564                         $channels{system}->send("error irc", 0);
1565                 }
1566                 else
1567                 {
1568                         # everything is fine, send a new ping
1569                         $store{irc_pingtime} = time();
1570                         out irc => 1, "PING $store{irc_pingtime}";
1571                 }
1572         }
1573
1574         schedule $timer => $config{irc_ping_delay};;
1575 } => 1;
1576
1577
1578
1579 # Main loop.
1580 for(;;)
1581 {
1582         # Build up an IO::Select object for all our channels.
1583         my $s = IO::Select->new();
1584         for my $chan(values %channels)
1585         {
1586                 $s->add($_) for $chan->fds();
1587         }
1588
1589         # wait for something to happen on our sockets, or wait 2 seconds without anything happening there
1590         $s->can_read(2);
1591         my @errors = $s->has_exception(0);
1592
1593         # on every channel, look for incoming messages
1594         CHANNEL:
1595         for my $chanstr(keys %channels)
1596         {
1597                 my $chan = $channels{$chanstr};
1598                 my @chanfds = $chan->fds();
1599
1600                 for my $chanfd(@chanfds)
1601                 {
1602                         if(grep { $_ == $chanfd } @errors)
1603                         {
1604                                 # STOP! This channel errored!
1605                                 $channels{system}->send("error $chanstr", 0);
1606                                 next CHANNEL;
1607                         }
1608                 }
1609
1610                 eval
1611                 {
1612                         for my $line($chan->recv())
1613                         {
1614                                 # found one! Check if it matches the regular expression of one of
1615                                 # our handlers...
1616                                 my $handled = 0;
1617                                 my $private = 0;
1618                                 for my $h(@handlers)
1619                                 {
1620                                         my ($chanstr_wanted, $re, $sub) = @$h;
1621                                         next
1622                                                 if $chanstr_wanted ne $chanstr;
1623                                         use re 'eval';
1624                                         my @matches = ($line =~ /^$re$/s);
1625                                         no re 'eval';
1626                                         next
1627                                                 unless @matches;
1628                                         # and if it is a match, handle it.
1629                                         ++$handled;
1630                                         my $result = $sub->(@matches);
1631                                         $private = 1
1632                                                 if $result < 0;
1633                                         last
1634                                                 if $result;
1635                                 }
1636                                 # print the message, together with info on whether it has been handled or not
1637                                 if($private)
1638                                 {
1639                                         print "           $chanstr >> (private)\n";
1640                                 }
1641                                 elsif($handled)
1642                                 {
1643                                         print "           $chanstr >> $line\n";
1644                                 }
1645                                 else
1646                                 {
1647                                         print "unhandled: $chanstr >> $line\n";
1648                                 }
1649                         }
1650                         1;
1651                 } or do {
1652                         if($@ eq "read error\n")
1653                         {
1654                                 $channels{system}->send("error $chanstr", 0);
1655                                 next CHANNEL;
1656                         }
1657                         else
1658                         {
1659                                 # re-throw
1660                                 die $@;
1661                         }
1662                 };
1663         }
1664
1665         # handle scheduled tasks...
1666         my @t = @tasks;
1667         my $t = time();
1668         # by emptying the list of tasks...
1669         @tasks = ();
1670         for(@t)
1671         {
1672                 my ($time, $sub) = @$_;
1673                 if($t >= $time)
1674                 {
1675                         # calling them if they are schedled for the "past"...
1676                         $sub->($sub);
1677                 }
1678                 else
1679                 {
1680                         # or re-adding them to the task list if they still are scheduled for the "future"
1681                         push @tasks, [$time, $sub];
1682                 }
1683         }
1684 }