server/rcon2irc/rcon2irc.pl

   1 #!/usr/bin/perl
   2
   3 our $VERSION = '0.4.2 svn $Revision$';
   4
   5 # Copyright (c) 2008 Rudolf "divVerent" Polzer
   6 #
   7 # Permission is hereby granted, free of charge, to any person
   8 # obtaining a copy of this software and associated documentation
   9 # files (the "Software"), to deal in the Software without
  10 # restriction, including without limitation the rights to use,
  11 # copy, modify, merge, publish, distribute, sublicense, and/or sell
  12 # copies of the Software, and to permit persons to whom the
  13 # Software is furnished to do so, subject to the following
  14 # conditions:
  15 #
  16 # The above copyright notice and this permission notice shall be
  17 # included in all copies or substantial portions of the Software.
  18 #
  19 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  21 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  22 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  23 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  24 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  26 # OTHER DEALINGS IN THE SOFTWARE.
  27
  28 # MISC STRING UTILITY ROUTINES to convert between DarkPlaces and IRC conventions
  29
  30 # convert mIRC color codes to DP color codes
  31 our @color_irc2dp_table = (7, 0, 4, 2, 1, 1, 6, 1, 3, 2, 5, 5, 4, 6, 7, 7);
  32 our @color_dp2irc_table = (-1, 4, 9, 8, 12, 11, 13, -1, -1, -1); # not accurate, but legible
  33 our @color_dp2ansi_table = ("m", "1;31m", "1;32m", "1;33m", "1;34m", "1;36m", "1;35m", "m", "1m", "1m"); # not accurate, but legible
  34 our %color_team2dp_table = (5 => 1, 14 => 4, 13 => 3, 10 => 6);
  35 our %color_team2irc_table = (5 => 4, 14 => 12, 13 => 8, 10 => 13);
  36 sub color_irc2dp($)
  37 {
  38         my ($message) = @_;
  39         $message =~ s/\^/^^/g;
  40         my $color = 7;
  41         $message =~ s{\003(\d\d?)(?:,(\d?\d?))?|(\017)}{
  42                 # $1 is FG, $2 is BG, but let's ignore BG
  43                 my $oldcolor = $color;
  44                 if($3)
  45                 {
  46                         $color = 7;
  47                 }
  48                 else
  49                 {
  50                         $color = $color_irc2dp_table[$1];
  51                         $color = $oldcolor if not defined $color;
  52                 }
  53                 ($color == $oldcolor) ? '' : '^' . $color;
  54         }esg;
  55         $message =~ s{[\000-\037]}{}gs; # kill bold etc. for now
  56         return $message;
  57 }
  58
  59 our @text_qfont_table = ( # ripped from DP console.c qfont_table
  60     "\0", '#',  '#',  '#',  '#',  '.',  '#',  '#',
  61     '#',  9,    10,   '#',  ' ',  13,   '.',  '.',
  62     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  63     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  64     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  65     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  66     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  67     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  68     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  69     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  70     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  71     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  72     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  73     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  74     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  75     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<',
  76     '<',  '=',  '>',  '#',  '#',  '.',  '#',  '#',
  77     '#',  '#',  ' ',  '#',  ' ',  '>',  '.',  '.',
  78     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  79     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  80     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  81     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  82     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  83     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  84     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  85     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  86     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  87     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  88     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  89     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  90     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  91     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<'
  92 );
  93 sub text_dp2ascii($)
  94 {
  95         my ($message) = @_;
  96         $message = join '', map { $text_qfont_table[ord $_] } split //, $message;
  97 }
  98
  99 sub color_dp_transform(&$)
 100 {
 101         my ($block, $message) = @_;
 102
 103         $message =~ s{(?:(\^\^)|\^x([0-9a-fA-F])([0-9a-fA-F])([0-9a-fA-F])|\^([0-9])|(.))(?=([0-9,]?))}{
 104                 defined $1 ? $block->(char => '^', $7) :
 105                 defined $2 ? $block->(rgb => [hex $2, hex $3, hex $4], $7) :
 106                 defined $5 ? $block->(color => $5, $7) :
 107                 defined $6 ? $block->(char => $6, $7) :
 108                         die "Invalid match";
 109         }esg;
 110
 111         return $message;
 112 }
 113
 114 sub color_dp2none($)
 115 {
 116         my ($message) = @_;
 117
 118         return color_dp_transform
 119         {
 120                 my ($type, $data, $next) = @_;
 121                 $type eq 'char'
 122                         ? $text_qfont_table[ord $data]
 123                         : "";
 124         }
 125         $message;
 126 }
 127
 128 sub color_rgb2basic($)
 129 {
 130         my ($data) = @_;
 131         my ($R, $G, $B) = @$data;
 132         my $min = [sort { $a <=> $b } ($R, $G, $B)]->[0];
 133         my $max = [sort { $a <=> $b } ($R, $G, $B)]->[-1];
 134
 135         my $v = $max / 15;
 136         my $s = ($max == $min) ? 0 : 1 - $min/$max;
 137
 138         if($s < 0.2)
 139         {
 140                 return 0 if $v < 0.5;
 141                 return 7;
 142         }
 143
 144         my $h;
 145         if($max == $min)
 146         {
 147                 $h = 0;
 148         }
 149         elsif($max == $R)
 150         {
 151                 $h = (60 * ($G - $B) / ($max - $min)) % 360;
 152         }
 153         elsif($max == $G)
 154         {
 155                 $h = (60 * ($B - $R) / ($max - $min)) + 120;
 156         }
 157         elsif($max == $B)
 158         {
 159                 $h = (60 * ($R - $G) / ($max - $min)) + 240;
 160         }
 161
 162         return 1 if $h < 36;
 163         return 3 if $h < 80;
 164         return 2 if $h < 150;
 165         return 5 if $h < 200;
 166         return 4 if $h < 270;
 167         return 6 if $h < 330;
 168         return 1;
 169 }
 170
 171 sub color_dp_rgb2basic($)
 172 {
 173         my ($message) = @_;
 174         return color_dp_transform
 175         {
 176                 my ($type, $data, $next) = @_;
 177                 $type eq 'char'  ? ($data eq '^' ? '^^' : $data) :
 178                 $type eq 'color' ? "^$data" :
 179                 $type eq 'rgb'   ? "^" . color_rgb2basic $data :
 180                         die "Invalid type";
 181         }
 182         $message;
 183 }
 184
 185 sub color_dp2irc($)
 186 {
 187         my ($message) = @_;
 188         my $color = -1;
 189         return color_dp_transform
 190         {
 191                 my ($type, $data, $next) = @_;
 192
 193                 if($type eq 'rgb')
 194                 {
 195                         $type = 'color';
 196                         $data = color_rgb2basic $data;
 197                 }
 198
 199                 $type eq 'char'  ? $text_qfont_table[ord $data] :
 200                 $type eq 'color' ? do {
 201                         my $oldcolor = $color;
 202                         $color = $color_dp2irc_table[$data];
 203
 204                         $color == $oldcolor ? '' :
 205                         $color < 0          ? "\017" :
 206                         $next eq ','        ? "\003$color\002\002" :
 207                                               sprintf "\003%02d", $color;
 208                 } :
 209                         die "Invalid type";
 210         }
 211         $message;
 212 }
 213
 214 sub color_dp2ansi($)
 215 {
 216         my ($message) = @_;
 217         my $color = -1;
 218         return color_dp_transform
 219         {
 220                 my ($type, $data, $next) = @_;
 221
 222                 if($type eq 'rgb')
 223                 {
 224                         $type = 'color';
 225                         $data = color_rgb2basic $data;
 226                 }
 227
 228                 $type eq 'char'  ? $text_qfont_table[ord $data] :
 229                 $type eq 'color' ? do {
 230                         my $oldcolor = $color;
 231                         $color = $color_dp2ansi_table[$data];
 232
 233                         $color eq $oldcolor ? '' :
 234                                               "\033[${color}"
 235                 } :
 236                         die "Invalid type";
 237         }
 238         $message;
 239 }
 240
 241 sub color_dpfix($)
 242 {
 243         my ($message) = @_;
 244         # if the message ends with an odd number of ^, kill one
 245         chop $message if $message =~ /(?:^|[^\^])\^(\^\^)*$/;
 246         return $message;
 247 }
 248
 249
 250
 251
 252 # Interfaces:
 253 #   Connection:
 254 #     $conn->sockname() returns a connection type specific representation
 255 #       string of the local address, or undef if not applicable.
 256 #     $conn->send("string") sends something over the connection.
 257 #     $conn->recv() receives a string from the connection, or returns "" if no
 258 #       data is available.
 259 #     $conn->fds() returns all file descriptors used by the connection, so one
 260 #       can use select() on them.
 261 #   Channel:
 262 #     Usually wraps around a connection and implements a command based
 263 #     structure over it. It usually is constructed using new
 264 #     ChannelType($connection, someparameters...)
 265 #     @cmds = $chan->join_commands(@cmds) joins multiple commands to a single
 266 #       command string if the protocol supports it, or does nothing and leaves
 267 #       @cmds unchanged if the protocol does not support that usage (this is
 268 #       meant to save send() invocations).
 269 #     $chan->send($command, $nothrottle) sends a command over the channel. If
 270 #       $nothrottle is sent, the command must not be left out even if the channel
 271 #       is saturated (for example, because of IRC's flood control mechanism).
 272 #     $chan->quote($str) returns a string in a quoted form so it can safely be
 273 #       inserted as a substring into a command, or returns $str as is if not
 274 #       applicable. It is assumed that the result of the quote method is used
 275 #       as part of a quoted string, if the protocol supports that.
 276 #     $chan->recv() returns a list of received commands from the channel, or
 277 #       the empty list if none are available.
 278 #     $conn->fds() returns all file descriptors used by the channel's
 279 #       connections, so one can use select() on them.
 280
 281
 282
 283
 284
 285
 286
 287 # Socket connection.
 288 # Represents a connection over a socket.
 289 # Mainly used to wrap a channel around it for, in this case, line based or rcon-like operation.
 290 package Connection::Socket;
 291 use strict;
 292 use warnings;
 293 use IO::Socket::INET;
 294 use IO::Handle;
 295
 296 # Constructor:
 297 #   my $conn = new Connection::Socket(tcp => "localaddress" => "remoteaddress" => 6667);
 298 # If the remote address does not contain a port number, the numeric port is
 299 # used (it serves as a default port).
 300 sub new($$)
 301 {
 302         my ($class, $proto, $local, $remote, $defaultport) = @_;
 303         my $sock = IO::Socket::INET->new(
 304                 Proto => $proto,
 305                 (length($local) ? (LocalAddr => $local) : ()),
 306                 PeerAddr => $remote,
 307                 PeerPort => $defaultport
 308         ) or die "socket $proto/$local/$remote/$defaultport: $!";
 309         $sock->blocking(0);
 310         my $you = {
 311                 # Mortal fool! Release me from this wretched tomb! I must be set free
 312                 # or I will haunt you forever! I will hide your keys beneath the
 313                 # cushions of your upholstered furniture... and NEVERMORE will you be
 314                 # able to find socks that match!
 315                 sock => $sock,
 316                 # My demonic powers have made me OMNIPOTENT! Bwahahahahahahaha!
 317         };
 318         return
 319                 bless $you, 'Connection::Socket';
 320 }
 321
 322 # $sock->sockname() returns the local address of the socket.
 323 sub sockname($)
 324 {
 325         my ($self) = @_;
 326         my ($port, $addr) = sockaddr_in $self->{sock}->sockname();
 327         return "@{[inet_ntoa $addr]}:$port";
 328 }
 329
 330 # $sock->send($data) sends some data over the socket; on success, 1 is returned.
 331 sub send($$)
 332 {
 333         my ($self, $data) = @_;
 334         return 1
 335                 if not length $data;
 336         if(not eval { $self->{sock}->send($data); })
 337         {
 338                 warn "$@";
 339                 return 0;
 340         }
 341         return 1;
 342 }
 343
 344 # $sock->recv() receives as much as possible from the socket (or at most 32k). Returns "" if no data is available.
 345 sub recv($)
 346 {
 347         my ($self) = @_;
 348         my $data = "";
 349         if(defined $self->{sock}->recv($data, 32768, 0))
 350         {
 351                 return $data;
 352         }
 353         elsif($!{EAGAIN})
 354         {
 355                 return "";
 356         }
 357         else
 358         {
 359                 return undef;
 360         }
 361 }
 362
 363 # $sock->fds() returns the socket file descriptor.
 364 sub fds($)
 365 {
 366         my ($self) = @_;
 367         return fileno $self->{sock};
 368 }
 369
 370
 371
 372
 373
 374
 375
 376 # Line-based buffered connectionless FIFO channel.
 377 # Whatever is sent to it using send() is echoed back when using recv().
 378 package Channel::FIFO;
 379 use strict;
 380 use warnings;
 381
 382 # Constructor:
 383 #   my $chan = new Channel::FIFO();
 384 sub new($)
 385 {
 386         my ($class) = @_;
 387         my $you = {
 388                 buffer => []
 389         };
 390         return
 391                 bless $you, 'Channel::FIFO';
 392 }
 393
 394 sub join_commands($@)
 395 {
 396         my ($self, @data) = @_;
 397         return @data;
 398 }
 399
 400 sub send($$$)
 401 {
 402         my ($self, $line, $nothrottle) = @_;
 403         push @{$self->{buffer}}, $line;
 404 }
 405
 406 sub quote($$)
 407 {
 408         my ($self, $data) = @_;
 409         return $data;
 410 }
 411
 412 sub recv($)
 413 {
 414         my ($self) = @_;
 415         my $r = $self->{buffer};
 416         $self->{buffer} = [];
 417         return @$r;
 418 }
 419
 420 sub fds($)
 421 {
 422         my ($self) = @_;
 423         return ();
 424 }
 425
 426
 427
 428
 429
 430
 431
 432 # QW rcon protocol channel.
 433 # Wraps around a UDP based Connection and sends commands as rcon commands as
 434 # well as receives rcon replies. The quote and join_commands methods are using
 435 # DarkPlaces engine specific rcon protocol extensions.
 436 package Channel::QW;
 437 use strict;
 438 use warnings;
 439
 440 # Constructor:
 441 #   my $chan = new Channel::QW($connection, "password");
 442 sub new($$)
 443 {
 444         my ($class, $conn, $password) = @_;
 445         my $you = {
 446                 connector => $conn,
 447                 password => $password,
 448                 recvbuf => "",
 449         };
 450         return
 451                 bless $you, 'Channel::QW';
 452 }
 453
 454 # Note: multiple commands in one rcon packet is a DarkPlaces extension.
 455 sub join_commands($@)
 456 {
 457         my ($self, @data) = @_;
 458         return join "\0", @data;
 459 }
 460
 461 sub send($$$)
 462 {
 463         my ($self, $line, $nothrottle) = @_;
 464         return $self->{connector}->send("\377\377\377\377rcon $self->{password} $line");
 465 }
 466
 467 # Note: backslash and quotation mark escaping is a DarkPlaces extension.
 468 sub quote($$)
 469 {
 470         my ($self, $data) = @_;
 471         $data =~ s/[\000-\037]//g;
 472         $data =~ s/([\\"])/\\$1/g;
 473         $data =~ s/\$/\$\$/g;
 474         return $data;
 475 }
 476
 477 sub recv($)
 478 {
 479         my ($self) = @_;
 480         for(;;)
 481         {
 482                 my $s = $self->{connector}->recv();
 483                 die "read error\n"
 484                         if not defined $s;
 485                 length $s
 486                         or last;
 487                 next
 488                         if $s !~ /^\377\377\377\377n(.*)$/s;
 489                 $self->{recvbuf} .= $1;
 490         }
 491         my @out = ();
 492         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 493         {
 494                 push @out, $1;
 495         }
 496         return @out;
 497 }
 498
 499 sub fds($)
 500 {
 501         my ($self) = @_;
 502         return $self->{connector}->fds();
 503 }
 504
 505
 506
 507
 508
 509
 510
 511 # Line based protocol channel.
 512 # Wraps around a TCP based Connection and sends commands as text lines
 513 # (separated by CRLF). When reading responses from the Connection, any type of
 514 # line ending is accepted.
 515 # A flood control mechanism is implemented.
 516 package Channel::Line;
 517 use strict;
 518 use warnings;
 519 use Time::HiRes qw/time/;
 520
 521 # Constructor:
 522 #   my $chan = new Channel::Line($connection);
 523 sub new($$)
 524 {
 525         my ($class, $conn) = @_;
 526         my $you = {
 527                 connector => $conn,
 528                 recvbuf => "",
 529                 capacity => undef,
 530                 linepersec => undef,
 531                 maxlines => undef,
 532                 lastsend => time()
 533         };
 534         return
 535                 bless $you, 'Channel::Line';
 536 }
 537
 538 sub join_commands($@)
 539 {
 540         my ($self, @data) = @_;
 541         return @data;
 542 }
 543
 544 # Sets new flood control parameters:
 545 #   $chan->throttle(maximum lines per second, maximum burst length allowed to
 546 #     exceed the lines per second limit);
 547 #   RFC 1459 describes these parameters to be 0.5 and 5 for the IRC protocol.
 548 #   If the $nothrottle flag is set while sending, the line is sent anyway even
 549 #   if flooding would take place.
 550 sub throttle($$$)
 551 {
 552         my ($self, $linepersec, $maxlines) = @_;
 553         $self->{linepersec} = $linepersec;
 554         $self->{maxlines} = $maxlines;
 555         $self->{capacity} = $maxlines;
 556 }
 557
 558 sub send($$$)
 559 {
 560         my ($self, $line, $nothrottle) = @_;
 561         my $t = time();
 562         if(defined $self->{capacity})
 563         {
 564                 $self->{capacity} += ($t - $self->{lastsend}) * $self->{linepersec};
 565                 $self->{lastsend} = $t;
 566                 $self->{capacity} = $self->{maxlines}
 567                         if $self->{capacity} > $self->{maxlines};
 568                 if(!$nothrottle)
 569                 {
 570                         return -1
 571                                 if $self->{capacity} < 0;
 572                 }
 573                 $self->{capacity} -= 1;
 574         }
 575         $line =~ s/\r|\n//g;
 576         return $self->{connector}->send("$line\r\n");
 577 }
 578
 579 sub quote($$)
 580 {
 581         my ($self, $data) = @_;
 582         $data =~ s/\r\n?/\n/g;
 583         $data =~ s/\n/*/g;
 584         return $data;
 585 }
 586
 587 sub recv($)
 588 {
 589         my ($self) = @_;
 590         for(;;)
 591         {
 592                 my $s = $self->{connector}->recv();
 593                 die "read error\n"
 594                         if not defined $s;
 595                 length $s
 596                         or last;
 597                 $self->{recvbuf} .= $s;
 598         }
 599         my @out = ();
 600         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 601         {
 602                 push @out, $1;
 603         }
 604         return @out;
 605 }
 606
 607 sub fds($)
 608 {
 609         my ($self) = @_;
 610         return $self->{connector}->fds();
 611 }
 612
 613
 614
 615
 616
 617
 618 # main program... a gateway between IRC and DarkPlaces servers
 619 package main;
 620
 621 use strict;
 622 use warnings;
 623 use IO::Select;
 624 use Digest::SHA;
 625 use Digest::HMAC;
 626 use Time::HiRes qw/time/;
 627
 628 our @handlers = (); # list of [channel, expression, sub to handle result]
 629 our @tasks = (); # list of [time, sub]
 630 our %channels = ();
 631 our %store = (
 632         irc_nick => "",
 633         playernick_byid_0 => "(console)",
 634 );
 635 our %config = (
 636         irc_server => undef,
 637         irc_nick => undef,
 638         irc_nick_alternates => "",
 639         irc_user => undef,
 640         irc_channel => undef,
 641         irc_ping_delay => 120,
 642         irc_trigger => "",
 643
 644         irc_nickserv_password => "",
 645         irc_nickserv_identify => 'PRIVMSG NickServ :IDENTIFY %2$s',
 646         irc_nickserv_ghost => 'PRIVMSG NickServ :GHOST %1$s %2$s',
 647         irc_nickserv_ghost_attempts => 3,
 648
 649         irc_quakenet_authname => "",
 650         irc_quakenet_password => "",
 651         irc_quakenet_getchallenge => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGE',
 652         irc_quakenet_challengeauth => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGEAUTH',
 653         irc_quakenet_challengeprefix => ':Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :CHALLENGE',
 654
 655         dp_server => undef,
 656         dp_listen => "",
 657         dp_password => undef,
 658         dp_status_delay => 30,
 659         dp_server_from_wan => "",
 660         irc_local => "",
 661
 662         irc_admin_password => "",
 663         irc_admin_timeout => 3600,
 664         irc_admin_quote_re => "",
 665
 666         irc_reconnect_delay => 300,
 667
 668         plugins => "",
 669 );
 670
 671
 672
 673 # Nexuiz specific parsing of some server messages
 674
 675 sub nex_is_teamplay($)
 676 {
 677         my ($map) = @_;
 678         return $map =~ /^(?:kh|ctf|tdm|dom)_/;
 679 }
 680
 681 sub nex_slotsstring()
 682 {
 683         my $slotsstr = "";
 684         if(defined $store{slots_max})
 685         {
 686                 my $slots = $store{slots_max} - $store{slots_active};
 687                 my $slots_s = ($slots == 1) ? '' : 's';
 688                 $slotsstr = " ($slots free slot$slots_s)";
 689                 my $s = $config{dp_server_from_wan} || $config{dp_server};
 690                 $slotsstr .= "; join now: \002nexuiz +connect $s"
 691                         if $slots >= 1 and not $store{lms_blocked};
 692         }
 693         return $slotsstr;
 694 }
 695
 696
 697
 698 # Do we have a config file? If yes, read and parse it (syntax: key = value
 699 # pairs, separated by newlines), if not, complain.
 700 die "Usage: $0 configfile\n"
 701         unless @ARGV == 1;
 702
 703 open my $fh, "<", $ARGV[0]
 704         or die "open $ARGV[0]: $!";
 705 while(<$fh>)
 706 {
 707         chomp;
 708         /^#/ and next;
 709         /^(.*?)\s*=(?:\s*(.*))?$/ or next;
 710         warn "Undefined config item: $1"
 711                 unless exists $config{$1};
 712         $config{$1} = defined $2 ? $2 : "";
 713 }
 714 close $fh;
 715 my @missing = grep { !defined $config{$_} } keys %config;
 716 die "The following config items are missing: @missing"
 717         if @missing;
 718
 719
 720
 721 # Create a channel for error messages and other internal status messages...
 722
 723 $channels{system} = new Channel::FIFO();
 724
 725 # for example, quit messages caused by signals (if SIGTERM or SIGINT is first
 726 # received, try to shut down cleanly, and if such a signal is received a second
 727 # time, just exit)
 728 my $quitting = 0;
 729 $SIG{INT} = sub {
 730         exit 1 if $quitting++;
 731         $channels{system}->send("quit SIGINT");
 732 };
 733 $SIG{TERM} = sub {
 734         exit 1 if $quitting++;
 735         $channels{system}->send("quit SIGTERM");
 736 };
 737
 738
 739
 740 # Create the two channels to gateway between...
 741
 742 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
 743 $channels{dp} = new Channel::QW(my $dpsock = new Connection::Socket(udp => $config{dp_listen} => $config{dp_server} => 26000), $config{dp_password});
 744 $config{dp_listen} = $dpsock->sockname();
 745 print "Listening on $config{dp_listen}\n";
 746
 747 $channels{irc}->throttle(0.5, 5);
 748
 749
 750 # Utility routine to write to a channel by name, also outputting what's been written and some status
 751 sub out($$@)
 752 {
 753         my $chanstr = shift;
 754         my $nothrottle = shift;
 755         my $chan = $channels{$chanstr};
 756         if(!$chan)
 757         {
 758                 print "UNDEFINED: $chanstr, ignoring message\n";
 759                 return;
 760         }
 761         @_ = $chan->join_commands(@_);
 762         for(@_)
 763         {
 764                 my $result = $chan->send($_, $nothrottle);
 765                 if($result > 0)
 766                 {
 767                         print "           $chanstr << $_\n";
 768                 }
 769                 elsif($result < 0)
 770                 {
 771                         print "FLOOD:     $chanstr << $_\n";
 772                 }
 773                 else
 774                 {
 775                         print "ERROR:     $chanstr << $_\n";
 776                         $channels{system}->send("error $chanstr", 0);
 777                 }
 778         }
 779 }
 780
 781
 782
 783 # Schedule a task for later execution by the main loop; usage: schedule sub {
 784 # task... }, $time; When a scheduled task is run, a reference to the task's own
 785 # sub is passed as first argument; that way, the task is able to re-schedule
 786 # itself so it gets periodically executed.
 787 sub schedule($$)
 788 {
 789         my ($sub, $time) = @_;
 790         push @tasks, [time() + $time, $sub];
 791 }
 792
 793 # On IRC error, delete some data store variables of the connection, and
 794 # reconnect to the IRC server soon (but only if someone is actually playing)
 795 sub irc_error()
 796 {
 797         # prevent multiple instances of this timer
 798         return if $store{irc_error_active};
 799         $store{irc_error_active} = 1;
 800
 801         delete $channels{irc};
 802         schedule sub {
 803                 my ($timer) = @_;
 804                 if(!defined $store{slots_active})
 805                 {
 806                         # DP is not running, then delay IRC reconnecting
 807                         #use Data::Dumper; print Dumper \$timer;
 808                         schedule $timer => 1;
 809                         return;
 810                         # this will keep irc_error_active
 811                 }
 812                 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => "" => $config{irc_server} => 6667));
 813                 delete $store{$_} for grep { /^irc_/ } keys %store;
 814                 $store{irc_nick} = "";
 815                 schedule sub {
 816                         my ($timer) = @_;
 817                         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp';
 818                         $store{status_waiting} = -1;
 819                 } => 1;
 820                 # this will clear irc_error_active
 821         } => $config{irc_reconnect_delay};
 822         return 0;
 823 }
 824
 825 sub uniq(@)
 826 {
 827         my @out = ();
 828         my %found = ();
 829         for(@_)
 830         {
 831                 next if $found{$_}++;
 832                 push @out, $_;
 833         }
 834         return @out;
 835 }
 836
 837 # IRC joining (if this is called as response to a nick name collision, $is433 is set);
 838 # among other stuff, it performs NickServ or Quakenet authentication. This is to be called
 839 # until the channel has been joined for every message that may be "interesting" (basically,
 840 # IRC 001 hello messages, 443 nick collision messages and some notices by services).
 841 sub irc_joinstage($)
 842 {
 843         my($is433) = @_;
 844
 845         return 0
 846                 if $store{irc_joined_channel};
 847
 848                 #use Data::Dumper; print Dumper \%store;
 849
 850         if($is433)
 851         {
 852                 if(length $store{irc_nick})
 853                 {
 854                         # we already have another nick, but couldn't change to the new one
 855                         # try ghosting and then get the nick again
 856                         if(length $config{irc_nickserv_password})
 857                         {
 858                                 if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 859                                 {
 860                                         $store{irc_nick_requested} = $config{irc_nick};
 861                                         out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 862                                         schedule sub {
 863                                                 out irc => 1, "NICK $config{irc_nick}";
 864                                         } => 1;
 865                                         return; # we'll get here again for the NICK success message, or for a 433 failure
 866                                 }
 867                                 # otherwise, we failed to ghost and will continue with the wrong
 868                                 # nick... also, no need to try to identify here
 869                         }
 870                         # otherwise, we can't handle this and will continue with our wrong nick
 871                 }
 872                 else
 873                 {
 874                         # we failed to get an initial nickname
 875                         # change ours a bit and try again
 876
 877                         my @alternates = uniq ($config{irc_nick}, grep { $_ ne "" } split /\s+/, $config{irc_nick_alternates});
 878                         my $nextnick = undef;
 879                         for(0..@alternates-2)
 880                         {
 881                                 if($store{irc_nick_requested} eq $alternates[$_])
 882                                 {
 883                                         $nextnick = $alternates[$_+1];
 884                                 }
 885                         }
 886                         if($store{irc_nick_requested} eq $alternates[@alternates-1]) # this will only happen once
 887                         {
 888                                 $store{irc_nick_requested} = $alternates[0];
 889                                 # but don't set nextnick, so we edit it
 890                         }
 891                         if(defined $nextnick)
 892                         {
 893                                 $store{irc_nick_requested} = $nextnick;
 894                         }
 895                         else
 896                         {
 897                                 for(;;)
 898                                 {
 899                                         if(length $store{irc_nick_requested} < 9)
 900                                         {
 901                                                 $store{irc_nick_requested} .= '_';
 902                                         }
 903                                         else
 904                                         {
 905                                                 substr $store{irc_nick_requested}, int(rand length $store{irc_nick_requested}), 1, chr(97 + int rand 26);
 906                                         }
 907                                         last unless grep { $_ eq $store{irc_nick_requested} } @alternates;
 908                                 }
 909                         }
 910                         out irc => 1, "NICK $store{irc_nick_requested}";
 911                         return; # when it fails, we'll get here again, and when it succeeds, we will continue
 912                 }
 913         }
 914
 915         # we got a 001 or a NICK message, so $store{irc_nick} has been updated
 916         if(length $config{irc_nickserv_password})
 917         {
 918                 if($store{irc_nick} eq $config{irc_nick})
 919                 {
 920                         # identify
 921                         out irc => 1, sprintf($config{irc_nickserv_identify}, $config{irc_nick}, $config{irc_nickserv_password});
 922                 }
 923                 else
 924                 {
 925                         # ghost
 926                         if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 927                         {
 928                                 $store{irc_nick_requested} = $config{irc_nick};
 929                                 out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 930                                 schedule sub {
 931                                         out irc => 1, "NICK $config{irc_nick}";
 932                                 } => 1;
 933                                 return; # we'll get here again for the NICK success message, or for a 433 failure
 934                         }
 935                         # otherwise, we failed to ghost and will continue with the wrong
 936                         # nick... also, no need to try to identify here
 937                 }
 938         }
 939
 940         # we are on Quakenet. Try to authenticate.
 941         if(length $config{irc_quakenet_password} and length $config{irc_quakenet_authname})
 942         {
 943                 if(defined $store{irc_quakenet_challenge})
 944                 {
 945                         if($store{irc_quakenet_challenge} =~ /^([0-9a-f]*)\b.*\bHMAC-SHA-256\b/)
 946                         {
 947                                 my $challenge = $1;
 948                                 my $hash1 = Digest::SHA::sha256_hex(substr $config{irc_quakenet_password}, 0, 10);
 949                                 my $key = Digest::SHA::sha256_hex("@{[lc $config{irc_quakenet_authname}]}:$hash1");
 950                                 my $digest = Digest::HMAC::hmac_hex($challenge, $key, \&Digest::SHA::sha256);
 951                                 out irc => 1, "$config{irc_quakenet_challengeauth} $config{irc_quakenet_authname} $digest HMAC-SHA-256";
 952                         }
 953                 }
 954                 else
 955                 {
 956                         out irc => 1, $config{irc_quakenet_getchallenge};
 957                         return;
 958                         # we get here again when Q asks us
 959                 }
 960         }
 961
 962         # if we get here, we are on IRC
 963         $store{irc_joined_channel} = 1;
 964         schedule sub {
 965                 out irc => 1, "JOIN $config{irc_channel}";
 966         } => 1;
 967         return 0;
 968 }
 969
 970 my $RE_FAIL = qr/$ $/;
 971 my $RE_SUCCEED = qr//;
 972 sub cond($)
 973 {
 974         return $_[0] ? $RE_FAIL : $RE_SUCCEED;
 975 }
 976
 977
 978 # List of all handlers on the various sockets. Additional handlers can be added by a plugin.
 979 @handlers = (
 980         # detect a server restart and set it up again
 981         [ dp => q{ *(?:Warning: Could not expand \$|Unknown command ")(?:rcon2irc_[a-z0-9_]*)[" ]*} => sub {
 982                 out dp => 0,
 983                         'alias rcon2irc_eval "$*"',
 984                         'log_dest_udp',
 985                         'sv_logscores_console 0',
 986                         'sv_logscores_bots 1',
 987                         'sv_eventlog 1',
 988                         'sv_eventlog_console 1',
 989                         'alias rcon2irc_say_as "set say_as_restorenick \"$sv_adminnick\"; sv_adminnick \"$1^3\"; say \"^7$2\"; rcon2irc_say_as_restore"',
 990                         'alias rcon2irc_say_as_restore "set sv_adminnick \"$say_as_restorenick\""',
 991                         'alias rcon2irc_quit "echo \"quitting rcon2irc $1: log_dest_udp is $log_dest_udp\""'; # note: \\\\\\" ->perl \\\" ->console \"
 992                 return 0;
 993         } ],
 994
 995         # detect missing entry in log_dest_udp and fix it
 996         [ dp => q{"log_dest_udp" is "([^"]*)" \["[^"]*"\]} => sub {
 997                 my ($dest) = @_;
 998                 my @dests = split ' ', $dest;
 999                 return 0 if grep { $_ eq $config{dp_listen} } @dests;
1000                 out dp => 0, 'log_dest_udp "' . join(" ", @dests, $config{dp_listen}) . '"';
1001                 return 0;
1002         } ],
1003
1004         # retrieve list of banned hosts
1005         [ dp => q{#(\d+): (\S+) is still banned for (\S+) seconds} => sub {
1006                 return 0 unless $store{status_waiting} < 0;
1007                 my ($id, $ip, $time) = @_;
1008                 $store{bans_new} = [] if $id == 0;
1009                 $store{bans_new}[$id] = { ip => $ip, 'time' => $time };
1010                 return 0;
1011         } ],
1012
1013         # retrieve hostname from status replies
1014         [ dp => q{host:     (.*)} => sub {
1015                 return 0 unless $store{status_waiting} < 0;
1016                 my ($name) = @_;
1017                 $store{dp_hostname} = $name;
1018                 $store{bans} = $store{bans_new};
1019                 return 0;
1020         } ],
1021
1022         # retrieve version from status replies
1023         [ dp => q{version:  (.*)} => sub {
1024                 return 0 unless $store{status_waiting} < 0;
1025                 my ($version) = @_;
1026                 $store{dp_version} = $version;
1027                 return 0;
1028         } ],
1029
1030         # retrieve player names
1031         [ dp => q{players:  (\d+) active \((\d+) max\)} => sub {
1032                 return 0 unless $store{status_waiting} < 0;
1033                 my ($active, $max) = @_;
1034                 my $full = ($active >= $max);
1035                 $store{slots_max} = $max;
1036                 $store{slots_active} = $active;
1037                 $store{status_waiting} = $active;
1038                 $store{playerslots_active_new} = [];
1039                 if($store{status_waiting} == 0)
1040                 {
1041                         $store{playerslots_active} = $store{playerslots_active_new};
1042                 }
1043                 if($full != ($store{slots_full} || 0))
1044                 {
1045                         $store{slots_full} = $full;
1046                         return 0
1047                                 if $store{lms_blocked};
1048                         if($full)
1049                         {
1050                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION is full!\001";
1051                         }
1052                         else
1053                         {
1054                                 my $slotsstr = nex_slotsstring();
1055                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can be joined again$slotsstr!\001";
1056                         }
1057                 }
1058                 return 0;
1059         } ],
1060
1061         # retrieve player names
1062         [ dp => q{\^\d(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+(-?\d+)\s+\#(\d+)\s+\^\d(.*)} => sub {
1063                 return 0 unless $store{status_waiting} > 0;
1064                 my ($ip, $pl, $ping, $time, $frags, $no, $name) = ($1, $2, $3, $4, $5, $6, $7);
1065                 $store{"playerslot_$no"} = { ip => $ip, pl => $pl, ping => $ping, 'time' => $time, frags => $frags, no => $no, name => $name };
1066                 push @{$store{playerslots_active_new}}, $no;
1067                 if(--$store{status_waiting} == 0)
1068                 {
1069                         $store{playerslots_active} = $store{playerslots_active_new};
1070                 }
1071                 return 0;
1072         } ],
1073
1074         # IRC admin commands
1075         [ irc => q{:(([^! ]*)![^ ]*) (?i:PRIVMSG) [^&#%]\S* :(.*)} => sub {
1076                 return 0 unless $config{irc_admin_password} ne '';
1077
1078                 my ($hostmask, $nick, $command) = @_;
1079                 my $dpnick = color_dpfix $nick;
1080
1081                 if($command eq "login $config{irc_admin_password}")
1082                 {
1083                         $store{logins}{$hostmask} = time() + $config{irc_admin_timeout};
1084                         out irc => 0, "PRIVMSG $nick :my wish is your command";
1085                         return -1;
1086                 }
1087
1088                 if($command =~ /^login /)
1089                 {
1090                         out irc => 0, "PRIVMSG $nick :invalid password";
1091                         return -1;
1092                 }
1093
1094                 if(($store{logins}{$hostmask} || 0) < time())
1095                 {
1096                         out irc => 0, "PRIVMSG $nick :authentication required";
1097                         return -1;
1098                 }
1099
1100                 if($command =~ /^status(?: (.*))?$/)
1101                 {
1102                         my ($match) = $1;
1103                         my $found = 0;
1104                         my $foundany = 0;
1105                         for my $slot(@{$store{playerslots_active} || []})
1106                         {
1107                                 my $s = $store{"playerslot_$slot"};
1108                                 next unless $s;
1109                                 if(not defined $match or index(color_dp2none($s->{name}), $match) >= 0)
1110                                 {
1111                                         out irc => 0, sprintf 'PRIVMSG %s :%-21s %2i %4i %8s %4i #%-3u %s', $nick, $s->{ip}, $s->{pl}, $s->{ping}, $s->{time}, $s->{frags}, $slot, color_dp2irc $s->{name};
1112                                         ++$found;
1113                                 }
1114                                 ++$foundany;
1115                         }
1116                         if(!$found)
1117                         {
1118                                 if(!$foundany)
1119                                 {
1120                                         out irc => 0, "PRIVMSG $nick :the server is empty";
1121                                 }
1122                                 else
1123                                 {
1124                                         out irc => 0, "PRIVMSG $nick :no nicknames match";
1125                                 }
1126                         }
1127                         return 0;
1128                 }
1129
1130                 if($command =~ /^kick # (\d+) (.*)$/)
1131                 {
1132                         my ($id, $reason) = ($1, $2);
1133                         my $dpreason = color_irc2dp $reason;
1134                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1135                         $dpreason =~ s/(["\\])/\\$1/g;
1136                         out dp => 0, "kick # $id $dpreason";
1137                         my $slotnik = "playerslot_$id";
1138                         out irc => 0, "PRIVMSG $nick :kicked #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}) ($reason)";
1139                         return 0;
1140                 }
1141
1142                 if($command =~ /^kickban # (\d+) (\d+) (\d+) (.*)$/)
1143                 {
1144                         my ($id, $bantime, $mask, $reason) = ($1, $2, $3, $4);
1145                         my $dpreason = color_irc2dp $reason;
1146                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1147                         $dpreason =~ s/(["\\])/\\$1/g;
1148                         out dp => 0, "kickban # $id $bantime $mask $dpreason";
1149                         my $slotnik = "playerslot_$id";
1150                         out irc => 0, "PRIVMSG $nick :kickbanned #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}), netmask $mask, for $bantime seconds ($reason)";
1151                         return 0;
1152                 }
1153
1154                 if($command eq "bans")
1155                 {
1156                         my $banlist =
1157                                 join ", ",
1158                                 map { "$_ ($store{bans}[$_]{ip}, $store{bans}[$_]{time}s)" }
1159                                 0..@{$store{bans} || []}-1;
1160                         $banlist = "no bans"
1161                                 if $banlist eq "";
1162                         out irc => 0, "PRIVMSG $nick :$banlist";
1163                         return 0;
1164                 }
1165
1166                 if($command =~ /^unban (\d+)$/)
1167                 {
1168                         my ($id) = ($1);
1169                         out dp => 0, "unban $id";
1170                         out irc => 0, "PRIVMSG $nick :removed ban $id ($store{bans}[$id]{ip})";
1171                         return 0;
1172                 }
1173
1174                 if($command =~ /^quote (.*)$/)
1175                 {
1176                         my ($cmd) = ($1);
1177                         if($cmd =~ /^(??{$config{irc_admin_quote_re}})$/si)
1178                         {
1179                                 out irc => 0, $cmd;
1180                                 out irc => 0, "PRIVMSG $nick :executed your command";
1181                         }
1182                         else
1183                         {
1184                                 out irc => 0, "PRIVMSG $nick :permission denied";
1185                         }
1186                         return 0;
1187                 }
1188
1189                 out irc => 0, "PRIVMSG $nick :unknown command (supported: status [substring], kick # id reason, kickban # id bantime mask reason, bans, unban banid)";
1190
1191                 return -1;
1192         } ],
1193
1194         # LMS: detect "no more lives" message
1195         [ dp => q{\^4.*\^4 has no more lives left} => sub {
1196                 if(!$store{lms_blocked})
1197                 {
1198                         $store{lms_blocked} = 1;
1199                         if(!$store{slots_full})
1200                         {
1201                                 schedule sub {
1202                                         if($store{lms_blocked})
1203                                         {
1204                                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can't be joined until next round (a player has no more lives left)\001";
1205                                         }
1206                                 } => 1;
1207                         }
1208                 }
1209         } ],
1210
1211         # detect IRC errors and reconnect
1212         [ irc => q{ERROR .*} => \&irc_error ],
1213         [ irc => q{:[^ ]* 404 .*} => \&irc_error ], # cannot send to channel
1214         [ system => q{error irc} => \&irc_error ],
1215
1216         # IRC nick in use
1217         [ irc => q{:[^ ]* 433 .*} => sub {
1218                 return irc_joinstage(433);
1219         } ],
1220
1221         # IRC welcome
1222         [ irc => q{:[^ ]* 001 .*} => sub {
1223                 $store{irc_seen_welcome} = 1;
1224                 $store{irc_nick} = $store{irc_nick_requested};
1225                 return irc_joinstage(0);
1226         } ],
1227
1228         # IRC my nickname changed
1229         [ irc => q{:(?i:(??{$store{irc_nick}}))![^ ]* (?i:NICK) :(.*)} => sub {
1230                 my ($n) = @_;
1231                 $store{irc_nick} = $n;
1232                 return irc_joinstage(0);
1233         } ],
1234
1235         # Quakenet: challenge from Q
1236         [ irc => q{(??{$config{irc_quakenet_challengeprefix}}) (.*)} => sub {
1237                 $store{irc_quakenet_challenge} = $1;
1238                 return irc_joinstage(0);
1239         } ],
1240
1241         # shut down everything on SIGINT
1242         [ system => q{quit (.*)} => sub {
1243                 my ($cause) = @_;
1244                 out irc => 1, "QUIT :$cause";
1245                 $store{quitcookie} = int rand 1000000000;
1246                 out dp => 0, "rcon2irc_quit $store{quitcookie}";
1247         } ],
1248
1249         # remove myself from the log destinations and exit everything
1250         [ dp => q{quitting rcon2irc (??{$store{quitcookie}}): log_dest_udp is (.*) *} => sub {
1251                 my ($dest) = @_;
1252                 my @dests = grep { $_ ne $config{dp_listen} } split ' ', $dest;
1253                 out dp => 0, 'log_dest_udp "' . join(" ", @dests) . '"';
1254                 exit 0;
1255                 return 0;
1256         } ],
1257
1258         # IRC PING
1259         [ irc => q{PING (.*)} => sub {
1260                 my ($data) = @_;
1261                 out irc => 1, "PONG $data";
1262                 return 1;
1263         } ],
1264
1265         # IRC PONG
1266         [ irc => q{:[^ ]* PONG .* :(.*)} => sub {
1267                 my ($data) = @_;
1268                 return 0
1269                         if not defined $store{irc_pingtime};
1270                 return 0
1271                         if $data ne $store{irc_pingtime};
1272                 print "* measured IRC line delay: @{[time() - $store{irc_pingtime}]}\n";
1273                 undef $store{irc_pingtime};
1274                 return 0;
1275         } ],
1276
1277         # detect channel join message and note hostname length to get the maximum allowed line length
1278         [ irc => q{(:(?i:(??{$store{irc_nick}}))![^ ]* )(?i:JOIN) :(?i:(??{$config{irc_channel}}))} => sub {
1279                 $store{irc_maxlen} = 510 - length($1);
1280                 $store{irc_joined_channel} = 1;
1281                 print "* detected maximum line length for channel messages: $store{irc_maxlen}\n";
1282                 return 0;
1283         } ],
1284
1285         # chat: Nexuiz server -> IRC channel
1286         [ dp => q{\001(.*?)\^7: (.*)} => sub {
1287                 my ($nick, $message) = map { color_dp2irc $_ } @_;
1288                 out irc => 0, "PRIVMSG $config{irc_channel} :<$nick\017> $message";
1289                 return 0;
1290         } ],
1291
1292         # chat: Nexuiz server -> IRC channel, nick set
1293         [ dp => q{:join:(\d+):(\d+):([^:]*):(.*)} => sub {
1294                 my ($id, $slot, $ip, $nick) = @_;
1295                 $store{"playernickraw_byid_$id"} = $nick;
1296                 $nick = color_dp2irc $nick;
1297                 $store{"playernick_byid_$id"} = $nick;
1298                 $store{"playerip_byid_$id"} = $ip;
1299                 $store{"playerslot_byid_$id"} = $slot;
1300                 $store{"playerid_byslot_$slot"} = $id;
1301                 return 0;
1302         } ],
1303
1304         # chat: Nexuiz server -> IRC channel, nick change/set
1305         [ dp => q{:name:(\d+):(.*)} => sub {
1306                 my ($id, $nick) = @_;
1307                 $store{"playernickraw_byid_$id"} = $nick;
1308                 $nick = color_dp2irc $nick;
1309                 my $oldnick = $store{"playernick_byid_$id"};
1310                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 is now known as $nick";
1311                 $store{"playernick_byid_$id"} = $nick;
1312                 return 0;
1313         } ],
1314
1315         # chat: Nexuiz server -> IRC channel, vote call
1316         [ dp => q{:vote:vcall:(\d+):(.*)} => sub {
1317                 my ($id, $command) = @_;
1318                 $command = color_dp2irc $command;
1319                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1320                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 calls a vote for \"$command\017\"";
1321                 return 0;
1322         } ],
1323
1324         # chat: Nexuiz server -> IRC channel, vote stop
1325         [ dp => q{:vote:vstop:(\d+)} => sub {
1326                 my ($id) = @_;
1327                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1328                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 stopped the vote";
1329                 return 0;
1330         } ],
1331
1332         # chat: Nexuiz server -> IRC channel, master login
1333         [ dp => q{:vote:vlogin:(\d+)} => sub {
1334                 my ($id) = @_;
1335                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1336                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 logged in as master";
1337                 return 0;
1338         } ],
1339
1340         # chat: Nexuiz server -> IRC channel, master do
1341         [ dp => q{:vote:vdo:(\d+):(.*)} => sub {
1342                 my ($id, $command) = @_;
1343                 $command = color_dp2irc $command;
1344                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1345                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 used his master status to do \"$command\017\"";
1346                 return 0;
1347         } ],
1348
1349         # chat: Nexuiz server -> IRC channel, result
1350         [ dp => q{:vote:v(yes|no|timeout):(\d+):(\d+):(\d+):(\d+):(-?\d+)} => sub {
1351                 my ($result, $yes, $no, $abstain, $not, $min) = @_;
1352                 my $spam = "$yes:$no" . (($min >= 0) ? " ($min needed)" : "") . ", $abstain didn't care, $not didn't vote";
1353                 out irc => 0, "PRIVMSG $config{irc_channel} :* the vote ended with $result: $spam";
1354                 return 0;
1355         } ],
1356
1357         # chat: IRC channel -> Nexuiz server
1358         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$store{irc_nick}}))(?: |: ?|, ?)(.*)} => sub {
1359                 my ($nick, $message) = @_;
1360                 $nick = color_dpfix $nick;
1361                         # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1362                 $message = color_irc2dp $message;
1363                 $message =~ s/(["\\])/\\$1/g;
1364                 out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1365                 return 0;
1366         } ],
1367
1368         (
1369                 length $config{irc_trigger}
1370                         ?
1371                                 [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$config{irc_trigger}}))(?: |: ?|, ?)(.*)} => sub {
1372                                         my ($nick, $message) = @_;
1373                                         $nick = color_dpfix $nick;
1374                                                 # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1375                                         $message = color_irc2dp $message;
1376                                         $message =~ s/(["\\])/\\$1/g;
1377                                         out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1378                                         return 0;
1379                                 } ]
1380                         :
1381                                 ()
1382         ),
1383
1384         # irc: CTCP VERSION reply
1385         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$store{irc_nick}})) :\001VERSION( .*)?\001} => sub {
1386                 my ($nick) = @_;
1387                 my $ver = $store{dp_version} or return 0;
1388                 $ver .= ", rcon2irc $VERSION";
1389                 out irc => 0, "NOTICE $nick :\001VERSION $ver\001";
1390         } ],
1391
1392         # on game start, notify the channel
1393         [ dp => q{:gamestart:(.*):[0-9.]*} => sub {
1394                 my ($map) = @_;
1395                 $store{playing} = 1;
1396                 $store{map} = $map;
1397                 $store{map_starttime} = time();
1398                 my $slotsstr = nex_slotsstring();
1399                 out irc => 0, "PRIVMSG $config{irc_channel} :\00304" . $map . "\017 has begun$slotsstr";
1400                 delete $store{lms_blocked};
1401                 return 0;
1402         } ],
1403
1404         # on game over, clear the current map
1405         [ dp => q{:gameover} => sub {
1406                 $store{playing} = 0;
1407                 return 0;
1408         } ],
1409
1410         # scores: Nexuiz server -> IRC channel (start)
1411         [ dp => q{:scores:(.*):(\d+)} => sub {
1412                 my ($map, $time) = @_;
1413                 $store{scores} = {};
1414                 $store{scores}{map} = $map;
1415                 $store{scores}{time} = $time;
1416                 $store{scores}{players} = [];
1417                 delete $store{lms_blocked};
1418                 return 0;
1419         } ],
1420
1421         # scores: Nexuiz server -> IRC channel, legacy format
1422         [ dp => q{:player:(-?\d+):(\d+):(\d+):(\d+):(\d+):(.*)} => sub {
1423                 my ($frags, $deaths, $time, $team, $id, $name) = @_;
1424                 return if not exists $store{scores};
1425                 push @{$store{scores}{players}}, [$frags, $team, $name]
1426                         unless $frags <= -666; # no spectators
1427                 return 0;
1428         } ],
1429
1430         # scores: Nexuiz server -> IRC channel (CTF), legacy format
1431         [ dp => q{:teamscores:(\d+:-?\d*(?::\d+:-?\d*)*)} => sub {
1432                 my ($teams) = @_;
1433                 return if not exists $store{scores};
1434                 $store{scores}{teams} = {split /:/, $teams};
1435                 return 0;
1436         } ],
1437
1438         # scores: Nexuiz server -> IRC channel, new format
1439         [ dp => q{:player:see-labels:(-?\d+)[-0-9,]*:(\d+):(\d+):(\d+):(.*)} => sub {
1440                 my ($frags, $time, $team, $id, $name) = @_;
1441                 return if not exists $store{scores};
1442                 push @{$store{scores}{players}}, [$frags, $team, $name];
1443                 return 0;
1444         } ],
1445
1446         # scores: Nexuiz server -> IRC channel (CTF), new format
1447         [ dp => q{:teamscores:see-labels:(-?\d+)[-0-9,]*:(\d+)} => sub {
1448                 my ($frags, $team) = @_;
1449                 return if not exists $store{scores};
1450                 $store{scores}{teams}{$team} = $frags;
1451                 return 0;
1452         } ],
1453
1454         # scores: Nexuiz server -> IRC channel
1455         [ dp => q{:end} => sub {
1456                 return if not exists $store{scores};
1457                 my $s = $store{scores};
1458                 delete $store{scores};
1459                 my $teams_matter = nex_is_teamplay($s->{map});
1460
1461                 my @t = ();
1462                 my @p = ();
1463
1464                 if($teams_matter)
1465                 {
1466                         # put players into teams
1467                         my %t = ();
1468                         for(@{$s->{players}})
1469                         {
1470                                 my $thisteam = ($t{$_->[1]} ||= {score => 0, team => $_->[1], players => []});
1471                                 push @{$thisteam->{players}}, [$_->[0], $_->[1], $_->[2]];
1472                                 if($s->{teams})
1473                                 {
1474                                         $thisteam->{score} = $s->{teams}{$_->[1]};
1475                                 }
1476                                 else
1477                                 {
1478                                         $thisteam->{score} += $_->[0];
1479                                 }
1480                         }
1481
1482                         # sort by team score
1483                         @t = sort { $b->{score} <=> $a->{score} } values %t;
1484
1485                         # sort by player score
1486                         @p = ();
1487                         for(@t)
1488                         {
1489                                 @{$_->{players}} = sort { $b->[0] <=> $a->[0] } @{$_->{players}};
1490                                 push @p, @{$_->{players}};
1491                         }
1492                 }
1493                 else
1494                 {
1495                         @p = sort { $b->[0] <=> $a->[0] } @{$s->{players}};
1496                 }
1497
1498                 # no display for empty server
1499                 return 0
1500                         if !@p;
1501
1502                 # make message fit somehow
1503                 for my $maxnamelen(reverse 3..64)
1504                 {
1505                         my $scores_string = "PRIVMSG $config{irc_channel} :\00304" . $s->{map} . "\017 ended:";
1506                         if($teams_matter)
1507                         {
1508                                 my $sep = ' ';
1509                                 for(@t)
1510                                 {
1511                                         $scores_string .= $sep . sprintf "\003%02d\%d\017", $color_team2irc_table{$_->{team}}, $_->{score};
1512                                         $sep = ':';
1513                                 }
1514                         }
1515                         my $sep = '';
1516                         for(@p)
1517                         {
1518                                 my ($frags, $team, $name) = @$_;
1519                                 $name = color_dpfix substr($name, 0, $maxnamelen);
1520                                 if($teams_matter)
1521                                 {
1522                                         $name = "\003" . $color_team2irc_table{$team} . " " . color_dp2none $name;
1523                                 }
1524                                 else
1525                                 {
1526                                         $name = " " . color_dp2irc $name;
1527                                 }
1528                                 $scores_string .= "$sep$name\017 $frags";
1529                                 $sep = ',';
1530                         }
1531                         if(length($scores_string) <= ($store{irc_maxlen} || 256))
1532                         {
1533                                 out irc => 0, $scores_string;
1534                                 return 0;
1535                         }
1536                 }
1537                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION would have LIKED to put the scores here, but they wouldn't fit :(\001";
1538                 return 0;
1539         } ],
1540
1541         # complain when system load gets too high
1542         [ dp => q{timing:   (([0-9.]*)% CPU, ([0-9.]*)% lost, offset avg ([0-9.]*)ms, max ([0-9.]*)ms, sdev ([0-9.]*)ms)} => sub {
1543                 my ($all, $cpu, $lost, $avg, $max, $sdev) = @_;
1544                 return 0 # don't complain when just on the voting screen
1545                         if !$store{playing};
1546                 return 0 # don't complain if it was less than 0.5%
1547                         if $lost < 0.5;
1548                 return 0 # don't complain if nobody is looking
1549                         if $store{slots_active} == 0;
1550                 return 0 # don't complain in the first two minutes
1551                         if time() - $store{map_starttime} < 120;
1552                 return 0 # don't complain if it was already at least half as bad in this round
1553                         if $store{map_starttime} == $store{timingerror_map_starttime} and $lost <= 2 * $store{timingerror_lost};
1554                 $store{timingerror_map_starttime} = $store{map_starttime};
1555                 $store{timingerror_lost} = $lost;
1556                 out dp => 0, 'rcon2irc_say_as server "There are currently some severe system load problems. The admins have been notified."';
1557                 out irc => 1, "PRIVMSG $config{irc_channel} :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1558                 #out irc => 1, "PRIVMSG OpBaI :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1559                 return 0;
1560         } ],
1561 );
1562
1563
1564
1565 # Load plugins and add them to the handler list in the front.
1566 for my $p(split ' ', $config{plugins})
1567 {
1568         my @h = eval { do $p; }
1569                 or die "Invalid plugin $p: $@";
1570         for(reverse @h)
1571         {
1572                 ref $_ eq 'ARRAY' or die "Invalid plugin $p: did not return a list of arrays";
1573                 @$_ == 3 or die "Invalid plugin $p: did not return a list of three-element arrays";
1574                 !ref $_->[0] && !ref $_->[1] && ref $_->[2] eq 'CODE' or die "Invalid plugin $p: did not return a list of string-string-sub arrays";
1575                 unshift @handlers, $_;
1576         }
1577 }
1578
1579
1580
1581 # verify that the server is up by letting it echo back a string that causes
1582 # re-initialization of the required aliases
1583 out dp => 0, 'echo "Unknown command \"rcon2irc_eval\""'; # assume the server has been restarted
1584
1585
1586
1587 # regularily, query the server status and if it still is connected to us using
1588 # the log_dest_udp feature. If not, we will detect the response to this rcon
1589 # command and re-initialize the server's connection to us (either by log_dest_udp
1590 # not containing our own IP:port, or by rcon2irc_eval not being a defined command).
1591 schedule sub {
1592         my ($timer) = @_;
1593         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp', 'rcon2irc_eval set dummy 1';
1594         $store{status_waiting} = -1;
1595         schedule $timer => (exists $store{dp_hostname} ? $config{dp_status_delay} : 1);;
1596 } => 1;
1597
1598
1599
1600 # Continue with connecting to IRC as soon as we get our first status reply from
1601 # the DP server (which contains the server's hostname that we'll use as
1602 # realname for IRC).
1603 schedule sub {
1604         my ($timer) = @_;
1605
1606         # log on to IRC when needed
1607         if(exists $store{dp_hostname} && !exists $store{irc_logged_in})
1608         {
1609                 $store{irc_nick_requested} = $config{irc_nick};
1610                 out irc => 1, "NICK $config{irc_nick}", "USER $config{irc_user} localhost localhost :$store{dp_hostname}";
1611                 $store{irc_logged_in} = 1;
1612                 undef $store{irc_maxlen};
1613                 undef $store{irc_pingtime};
1614         }
1615
1616         schedule $timer => 1;;
1617 } => 1;
1618
1619
1620
1621 # Regularily ping the IRC server to detect if the connection is down. If it is,
1622 # schedule an IRC error that will cause reconnection later.
1623 schedule sub {
1624         my ($timer) = @_;
1625
1626         if($store{irc_logged_in})
1627         {
1628                 if(defined $store{irc_pingtime})
1629                 {
1630                         # IRC connection apparently broke
1631                         # so... KILL IT WITH FIRE
1632                         $channels{system}->send("error irc", 0);
1633                 }
1634                 else
1635                 {
1636                         # everything is fine, send a new ping
1637                         $store{irc_pingtime} = time();
1638                         out irc => 1, "PING $store{irc_pingtime}";
1639                 }
1640         }
1641
1642         schedule $timer => $config{irc_ping_delay};;
1643 } => 1;
1644
1645
1646
1647 # Main loop.
1648 for(;;)
1649 {
1650         # Build up an IO::Select object for all our channels.
1651         my $s = IO::Select->new();
1652         for my $chan(values %channels)
1653         {
1654                 $s->add($_) for $chan->fds();
1655         }
1656
1657         # wait for something to happen on our sockets, or wait 2 seconds without anything happening there
1658         $s->can_read(2);
1659         my @errors = $s->has_exception(0);
1660
1661         # on every channel, look for incoming messages
1662         CHANNEL:
1663         for my $chanstr(keys %channels)
1664         {
1665                 my $chan = $channels{$chanstr};
1666                 my @chanfds = $chan->fds();
1667
1668                 for my $chanfd(@chanfds)
1669                 {
1670                         if(grep { $_ == $chanfd } @errors)
1671                         {
1672                                 # STOP! This channel errored!
1673                                 $channels{system}->send("error $chanstr", 0);
1674                                 next CHANNEL;
1675                         }
1676                 }
1677
1678                 eval
1679                 {
1680                         for my $line($chan->recv())
1681                         {
1682                                 # found one! Check if it matches the regular expression of one of
1683                                 # our handlers...
1684                                 my $handled = 0;
1685                                 my $private = 0;
1686                                 for my $h(@handlers)
1687                                 {
1688                                         my ($chanstr_wanted, $re, $sub) = @$h;
1689                                         next
1690                                                 if $chanstr_wanted ne $chanstr;
1691                                         use re 'eval';
1692                                         my @matches = ($line =~ /^$re$/s);
1693                                         no re 'eval';
1694                                         next
1695                                                 unless @matches;
1696                                         # and if it is a match, handle it.
1697                                         ++$handled;
1698                                         my $result = $sub->(@matches);
1699                                         $private = 1
1700                                                 if $result < 0;
1701                                         last
1702                                                 if $result;
1703                                 }
1704                                 # print the message, together with info on whether it has been handled or not
1705                                 if($private)
1706                                 {
1707                                         print "           $chanstr >> (private)\n";
1708                                 }
1709                                 elsif($handled)
1710                                 {
1711                                         print "           $chanstr >> $line\n";
1712                                 }
1713                                 else
1714                                 {
1715                                         print "unhandled: $chanstr >> $line\n";
1716                                 }
1717                         }
1718                         1;
1719                 } or do {
1720                         if($@ eq "read error\n")
1721                         {
1722                                 $channels{system}->send("error $chanstr", 0);
1723                                 next CHANNEL;
1724                         }
1725                         else
1726                         {
1727                                 # re-throw
1728                                 die $@;
1729                         }
1730                 };
1731         }
1732
1733         # handle scheduled tasks...
1734         my @t = @tasks;
1735         my $t = time();
1736         # by emptying the list of tasks...
1737         @tasks = ();
1738         for(@t)
1739         {
1740                 my ($time, $sub) = @$_;
1741                 if($t >= $time)
1742                 {
1743                         # calling them if they are schedled for the "past"...
1744                         $sub->($sub);
1745                 }
1746                 else
1747                 {
1748                         # or re-adding them to the task list if they still are scheduled for the "future"
1749                         push @tasks, [$time, $sub];
1750                 }
1751         }
1752 }