ec614ec554c484e6a56605e113bb9396ba456d6e
[divverent/nexuiz.git] / server / rcon2irc / rcon2irc.pl
1 #!/usr/bin/perl
2
3 our $VERSION = '0.4.2 svn $Revision$';
4
5 # Copyright (c) 2008 Rudolf "divVerent" Polzer
6
7 # Permission is hereby granted, free of charge, to any person
8 # obtaining a copy of this software and associated documentation
9 # files (the "Software"), to deal in the Software without
10 # restriction, including without limitation the rights to use,
11 # copy, modify, merge, publish, distribute, sublicense, and/or sell
12 # copies of the Software, and to permit persons to whom the
13 # Software is furnished to do so, subject to the following
14 # conditions:
15
16 # The above copyright notice and this permission notice shall be
17 # included in all copies or substantial portions of the Software.
18
19 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
21 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
22 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
23 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
24 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
25 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
26 # OTHER DEALINGS IN THE SOFTWARE.
27
28 # MISC STRING UTILITY ROUTINES to convert between DarkPlaces and IRC conventions
29
30 # convert mIRC color codes to DP color codes
31 our @color_irc2dp_table = (7, 0, 4, 2, 1, 1, 6, 1, 3, 2, 5, 5, 4, 6, 7, 7);
32 our @color_dp2irc_table = (-1, 4, 9, 8, 12, 11, 13, -1, -1, -1); # not accurate, but legible
33 our @color_dp2ansi_table = ("m", "1;31m", "1;32m", "1;33m", "1;34m", "1;36m", "1;35m", "m", "1m", "1m"); # not accurate, but legible
34 our %color_team2dp_table = (5 => 1, 14 => 4, 13 => 3, 10 => 6);
35 our %color_team2irc_table = (5 => 4, 14 => 12, 13 => 8, 10 => 13);
36 sub color_irc2dp($)
37 {
38         my ($message) = @_;
39         $message =~ s/\^/^^/g;
40         my $color = 7;
41         $message =~ s{\003(\d\d?)(?:,(\d?\d?))?|(\017)}{
42                 # $1 is FG, $2 is BG, but let's ignore BG
43                 my $oldcolor = $color;
44                 if($3)
45                 {
46                         $color = 7;
47                 }
48                 else
49                 {
50                         $color = $color_irc2dp_table[$1];
51                         $color = $oldcolor if not defined $color;
52                 }
53                 ($color == $oldcolor) ? '' : '^' . $color;
54         }esg;
55         $message =~ s{[\000-\037]}{}gs; # kill bold etc. for now
56         return $message;
57 }
58
59 our @text_qfont_table = ( # ripped from DP console.c qfont_table
60     "\0", '#',  '#',  '#',  '#',  '.',  '#',  '#',
61     '#',  9,    10,   '#',  ' ',  13,   '.',  '.',
62     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
63     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
64     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
65     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
66     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
67     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
68     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
69     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
70     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
71     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
72     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
73     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
74     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
75     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<',
76     '<',  '=',  '>',  '#',  '#',  '.',  '#',  '#',
77     '#',  '#',  ' ',  '#',  ' ',  '>',  '.',  '.',
78     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
79     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
80     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
81     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
82     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
83     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
84     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
85     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
86     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
87     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
88     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
89     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
90     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
91     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<'
92 );
93 sub text_dp2ascii($)
94 {
95         my ($message) = @_;
96         $message = join '', map { $text_qfont_table[ord $_] } split //, $message;
97 }
98
99 sub color_dp_transform(&$)
100 {
101         my ($block, $message) = @_;
102
103         $message =~ s{(?:(\^\^)|\^x([0-9a-fA-F])([0-9a-fA-F])([0-9a-fA-F])|\^([0-9])|(.))(?=([0-9,]?))}{
104                 defined $1 ? $block->(char => '^', $7) :
105                 defined $2 ? $block->(rgb => [hex $2, hex $3, hex $4], $7) :
106                 defined $5 ? $block->(color => $5, $7) :
107                 defined $6 ? $block->(char => $6, $7) :
108                         die "Invalid match";
109         }esg;
110
111         return $message;
112 }
113
114 sub color_dp2none($)
115 {
116         my ($message) = @_;
117
118         return color_dp_transform
119         {
120                 my ($type, $data, $next) = @_;
121                 $type eq 'char'
122                         ? $text_qfont_table[ord $data]
123                         : "";
124         }
125         $message;
126 }
127
128 sub color_rgb2basic($)
129 {
130         my ($data) = @_;
131         my ($R, $G, $B) = @$data;
132         my $min = [sort { $a <=> $b } ($R, $G, $B)]->[0];
133         my $max = [sort { $a <=> $b } ($R, $G, $B)]->[-1];
134
135         my $v = $max / 15;
136         my $s = ($max == $min) ? 0 : 1 - $min/$max;
137
138         if($s < 0.2)
139         {
140                 return 0 if $v < 0.5;
141                 return 7;
142         }
143
144         my $h;
145         if($max == $min)
146         {
147                 $h = 0;
148         }
149         elsif($max == $R)
150         {
151                 $h = (60 * ($G - $B) / ($max - $min)) % 360;
152         }
153         elsif($max == $G)
154         {
155                 $h = (60 * ($B - $R) / ($max - $min)) + 120;
156         }
157         elsif($max == $B)
158         {
159                 $h = (60 * ($R - $G) / ($max - $min)) + 240;
160         }
161
162         return 1 if $h < 36;
163         return 3 if $h < 80;
164         return 2 if $h < 150;
165         return 5 if $h < 200;
166         return 4 if $h < 270;
167         return 6 if $h < 330;
168         return 1;
169 }
170
171 sub color_dp_rgb2basic($)
172 {
173         my ($message) = @_;
174         return color_dp_transform
175         {
176                 my ($type, $data, $next) = @_;
177                 $type eq 'char'  ? ($data eq '^' ? '^^' : $data) :
178                 $type eq 'color' ? "^$data" :
179                 $type eq 'rgb'   ? "^" . color_rgb2basic $data :
180                         die "Invalid type";
181         }
182         $message;
183 }
184
185 sub color_dp2irc($)
186 {
187         my ($message) = @_;
188         my $color = -1;
189         return color_dp_transform
190         {
191                 my ($type, $data, $next) = @_;
192
193                 if($type eq 'rgb')
194                 {
195                         $type = 'color';
196                         $data = color_rgb2basic $data;
197                 }
198
199                 $type eq 'char'  ? $text_qfont_table[ord $data] :
200                 $type eq 'color' ? do {
201                         my $oldcolor = $color;
202                         $color = $color_dp2irc_table[$data];
203
204                         $color == $oldcolor ? '' :
205                         $color < 0          ? "\017" :
206                         $next eq ','        ? "\003$color\002\002" :
207                                               sprintf "\003%02d", $color;
208                 } :
209                         die "Invalid type";
210         }
211         $message;
212 }
213
214 sub color_dp2ansi($)
215 {
216         my ($message) = @_;
217         my $color = -1;
218         return color_dp_transform
219         {
220                 my ($type, $data, $next) = @_;
221
222                 if($type eq 'rgb')
223                 {
224                         $type = 'color';
225                         $data = color_rgb2basic $data;
226                 }
227
228                 $type eq 'char'  ? $text_qfont_table[ord $data] :
229                 $type eq 'color' ? do {
230                         my $oldcolor = $color;
231                         $color = $color_dp2ansi_table[$data];
232
233                         $color eq $oldcolor ? '' :
234                                               "\033[${color}"
235                 } :
236                         die "Invalid type";
237         }
238         $message;
239 }
240
241 sub color_dpfix($)
242 {
243         my ($message) = @_;
244         # if the message ends with an odd number of ^, kill one
245         chop $message if $message =~ /(?:^|[^\^])\^(\^\^)*$/;
246         return $message;
247 }
248
249
250
251
252 # Interfaces:
253 #   Connection:
254 #     $conn->sockname() returns a connection type specific representation
255 #       string of the local address, or undef if not applicable.
256 #     $conn->send("string") sends something over the connection.
257 #     $conn->recv() receives a string from the connection, or returns "" if no
258 #       data is available.
259 #     $conn->fds() returns all file descriptors used by the connection, so one
260 #       can use select() on them.
261 #   Channel:
262 #     Usually wraps around a connection and implements a command based
263 #     structure over it. It usually is constructed using new
264 #     ChannelType($connection, someparameters...)
265 #     @cmds = $chan->join_commands(@cmds) joins multiple commands to a single
266 #       command string if the protocol supports it, or does nothing and leaves
267 #       @cmds unchanged if the protocol does not support that usage (this is
268 #       meant to save send() invocations).
269 #     $chan->send($command, $nothrottle) sends a command over the channel. If
270 #       $nothrottle is sent, the command must not be left out even if the channel
271 #       is saturated (for example, because of IRC's flood control mechanism).
272 #     $chan->quote($str) returns a string in a quoted form so it can safely be
273 #       inserted as a substring into a command, or returns $str as is if not
274 #       applicable. It is assumed that the result of the quote method is used
275 #       as part of a quoted string, if the protocol supports that.
276 #     $chan->recv() returns a list of received commands from the channel, or
277 #       the empty list if none are available.
278 #     $conn->fds() returns all file descriptors used by the channel's
279 #       connections, so one can use select() on them.
280
281
282
283
284
285
286
287 # Socket connection.
288 # Represents a connection over a socket.
289 # Mainly used to wrap a channel around it for, in this case, line based or rcon-like operation.
290 package Connection::Socket;
291 use strict;
292 use warnings;
293 use IO::Socket::INET;
294 use IO::Handle;
295
296 # Constructor:
297 #   my $conn = new Connection::Socket(tcp => "localaddress" => "remoteaddress" => 6667);
298 # If the remote address does not contain a port number, the numeric port is
299 # used (it serves as a default port).
300 sub new($$)
301 {
302         my ($class, $proto, $local, $remote, $defaultport) = @_;
303         my $sock = IO::Socket::INET->new(
304                 Proto => $proto,
305                 (length($local) ? (LocalAddr => $local) : ()),
306                 PeerAddr => $remote,
307                 PeerPort => $defaultport
308         ) or die "socket $proto/$local/$remote: $!";
309         $sock->blocking(0);
310         my $you = {
311                 # Mortal fool! Release me from this wretched tomb! I must be set free
312                 # or I will haunt you forever! I will hide your keys beneath the
313                 # cushions of your upholstered furniture... and NEVERMORE will you be
314                 # able to find socks that match!
315                 sock => $sock,
316                 # My demonic powers have made me OMNIPOTENT! Bwahahahahahahaha!
317         };
318         return
319                 bless $you, 'Connection::Socket';
320 }
321
322 # $sock->sockname() returns the local address of the socket.
323 sub sockname($)
324 {
325         my ($self) = @_;
326         my ($port, $addr) = sockaddr_in $self->{sock}->sockname();
327         return "@{[inet_ntoa $addr]}:$port";
328 }
329
330 # $sock->send($data) sends some data over the socket; on success, 1 is returned.
331 sub send($$)
332 {
333         my ($self, $data) = @_;
334         return 1
335                 if not length $data;
336         if(not eval { $self->{sock}->send($data); })
337         {
338                 warn "$@";
339                 return 0;
340         }
341         return 1;
342 }
343
344 # $sock->recv() receives as much as possible from the socket (or at most 32k). Returns "" if no data is available.
345 sub recv($)
346 {
347         my ($self) = @_;
348         my $data = "";
349         if(defined $self->{sock}->recv($data, 32768, 0))
350         {
351                 return $data;
352         }
353         elsif($!{EAGAIN})
354         {
355                 return "";
356         }
357         else
358         {
359                 return undef;
360         }
361 }
362
363 # $sock->fds() returns the socket file descriptor.
364 sub fds($)
365 {
366         my ($self) = @_;
367         return fileno $self->{sock};
368 }
369
370
371
372
373
374
375
376 # Line-based buffered connectionless FIFO channel.
377 # Whatever is sent to it using send() is echoed back when using recv().
378 package Channel::FIFO;
379 use strict;
380 use warnings;
381
382 # Constructor:
383 #   my $chan = new Channel::FIFO();
384 sub new($)
385 {
386         my ($class) = @_;
387         my $you = {
388                 buffer => []
389         };
390         return
391                 bless $you, 'Channel::FIFO';
392 }
393
394 sub join_commands($@)
395 {
396         my ($self, @data) = @_;
397         return @data;
398 }
399
400 sub send($$$)
401 {
402         my ($self, $line, $nothrottle) = @_;
403         push @{$self->{buffer}}, $line;
404 }
405
406 sub quote($$)
407 {
408         my ($self, $data) = @_;
409         return $data;
410 }
411
412 sub recv($)
413 {
414         my ($self) = @_;
415         my $r = $self->{buffer};
416         $self->{buffer} = [];
417         return @$r;
418 }
419
420 sub fds($)
421 {
422         my ($self) = @_;
423         return ();
424 }
425
426
427
428
429
430
431
432 # QW rcon protocol channel.
433 # Wraps around a UDP based Connection and sends commands as rcon commands as
434 # well as receives rcon replies. The quote and join_commands methods are using
435 # DarkPlaces engine specific rcon protocol extensions.
436 package Channel::QW;
437 use strict;
438 use warnings;
439
440 # Constructor:
441 #   my $chan = new Channel::QW($connection, "password");
442 sub new($$)
443 {
444         my ($class, $conn, $password) = @_;
445         my $you = {
446                 connector => $conn,
447                 password => $password,
448                 recvbuf => "",
449         };
450         return
451                 bless $you, 'Channel::QW';
452 }
453
454 # Note: multiple commands in one rcon packet is a DarkPlaces extension.
455 sub join_commands($@)
456 {
457         my ($self, @data) = @_;
458         return join "\0", @data;
459 }
460
461 sub send($$$)
462 {
463         my ($self, $line, $nothrottle) = @_;
464         return $self->{connector}->send("\377\377\377\377rcon $self->{password} $line");
465 }
466
467 # Note: backslash and quotation mark escaping is a DarkPlaces extension.
468 sub quote($$)
469 {
470         my ($self, $data) = @_;
471         $data =~ s/[\000-\037]//g;
472         $data =~ s/([\\"])/\\$1/g;
473         $data =~ s/\$/\$\$/g;
474         return $data;
475 }
476
477 sub recv($)
478 {
479         my ($self) = @_;
480         for(;;)
481         {
482                 my $s = $self->{connector}->recv();
483                 die "read error\n"
484                         if not defined $s;
485                 length $s
486                         or last;
487                 next
488                         if $s !~ /^\377\377\377\377n(.*)$/s;
489                 $self->{recvbuf} .= $1;
490         }
491         my @out = ();
492         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
493         {
494                 push @out, $1;
495         }
496         return @out;
497 }
498
499 sub fds($)
500 {
501         my ($self) = @_;
502         return $self->{connector}->fds();
503 }
504
505
506
507
508
509
510
511 # Line based protocol channel.
512 # Wraps around a TCP based Connection and sends commands as text lines
513 # (separated by CRLF). When reading responses from the Connection, any type of
514 # line ending is accepted.
515 # A flood control mechanism is implemented.
516 package Channel::Line;
517 use strict;
518 use warnings;
519 use Time::HiRes qw/time/;
520
521 # Constructor:
522 #   my $chan = new Channel::Line($connection);
523 sub new($$)
524 {
525         my ($class, $conn) = @_;
526         my $you = {
527                 connector => $conn,
528                 recvbuf => "",
529                 capacity => undef,
530                 linepersec => undef,
531                 maxlines => undef,
532                 lastsend => time()
533         };
534         return 
535                 bless $you, 'Channel::Line';
536 }
537
538 sub join_commands($@)
539 {
540         my ($self, @data) = @_;
541         return @data;
542 }
543
544 # Sets new flood control parameters:
545 #   $chan->throttle(maximum lines per second, maximum burst length allowed to
546 #     exceed the lines per second limit);
547 #   RFC 1459 describes these parameters to be 0.5 and 5 for the IRC protocol.
548 #   If the $nothrottle flag is set while sending, the line is sent anyway even
549 #   if flooding would take place.
550 sub throttle($$$)
551 {
552         my ($self, $linepersec, $maxlines) = @_;
553         $self->{linepersec} = $linepersec;
554         $self->{maxlines} = $maxlines;
555         $self->{capacity} = $maxlines;
556 }
557
558 sub send($$$)
559 {
560         my ($self, $line, $nothrottle) = @_;
561         my $t = time();
562         if(defined $self->{capacity})
563         {
564                 $self->{capacity} += ($t - $self->{lastsend}) * $self->{linepersec};
565                 $self->{lastsend} = $t;
566                 $self->{capacity} = $self->{maxlines}
567                         if $self->{capacity} > $self->{maxlines};
568                 if(!$nothrottle)
569                 {
570                         return -1
571                                 if $self->{capacity} < 0;
572                 }
573                 $self->{capacity} -= 1;
574         }
575         $line =~ s/\r|\n//g;
576         return $self->{connector}->send("$line\r\n");
577 }
578
579 sub quote($$)
580 {
581         my ($self, $data) = @_;
582         $data =~ s/\r\n?/\n/g;
583         $data =~ s/\n/*/g;
584         return $data;
585 }
586
587 sub recv($)
588 {
589         my ($self) = @_;
590         for(;;)
591         {
592                 my $s = $self->{connector}->recv();
593                 die "read error\n"
594                         if not defined $s;
595                 length $s
596                         or last;
597                 $self->{recvbuf} .= $s;
598         }
599         my @out = ();
600         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
601         {
602                 push @out, $1;
603         }
604         return @out;
605 }
606
607 sub fds($)
608 {
609         my ($self) = @_;
610         return $self->{connector}->fds();
611 }
612
613
614
615
616
617
618 # main program... a gateway between IRC and DarkPlaces servers
619 package main;
620
621 use strict;
622 use warnings;
623 use IO::Select;
624 use Digest::MD5;
625 use Time::HiRes qw/time/;
626
627 our @handlers = (); # list of [channel, expression, sub to handle result]
628 our @tasks = (); # list of [time, sub]
629 our %channels = ();
630 our %store = (
631         irc_nick => "",
632         playernick_byid_0 => "(console)",
633 );
634 our %config = (
635         irc_server => undef,
636         irc_nick => undef,
637         irc_nick_alternates => "",
638         irc_user => undef,
639         irc_channel => undef,
640         irc_ping_delay => 120,
641         irc_trigger => "",
642
643         irc_nickserv_password => "",
644         irc_nickserv_identify => 'PRIVMSG NickServ :IDENTIFY %2$s',
645         irc_nickserv_ghost => 'PRIVMSG NickServ :GHOST %1$s %2$s',
646         irc_nickserv_ghost_attempts => 3,
647
648         irc_quakenet_authname => "",
649         irc_quakenet_password => "",
650         irc_quakenet_getchallenge => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGE',
651         irc_quakenet_challengeauth => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGEAUTH',
652         irc_quakenet_challengeprefix => ':Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :CHALLENGE',
653
654         dp_server => undef,
655         dp_listen => "", 
656         dp_password => undef,
657         dp_status_delay => 30,
658         dp_server_from_wan => "",
659         irc_local => "",
660
661         irc_admin_password => "",
662         irc_admin_timeout => 3600,
663
664         irc_reconnect_delay => 300,
665
666         plugins => "",
667 );
668
669
670
671 # Nexuiz specific parsing of some server messages
672
673 sub nex_is_teamplay($)
674 {
675         my ($map) = @_;
676         return $map =~ /^(?:kh|ctf|tdm|dom)_/;
677 }
678
679 sub nex_slotsstring()
680 {
681         my $slotsstr = "";
682         if(defined $store{slots_max})
683         {
684                 my $slots = $store{slots_max} - $store{slots_active};
685                 my $slots_s = ($slots == 1) ? '' : 's';
686                 $slotsstr = " ($slots free slot$slots_s)";
687                 my $s = $config{dp_server_from_wan} || $config{dp_server};
688                 $slotsstr .= "; join now: \002nexuiz +connect $s"
689                         if $slots >= 1 and not $store{lms_blocked};
690         }
691         return $slotsstr;
692 }
693
694
695
696 # Do we have a config file? If yes, read and parse it (syntax: key = value
697 # pairs, separated by newlines), if not, complain.
698 die "Usage: $0 configfile\n"
699         unless @ARGV == 1;
700
701 open my $fh, "<", $ARGV[0]
702         or die "open $ARGV[0]: $!";
703 while(<$fh>)
704 {
705         chomp;
706         /^#/ and next;
707         /^(.*?)\s*=(?:\s*(.*))?$/ or next;
708         warn "Undefined config item: $1"
709                 unless exists $config{$1};
710         $config{$1} = defined $2 ? $2 : "";
711 }
712 close $fh;
713 my @missing = grep { !defined $config{$_} } keys %config;
714 die "The following config items are missing: @missing"
715         if @missing;
716
717
718
719 # Create a channel for error messages and other internal status messages...
720
721 $channels{system} = new Channel::FIFO();
722
723 # for example, quit messages caused by signals (if SIGTERM or SIGINT is first
724 # received, try to shut down cleanly, and if such a signal is received a second
725 # time, just exit)
726 my $quitting = 0;
727 $SIG{INT} = sub {
728         exit 1 if $quitting++;
729         $channels{system}->send("quit SIGINT");
730 };
731 $SIG{TERM} = sub {
732         exit 1 if $quitting++;
733         $channels{system}->send("quit SIGTERM");
734 };
735
736
737
738 # Create the two channels to gateway between...
739
740 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
741 $channels{dp} = new Channel::QW(my $dpsock = new Connection::Socket(udp => $config{dp_listen} => $config{dp_server} => 26000), $config{dp_password});
742 $config{dp_listen} = $dpsock->sockname();
743 print "Listening on $config{dp_listen}\n";
744
745 $channels{irc}->throttle(0.5, 5);
746
747
748 # Utility routine to write to a channel by name, also outputting what's been written and some status
749 sub out($$@)
750 {
751         my $chanstr = shift;
752         my $nothrottle = shift;
753         my $chan = $channels{$chanstr};
754         if(!$chan)
755         {
756                 print "UNDEFINED: $chanstr, ignoring message\n";
757                 return;
758         }
759         @_ = $chan->join_commands(@_);
760         for(@_)
761         {
762                 my $result = $chan->send($_, $nothrottle);
763                 if($result > 0)
764                 {
765                         print "           $chanstr << $_\n";
766                 }
767                 elsif($result < 0)
768                 {
769                         print "FLOOD:     $chanstr << $_\n";
770                 }
771                 else
772                 {
773                         print "ERROR:     $chanstr << $_\n";
774                         $channels{system}->send("error $chanstr", 0);
775                 }
776         }
777 }
778
779
780
781 # Schedule a task for later execution by the main loop; usage: schedule sub {
782 # task... }, $time; When a scheduled task is run, a reference to the task's own
783 # sub is passed as first argument; that way, the task is able to re-schedule
784 # itself so it gets periodically executed.
785 sub schedule($$)
786 {
787         my ($sub, $time) = @_;
788         push @tasks, [time() + $time, $sub];
789 }
790
791 # On IRC error, delete some data store variables of the connection, and
792 # reconnect to the IRC server soon (but only if someone is actually playing)
793 sub irc_error()
794 {
795         # prevent multiple instances of this timer
796         return if $store{irc_error_active};
797         $store{irc_error_active} = 1;
798
799         delete $channels{irc};
800         schedule sub {
801                 my ($timer) = @_;
802                 if(!defined $store{slots_full})
803                 {
804                         # DP is not running, then delay IRC reconnecting
805                         #use Data::Dumper; print Dumper \$timer;
806                         schedule $timer => 1;;
807                         return;
808                         # this will keep irc_error_active
809                 }
810                 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => "" => $config{irc_server}));
811                 delete $store{$_} for grep { /^irc_/ } keys %store;
812                 $store{irc_nick} = "";
813                 schedule sub {
814                         my ($timer) = @_;
815                         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp';
816                         $store{status_waiting} = -1;
817                 } => 1;
818                 # this will clear irc_error_active
819         } => $config{irc_reconnect_delay};
820         return 0;
821 }
822
823 sub uniq(@)
824 {
825         my @out = ();
826         my %found = ();
827         for(@_)
828         {
829                 next if $found{$_}++;
830                 push @out, $_;
831         }
832         return @out;
833 }
834
835 # IRC joining (if this is called as response to a nick name collision, $is433 is set);
836 # among other stuff, it performs NickServ or Quakenet authentication. This is to be called
837 # until the channel has been joined for every message that may be "interesting" (basically,
838 # IRC 001 hello messages, 443 nick collision messages and some notices by services).
839 sub irc_joinstage($)
840 {
841         my($is433) = @_;
842
843         return 0
844                 if $store{irc_joined_channel};
845         
846                 #use Data::Dumper; print Dumper \%store;
847
848         if($is433)
849         {
850                 if(length $store{irc_nick})
851                 {
852                         # we already have another nick, but couldn't change to the new one
853                         # try ghosting and then get the nick again
854                         if(length $config{irc_nickserv_password})
855                         {
856                                 if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
857                                 {
858                                         $store{irc_nick_requested} = $config{irc_nick};
859                                         out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
860                                         schedule sub {
861                                                 out irc => 1, "NICK $config{irc_nick}";
862                                         } => 1;
863                                         return; # we'll get here again for the NICK success message, or for a 433 failure
864                                 }
865                                 # otherwise, we failed to ghost and will continue with the wrong
866                                 # nick... also, no need to try to identify here
867                         }
868                         # otherwise, we can't handle this and will continue with our wrong nick
869                 }
870                 else
871                 {
872                         # we failed to get an initial nickname
873                         # change ours a bit and try again
874
875                         my @alternates = uniq ($config{irc_nick}, grep { $_ ne "" } split /\s+/, $config{irc_nick_alternates});
876                         my $nextnick = undef;
877                         for(0..@alternates-2)
878                         {
879                                 if($store{irc_nick_requested} eq $alternates[$_])
880                                 {
881                                         $nextnick = $alternates[$_+1];
882                                 }
883                         }
884                         if($store{irc_nick_requested} eq $alternates[@alternates-1]) # this will only happen once
885                         {
886                                 $store{irc_nick_requested} = $alternates[0];
887                                 # but don't set nextnick, so we edit it
888                         }
889                         if(defined $nextnick)
890                         {
891                                 $store{irc_nick_requested} = $nextnick;
892                         }
893                         else
894                         {
895                                 for(;;)
896                                 {
897                                         if(length $store{irc_nick_requested} < 9)
898                                         {
899                                                 $store{irc_nick_requested} .= '_';
900                                         }
901                                         else
902                                         {
903                                                 substr $store{irc_nick_requested}, int(rand length $store{irc_nick_requested}), 1, chr(97 + int rand 26);
904                                         }
905                                         last unless grep { $_ eq $store{irc_nick_requested} } @alternates;
906                                 }
907                         }
908                         out irc => 1, "NICK $store{irc_nick_requested}";
909                         return; # when it fails, we'll get here again, and when it succeeds, we will continue
910                 }
911         }
912
913         # we got a 001 or a NICK message, so $store{irc_nick} has been updated
914         if(length $config{irc_nickserv_password})
915         {
916                 if($store{irc_nick} eq $config{irc_nick})
917                 {
918                         # identify
919                         out irc => 1, sprintf($config{irc_nickserv_identify}, $config{irc_nick}, $config{irc_nickserv_password});
920                 }
921                 else
922                 {
923                         # ghost
924                         if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
925                         {
926                                 $store{irc_nick_requested} = $config{irc_nick};
927                                 out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
928                                 schedule sub {
929                                         out irc => 1, "NICK $config{irc_nick}";
930                                 } => 1;
931                                 return; # we'll get here again for the NICK success message, or for a 433 failure
932                         }
933                         # otherwise, we failed to ghost and will continue with the wrong
934                         # nick... also, no need to try to identify here
935                 }
936         }
937
938         # we are on Quakenet. Try to authenticate.
939         if(length $config{irc_quakenet_password} and length $config{irc_quakenet_authname})
940         {
941                 if(defined $store{irc_quakenet_challenge})
942                 {
943                         if($store{irc_quakenet_challenge} =~ /^MD5 (.*)/)
944                         {
945                                 out irc => 1, "$config{irc_quakenet_challengeauth} $config{irc_quakenet_authname} " . Digest::MD5::md5_hex("$config{irc_quakenet_password} $1");
946                         }
947                 }
948                 else
949                 {
950                         out irc => 1, $config{irc_quakenet_getchallenge};
951                         return;
952                         # we get here again when Q asks us
953                 }
954         }
955         
956         # if we get here, we are on IRC
957         $store{irc_joined_channel} = 1;
958         schedule sub {
959                 out irc => 1, "JOIN $config{irc_channel}";
960         } => 1;
961         return 0;
962 }
963
964 my $RE_FAIL = qr/$ $/;
965 my $RE_SUCCEED = qr//;
966 sub cond($)
967 {
968         return $_[0] ? $RE_FAIL : $RE_SUCCEED;
969 }
970
971
972 # List of all handlers on the various sockets. Additional handlers can be added by a plugin.
973 @handlers = (
974         # detect a server restart and set it up again
975         [ dp => q{ *(?:Warning: Could not expand \$|Unknown command ")(?:rcon2irc_[a-z0-9_]*)[" ]*} => sub {
976                 out dp => 0,
977                         'alias rcon2irc_eval "$*"',
978                         'log_dest_udp',
979                         'sv_logscores_console 0',
980                         'sv_logscores_bots 1',
981                         'sv_eventlog 1',
982                         'sv_eventlog_console 1',
983                         'alias rcon2irc_say_as "set say_as_restorenick \"$sv_adminnick\"; sv_adminnick \"$1^3\"; say \"^7$2\"; rcon2irc_say_as_restore"',
984                         'alias rcon2irc_say_as_restore "set sv_adminnick \"$say_as_restorenick\""',
985                         'alias rcon2irc_quit "echo \"quitting rcon2irc $1: log_dest_udp is $log_dest_udp\""'; # note: \\\\\\" ->perl \\\" ->console \"
986                 return 0;
987         } ],
988
989         # detect missing entry in log_dest_udp and fix it
990         [ dp => q{"log_dest_udp" is "([^"]*)" \["[^"]*"\]} => sub {
991                 my ($dest) = @_;
992                 my @dests = split ' ', $dest;
993                 return 0 if grep { $_ eq $config{dp_listen} } @dests;
994                 out dp => 0, 'log_dest_udp "' . join(" ", @dests, $config{dp_listen}) . '"';
995                 return 0;
996         } ],
997
998         # retrieve list of banned hosts
999         [ dp => q{#(\d+): (\S+) is still banned for (\S+) seconds} => sub {
1000                 return 0 unless $store{status_waiting} < 0;
1001                 my ($id, $ip, $time) = @_;
1002                 $store{bans_new} = [] if $id == 0;
1003                 $store{bans_new}[$id] = { ip => $ip, 'time' => $time };
1004                 return 0;
1005         } ],
1006
1007         # retrieve hostname from status replies
1008         [ dp => q{host:     (.*)} => sub {
1009                 return 0 unless $store{status_waiting} < 0;
1010                 my ($name) = @_;
1011                 $store{dp_hostname} = $name;
1012                 $store{bans} = $store{bans_new};
1013                 return 0;
1014         } ],
1015
1016         # retrieve version from status replies
1017         [ dp => q{version:  (.*)} => sub {
1018                 return 0 unless $store{status_waiting} < 0;
1019                 my ($version) = @_;
1020                 $store{dp_version} = $version;
1021                 return 0;
1022         } ],
1023
1024         # retrieve player names
1025         [ dp => q{players:  (\d+) active \((\d+) max\)} => sub {
1026                 return 0 unless $store{status_waiting} < 0;
1027                 my ($active, $max) = @_;
1028                 my $full = ($active >= $max);
1029                 $store{slots_max} = $max;
1030                 $store{slots_active} = $active;
1031                 $store{status_waiting} = $active;
1032                 $store{playerslots_active_new} = [];
1033                 if($store{status_waiting} == 0)
1034                 {
1035                         $store{playerslots_active} = $store{playerslots_active_new};
1036                 }
1037                 if($full != ($store{slots_full} || 0))
1038                 {
1039                         $store{slots_full} = $full;
1040                         return 0
1041                                 if $store{lms_blocked};
1042                         if($full)
1043                         {
1044                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION is full!\001";
1045                         }
1046                         else
1047                         {
1048                                 my $slotsstr = nex_slotsstring();
1049                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can be joined again$slotsstr!\001";
1050                         }
1051                 }
1052                 return 0;
1053         } ],
1054
1055         # retrieve player names
1056         [ dp => q{\^\d(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+(-?\d+)\s+\#(\d+)\s+\^\d(.*)} => sub {
1057                 return 0 unless $store{status_waiting} > 0;
1058                 my ($ip, $pl, $ping, $time, $frags, $no, $name) = ($1, $2, $3, $4, $5, $6, $7);
1059                 $store{"playerslot_$no"} = { ip => $ip, pl => $pl, ping => $ping, 'time' => $time, frags => $frags, no => $no, name => $name };
1060                 push @{$store{playerslots_active_new}}, $no;
1061                 if(--$store{status_waiting} == 0)
1062                 {
1063                         $store{playerslots_active} = $store{playerslots_active_new};
1064                 }
1065                 return 0;
1066         } ],
1067
1068         # IRC admin commands
1069         [ irc => q{:(([^! ]*)![^ ]*) (?i:PRIVMSG) [^&#%]\S* :(.*)} => sub {
1070                 return 0 unless $config{irc_admin_password} ne '';
1071
1072                 my ($hostmask, $nick, $command) = @_;
1073                 my $dpnick = color_dpfix $nick;
1074
1075                 if($command eq "login $config{irc_admin_password}")
1076                 {
1077                         $store{logins}{$hostmask} = time() + $config{irc_admin_timeout};
1078                         out irc => 0, "PRIVMSG $nick :my wish is your command";
1079                         return -1;
1080                 }
1081
1082                 if($command =~ /^login /)
1083                 {
1084                         out irc => 0, "PRIVMSG $nick :invalid password";
1085                         return -1;
1086                 }
1087
1088                 if(($store{logins}{$hostmask} || 0) < time())
1089                 {
1090                         out irc => 0, "PRIVMSG $nick :authentication required";
1091                         return -1;
1092                 }
1093
1094                 if($command =~ /^status(?: (.*))?$/)
1095                 {
1096                         my ($match) = $1;
1097                         my $found = 0;
1098                         my $foundany = 0;
1099                         for my $slot(@{$store{playerslots_active} || []})
1100                         {
1101                                 my $s = $store{"playerslot_$slot"};
1102                                 next unless $s;
1103                                 if(not defined $match or index(color_dp2none($s->{name}), $match) >= 0)
1104                                 {
1105                                         out irc => 0, sprintf 'PRIVMSG %s :%-21s %2i %4i %8s %4i #%-3u %s', $nick, $s->{ip}, $s->{pl}, $s->{ping}, $s->{time}, $s->{frags}, $slot, color_dp2irc $s->{name};
1106                                         ++$found;
1107                                 }
1108                                 ++$foundany;
1109                         }
1110                         if(!$found)
1111                         {
1112                                 if(!$foundany)
1113                                 {
1114                                         out irc => 0, "PRIVMSG $nick :the server is empty";
1115                                 }
1116                                 else
1117                                 {
1118                                         out irc => 0, "PRIVMSG $nick :no nicknames match";
1119                                 }
1120                         }
1121                         return 0;
1122                 }
1123
1124                 if($command =~ /^kick # (\d+) (.*)$/)
1125                 {
1126                         my ($id, $reason) = ($1, $2);
1127                         my $dpreason = color_irc2dp $reason;
1128                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1129                         $dpreason =~ s/(["\\])/\\$1/g;
1130                         out dp => 0, "kick # $id $dpreason";
1131                         my $slotnik = "playerslot_$id";
1132                         out irc => 0, "PRIVMSG $nick :kicked #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}) ($reason)";
1133                         return 0;
1134                 }
1135
1136                 if($command =~ /^kickban # (\d+) (\d+) (\d+) (.*)$/)
1137                 {
1138                         my ($id, $bantime, $mask, $reason) = ($1, $2, $3, $4);
1139                         my $dpreason = color_irc2dp $reason;
1140                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1141                         $dpreason =~ s/(["\\])/\\$1/g;
1142                         out dp => 0, "kickban # $id $bantime $mask $dpreason";
1143                         my $slotnik = "playerslot_$id";
1144                         out irc => 0, "PRIVMSG $nick :kickbanned #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}), netmask $mask, for $bantime seconds ($reason)";
1145                         return 0;
1146                 }
1147
1148                 if($command eq "bans")
1149                 {
1150                         my $banlist =
1151                                 join ", ",
1152                                 map { "$_ ($store{bans}[$_]{ip}, $store{bans}[$_]{time}s)" }
1153                                 0..@{$store{bans} || []}-1;
1154                         $banlist = "no bans"
1155                                 if $banlist eq "";
1156                         out irc => 0, "PRIVMSG $nick :$banlist";
1157                         return 0;
1158                 }
1159
1160                 if($command =~ /^unban (\d+)$/)
1161                 {
1162                         my ($id) = ($1);
1163                         out dp => 0, "unban $id";
1164                         out irc => 0, "PRIVMSG $nick :removed ban $id ($store{bans}[$id]{ip})";
1165                         return 0;
1166                 }
1167
1168                 out irc => 0, "PRIVMSG $nick :unknown command (supported: status [substring], kick # id reason, kickban # id bantime mask reason, bans, unban banid)";
1169
1170                 return -1;
1171         } ],
1172
1173         # LMS: detect "no more lives" message
1174         [ dp => q{\^4.*\^4 has no more lives left} => sub {
1175                 if(!$store{lms_blocked})
1176                 {
1177                         $store{lms_blocked} = 1;
1178                         if(!$store{slots_full})
1179                         {
1180                                 schedule sub {
1181                                         if($store{lms_blocked})
1182                                         {
1183                                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can't be joined until next round (a player has no more lives left)\001";
1184                                         }
1185                                 } => 1;
1186                         }
1187                 }
1188         } ],
1189
1190         # detect IRC errors and reconnect
1191         [ irc => q{ERROR .*} => \&irc_error ],
1192         [ system => q{error irc} => \&irc_error ],
1193
1194         # IRC nick in use
1195         [ irc => q{:[^ ]* 433 .*} => sub {
1196                 return irc_joinstage(433);
1197         } ],
1198
1199         # IRC welcome
1200         [ irc => q{:[^ ]* 001 .*} => sub {
1201                 $store{irc_seen_welcome} = 1;
1202                 $store{irc_nick} = $store{irc_nick_requested};
1203                 return irc_joinstage(0);
1204         } ],
1205
1206         # IRC my nickname changed
1207         [ irc => q{:(?i:(??{$store{irc_nick}}))![^ ]* (?i:NICK) :(.*)} => sub {
1208                 my ($n) = @_;
1209                 $store{irc_nick} = $n;
1210                 return irc_joinstage(0);
1211         } ],
1212
1213         # Quakenet: challenge from Q
1214         [ irc => q{(??{$config{irc_quakenet_challengeprefix}}) (.*)} => sub {
1215                 $store{irc_quakenet_challenge} = $1;
1216                 return irc_joinstage(0);
1217         } ],
1218
1219         # shut down everything on SIGINT
1220         [ system => q{quit (.*)} => sub {
1221                 my ($cause) = @_;
1222                 out irc => 1, "QUIT :$cause";
1223                 $store{quitcookie} = int rand 1000000000;
1224                 out dp => 0, "rcon2irc_quit $store{quitcookie}";
1225         } ],
1226
1227         # remove myself from the log destinations and exit everything
1228         [ dp => q{quitting rcon2irc (??{$store{quitcookie}}): log_dest_udp is (.*) *} => sub {
1229                 my ($dest) = @_;
1230                 my @dests = grep { $_ ne $config{dp_listen} } split ' ', $dest;
1231                 out dp => 0, 'log_dest_udp "' . join(" ", @dests) . '"';
1232                 exit 0;
1233                 return 0;
1234         } ],
1235
1236         # IRC PING
1237         [ irc => q{PING (.*)} => sub {
1238                 my ($data) = @_;
1239                 out irc => 1, "PONG $data";
1240                 return 1;
1241         } ],
1242
1243         # IRC PONG
1244         [ irc => q{:[^ ]* PONG .* :(.*)} => sub {
1245                 my ($data) = @_;
1246                 return 0
1247                         if not defined $store{irc_pingtime};
1248                 return 0
1249                         if $data ne $store{irc_pingtime};
1250                 print "* measured IRC line delay: @{[time() - $store{irc_pingtime}]}\n";
1251                 undef $store{irc_pingtime};
1252                 return 0;
1253         } ],
1254
1255         # detect channel join message and note hostname length to get the maximum allowed line length
1256         [ irc => q{(:(?i:(??{$store{irc_nick}}))![^ ]* )(?i:JOIN) :(?i:(??{$config{irc_channel}}))} => sub {
1257                 $store{irc_maxlen} = 510 - length($1);
1258                 $store{irc_joined_channel} = 1;
1259                 print "* detected maximum line length for channel messages: $store{irc_maxlen}\n";
1260                 return 0;
1261         } ],
1262
1263         # chat: Nexuiz server -> IRC channel
1264         [ dp => q{\001(.*?)\^7: (.*)} => sub {
1265                 my ($nick, $message) = map { color_dp2irc $_ } @_;
1266                 out irc => 0, "PRIVMSG $config{irc_channel} :<$nick\017> $message";
1267                 return 0;
1268         } ],
1269
1270         # chat: Nexuiz server -> IRC channel, nick set
1271         [ dp => q{:join:(\d+):(\d+):([^:]*):(.*)} => sub {
1272                 my ($id, $slot, $ip, $nick) = @_;
1273                 $nick = color_dp2irc $nick;
1274                 $store{"playernick_byid_$id"} = $nick;
1275                 $store{"playerip_byid_$id"} = $ip;
1276                 $store{"playerslot_byid_$id"} = $slot;
1277                 $store{"playerid_byslot_$slot"} = $id;
1278                 return 0;
1279         } ],
1280
1281         # chat: Nexuiz server -> IRC channel, nick change/set
1282         [ dp => q{:name:(\d+):(.*)} => sub {
1283                 my ($id, $nick) = @_;
1284                 $nick = color_dp2irc $nick;
1285                 my $oldnick = $store{"playernick_byid_$id"};
1286                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 is now known as $nick";
1287                 $store{"playernick_byid_$id"} = $nick;
1288                 return 0;
1289         } ],
1290
1291         # chat: Nexuiz server -> IRC channel, vote call
1292         [ dp => q{:vote:vcall:(\d+):(.*)} => sub {
1293                 my ($id, $command) = @_;
1294                 $command = color_dp2irc $command;
1295                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1296                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 calls a vote for \"$command\017\"";
1297                 return 0;
1298         } ],
1299
1300         # chat: Nexuiz server -> IRC channel, vote stop
1301         [ dp => q{:vote:vstop:(\d+)} => sub {
1302                 my ($id) = @_;
1303                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1304                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 stopped the vote";
1305                 return 0;
1306         } ],
1307
1308         # chat: Nexuiz server -> IRC channel, master login
1309         [ dp => q{:vote:vlogin:(\d+)} => sub {
1310                 my ($id) = @_;
1311                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1312                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 logged in as master";
1313                 return 0;
1314         } ],
1315
1316         # chat: Nexuiz server -> IRC channel, master do
1317         [ dp => q{:vote:vdo:(\d+):(.*)} => sub {
1318                 my ($id, $command) = @_;
1319                 $command = color_dp2irc $command;
1320                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1321                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 used his master status to do \"$command\017\"";
1322                 return 0;
1323         } ],
1324
1325         # chat: Nexuiz server -> IRC channel, result
1326         [ dp => q{:vote:v(yes|no|timeout):(\d+):(\d+):(\d+):(\d+):(-?\d+)} => sub {
1327                 my ($result, $yes, $no, $abstain, $not, $min) = @_;
1328                 my $spam = "$yes:$no" . (($min >= 0) ? " ($min needed)" : "") . ", $abstain didn't care, $not didn't vote";
1329                 out irc => 0, "PRIVMSG $config{irc_channel} :* the vote ended with $result: $spam";
1330                 return 0;
1331         } ],
1332
1333         # chat: IRC channel -> Nexuiz server
1334         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$store{irc_nick}}))(?: |: ?|, ?)(.*)} => sub {
1335                 my ($nick, $message) = @_;
1336                 $nick = color_dpfix $nick;
1337                         # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1338                 $message = color_irc2dp $message;
1339                 $message =~ s/(["\\])/\\$1/g;
1340                 out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1341                 return 0;
1342         } ],
1343
1344         (
1345                 length $config{irc_trigger}
1346                         ?
1347                                 [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$config{irc_trigger}}))(?: |: ?|, ?)(.*)} => sub {
1348                                         my ($nick, $message) = @_;
1349                                         $nick = color_dpfix $nick;
1350                                                 # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1351                                         $message = color_irc2dp $message;
1352                                         $message =~ s/(["\\])/\\$1/g;
1353                                         out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1354                                         return 0;
1355                                 } ]
1356                         :
1357                                 ()
1358         ),
1359
1360         # irc: CTCP VERSION reply
1361         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$store{irc_nick}})) :\001VERSION( .*)?\001} => sub {
1362                 my ($nick) = @_;
1363                 my $ver = $store{dp_version} or return 0;
1364                 $ver .= ", rcon2irc $VERSION";
1365                 out irc => 0, "NOTICE $nick :\001VERSION $ver\001";
1366         } ],
1367
1368         # on game start, notify the channel
1369         [ dp => q{:gamestart:(.*):[0-9.]*} => sub {
1370                 my ($map) = @_;
1371                 $store{playing} = 1;
1372                 $store{map} = $map;
1373                 $store{map_starttime} = time();
1374                 my $slotsstr = nex_slotsstring();
1375                 out irc => 0, "PRIVMSG $config{irc_channel} :\00304" . $map . "\017 has begun$slotsstr";
1376                 delete $store{lms_blocked};
1377                 return 0;
1378         } ],
1379
1380         # on game over, clear the current map
1381         [ dp => q{:gameover} => sub {
1382                 $store{playing} = 0;
1383                 return 0;
1384         } ],
1385
1386         # scores: Nexuiz server -> IRC channel (start)
1387         [ dp => q{:scores:(.*):(\d+)} => sub {
1388                 my ($map, $time) = @_;
1389                 $store{scores} = {};
1390                 $store{scores}{map} = $map;
1391                 $store{scores}{time} = $time;
1392                 $store{scores}{players} = [];
1393                 delete $store{lms_blocked};
1394                 return 0;
1395         } ],
1396
1397         # scores: Nexuiz server -> IRC channel, legacy format
1398         [ dp => q{:player:(-?\d+):(\d+):(\d+):(\d+):(\d+):(.*)} => sub {
1399                 my ($frags, $deaths, $time, $team, $id, $name) = @_;
1400                 return if not exists $store{scores};
1401                 push @{$store{scores}{players}}, [$frags, $team, $name]
1402                         unless $frags <= -666; # no spectators
1403                 return 0;
1404         } ],
1405
1406         # scores: Nexuiz server -> IRC channel (CTF), legacy format
1407         [ dp => q{:teamscores:(\d+:-?\d*(?::\d+:-?\d*)*)} => sub {
1408                 my ($teams) = @_;
1409                 return if not exists $store{scores};
1410                 $store{scores}{teams} = {split /:/, $teams};
1411                 return 0;
1412         } ],
1413
1414         # scores: Nexuiz server -> IRC channel, new format
1415         [ dp => q{:player:see-labels:(-?\d+)[-0-9,]*:(\d+):(\d+):(\d+):(.*)} => sub {
1416                 my ($frags, $time, $team, $id, $name) = @_;
1417                 return if not exists $store{scores};
1418                 push @{$store{scores}{players}}, [$frags, $team, $name];
1419                 return 0;
1420         } ],
1421
1422         # scores: Nexuiz server -> IRC channel (CTF), new format
1423         [ dp => q{:teamscores:see-labels:(-?\d+)[-0-9,]*:(\d+)} => sub {
1424                 my ($frags, $team) = @_;
1425                 return if not exists $store{scores};
1426                 $store{scores}{teams}{$team} = $frags;
1427                 return 0;
1428         } ],
1429
1430         # scores: Nexuiz server -> IRC channel
1431         [ dp => q{:end} => sub {
1432                 return if not exists $store{scores};
1433                 my $s = $store{scores};
1434                 delete $store{scores};
1435                 my $teams_matter = nex_is_teamplay($s->{map});
1436
1437                 my @t = ();
1438                 my @p = ();
1439
1440                 if($teams_matter)
1441                 {
1442                         # put players into teams
1443                         my %t = ();
1444                         for(@{$s->{players}})
1445                         {
1446                                 my $thisteam = ($t{$_->[1]} ||= {score => 0, team => $_->[1], players => []});
1447                                 push @{$thisteam->{players}}, [$_->[0], $_->[1], $_->[2]];
1448                                 if($s->{teams})
1449                                 {
1450                                         $thisteam->{score} = $s->{teams}{$_->[1]};
1451                                 }
1452                                 else
1453                                 {
1454                                         $thisteam->{score} += $_->[0];
1455                                 }
1456                         }
1457
1458                         # sort by team score
1459                         @t = sort { $b->{score} <=> $a->{score} } values %t;
1460
1461                         # sort by player score
1462                         @p = ();
1463                         for(@t)
1464                         {
1465                                 @{$_->{players}} = sort { $b->[0] <=> $a->[0] } @{$_->{players}};
1466                                 push @p, @{$_->{players}};
1467                         }
1468                 }
1469                 else
1470                 {
1471                         @p = sort { $b->[0] <=> $a->[0] } @{$s->{players}};
1472                 }
1473
1474                 # no display for empty server
1475                 return 0
1476                         if !@p;
1477
1478                 # make message fit somehow
1479                 for my $maxnamelen(reverse 3..64)
1480                 {
1481                         my $scores_string = "PRIVMSG $config{irc_channel} :\00304" . $s->{map} . "\017 ended:";
1482                         if($teams_matter)
1483                         {
1484                                 my $sep = ' ';
1485                                 for(@t)
1486                                 {
1487                                         $scores_string .= $sep . sprintf "\003%02d\%d\017", $color_team2irc_table{$_->{team}}, $_->{score};
1488                                         $sep = ':';
1489                                 }
1490                         }
1491                         my $sep = '';
1492                         for(@p)
1493                         {
1494                                 my ($frags, $team, $name) = @$_;
1495                                 $name = color_dpfix substr($name, 0, $maxnamelen);
1496                                 if($teams_matter)
1497                                 {
1498                                         $name = "\003" . $color_team2irc_table{$team} . " " . color_dp2none $name;
1499                                 }
1500                                 else
1501                                 {
1502                                         $name = " " . color_dp2irc $name;
1503                                 }
1504                                 $scores_string .= "$sep$name\017 $frags";
1505                                 $sep = ',';
1506                         }
1507                         if(length($scores_string) <= ($store{irc_maxlen} || 256))
1508                         {
1509                                 out irc => 0, $scores_string;
1510                                 return 0;
1511                         }
1512                 }
1513                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION would have LIKED to put the scores here, but they wouldn't fit :(\001";
1514                 return 0;
1515         } ],
1516
1517         # complain when system load gets too high
1518         [ dp => q{timing:   (([0-9.]*)% CPU, ([0-9.]*)% lost, offset avg ([0-9.]*)ms, max ([0-9.]*)ms, sdev ([0-9.]*)ms)} => sub {
1519                 my ($all, $cpu, $lost, $avg, $max, $sdev) = @_;
1520                 return 0 # don't complain when just on the voting screen
1521                         if !$store{playing};
1522                 return 0 # don't complain if it was less than 0.5%
1523                         if $lost < 0.5;
1524                 return 0 # don't complain if nobody is looking
1525                         if $store{slots_active} == 0;
1526                 return 0 # don't complain in the first two minutes
1527                         if time() - $store{map_starttime} < 120;
1528                 return 0 # don't complain if it was already at least half as bad in this round
1529                         if $store{map_starttime} == $store{timingerror_map_starttime} and $lost <= 2 * $store{timingerror_lost};
1530                 $store{timingerror_map_starttime} = $store{map_starttime};
1531                 $store{timingerror_lost} = $lost;
1532                 out dp => 0, 'rcon2irc_say_as server "There are currently some severe system load problems. The admins have been notified."';
1533                 out irc => 1, "PRIVMSG $config{irc_channel} :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1534                 #out irc => 1, "PRIVMSG OpBaI :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1535                 return 0;
1536         } ],
1537 );
1538
1539
1540
1541 # Load plugins and add them to the handler list in the front.
1542 for my $p(split ' ', $config{plugins})
1543 {
1544         my @h = eval { do $p; }
1545                 or die "Invalid plugin $p: $@";
1546         for(reverse @h)
1547         {
1548                 ref $_ eq 'ARRAY' or die "Invalid plugin $p: did not return a list of arrays";
1549                 @$_ == 3 or die "Invalid plugin $p: did not return a list of three-element arrays";
1550                 !ref $_->[0] && !ref $_->[1] && ref $_->[2] eq 'CODE' or die "Invalid plugin $p: did not return a list of string-string-sub arrays";
1551                 unshift @handlers, $_;
1552         }
1553 }
1554
1555
1556
1557 # verify that the server is up by letting it echo back a string that causes
1558 # re-initialization of the required aliases
1559 out dp => 0, 'echo "Unknown command \"rcon2irc_eval\""'; # assume the server has been restarted
1560
1561
1562
1563 # regularily, query the server status and if it still is connected to us using
1564 # the log_dest_udp feature. If not, we will detect the response to this rcon
1565 # command and re-initialize the server's connection to us (either by log_dest_udp
1566 # not containing our own IP:port, or by rcon2irc_eval not being a defined command).
1567 schedule sub {
1568         my ($timer) = @_;
1569         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp', 'rcon2irc_eval set dummy 1';
1570         $store{status_waiting} = -1;
1571         schedule $timer => (exists $store{dp_hostname} ? $config{dp_status_delay} : 1);;
1572 } => 1;
1573
1574
1575
1576 # Continue with connecting to IRC as soon as we get our first status reply from
1577 # the DP server (which contains the server's hostname that we'll use as
1578 # realname for IRC).
1579 schedule sub {
1580         my ($timer) = @_;
1581
1582         # log on to IRC when needed
1583         if(exists $store{dp_hostname} && !exists $store{irc_logged_in})
1584         {
1585                 $store{irc_nick_requested} = $config{irc_nick};
1586                 out irc => 1, "NICK $config{irc_nick}", "USER $config{irc_user} localhost localhost :$store{dp_hostname}";
1587                 $store{irc_logged_in} = 1;
1588                 undef $store{irc_maxlen};
1589                 undef $store{irc_pingtime};
1590         }
1591
1592         schedule $timer => 1;;
1593 } => 1;
1594
1595
1596
1597 # Regularily ping the IRC server to detect if the connection is down. If it is,
1598 # schedule an IRC error that will cause reconnection later.
1599 schedule sub {
1600         my ($timer) = @_;
1601
1602         if($store{irc_logged_in})
1603         {
1604                 if(defined $store{irc_pingtime})
1605                 {
1606                         # IRC connection apparently broke
1607                         # so... KILL IT WITH FIRE
1608                         $channels{system}->send("error irc", 0);
1609                 }
1610                 else
1611                 {
1612                         # everything is fine, send a new ping
1613                         $store{irc_pingtime} = time();
1614                         out irc => 1, "PING $store{irc_pingtime}";
1615                 }
1616         }
1617
1618         schedule $timer => $config{irc_ping_delay};;
1619 } => 1;
1620
1621
1622
1623 # Main loop.
1624 for(;;)
1625 {
1626         # Build up an IO::Select object for all our channels.
1627         my $s = IO::Select->new();
1628         for my $chan(values %channels)
1629         {
1630                 $s->add($_) for $chan->fds();
1631         }
1632
1633         # wait for something to happen on our sockets, or wait 2 seconds without anything happening there
1634         $s->can_read(2);
1635         my @errors = $s->has_exception(0);
1636
1637         # on every channel, look for incoming messages
1638         CHANNEL:
1639         for my $chanstr(keys %channels)
1640         {
1641                 my $chan = $channels{$chanstr};
1642                 my @chanfds = $chan->fds();
1643
1644                 for my $chanfd(@chanfds)
1645                 {
1646                         if(grep { $_ == $chanfd } @errors)
1647                         {
1648                                 # STOP! This channel errored!
1649                                 $channels{system}->send("error $chanstr", 0);
1650                                 next CHANNEL;
1651                         }
1652                 }
1653
1654                 eval
1655                 {
1656                         for my $line($chan->recv())
1657                         {
1658                                 # found one! Check if it matches the regular expression of one of
1659                                 # our handlers...
1660                                 my $handled = 0;
1661                                 my $private = 0;
1662                                 for my $h(@handlers)
1663                                 {
1664                                         my ($chanstr_wanted, $re, $sub) = @$h;
1665                                         next
1666                                                 if $chanstr_wanted ne $chanstr;
1667                                         use re 'eval';
1668                                         my @matches = ($line =~ /^$re$/s);
1669                                         no re 'eval';
1670                                         next
1671                                                 unless @matches;
1672                                         # and if it is a match, handle it.
1673                                         ++$handled;
1674                                         my $result = $sub->(@matches);
1675                                         $private = 1
1676                                                 if $result < 0;
1677                                         last
1678                                                 if $result;
1679                                 }
1680                                 # print the message, together with info on whether it has been handled or not
1681                                 if($private)
1682                                 {
1683                                         print "           $chanstr >> (private)\n";
1684                                 }
1685                                 elsif($handled)
1686                                 {
1687                                         print "           $chanstr >> $line\n";
1688                                 }
1689                                 else
1690                                 {
1691                                         print "unhandled: $chanstr >> $line\n";
1692                                 }
1693                         }
1694                         1;
1695                 } or do {
1696                         if($@ eq "read error\n")
1697                         {
1698                                 $channels{system}->send("error $chanstr", 0);
1699                                 next CHANNEL;
1700                         }
1701                         else
1702                         {
1703                                 # re-throw
1704                                 die $@;
1705                         }
1706                 };
1707         }
1708
1709         # handle scheduled tasks...
1710         my @t = @tasks;
1711         my $t = time();
1712         # by emptying the list of tasks...
1713         @tasks = ();
1714         for(@t)
1715         {
1716                 my ($time, $sub) = @$_;
1717                 if($t >= $time)
1718                 {
1719                         # calling them if they are schedled for the "past"...
1720                         $sub->($sub);
1721                 }
1722                 else
1723                 {
1724                         # or re-adding them to the task list if they still are scheduled for the "future"
1725                         push @tasks, [$time, $sub];
1726                 }
1727         }
1728 }