CMakeLists.txt

   1
   2 project(freespace2)
   3
   4 cmake_minimum_required(VERSION 2.8.6)
   5 cmake_policy(VERSION 2.8.6)
   6
   7 if(POLICY CMP0043)
   8   cmake_policy(SET CMP0043 OLD)
   9 endif()
  10
  11 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake")
  12
  13 include(CreateSourceGroups)
  14
  15
  16 # ##############################################################################
  17
  18 option(FS1 "Build original FreeSpace" OFF)
  19
  20 if(EMSCRIPTEN)
  21   # only build for demo with emscripten
  22   set(DEMO 1)
  23 else()
  24   option(DEMO "Create demo build" OFF)
  25 endif()
  26
  27 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  28   message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  29   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  30   # Set the possible values of build type for cmake-gui
  31   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "RelWithDebInfo" "Release" "Debug")
  32 endif()
  33
  34
  35 if(FS1)
  36   add_definitions(-DMAKE_FS1)
  37
  38   if(DEMO)
  39     add_definitions(-DDEMO -DFS1_DEMO)
  40   endif()
  41 else()
  42   if(DEMO)
  43     add_definitions(-DFS2_DEMO)
  44   endif()
  45 endif()
  46
  47 # build everything by default
  48 set(GAME_ONLY)
  49
  50 if(DEMO)
  51   set(GAME_ONLY 1)
  52 endif()
  53
  54 if(EMSCRIPTEN)
  55   set(GAME_ONLY 1)  # don't build launcher or toolset
  56   add_definitions(-s USE_SDL=2)
  57   add_definitions(-s FULL_ES2=1)
  58
  59   set(CMAKE_EXECUTABLE_SUFFIX ".html")
  60 endif()
  61
  62 if(NOT EMSCRIPTEN)
  63   add_definitions(-DLEGACY_GL)
  64 endif()
  65
  66 if(NOT WIN32)
  67   set(PLATFORM_LIBRARIES "")
  68
  69   add_definitions(-DPLAT_UNIX)
  70   add_definitions(-Wall)
  71   add_definitions(-Wshadow)
  72 # add_definitions(-Wno-format-y2k)
  73 # add_definitions(-Wno-deprecated)
  74   add_definitions(-fsigned-char)
  75
  76   set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -DNDEBUG -DRELEASE_REAL -g -O2")
  77   set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -DNDEBUG -DRELEASE_REAL -O3")
  78   set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -g3")
  79 else()
  80   set(SDL2DIR "${CMAKE_SOURCE_DIR}/../Support/SDL2" CACHE PATH "Path to SDL2")
  81   set(OPENALDIR "${CMAKE_SOURCE_DIR}/../Support/OpenAL" CACHE PATH "Path to OpenAL")
  82   set(LWSDIR "${CMAKE_SOURCE_DIR}/../Support/libwebsockets" CACHE PATH "Path to libwebsockets")
  83   set(WXWIDGETSDIR "${CMAKE_SOURCE_DIR}/../Support/wxWidgets" CACHE PATH "Path to wxWidgets")
  84   set(ANGLEDIR "${CMAKE_SOURCE_DIR}/../Support/ANGLE" CACHE PATH "Path to ANGLE")
  85
  86   set(PLATFORM_LIBRARIES
  87     ws2_32.lib
  88     ${ANGLEDIR}/lib/libEGL.lib
  89     ${ANGLEDIR}/lib/libGLESv2.lib
  90   )
  91
  92   add_definitions(/D _CRT_SECURE_NO_WARNINGS)
  93   add_definitions(/W4)
  94   add_definitions(/wd4100) # unreferenced parameter
  95   add_definitions(/wd4127) # conditional expression is constant: do { } while (0)
  96   add_definitions(/wd4996) # deprecated functions: fopen, fileno, ...
  97 endif()
  98
  99 set(BIN_SUFFIX "")
 100
 101 if(NOT FS1)
 102         set(BIN_SUFFIX "2")
 103 endif()
 104
 105 if(DEMO)
 106         set(BIN_SUFFIX "${BIN_SUFFIX}demo")
 107 endif()
 108
 109 find_package(SDL2 "2.0.5" REQUIRED)
 110 find_package(OpenGL REQUIRED)
 111 find_package(OpenAL REQUIRED)
 112
 113 if(NOT EMSCRIPTEN)
 114   find_package(LibWebSockets REQUIRED)
 115
 116   find_package(wxWidgets COMPONENTS core base gl net)
 117   include(${wxWidgets_USE_FILE})
 118 endif()
 119
 120 # ##############################################################################
 121
 122
 123 include_directories(
 124   ${PROJECT_SOURCE_DIR}/include
 125   ${CMAKE_BINARY_DIR}/include
 126   ${SDL2_INCLUDE_DIR}
 127   ${OPENAL_INCLUDE_DIR}
 128   ${LIBWEBSOCKETS_INCLUDE_DIR}
 129   ${wxWidgets_INCLUDE_DIRS}
 130 )
 131
 132
 133 add_subdirectory(src)
 134 add_subdirectory(include)
 135
 136
 137 # ##############################################################################
 138 #
 139
 140 #
 141 # custom target for source tree version info
 142 #
 143
 144 add_custom_target(buildver
 145   COMMAND ${CMAKE_COMMAND}
 146     -DSOURCE_DIR=${CMAKE_SOURCE_DIR}
 147     -DBINARY_DIR=${CMAKE_BINARY_DIR}
 148     -P ${CMAKE_SOURCE_DIR}/cmake/GitInfo.cmake
 149   WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 150   SOURCES ${CMAKE_SOURCE_DIR}/cmake/GitInfo.cmake
 151 )
 152
 153 #
 154 # main code/game library
 155 #
 156
 157 add_library(code
 158   STATIC
 159   ${code_SOURCE}
 160   ${code_HEADERS}
 161   ${platform_SOURCE}
 162   ${platform_HEADERS}
 163 )
 164
 165 CreateSourceGroups(${code_SOURCE} ${platform_SOURCE})
 166
 167 add_dependencies(code
 168   buildver
 169 )
 170
 171 #
 172 # the game itself
 173 #
 174
 175 set(FS_BINARY "fs${BIN_SUFFIX}")
 176
 177 add_executable(${FS_BINARY}
 178   WIN32
 179   ${freespace_SOURCE}
 180   ${freespace_HEADERS}
 181 )
 182
 183 CreateSourceGroups(${freespace_SOURCE})
 184
 185 target_link_libraries(
 186   ${FS_BINARY}
 187   code
 188   ${SDL2_LIBRARY}
 189   ${OPENGL_LIBRARIES}
 190   ${OPENAL_LIBRARY}
 191   ${LIBWEBSOCKETS_LIBRARIES}
 192   ${PLATFORM_LIBRARIES}
 193 )
 194
 195 if(EMSCRIPTEN)
 196   set(ASYNC_FUNCTIONS
 197         # common
 198     main
 199     game_main
 200     game_init
 201     # fs2 title screen
 202     display_title_screen
 203     # loading screen
 204     game_loop_caller
 205     gameseq_process_events
 206     game_process_event
 207     gameseq_set_state
 208     game_enter_state
 209     game_start_mission
 210     freespace_mission_load_stuff
 211     game_busy_callback
 212     game_loading_callback
 213     game_loading_callback_close
 214     level_page_in
 215     bm_page_in_stop
 216     gamesnd_preload_common_sounds
 217     game_busy
 218   )
 219
 220   list(GET ASYNC_FUNCTIONS -1 LastOne)
 221
 222   set(EMTERPRETIFY_WHITELIST "[")
 223
 224   foreach(func ${ASYNC_FUNCTIONS})
 225     if (${func} STREQUAL ${LastOne})
 226       set(EMTERPRETIFY_WHITELIST "${EMTERPRETIFY_WHITELIST}\"_${func}\"]")
 227     else()
 228       set(EMTERPRETIFY_WHITELIST "${EMTERPRETIFY_WHITELIST}\"_${func}\",")
 229     endif()
 230   endforeach()
 231
 232   set(LINK_FLAGS
 233     "-s USE_SDL=2"
 234     "-s FULL_ES2=1"
 235   # "-s WASM=1"
 236     "-s TOTAL_MEMORY=184549376"
 237     "--shell-file ${CMAKE_SOURCE_DIR}/dist/fs_shell.html"
 238     "--preload-file game@/"
 239     "-s SAFE_HEAP=1"
 240     "-s DEMANGLE_SUPPORT=1"
 241     "-s ASSERTIONS=2"
 242     "--profiling-funcs"
 243   # "-s EMTERPRETIFY=1"
 244   # "-s EMTERPRETIFY_ASYNC=1"
 245   # "-s 'EMTERPRETIFY_FILE=\"${FS_BINARY}.binary\"'"
 246   # "-s 'EMTERPRETIFY_WHITELIST=${EMTERPRETIFY_WHITELIST}'"
 247   )
 248
 249   foreach(Flag ${LINK_FLAGS})
 250     set_property(TARGET ${FS_BINARY} APPEND_STRING PROPERTY LINK_FLAGS " ${Flag}")
 251   endforeach()
 252 endif(EMSCRIPTEN)
 253
 254 if(FS1)
 255   set_target_properties(${FS_BINARY} PROPERTIES PROJECT_LABEL "Freespace")
 256 else()
 257   set_target_properties(${FS_BINARY} PROPERTIES PROJECT_LABEL "Freespace2")
 258 endif()
 259
 260 #
 261 # launcher
 262 #
 263
 264 if(NOT GAME_ONLY)
 265   set(LAUNCHER_BINARY "freespace${BIN_SUFFIX}")
 266
 267   add_executable(${LAUNCHER_BINARY}
 268   WIN32
 269     ${launcher_SOURCE}
 270     ${launcher_HEADERS}
 271   )
 272
 273   add_dependencies(${LAUNCHER_BINARY}
 274     buildver
 275   )
 276
 277   CreateSourceGroups(${launcher_SOURCE})
 278
 279   target_link_libraries(
 280     ${LAUNCHER_BINARY}
 281     ${SDL2_LIBRARY}
 282     ${OPENGL_LIBRARIES}
 283     ${OPENAL_LIBRARY}
 284     ${wxWidgets_LIBRARIES}
 285     ${PLATFORM_LIBRARIES}
 286   )
 287
 288   set_target_properties(${LAUNCHER_BINARY} PROPERTIES PROJECT_LABEL "Launcher")
 289
 290   # wxWidgets appears to need c++11 for one or more headers
 291   if(NOT WIN32)
 292     set_target_properties(${LAUNCHER_BINARY} PROPERTIES COMPILE_FLAGS -std=c++11)
 293   endif()
 294 endif(NOT GAME_ONLY)
 295
 296 #
 297 # standalone server GUI
 298 #
 299
 300 if(NOT GAME_ONLY)
 301   # Not for FS1 Demo
 302   if(NOT FS1 OR NOT DEMO)
 303     if(FS1)
 304       set(STANDALONE_BINARY fsstandalone)
 305     else()
 306       set(STANDALONE_BINARY fs2standalone)
 307     endif()
 308
 309     add_executable(${STANDALONE_BINARY}
 310       WIN32
 311       ${standalone_SOURCE}
 312       ${standalone_HEADERS}
 313     )
 314
 315     CreateSourceGroups(${standalone_SOURCE})
 316
 317     target_link_libraries(
 318       ${STANDALONE_BINARY}
 319       ${SDL2_LIBRARY}
 320       ${wxWidgets_LIBRARIES}
 321       ${LIBWEBSOCKETS_LIBRARIES}
 322       ${PLATFORM_LIBRARIES}
 323     )
 324
 325     set_target_properties(${STANDALONE_BINARY} PROPERTIES PROJECT_LABEL "Standalone")
 326
 327     # wxWidgets appears to need c++11 for one or more headers
 328     if(NOT WIN32)
 329       set_target_properties(${STANDALONE_BINARY} PROPERTIES COMPILE_FLAGS -std=c++11)
 330     endif()
 331   endif(NOT FS1 OR NOT DEMO)
 332 endif(NOT GAME_ONLY)
 333
 334 #
 335 # extra rule to make sure we cleanup all exe variants
 336 #
 337
 338 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES
 339   # FS1 demo
 340   fsdemo${CMAKE_EXECUTABLE_SUFFIX}
 341   fsdemo.html.mem
 342   fsdemo.binary
 343   fsdemo.wast
 344   fsdemo.wasm
 345   fsdemo.js
 346   fsdemo.data
 347   freespacedemo${CMAKE_EXECUTABLE_SUFFIX}
 348   # FS1
 349   fs${CMAKE_EXECUTABLE_SUFFIX}
 350   freespace${CMAKE_EXECUTABLE_SUFFIX}
 351   # FS2 demo
 352   fs2demo${CMAKE_EXECUTABLE_SUFFIX}
 353   fs2demo.html.mem
 354   fs2demo.binary
 355   fs2demo.wast
 356   fs2demo.wasm
 357   fs2demo.js
 358   fs2demo.data
 359   freespace2demo${CMAKE_EXECUTABLE_SUFFIX}
 360   # FS2
 361   fs2${CMAKE_EXECUTABLE_SUFFIX}
 362   freespace2${CMAKE_EXECUTABLE_SUFFIX}
 363   # standalone GUI
 364   fsstandalone${CMAKE_EXECUTABLE_SUFFIX}
 365   fs2standalone${CMAKE_EXECUTABLE_SUFFIX}
 366 )
 367
 368 #
 369 # ##############################################################################
 370
 371 # ##############################################################################
 372 #
 373 # toolset: targets for creating/modifying game assets
 374 #
 375
 376 # don't build toolset unless it's a full build
 377 if(NOT GAME_ONLY)
 378
 379   #
 380   # AC: anim converter
 381   #
 382
 383   add_executable(ac
 384     EXCLUDE_FROM_ALL
 385     ${ac_SOURCE}
 386     ${ac_HEADERS}
 387   )
 388
 389   CreateSourceGroups(${ac_SOURCE})
 390
 391   target_link_libraries(
 392     ac
 393     code
 394     ${SDL2_LIBRARY}
 395     ${OPENGL_LIBRARIES}
 396     ${OPENAL_LIBRARY}
 397     ${LIBWEBSOCKETS_LIBRARIES}
 398     ${PLATFORM_LIBRARIES}
 399   )
 400
 401   #
 402   # CFILEARCHIVER: to create VP file archives
 403   #
 404
 405   add_executable(cfilearchiver
 406     EXCLUDE_FROM_ALL
 407     ${cfilearchiver_SOURCE}
 408   )
 409
 410   CreateSourceGroups(${cfilearchiver_SOURCE})
 411
 412   #
 413   # CRYPTSTRING: string encryption (for embedded cheat codes)
 414   #
 415
 416   add_executable(cryptstring
 417     EXCLUDE_FROM_ALL
 418     ${cryptstring_SOURCE}
 419   )
 420
 421   CreateSourceGroups(${cryptstring_SOURCE})
 422
 423   #
 424   # NEBEDIT: FS1 style nebula editor/creator
 425   #
 426
 427   add_executable(nebedit
 428     EXCLUDE_FROM_ALL
 429     WIN32
 430     ${nebedit_SOURCE}
 431   )
 432
 433   CreateSourceGroups(${nebedit_SOURCE})
 434
 435   target_link_libraries(
 436     nebedit
 437     code
 438     ${SDL2_LIBRARY}
 439     ${OPENGL_LIBRARIES}
 440     ${OPENAL_LIBRARY}
 441     ${wxWidgets_LIBRARIES}
 442     ${LIBWEBSOCKETS_LIBRARIES}
 443     ${PLATFORM_LIBRARIES}
 444   )
 445
 446   # wxWidgets appears to need c++11 for one or more headers
 447   if(NOT WIN32)
 448     set_target_properties(nebedit PROPERTIES COMPILE_FLAGS -std=c++11)
 449   endif()
 450
 451   #
 452   # POFVIEW: model viewer
 453   #
 454
 455   add_executable(pofview
 456     EXCLUDE_FROM_ALL
 457     WIN32
 458     ${pofview_SOURCE}
 459     ${pofview_HEADERS}
 460   )
 461
 462   CreateSourceGroups(${pofview_SOURCE})
 463
 464   target_link_libraries(
 465     pofview
 466     code
 467     ${SDL2_LIBRARY}
 468     ${OPENGL_LIBRARIES}
 469     ${OPENAL_LIBRARY}
 470     ${wxWidgets_LIBRARIES}
 471     ${LIBWEBSOCKETS_LIBRARIES}
 472     ${PLATFORM_LIBRARIES}
 473   )
 474
 475   # wxWidgets appears to need c++11 for one or more headers
 476   if(NOT WIN32)
 477     set_target_properties(pofview PROPERTIES COMPILE_FLAGS -std=c++11)
 478   endif()
 479
 480   #
 481   # SCRAMBLE: file-based encryption for TBLs
 482   #
 483
 484   add_executable(scramble
 485     EXCLUDE_FROM_ALL
 486     ${scramble_SOURCE}
 487     ${scramble_HEADERS}
 488   )
 489
 490   CreateSourceGroups(${scramble_SOURCE})
 491
 492   #
 493   # FONTTOOL: create font files / edit kerning data
 494   #
 495
 496   add_executable(fonttool
 497     EXCLUDE_FROM_ALL
 498     ${fonttool_SOURCE}
 499     ${fonttool_HEADERS}
 500   )
 501
 502   CreateSourceGroups(${fonttool_SOURCE})
 503
 504   # background setup, to allow running from build location without installing
 505   add_custom_command(TARGET fonttool
 506     POST_BUILD
 507     COMMAND ${CMAKE_COMMAND} -E make_directory "${CMAKE_CURRENT_BINARY_DIR}/src/fonttool"
 508     COMMAND ${CMAKE_COMMAND} -E copy "${PROJECT_SOURCE_DIR}/src/fonttool/fonttool.pcx" "${CMAKE_CURRENT_BINARY_DIR}/src/fonttool"
 509   )
 510
 511   target_link_libraries(
 512     fonttool
 513     code
 514     ${SDL2_LIBRARY}
 515     ${OPENGL_LIBRARIES}
 516     ${OPENAL_LIBRARY}
 517     ${LIBWEBSOCKETS_LIBRARIES}
 518     ${PLATFORM_LIBRARIES}
 519   )
 520
 521   #
 522   # custom target to build all tools in one pass
 523   #
 524
 525   add_custom_target(tools)
 526
 527   add_dependencies(tools
 528     ac
 529     cfilearchiver
 530     cryptstring
 531     nebedit
 532     pofview
 533     scramble
 534     fonttool
 535   )
 536
 537 endif(NOT GAME_ONLY)
 538
 539 #
 540 # ##############################################################################
 541
 542 #
 543 # optionally include any dev/user preferred build commands and/or options
 544 #
 545
 546 include(custom.cmake OPTIONAL)