configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 # Author: Lasse Collin
   7 #
   8 # This file has been put into the public domain.
   9 # You can do whatever you want with this file.
  10 #
  11 ###############################################################################
  12
  13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  14 # let it confuse you. For example, we don't care about checking for behavior
  15 # of malloc(), stat(), or lstat(), since we don't use those functions in
  16 # a way that would cause the problems the autoconf macros check.
  17
  18 AC_PREREQ([2.61])
  19
  20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh version.sh]),
  21         [lasse.collin@tukaani.org], [xz])
  22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CONFIG_HEADER([config.h])
  26
  27 PACKAGE_HOMEPAGE=http://tukaani.org/xz/
  28 AC_DEFINE_UNQUOTED([PACKAGE_HOMEPAGE], ["$PACKAGE_HOMEPAGE"],
  29         [Define to the URL of the home page of this package.])
  30 AC_SUBST([PACKAGE_HOMEPAGE])
  31
  32 echo
  33 echo "$PACKAGE_STRING"
  34
  35 echo
  36 echo "System type:"
  37 # This is needed to know if assembler optimizations can be used.
  38 AC_CANONICAL_HOST
  39
  40 # We do some special things on Windows (32-bit or 64-bit) builds.
  41 case $host_os in
  42         mingw* | cygwin*) is_w32=yes ;;
  43         *)                is_w32=no ;;
  44 esac
  45 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
  46
  47 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
  48 # executables. Cygwin is an exception to this, since it is recommended
  49 # that symlinks don't have the .exe suffix. To make this work, we
  50 # define LN_EXEEXT.
  51 case $host_os in
  52         cygwin)  LN_EXEEXT= ;;
  53         *)       LN_EXEEXT='$(EXEEXT)' ;;
  54 esac
  55 AC_SUBST([LN_EXEEXT])
  56
  57 echo
  58 echo "Configure options:"
  59 AM_CFLAGS=
  60
  61
  62 #############
  63 # Debugging #
  64 #############
  65
  66 AC_MSG_CHECKING([if debugging code should be compiled])
  67 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  68         [], enable_debug=no)
  69 if test "x$enable_debug" = xyes; then
  70         AC_MSG_RESULT([yes])
  71 else
  72         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  73         AC_MSG_RESULT([no])
  74 fi
  75
  76
  77 ###########
  78 # Filters #
  79 ###########
  80
  81 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,subblock,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
  82 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
  83 m4_define([LZ_FILTERS], [lzma1,lzma2])
  84
  85 m4_foreach([NAME], [SUPPORTED_FILTERS],
  86 [enable_filter_[]NAME=no
  87 enable_encoder_[]NAME=no
  88 enable_decoder_[]NAME=no
  89 ])dnl
  90
  91 AC_MSG_CHECKING([which encoders to build])
  92 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
  93                 [Comma-separated list of encoders to build. Default=all.
  94                 Available encoders:]
  95                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
  96         [], [enable_encoders=SUPPORTED_FILTERS])
  97 enable_encoders=`echo "$enable_encoders" | sed 's/,subblock//; s/,/ /g'`
  98 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
  99         AC_MSG_RESULT([(none)])
 100 else
 101         AC_DEFINE([HAVE_ENCODER], [1],
 102                 [Define to 1 if encoder components are enabled.])
 103         for arg in $enable_encoders
 104         do
 105                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 106                         NAME)
 107                                 enable_filter_[]NAME=yes
 108                                 enable_encoder_[]NAME=yes
 109                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
 110                                 [Define to 1 if] NAME [encoder is enabled.])
 111                                 ;;])
 112                         *)
 113                                 AC_MSG_RESULT([])
 114                                 AC_MSG_ERROR([unknown filter: $arg])
 115                                 ;;
 116                 esac
 117         done
 118         AC_MSG_RESULT([$enable_encoders])
 119 fi
 120
 121 AC_MSG_CHECKING([which decoders to build])
 122 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 123                 [Comma-separated list of decoders to build. Default=all.
 124                 Available decoders are the same as available encoders.]),
 125         [], [enable_decoders=SUPPORTED_FILTERS])
 126 enable_decoders=`echo "$enable_decoders" | sed 's/,subblock//; s/,/ /g'`
 127 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 128         AC_MSG_RESULT([(none)])
 129 else
 130         AC_DEFINE([HAVE_DECODER], [1],
 131                 [Define to 1 if decoder components are enabled.])
 132         for arg in $enable_decoders
 133         do
 134                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 135                         NAME)
 136                                 enable_filter_[]NAME=yes
 137                                 enable_decoder_[]NAME=yes
 138                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 139                                 [Define to 1 if] NAME [decoder is enabled.])
 140                                 ;;])
 141                         *)
 142                                 AC_MSG_RESULT([])
 143                                 AC_MSG_ERROR([unknown filter: $arg])
 144                                 ;;
 145                 esac
 146         done
 147
 148         # LZMA2 requires that LZMA1 is enabled.
 149         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 150         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 151
 152         AC_MSG_RESULT([$enable_decoders])
 153 fi
 154
 155 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 156                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 157         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 158 fi
 159
 160 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno && test "x$enable_encoders" != x)
 161 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno && test "x$enable_decoders" != x)
 162
 163 m4_foreach([NAME], [SUPPORTED_FILTERS],
 164 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 165 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 166 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 167 ])dnl
 168
 169 # The so called "simple filters" share common code.
 170 enable_filter_simple=no
 171 enable_encoder_simple=no
 172 enable_decoder_simple=no
 173 m4_foreach([NAME], [SIMPLE_FILTERS],
 174 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 175 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 176 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 177 ])dnl
 178 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 179 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 180 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 181
 182 # LZ-based filters share common code.
 183 enable_filter_lz=no
 184 enable_encoder_lz=no
 185 enable_decoder_lz=no
 186 m4_foreach([NAME], [LZ_FILTERS],
 187 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 188 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 189 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 190 ])dnl
 191 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 192 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 193 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 194
 195
 196 #################
 197 # Match finders #
 198 #################
 199
 200 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 201
 202 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 203 [enable_match_finder_[]NAME=no
 204 ])
 205
 206 AC_MSG_CHECKING([which match finders to build])
 207 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 208                 [Comma-separated list of match finders to build. Default=all.
 209                 At least one match finder is required for encoding with
 210                 the LZMA1 and LZMA2 filters. Available match finders:]
 211                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 212         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 213 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 214 if test "x$enable_encoder_lz" = xyes ; then
 215         for arg in $enable_match_finders
 216                 do
 217                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 218                         NAME)
 219                                 enable_match_finder_[]NAME=yes
 220                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 221                                 [Define to 1 to enable] NAME [match finder.])
 222                                 ;;])
 223                         *)
 224                                 AC_MSG_RESULT([])
 225                                 AC_MSG_ERROR([unknown match finder: $arg])
 226                                 ;;
 227                 esac
 228         done
 229         AC_MSG_RESULT([$enable_match_finders])
 230 else
 231         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 232 fi
 233
 234
 235 ####################
 236 # Integrity checks #
 237 ####################
 238
 239 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 240
 241 m4_foreach([NAME], [SUPPORTED_FILTERS],
 242 [enable_check_[]NAME=no
 243 ])dnl
 244
 245 AC_MSG_CHECKING([which integrity checks to build])
 246 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 247                 [Comma-separated list of integrity checks to build.
 248                 Default=all. Available integrity checks:]
 249                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 250         [], [enable_checks=SUPPORTED_CHECKS])
 251 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 252 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 253         AC_MSG_RESULT([(none)])
 254 else
 255         for arg in $enable_checks
 256         do
 257                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 258                         NAME)
 259                                 enable_check_[]NAME=yes
 260                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 261                                 [Define to 1 if] NAME
 262                                 [integrity check is enabled.])
 263                                 ;;])
 264                         *)
 265                                 AC_MSG_RESULT([])
 266                                 AC_MSG_ERROR([unknown integrity check: $arg])
 267                                 ;;
 268                 esac
 269         done
 270         AC_MSG_RESULT([$enable_checks])
 271 fi
 272 if test "x$enable_checks_crc32" = xno ; then
 273         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 274 fi
 275
 276 m4_foreach([NAME], [SUPPORTED_CHECKS],
 277 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 278 ])dnl
 279
 280
 281 ###########################
 282 # Assembler optimizations #
 283 ###########################
 284
 285 AC_MSG_CHECKING([if assembler optimizations should be used])
 286 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 287                 [Do not use assembler optimizations even if such exist
 288                 for the architecture.]),
 289         [], [enable_assembler=yes])
 290 if test "x$enable_assembler" = xyes; then
 291         case $host_cpu in
 292                 i?86)   enable_assembler=x86 ;;
 293                 x86_64) enable_assembler=x86_64 ;;
 294                 *)      enable_assembler=no ;;
 295         esac
 296 fi
 297 case $enable_assembler in
 298         x86)
 299                 AC_DEFINE([HAVE_ASM_X86], [1],
 300                         [Define to 1 if using x86 assembler optimizations.])
 301                 ;;
 302         x86_64)
 303                 AC_DEFINE([HAVE_ASM_X86_64], [1],
 304                         [Define to 1 if using x86_64 assembler optimizations.])
 305                 ;;
 306         no)
 307                 ;;
 308         *)
 309                 AC_MSG_RESULT([])
 310                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 311                 ;;
 312 esac
 313 AC_MSG_RESULT([$enable_assembler])
 314 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 315 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 316
 317
 318 #####################
 319 # Size optimization #
 320 #####################
 321
 322 AC_MSG_CHECKING([if small size is preferred over speed])
 323 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 324                 [Make liblzma smaller and a little slower.
 325                 This is disabled by default to optimize for speed.]),
 326         [], [enable_small=no])
 327 if test "x$enable_small" = xyes; then
 328         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 329 elif test "x$enable_small" != xno; then
 330         AC_MSG_RESULT([])
 331         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 332 fi
 333 AC_MSG_RESULT([$enable_small])
 334 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 335
 336
 337 #############
 338 # Threading #
 339 #############
 340
 341 AC_MSG_CHECKING([if threading support is wanted])
 342 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 343                 [Disable threading support.
 344                 This makes some things thread-unsafe.]),
 345         [], [enable_threads=yes])
 346 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 347         AC_MSG_RESULT([])
 348         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 349 fi
 350 AC_MSG_RESULT([$enable_threads])
 351 # We use the actual result a little later.
 352
 353
 354 #########################
 355 # Assumed amount of RAM #
 356 #########################
 357
 358 # We use 32 MiB as default, because it should be small enough for most
 359 # cases and allows decompressing files compressed with the default settings.
 360 # Probably it is too small for most systems, but it's safer to guess too low.
 361 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
 362 AC_ARG_ENABLE([assume-ram], AC_HELP_STRING([--enable-assume-ram=SIZE],
 363                 [If and only if the real amount of RAM cannot be determined,
 364                 assume SIZE MiB. The default is 32 MiB. This affects the
 365                 default memory usage limit.]),
 366         [], [enable_assume_ram=32])
 367 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
 368 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
 369         AC_MSG_RESULT([])
 370         AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
 371 fi
 372 AC_MSG_RESULT([$enable_assume_ram MiB])
 373 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
 374                 [How many MiB of RAM to assume if the real amount cannot
 375                 be determined.])
 376
 377
 378 ############################################
 379 # xz/xzdec/lzmadec linkage against liblzma #
 380 ############################################
 381
 382 # Link the xz, xzdec, and lzmadec command line tools against static liblzma
 383 # unless using --enable-dynamic. Using static liblzma gives a little bit
 384 # faster executable on x86, because no register is wasted for PIC. We also
 385 # have one dependency less, which allows users to more freely copy the xz
 386 # binary to other boxes. However, I wouldn't be surprised if distro
 387 # maintainers still prefer dynamic linking, so let's make it easy for them.
 388
 389 AC_MSG_CHECKING([how programs should be linked against liblzma])
 390 AC_ARG_ENABLE([dynamic], [AC_HELP_STRING([--enable-dynamic=TYPE],
 391                         [Set how command line tools are linked against liblzma.
 392                         TYPE can be mixed, yes, or no. The default is mixed.])],
 393                 [], [enable_dynamic=mixed])
 394 case $enable_dynamic in
 395         mixed)
 396                 AC_MSG_RESULT([mixed (some dynamically, some statically)])
 397                 ;;
 398         yes)
 399                 AC_MSG_RESULT([dynamically])
 400                 ;;
 401         no)
 402                 AC_MSG_RESULT([statically])
 403                 ;;
 404         *)
 405                 AC_MSG_RESULT([])
 406                 AC_MSG_ERROR([--enable-dynamic accepts only \`mixed', \`yes', or \`no'])
 407                 ;;
 408 esac
 409 # We use the actual results later, because we don't know yet
 410 # if --disable-shared or --disable-static was used.
 411
 412
 413 ###############################################################################
 414 # Checks for programs.
 415 ###############################################################################
 416
 417 echo
 418 gl_POSIX_SHELL
 419 if test -z "$POSIX_SHELL" ; then
 420         AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
 421 fi
 422
 423 echo
 424 echo "Initializing Automake:"
 425
 426 AM_INIT_AUTOMAKE([1.10 foreign tar-v7 filename-length-max=99])
 427 AC_PROG_LN_S
 428
 429 AC_PROG_CC_C99
 430 if test x$ac_cv_prog_cc_c99 = xno ; then
 431         AC_MSG_ERROR([No C99 compiler was found.])
 432 fi
 433
 434 AM_PROG_CC_C_O
 435 AM_PROG_AS
 436 AC_USE_SYSTEM_EXTENSIONS
 437
 438 if test "x$enable_threads" = xyes; then
 439         echo
 440         echo "Threading support:"
 441         ACX_PTHREAD
 442         LIBS="$LIBS $PTHREAD_LIBS"
 443         AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 444         CC="$PTHREAD_CC"
 445 fi
 446
 447 echo
 448 echo "Initializing Libtool:"
 449 LT_PREREQ([2.2])
 450 LT_INIT([win32-dll])
 451 LT_LANG([Windows Resource])
 452
 453 # This is a bit wrong since it is possible to request that only some libs
 454 # are built as shared. Using that feature isn't so common though, and this
 455 # breaks only on Windows (at least for now) if the user enables only some
 456 # libs as shared.
 457 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
 458
 459
 460 ###############################################################################
 461 # Checks for libraries.
 462 ###############################################################################
 463
 464 echo
 465 echo "Initializing gettext:"
 466 AM_GNU_GETTEXT_VERSION([0.16.1])
 467 AM_GNU_GETTEXT([external])
 468
 469 ###############################################################################
 470 # Checks for header files.
 471 ###############################################################################
 472
 473 echo
 474 echo "System headers and functions:"
 475
 476 # There is currently no workarounds in this package if some of
 477 # these headers are missing.
 478 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 479         [],
 480         [AC_MSG_ERROR([Required header file(s) are missing.])])
 481
 482
 483 ###############################################################################
 484 # Checks for typedefs, structures, and compiler characteristics.
 485 ###############################################################################
 486
 487 dnl We don't need these as long as we need a C99 compiler anyway.
 488 dnl AC_C_INLINE
 489 dnl AC_C_RESTRICT
 490
 491 AC_HEADER_STDBOOL
 492
 493 AC_TYPE_UINT8_T
 494 AC_TYPE_UINT16_T
 495 AC_TYPE_INT32_T
 496 AC_TYPE_UINT32_T
 497 AC_TYPE_INT64_T
 498 AC_TYPE_UINT64_T
 499 AC_TYPE_UINTPTR_T
 500
 501 AC_CHECK_SIZEOF([size_t])
 502
 503 # The command line tool can copy high resolution timestamps if such
 504 # information is availabe in struct stat. Otherwise one second accuracy
 505 # is used.
 506 AC_CHECK_MEMBERS([
 507         struct stat.st_atim.tv_nsec,
 508         struct stat.st_atimespec.tv_nsec,
 509         struct stat.st_atimensec,
 510         struct stat.st_uatime,
 511         struct stat.st_atim.st__tim.tv_nsec])
 512
 513 AC_SYS_LARGEFILE
 514 AC_C_BIGENDIAN
 515
 516
 517 ###############################################################################
 518 # Checks for library functions.
 519 ###############################################################################
 520
 521 # Gnulib replacements as needed
 522 gl_GETOPT
 523
 524 # Find the best function to set timestamps.
 525 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 526
 527 TUKLIB_PROGNAME
 528 TUKLIB_INTEGER
 529 TUKLIB_PHYSMEM
 530 TUKLIB_CPUCORES
 531
 532
 533 ###############################################################################
 534 # If using GCC, set some additional AM_CFLAGS:
 535 ###############################################################################
 536
 537 if test "$GCC" = yes ; then
 538         echo
 539         echo "GCC extensions:"
 540 fi
 541
 542 # Always do the visibility check but don't set AM_CFLAGS on Windows.
 543 # This way things get set properly even on Windows.
 544 gl_VISIBILITY
 545 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
 546         AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
 547 fi
 548
 549 if test "$GCC" = yes ; then
 550         # Enable as much warnings as possible. These commented warnings won't
 551         # work for this package though:
 552         #   * -Wunreachable-code breaks several assert(0) cases, which are
 553         #     backed up with "return LZMA_PROG_ERROR".
 554         #   * -Wcast-qual would break various things where we need a non-const
 555         #     pointer although we don't modify anything through it.
 556         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 557         #     on some architectures (not on x86), where this warning is bogus,
 558         #     because we take care of correct alignment.
 559         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 560         #     don't seem so useful here; at least the last one gives some
 561         #     warnings which are not bugs.
 562         for NEW_FLAG in \
 563                         -Wall \
 564                         -Wextra \
 565                         -Wformat=2 \
 566                         -Winit-self \
 567                         -Wmissing-include-dirs \
 568                         -Wstrict-aliasing \
 569                         -Wfloat-equal \
 570                         -Wundef \
 571                         -Wshadow \
 572                         -Wpointer-arith \
 573                         -Wbad-function-cast \
 574                         -Wwrite-strings \
 575                         -Wlogical-op \
 576                         -Waggregate-return \
 577                         -Wstrict-prototypes \
 578                         -Wold-style-definition \
 579                         -Wmissing-prototypes \
 580                         -Wmissing-declarations \
 581                         -Wmissing-noreturn \
 582                         -Wredundant-decls
 583         do
 584                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 585                 OLD_CFLAGS="$CFLAGS"
 586                 CFLAGS="$CFLAGS $NEW_FLAG"
 587                 AC_COMPILE_IFELSE([void foo(void) { }], [
 588                         AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
 589                         AC_MSG_RESULT([yes])
 590                 ], [
 591                         AC_MSG_RESULT([no])
 592                 ])
 593                 CFLAGS="$OLD_CFLAGS"
 594         done
 595
 596         AC_ARG_ENABLE([werror],
 597                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 598                         compilation on all compiler warnings.]),
 599                 [], [enable_werror=no])
 600         if test "x$enable_werror" = "xyes"; then
 601                 AM_CFLAGS="$AM_CFLAGS -Werror"
 602         fi
 603 fi
 604
 605
 606 ###############################################################################
 607 # Create the makefiles and config.h
 608 ###############################################################################
 609
 610 echo
 611
 612 # Don't build the lib directory at all if we don't need any replacement
 613 # functions.
 614 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 615
 616 # Add default AM_CFLAGS.
 617 AC_SUBST([AM_CFLAGS])
 618
 619 # Set additional flags for static/dynamic linking. The idea is that every
 620 # program (not library) being built will use either STATIC_{CPPFLAGS,LDFLAGS}
 621 # or DYNAMIC_{CPPFLAGS,LDFLAGS} depending on which type of linkage is
 622 # preferred. These preferences get overriden by use of --disable-static,
 623 # --disable-shared, or --enable-dynamic.
 624 #
 625 # This is quite messy, because we want to use LZMA_API_STATIC when linking
 626 # against static liblzma. It's needed on Windows.
 627 if test "x$enable_static" = xno; then
 628         enable_dynamic=yes
 629 fi
 630 if test "x$enable_shared" = xno; then
 631         enable_dynamic=no
 632 fi
 633 case $enable_dynamic in
 634         yes)
 635                 STATIC_CPPFLAGS=
 636                 STATIC_LDFLAGS=
 637                 DYNAMIC_CPPFLAGS=
 638                 DYNAMIC_LDFLAGS=
 639                 ;;
 640         mixed)
 641                 STATIC_CPPFLAGS="-DLZMA_API_STATIC"
 642                 STATIC_LDFLAGS="-static"
 643                 DYNAMIC_CPPFLAGS=
 644                 DYNAMIC_LDFLAGS=
 645                 ;;
 646         no)
 647                 STATIC_CPPFLAGS="-DLZMA_API_STATIC"
 648                 STATIC_LDFLAGS="-static"
 649                 DYNAMIC_CPPFLAGS="-DLZMA_API_STATIC"
 650                 DYNAMIC_LDFLAGS="-static"
 651                 ;;
 652 esac
 653 AC_SUBST([STATIC_CPPFLAGS])
 654 AC_SUBST([STATIC_LDFLAGS])
 655 AC_SUBST([DYNAMIC_CPPFLAGS])
 656 AC_SUBST([DYNAMIC_LDFLAGS])
 657
 658 # This is needed for src/scripts.
 659 xz=`echo xz | sed "$program_transform_name"`
 660 AC_SUBST([xz])
 661
 662 AC_CONFIG_FILES([
 663         Doxyfile
 664         Makefile
 665         po/Makefile.in
 666         lib/Makefile
 667         src/Makefile
 668         src/liblzma/liblzma.pc
 669         src/liblzma/Makefile
 670         src/liblzma/api/Makefile
 671         src/xz/Makefile
 672         src/xzdec/Makefile
 673         src/lzmainfo/Makefile
 674         src/scripts/Makefile
 675         src/scripts/xzdiff
 676         src/scripts/xzgrep
 677         src/scripts/xzmore
 678         src/scripts/xzless
 679         tests/Makefile
 680         debug/Makefile
 681 ])
 682
 683 AC_OUTPUT