better detect teamplay
[divverent/nexuiz.git] / server / rcon2irc / rcon2irc.pl
1 #!/usr/bin/perl
2
3 our $VERSION = '0.4.2 svn $Revision$';
4
5 # Copyright (c) 2008 Rudolf "divVerent" Polzer
6
7 # Permission is hereby granted, free of charge, to any person
8 # obtaining a copy of this software and associated documentation
9 # files (the "Software"), to deal in the Software without
10 # restriction, including without limitation the rights to use,
11 # copy, modify, merge, publish, distribute, sublicense, and/or sell
12 # copies of the Software, and to permit persons to whom the
13 # Software is furnished to do so, subject to the following
14 # conditions:
15
16 # The above copyright notice and this permission notice shall be
17 # included in all copies or substantial portions of the Software.
18
19 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
21 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
22 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
23 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
24 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
25 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
26 # OTHER DEALINGS IN THE SOFTWARE.
27
28 # MISC STRING UTILITY ROUTINES to convert between DarkPlaces and IRC conventions
29
30 # convert mIRC color codes to DP color codes
31 our @color_irc2dp_table = (7, 0, 4, 2, 1, 1, 6, 1, 3, 2, 5, 5, 4, 6, 7, 7);
32 our @color_dp2irc_table = (-1, 4, 9, 8, 12, 11, 13, -1, -1, -1); # not accurate, but legible
33 our @color_dp2ansi_table = ("m", "1;31m", "1;32m", "1;33m", "1;34m", "1;36m", "1;35m", "m", "1m", "1m"); # not accurate, but legible
34 our %color_team2dp_table = (5 => 1, 14 => 4, 13 => 3, 10 => 6);
35 our %color_team2irc_table = (5 => 4, 14 => 12, 13 => 8, 10 => 13);
36 sub color_irc2dp($)
37 {
38         my ($message) = @_;
39         $message =~ s/\^/^^/g;
40         my $color = 7;
41         $message =~ s{\003(\d\d?)(?:,(\d?\d?))?|(\017)}{
42                 # $1 is FG, $2 is BG, but let's ignore BG
43                 my $oldcolor = $color;
44                 if($3)
45                 {
46                         $color = 7;
47                 }
48                 else
49                 {
50                         $color = $color_irc2dp_table[$1];
51                         $color = $oldcolor if not defined $color;
52                 }
53                 ($color == $oldcolor) ? '' : '^' . $color;
54         }esg;
55         $message =~ s{[\000-\037]}{}gs; # kill bold etc. for now
56         return $message;
57 }
58
59 our @text_qfont_table = ( # ripped from DP console.c qfont_table
60     "\0", '#',  '#',  '#',  '#',  '.',  '#',  '#',
61     '#',  9,    10,   '#',  ' ',  13,   '.',  '.',
62     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
63     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
64     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
65     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
66     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
67     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
68     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
69     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
70     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
71     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
72     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
73     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
74     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
75     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<',
76     '<',  '=',  '>',  '#',  '#',  '.',  '#',  '#',
77     '#',  '#',  ' ',  '#',  ' ',  '>',  '.',  '.',
78     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
79     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
80     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
81     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
82     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
83     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
84     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
85     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
86     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
87     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
88     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
89     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
90     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
91     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<'
92 );
93 sub text_dp2ascii($)
94 {
95         my ($message) = @_;
96         $message = join '', map { $text_qfont_table[ord $_] } split //, $message;
97 }
98
99 sub color_dp_transform(&$)
100 {
101         my ($block, $message) = @_;
102
103         $message =~ s{(?:(\^\^)|\^x([0-9a-fA-F])([0-9a-fA-F])([0-9a-fA-F])|\^([0-9])|(.))(?=([0-9,]?))}{
104                 defined $1 ? $block->(char => '^', $7) :
105                 defined $2 ? $block->(rgb => [hex $2, hex $3, hex $4], $7) :
106                 defined $5 ? $block->(color => $5, $7) :
107                 defined $6 ? $block->(char => $6, $7) :
108                         die "Invalid match";
109         }esg;
110
111         return $message;
112 }
113
114 sub color_dp2none($)
115 {
116         my ($message) = @_;
117
118         return color_dp_transform
119         {
120                 my ($type, $data, $next) = @_;
121                 $type eq 'char'
122                         ? $text_qfont_table[ord $data]
123                         : "";
124         }
125         $message;
126 }
127
128 sub color_rgb2basic($)
129 {
130         my ($data) = @_;
131         my ($R, $G, $B) = @$data;
132         my $min = [sort { $a <=> $b } ($R, $G, $B)]->[0];
133         my $max = [sort { $a <=> $b } ($R, $G, $B)]->[-1];
134
135         my $v = $max / 15;
136         my $s = ($max == $min) ? 0 : 1 - $min/$max;
137
138         if($s < 0.2)
139         {
140                 return 0 if $v < 0.5;
141                 return 7;
142         }
143
144         my $h;
145         if($max == $min)
146         {
147                 $h = 0;
148         }
149         elsif($max == $R)
150         {
151                 $h = (60 * ($G - $B) / ($max - $min)) % 360;
152         }
153         elsif($max == $G)
154         {
155                 $h = (60 * ($B - $R) / ($max - $min)) + 120;
156         }
157         elsif($max == $B)
158         {
159                 $h = (60 * ($R - $G) / ($max - $min)) + 240;
160         }
161
162         return 1 if $h < 36;
163         return 3 if $h < 80;
164         return 2 if $h < 150;
165         return 5 if $h < 200;
166         return 4 if $h < 270;
167         return 6 if $h < 330;
168         return 1;
169 }
170
171 sub color_dp_rgb2basic($)
172 {
173         my ($message) = @_;
174         return color_dp_transform
175         {
176                 my ($type, $data, $next) = @_;
177                 $type eq 'char'  ? ($data eq '^' ? '^^' : $data) :
178                 $type eq 'color' ? "^$data" :
179                 $type eq 'rgb'   ? "^" . color_rgb2basic $data :
180                         die "Invalid type";
181         }
182         $message;
183 }
184
185 sub color_dp2irc($)
186 {
187         my ($message) = @_;
188         my $color = -1;
189         return color_dp_transform
190         {
191                 my ($type, $data, $next) = @_;
192
193                 if($type eq 'rgb')
194                 {
195                         $type = 'color';
196                         $data = color_rgb2basic $data;
197                 }
198
199                 $type eq 'char'  ? $text_qfont_table[ord $data] :
200                 $type eq 'color' ? do {
201                         my $oldcolor = $color;
202                         $color = $color_dp2irc_table[$data];
203
204                         $color == $oldcolor ? '' :
205                         $color < 0          ? "\017" :
206                         $next eq ','        ? "\003$color\002\002" :
207                                               sprintf "\003%02d", $color;
208                 } :
209                         die "Invalid type";
210         }
211         $message;
212 }
213
214 sub color_dp2ansi($)
215 {
216         my ($message) = @_;
217         my $color = -1;
218         return color_dp_transform
219         {
220                 my ($type, $data, $next) = @_;
221
222                 if($type eq 'rgb')
223                 {
224                         $type = 'color';
225                         $data = color_rgb2basic $data;
226                 }
227
228                 $type eq 'char'  ? $text_qfont_table[ord $data] :
229                 $type eq 'color' ? do {
230                         my $oldcolor = $color;
231                         $color = $color_dp2ansi_table[$data];
232
233                         $color eq $oldcolor ? '' :
234                                               "\033[${color}"
235                 } :
236                         die "Invalid type";
237         }
238         $message;
239 }
240
241 sub color_dpfix($)
242 {
243         my ($message) = @_;
244         # if the message ends with an odd number of ^, kill one
245         chop $message if $message =~ /(?:^|[^\^])\^(\^\^)*$/;
246         return $message;
247 }
248
249
250
251
252 # Interfaces:
253 #   Connection:
254 #     $conn->sockname() returns a connection type specific representation
255 #       string of the local address, or undef if not applicable.
256 #     $conn->send("string") sends something over the connection.
257 #     $conn->recv() receives a string from the connection, or returns "" if no
258 #       data is available.
259 #     $conn->fds() returns all file descriptors used by the connection, so one
260 #       can use select() on them.
261 #   Channel:
262 #     Usually wraps around a connection and implements a command based
263 #     structure over it. It usually is constructed using new
264 #     ChannelType($connection, someparameters...)
265 #     @cmds = $chan->join_commands(@cmds) joins multiple commands to a single
266 #       command string if the protocol supports it, or does nothing and leaves
267 #       @cmds unchanged if the protocol does not support that usage (this is
268 #       meant to save send() invocations).
269 #     $chan->send($command, $nothrottle) sends a command over the channel. If
270 #       $nothrottle is sent, the command must not be left out even if the channel
271 #       is saturated (for example, because of IRC's flood control mechanism).
272 #     $chan->quote($str) returns a string in a quoted form so it can safely be
273 #       inserted as a substring into a command, or returns $str as is if not
274 #       applicable. It is assumed that the result of the quote method is used
275 #       as part of a quoted string, if the protocol supports that.
276 #     $chan->recv() returns a list of received commands from the channel, or
277 #       the empty list if none are available.
278 #     $conn->fds() returns all file descriptors used by the channel's
279 #       connections, so one can use select() on them.
280
281
282
283
284
285
286
287 # Socket connection.
288 # Represents a connection over a socket.
289 # Mainly used to wrap a channel around it for, in this case, line based or rcon-like operation.
290 package Connection::Socket;
291 use strict;
292 use warnings;
293 use IO::Socket::INET;
294 use IO::Handle;
295
296 # Constructor:
297 #   my $conn = new Connection::Socket(tcp => "localaddress" => "remoteaddress" => 6667);
298 # If the remote address does not contain a port number, the numeric port is
299 # used (it serves as a default port).
300 sub new($$)
301 {
302         my ($class, $proto, $local, $remote, $defaultport) = @_;
303         my $sock = IO::Socket::INET->new(
304                 Proto => $proto,
305                 (length($local) ? (LocalAddr => $local) : ()),
306                 PeerAddr => $remote,
307                 PeerPort => $defaultport
308         ) or die "socket $proto/$local/$remote/$defaultport: $!";
309         $sock->blocking(0);
310         my $you = {
311                 # Mortal fool! Release me from this wretched tomb! I must be set free
312                 # or I will haunt you forever! I will hide your keys beneath the
313                 # cushions of your upholstered furniture... and NEVERMORE will you be
314                 # able to find socks that match!
315                 sock => $sock,
316                 # My demonic powers have made me OMNIPOTENT! Bwahahahahahahaha!
317         };
318         return
319                 bless $you, 'Connection::Socket';
320 }
321
322 # $sock->sockname() returns the local address of the socket.
323 sub sockname($)
324 {
325         my ($self) = @_;
326         my ($port, $addr) = sockaddr_in $self->{sock}->sockname();
327         return "@{[inet_ntoa $addr]}:$port";
328 }
329
330 # $sock->send($data) sends some data over the socket; on success, 1 is returned.
331 sub send($$)
332 {
333         my ($self, $data) = @_;
334         return 1
335                 if not length $data;
336         if(not eval { $self->{sock}->send($data); })
337         {
338                 warn "$@";
339                 return 0;
340         }
341         return 1;
342 }
343
344 # $sock->recv() receives as much as possible from the socket (or at most 32k). Returns "" if no data is available.
345 sub recv($)
346 {
347         my ($self) = @_;
348         my $data = "";
349         if(defined $self->{sock}->recv($data, 32768, 0))
350         {
351                 return $data;
352         }
353         elsif($!{EAGAIN})
354         {
355                 return "";
356         }
357         else
358         {
359                 return undef;
360         }
361 }
362
363 # $sock->fds() returns the socket file descriptor.
364 sub fds($)
365 {
366         my ($self) = @_;
367         return fileno $self->{sock};
368 }
369
370
371
372
373
374
375
376 # Line-based buffered connectionless FIFO channel.
377 # Whatever is sent to it using send() is echoed back when using recv().
378 package Channel::FIFO;
379 use strict;
380 use warnings;
381
382 # Constructor:
383 #   my $chan = new Channel::FIFO();
384 sub new($)
385 {
386         my ($class) = @_;
387         my $you = {
388                 buffer => []
389         };
390         return
391                 bless $you, 'Channel::FIFO';
392 }
393
394 sub join_commands($@)
395 {
396         my ($self, @data) = @_;
397         return @data;
398 }
399
400 sub send($$$)
401 {
402         my ($self, $line, $nothrottle) = @_;
403         push @{$self->{buffer}}, $line;
404 }
405
406 sub quote($$)
407 {
408         my ($self, $data) = @_;
409         return $data;
410 }
411
412 sub recv($)
413 {
414         my ($self) = @_;
415         my $r = $self->{buffer};
416         $self->{buffer} = [];
417         return @$r;
418 }
419
420 sub fds($)
421 {
422         my ($self) = @_;
423         return ();
424 }
425
426
427
428
429
430
431
432 # QW rcon protocol channel.
433 # Wraps around a UDP based Connection and sends commands as rcon commands as
434 # well as receives rcon replies. The quote and join_commands methods are using
435 # DarkPlaces engine specific rcon protocol extensions.
436 package Channel::QW;
437 use strict;
438 use warnings;
439 use Digest::HMAC;
440 use Digest::MD4;
441
442 # Constructor:
443 #   my $chan = new Channel::QW($connection, "password");
444 sub new($$$)
445 {
446         my ($class, $conn, $password, $secure) = @_;
447         my $you = {
448                 connector => $conn,
449                 password => $password,
450                 recvbuf => "",
451                 secure => $secure,
452         };
453         return
454                 bless $you, 'Channel::QW';
455 }
456
457 # Note: multiple commands in one rcon packet is a DarkPlaces extension.
458 sub join_commands($@)
459 {
460         my ($self, @data) = @_;
461         return join "\0", @data;
462 }
463
464 sub send($$$)
465 {
466         my ($self, $line, $nothrottle) = @_;
467         if($self->{secure})
468         {
469                 my $t = sprintf "%ld", time();
470                 my $key = Digest::HMAC::hmac("$t $line", $self->{password}, \&Digest::MD4::md4);
471                 return $self->{connector}->send("\377\377\377\377srcon HMAC-MD4 TIME $key $t $line");
472         }
473         else
474         {
475                 return $self->{connector}->send("\377\377\377\377rcon $self->{password} $line");
476         }
477 }
478
479 # Note: backslash and quotation mark escaping is a DarkPlaces extension.
480 sub quote($$)
481 {
482         my ($self, $data) = @_;
483         $data =~ s/[\000-\037]//g;
484         $data =~ s/([\\"])/\\$1/g;
485         $data =~ s/\$/\$\$/g;
486         return $data;
487 }
488
489 sub recv($)
490 {
491         my ($self) = @_;
492         for(;;)
493         {
494                 my $s = $self->{connector}->recv();
495                 die "read error\n"
496                         if not defined $s;
497                 length $s
498                         or last;
499                 next
500                         if $s !~ /^\377\377\377\377n(.*)$/s;
501                 $self->{recvbuf} .= $1;
502         }
503         my @out = ();
504         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
505         {
506                 push @out, $1;
507         }
508         return @out;
509 }
510
511 sub fds($)
512 {
513         my ($self) = @_;
514         return $self->{connector}->fds();
515 }
516
517
518
519
520
521
522
523 # Line based protocol channel.
524 # Wraps around a TCP based Connection and sends commands as text lines
525 # (separated by CRLF). When reading responses from the Connection, any type of
526 # line ending is accepted.
527 # A flood control mechanism is implemented.
528 package Channel::Line;
529 use strict;
530 use warnings;
531 use Time::HiRes qw/time/;
532
533 # Constructor:
534 #   my $chan = new Channel::Line($connection);
535 sub new($$)
536 {
537         my ($class, $conn) = @_;
538         my $you = {
539                 connector => $conn,
540                 recvbuf => "",
541                 capacity => undef,
542                 linepersec => undef,
543                 maxlines => undef,
544                 lastsend => time()
545         };
546         return 
547                 bless $you, 'Channel::Line';
548 }
549
550 sub join_commands($@)
551 {
552         my ($self, @data) = @_;
553         return @data;
554 }
555
556 # Sets new flood control parameters:
557 #   $chan->throttle(maximum lines per second, maximum burst length allowed to
558 #     exceed the lines per second limit);
559 #   RFC 1459 describes these parameters to be 0.5 and 5 for the IRC protocol.
560 #   If the $nothrottle flag is set while sending, the line is sent anyway even
561 #   if flooding would take place.
562 sub throttle($$$)
563 {
564         my ($self, $linepersec, $maxlines) = @_;
565         $self->{linepersec} = $linepersec;
566         $self->{maxlines} = $maxlines;
567         $self->{capacity} = $maxlines;
568 }
569
570 sub send($$$)
571 {
572         my ($self, $line, $nothrottle) = @_;
573         my $t = time();
574         if(defined $self->{capacity})
575         {
576                 $self->{capacity} += ($t - $self->{lastsend}) * $self->{linepersec};
577                 $self->{lastsend} = $t;
578                 $self->{capacity} = $self->{maxlines}
579                         if $self->{capacity} > $self->{maxlines};
580                 if(!$nothrottle)
581                 {
582                         return -1
583                                 if $self->{capacity} < 0;
584                 }
585                 $self->{capacity} -= 1;
586         }
587         $line =~ s/\r|\n//g;
588         return $self->{connector}->send("$line\r\n");
589 }
590
591 sub quote($$)
592 {
593         my ($self, $data) = @_;
594         $data =~ s/\r\n?/\n/g;
595         $data =~ s/\n/*/g;
596         return $data;
597 }
598
599 sub recv($)
600 {
601         my ($self) = @_;
602         for(;;)
603         {
604                 my $s = $self->{connector}->recv();
605                 die "read error\n"
606                         if not defined $s;
607                 length $s
608                         or last;
609                 $self->{recvbuf} .= $s;
610         }
611         my @out = ();
612         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
613         {
614                 push @out, $1;
615         }
616         return @out;
617 }
618
619 sub fds($)
620 {
621         my ($self) = @_;
622         return $self->{connector}->fds();
623 }
624
625
626
627
628
629
630 # main program... a gateway between IRC and DarkPlaces servers
631 package main;
632
633 use strict;
634 use warnings;
635 use IO::Select;
636 use Digest::SHA;
637 use Digest::HMAC;
638 use Time::HiRes qw/time/;
639
640 our @handlers = (); # list of [channel, expression, sub to handle result]
641 our @tasks = (); # list of [time, sub]
642 our %channels = ();
643 our %store = (
644         irc_nick => "",
645         playernick_byid_0 => "(console)",
646 );
647 our %config = (
648         irc_server => undef,
649         irc_nick => undef,
650         irc_nick_alternates => "",
651         irc_user => undef,
652         irc_channel => undef,
653         irc_ping_delay => 120,
654         irc_trigger => "",
655
656         irc_nickserv_password => "",
657         irc_nickserv_identify => 'PRIVMSG NickServ :IDENTIFY %2$s',
658         irc_nickserv_ghost => 'PRIVMSG NickServ :GHOST %1$s %2$s',
659         irc_nickserv_ghost_attempts => 3,
660
661         irc_quakenet_authname => "",
662         irc_quakenet_password => "",
663         irc_quakenet_getchallenge => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGE',
664         irc_quakenet_challengeauth => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGEAUTH',
665         irc_quakenet_challengeprefix => ':Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :CHALLENGE',
666
667         dp_server => undef,
668         dp_secure => 1,
669         dp_listen => "", 
670         dp_password => undef,
671         dp_status_delay => 30,
672         dp_server_from_wan => "",
673         irc_local => "",
674
675         irc_admin_password => "",
676         irc_admin_timeout => 3600,
677         irc_admin_quote_re => "",
678
679         irc_reconnect_delay => 300,
680
681         plugins => "",
682 );
683
684
685
686 # Nexuiz specific parsing of some server messages
687
688 sub nex_slotsstring()
689 {
690         my $slotsstr = "";
691         if(defined $store{slots_max})
692         {
693                 my $slots = $store{slots_max} - $store{slots_active};
694                 my $slots_s = ($slots == 1) ? '' : 's';
695                 $slotsstr = " ($slots free slot$slots_s)";
696                 my $s = $config{dp_server_from_wan} || $config{dp_server};
697                 $slotsstr .= "; join now: \002nexuiz +connect $s"
698                         if $slots >= 1 and not $store{lms_blocked};
699         }
700         return $slotsstr;
701 }
702
703
704
705 # Do we have a config file? If yes, read and parse it (syntax: key = value
706 # pairs, separated by newlines), if not, complain.
707 die "Usage: $0 configfile\n"
708         unless @ARGV == 1;
709
710 open my $fh, "<", $ARGV[0]
711         or die "open $ARGV[0]: $!";
712 while(<$fh>)
713 {
714         chomp;
715         /^#/ and next;
716         /^(.*?)\s*=(?:\s*(.*))?$/ or next;
717         warn "Undefined config item: $1"
718                 unless exists $config{$1};
719         $config{$1} = defined $2 ? $2 : "";
720 }
721 close $fh;
722 my @missing = grep { !defined $config{$_} } keys %config;
723 die "The following config items are missing: @missing"
724         if @missing;
725
726
727
728 # Create a channel for error messages and other internal status messages...
729
730 $channels{system} = new Channel::FIFO();
731
732 # for example, quit messages caused by signals (if SIGTERM or SIGINT is first
733 # received, try to shut down cleanly, and if such a signal is received a second
734 # time, just exit)
735 my $quitting = 0;
736 $SIG{INT} = sub {
737         exit 1 if $quitting++;
738         $channels{system}->send("quit SIGINT");
739 };
740 $SIG{TERM} = sub {
741         exit 1 if $quitting++;
742         $channels{system}->send("quit SIGTERM");
743 };
744
745
746
747 # Create the two channels to gateway between...
748
749 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
750 $channels{dp} = new Channel::QW(my $dpsock = new Connection::Socket(udp => $config{dp_listen} => $config{dp_server} => 26000), $config{dp_password}, $config{dp_secure});
751 $config{dp_listen} = $dpsock->sockname();
752 print "Listening on $config{dp_listen}\n";
753
754 $channels{irc}->throttle(0.5, 5);
755
756
757 # Utility routine to write to a channel by name, also outputting what's been written and some status
758 sub out($$@)
759 {
760         my $chanstr = shift;
761         my $nothrottle = shift;
762         my $chan = $channels{$chanstr};
763         if(!$chan)
764         {
765                 print "UNDEFINED: $chanstr, ignoring message\n";
766                 return;
767         }
768         @_ = $chan->join_commands(@_);
769         for(@_)
770         {
771                 my $result = $chan->send($_, $nothrottle);
772                 if($result > 0)
773                 {
774                         print "           $chanstr << $_\n";
775                 }
776                 elsif($result < 0)
777                 {
778                         print "FLOOD:     $chanstr << $_\n";
779                 }
780                 else
781                 {
782                         print "ERROR:     $chanstr << $_\n";
783                         $channels{system}->send("error $chanstr", 0);
784                 }
785         }
786 }
787
788
789
790 # Schedule a task for later execution by the main loop; usage: schedule sub {
791 # task... }, $time; When a scheduled task is run, a reference to the task's own
792 # sub is passed as first argument; that way, the task is able to re-schedule
793 # itself so it gets periodically executed.
794 sub schedule($$)
795 {
796         my ($sub, $time) = @_;
797         push @tasks, [time() + $time, $sub];
798 }
799
800 # On IRC error, delete some data store variables of the connection, and
801 # reconnect to the IRC server soon (but only if someone is actually playing)
802 sub irc_error()
803 {
804         # prevent multiple instances of this timer
805         return if $store{irc_error_active};
806         $store{irc_error_active} = 1;
807
808         delete $channels{irc};
809         schedule sub {
810                 my ($timer) = @_;
811                 if(!defined $store{slots_active})
812                 {
813                         # DP is not running, then delay IRC reconnecting
814                         #use Data::Dumper; print Dumper \$timer;
815                         schedule $timer => 1;
816                         return;
817                         # this will keep irc_error_active
818                 }
819                 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => "" => $config{irc_server} => 6667));
820                 delete $store{$_} for grep { /^irc_/ } keys %store;
821                 $store{irc_nick} = "";
822                 schedule sub {
823                         my ($timer) = @_;
824                         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp';
825                         $store{status_waiting} = -1;
826                 } => 1;
827                 # this will clear irc_error_active
828         } => $config{irc_reconnect_delay};
829         return 0;
830 }
831
832 sub uniq(@)
833 {
834         my @out = ();
835         my %found = ();
836         for(@_)
837         {
838                 next if $found{$_}++;
839                 push @out, $_;
840         }
841         return @out;
842 }
843
844 # IRC joining (if this is called as response to a nick name collision, $is433 is set);
845 # among other stuff, it performs NickServ or Quakenet authentication. This is to be called
846 # until the channel has been joined for every message that may be "interesting" (basically,
847 # IRC 001 hello messages, 443 nick collision messages and some notices by services).
848 sub irc_joinstage($)
849 {
850         my($is433) = @_;
851
852         return 0
853                 if $store{irc_joined_channel};
854         
855                 #use Data::Dumper; print Dumper \%store;
856
857         if($is433)
858         {
859                 if(length $store{irc_nick})
860                 {
861                         # we already have another nick, but couldn't change to the new one
862                         # try ghosting and then get the nick again
863                         if(length $config{irc_nickserv_password})
864                         {
865                                 if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
866                                 {
867                                         $store{irc_nick_requested} = $config{irc_nick};
868                                         out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
869                                         schedule sub {
870                                                 out irc => 1, "NICK $config{irc_nick}";
871                                         } => 1;
872                                         return; # we'll get here again for the NICK success message, or for a 433 failure
873                                 }
874                                 # otherwise, we failed to ghost and will continue with the wrong
875                                 # nick... also, no need to try to identify here
876                         }
877                         # otherwise, we can't handle this and will continue with our wrong nick
878                 }
879                 else
880                 {
881                         # we failed to get an initial nickname
882                         # change ours a bit and try again
883
884                         my @alternates = uniq ($config{irc_nick}, grep { $_ ne "" } split /\s+/, $config{irc_nick_alternates});
885                         my $nextnick = undef;
886                         for(0..@alternates-2)
887                         {
888                                 if($store{irc_nick_requested} eq $alternates[$_])
889                                 {
890                                         $nextnick = $alternates[$_+1];
891                                 }
892                         }
893                         if($store{irc_nick_requested} eq $alternates[@alternates-1]) # this will only happen once
894                         {
895                                 $store{irc_nick_requested} = $alternates[0];
896                                 # but don't set nextnick, so we edit it
897                         }
898                         if(defined $nextnick)
899                         {
900                                 $store{irc_nick_requested} = $nextnick;
901                         }
902                         else
903                         {
904                                 for(;;)
905                                 {
906                                         if(length $store{irc_nick_requested} < 9)
907                                         {
908                                                 $store{irc_nick_requested} .= '_';
909                                         }
910                                         else
911                                         {
912                                                 substr $store{irc_nick_requested}, int(rand length $store{irc_nick_requested}), 1, chr(97 + int rand 26);
913                                         }
914                                         last unless grep { $_ eq $store{irc_nick_requested} } @alternates;
915                                 }
916                         }
917                         out irc => 1, "NICK $store{irc_nick_requested}";
918                         return; # when it fails, we'll get here again, and when it succeeds, we will continue
919                 }
920         }
921
922         # we got a 001 or a NICK message, so $store{irc_nick} has been updated
923         if(length $config{irc_nickserv_password})
924         {
925                 if($store{irc_nick} eq $config{irc_nick})
926                 {
927                         # identify
928                         out irc => 1, sprintf($config{irc_nickserv_identify}, $config{irc_nick}, $config{irc_nickserv_password});
929                 }
930                 else
931                 {
932                         # ghost
933                         if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
934                         {
935                                 $store{irc_nick_requested} = $config{irc_nick};
936                                 out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
937                                 schedule sub {
938                                         out irc => 1, "NICK $config{irc_nick}";
939                                 } => 1;
940                                 return; # we'll get here again for the NICK success message, or for a 433 failure
941                         }
942                         # otherwise, we failed to ghost and will continue with the wrong
943                         # nick... also, no need to try to identify here
944                 }
945         }
946
947         # we are on Quakenet. Try to authenticate.
948         if(length $config{irc_quakenet_password} and length $config{irc_quakenet_authname})
949         {
950                 if(defined $store{irc_quakenet_challenge})
951                 {
952                         if($store{irc_quakenet_challenge} =~ /^([0-9a-f]*)\b.*\bHMAC-SHA-256\b/)
953                         {
954                                 my $challenge = $1;
955                                 my $hash1 = Digest::SHA::sha256_hex(substr $config{irc_quakenet_password}, 0, 10);
956                                 my $key = Digest::SHA::sha256_hex("@{[lc $config{irc_quakenet_authname}]}:$hash1");
957                                 my $digest = Digest::HMAC::hmac_hex($challenge, $key, \&Digest::SHA::sha256);
958                                 out irc => 1, "$config{irc_quakenet_challengeauth} $config{irc_quakenet_authname} $digest HMAC-SHA-256";
959                         }
960                 }
961                 else
962                 {
963                         out irc => 1, $config{irc_quakenet_getchallenge};
964                         return;
965                         # we get here again when Q asks us
966                 }
967         }
968         
969         # if we get here, we are on IRC
970         $store{irc_joined_channel} = 1;
971         schedule sub {
972                 out irc => 1, "JOIN $config{irc_channel}";
973         } => 1;
974         return 0;
975 }
976
977 my $RE_FAIL = qr/$ $/;
978 my $RE_SUCCEED = qr//;
979 sub cond($)
980 {
981         return $_[0] ? $RE_FAIL : $RE_SUCCEED;
982 }
983
984
985 # List of all handlers on the various sockets. Additional handlers can be added by a plugin.
986 @handlers = (
987         # detect a server restart and set it up again
988         [ dp => q{ *(?:Warning: Could not expand \$|Unknown command ")(?:rcon2irc_[a-z0-9_]*)[" ]*} => sub {
989                 out dp => 0,
990                         'alias rcon2irc_eval "$*"',
991                         'log_dest_udp',
992                         'sv_logscores_console 0',
993                         'sv_logscores_bots 1',
994                         'sv_eventlog 1',
995                         'sv_eventlog_console 1',
996                         'alias rcon2irc_say_as "set say_as_restorenick \"$sv_adminnick\"; sv_adminnick \"$1^3\"; say \"^7$2\"; rcon2irc_say_as_restore"',
997                         'alias rcon2irc_say_as_restore "set sv_adminnick \"$say_as_restorenick\""',
998                         'alias rcon2irc_quit "echo \"quitting rcon2irc $1: log_dest_udp is $log_dest_udp\""'; # note: \\\\\\" ->perl \\\" ->console \"
999                 return 0;
1000         } ],
1001
1002         # detect missing entry in log_dest_udp and fix it
1003         [ dp => q{"log_dest_udp" is "([^"]*)" \["[^"]*"\]} => sub {
1004                 my ($dest) = @_;
1005                 my @dests = split ' ', $dest;
1006                 return 0 if grep { $_ eq $config{dp_listen} } @dests;
1007                 out dp => 0, 'log_dest_udp "' . join(" ", @dests, $config{dp_listen}) . '"';
1008                 return 0;
1009         } ],
1010
1011         # retrieve list of banned hosts
1012         [ dp => q{#(\d+): (\S+) is still banned for (\S+) seconds} => sub {
1013                 return 0 unless $store{status_waiting} < 0;
1014                 my ($id, $ip, $time) = @_;
1015                 $store{bans_new} = [] if $id == 0;
1016                 $store{bans_new}[$id] = { ip => $ip, 'time' => $time };
1017                 return 0;
1018         } ],
1019
1020         # retrieve hostname from status replies
1021         [ dp => q{host:     (.*)} => sub {
1022                 return 0 unless $store{status_waiting} < 0;
1023                 my ($name) = @_;
1024                 $store{dp_hostname} = $name;
1025                 $store{bans} = $store{bans_new};
1026                 return 0;
1027         } ],
1028
1029         # retrieve version from status replies
1030         [ dp => q{version:  (.*)} => sub {
1031                 return 0 unless $store{status_waiting} < 0;
1032                 my ($version) = @_;
1033                 $store{dp_version} = $version;
1034                 return 0;
1035         } ],
1036
1037         # retrieve player names
1038         [ dp => q{players:  (\d+) active \((\d+) max\)} => sub {
1039                 return 0 unless $store{status_waiting} < 0;
1040                 my ($active, $max) = @_;
1041                 my $full = ($active >= $max);
1042                 $store{slots_max} = $max;
1043                 $store{slots_active} = $active;
1044                 $store{status_waiting} = $active;
1045                 $store{playerslots_active_new} = [];
1046                 if($store{status_waiting} == 0)
1047                 {
1048                         $store{playerslots_active} = $store{playerslots_active_new};
1049                 }
1050                 if($full != ($store{slots_full} || 0))
1051                 {
1052                         $store{slots_full} = $full;
1053                         return 0
1054                                 if $store{lms_blocked};
1055                         if($full)
1056                         {
1057                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION is full!\001";
1058                         }
1059                         else
1060                         {
1061                                 my $slotsstr = nex_slotsstring();
1062                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can be joined again$slotsstr!\001";
1063                         }
1064                 }
1065                 return 0;
1066         } ],
1067
1068         # retrieve player names
1069         [ dp => q{\^\d(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+(-?\d+)\s+\#(\d+)\s+\^\d(.*)} => sub {
1070                 return 0 unless $store{status_waiting} > 0;
1071                 my ($ip, $pl, $ping, $time, $frags, $no, $name) = ($1, $2, $3, $4, $5, $6, $7);
1072                 $store{"playerslot_$no"} = { ip => $ip, pl => $pl, ping => $ping, 'time' => $time, frags => $frags, no => $no, name => $name };
1073                 push @{$store{playerslots_active_new}}, $no;
1074                 if(--$store{status_waiting} == 0)
1075                 {
1076                         $store{playerslots_active} = $store{playerslots_active_new};
1077                 }
1078                 return 0;
1079         } ],
1080
1081         # IRC admin commands
1082         [ irc => q{:(([^! ]*)![^ ]*) (?i:PRIVMSG) [^&#%]\S* :(.*)} => sub {
1083                 return 0 unless $config{irc_admin_password} ne '';
1084
1085                 my ($hostmask, $nick, $command) = @_;
1086                 my $dpnick = color_dpfix $nick;
1087
1088                 if($command eq "login $config{irc_admin_password}")
1089                 {
1090                         $store{logins}{$hostmask} = time() + $config{irc_admin_timeout};
1091                         out irc => 0, "PRIVMSG $nick :my wish is your command";
1092                         return -1;
1093                 }
1094
1095                 if($command =~ /^login /)
1096                 {
1097                         out irc => 0, "PRIVMSG $nick :invalid password";
1098                         return -1;
1099                 }
1100
1101                 if(($store{logins}{$hostmask} || 0) < time())
1102                 {
1103                         out irc => 0, "PRIVMSG $nick :authentication required";
1104                         return -1;
1105                 }
1106
1107                 if($command =~ /^status(?: (.*))?$/)
1108                 {
1109                         my ($match) = $1;
1110                         my $found = 0;
1111                         my $foundany = 0;
1112                         for my $slot(@{$store{playerslots_active} || []})
1113                         {
1114                                 my $s = $store{"playerslot_$slot"};
1115                                 next unless $s;
1116                                 if(not defined $match or index(color_dp2none($s->{name}), $match) >= 0)
1117                                 {
1118                                         out irc => 0, sprintf 'PRIVMSG %s :%-21s %2i %4i %8s %4i #%-3u %s', $nick, $s->{ip}, $s->{pl}, $s->{ping}, $s->{time}, $s->{frags}, $slot, color_dp2irc $s->{name};
1119                                         ++$found;
1120                                 }
1121                                 ++$foundany;
1122                         }
1123                         if(!$found)
1124                         {
1125                                 if(!$foundany)
1126                                 {
1127                                         out irc => 0, "PRIVMSG $nick :the server is empty";
1128                                 }
1129                                 else
1130                                 {
1131                                         out irc => 0, "PRIVMSG $nick :no nicknames match";
1132                                 }
1133                         }
1134                         return 0;
1135                 }
1136
1137                 if($command =~ /^kick # (\d+) (.*)$/)
1138                 {
1139                         my ($id, $reason) = ($1, $2);
1140                         my $dpreason = color_irc2dp $reason;
1141                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1142                         $dpreason =~ s/(["\\])/\\$1/g;
1143                         out dp => 0, "kick # $id $dpreason";
1144                         my $slotnik = "playerslot_$id";
1145                         out irc => 0, "PRIVMSG $nick :kicked #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}) ($reason)";
1146                         return 0;
1147                 }
1148
1149                 if($command =~ /^kickban # (\d+) (\d+) (\d+) (.*)$/)
1150                 {
1151                         my ($id, $bantime, $mask, $reason) = ($1, $2, $3, $4);
1152                         my $dpreason = color_irc2dp $reason;
1153                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1154                         $dpreason =~ s/(["\\])/\\$1/g;
1155                         out dp => 0, "kickban # $id $bantime $mask $dpreason";
1156                         my $slotnik = "playerslot_$id";
1157                         out irc => 0, "PRIVMSG $nick :kickbanned #$id (@{[color_dp2irc $store{$slotnik}{name}]} @ $store{$slotnik}{ip}), netmask $mask, for $bantime seconds ($reason)";
1158                         return 0;
1159                 }
1160
1161                 if($command eq "bans")
1162                 {
1163                         my $banlist =
1164                                 join ", ",
1165                                 map { "$_ ($store{bans}[$_]{ip}, $store{bans}[$_]{time}s)" }
1166                                 0..@{$store{bans} || []}-1;
1167                         $banlist = "no bans"
1168                                 if $banlist eq "";
1169                         out irc => 0, "PRIVMSG $nick :$banlist";
1170                         return 0;
1171                 }
1172
1173                 if($command =~ /^unban (\d+)$/)
1174                 {
1175                         my ($id) = ($1);
1176                         out dp => 0, "unban $id";
1177                         out irc => 0, "PRIVMSG $nick :removed ban $id ($store{bans}[$id]{ip})";
1178                         return 0;
1179                 }
1180
1181                 if($command =~ /^quote (.*)$/)
1182                 {
1183                         my ($cmd) = ($1);
1184                         if($cmd =~ /^(??{$config{irc_admin_quote_re}})$/si)
1185                         {
1186                                 out irc => 0, $cmd;
1187                                 out irc => 0, "PRIVMSG $nick :executed your command";
1188                         }
1189                         else
1190                         {
1191                                 out irc => 0, "PRIVMSG $nick :permission denied";
1192                         }
1193                         return 0;
1194                 }
1195
1196                 out irc => 0, "PRIVMSG $nick :unknown command (supported: status [substring], kick # id reason, kickban # id bantime mask reason, bans, unban banid)";
1197
1198                 return -1;
1199         } ],
1200
1201         # LMS: detect "no more lives" message
1202         [ dp => q{\^4.*\^4 has no more lives left} => sub {
1203                 if(!$store{lms_blocked})
1204                 {
1205                         $store{lms_blocked} = 1;
1206                         if(!$store{slots_full})
1207                         {
1208                                 schedule sub {
1209                                         if($store{lms_blocked})
1210                                         {
1211                                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can't be joined until next round (a player has no more lives left)\001";
1212                                         }
1213                                 } => 1;
1214                         }
1215                 }
1216         } ],
1217
1218         # detect IRC errors and reconnect
1219         [ irc => q{ERROR .*} => \&irc_error ],
1220         [ irc => q{:[^ ]* 404 .*} => \&irc_error ], # cannot send to channel
1221         [ system => q{error irc} => \&irc_error ],
1222
1223         # IRC nick in use
1224         [ irc => q{:[^ ]* 433 .*} => sub {
1225                 return irc_joinstage(433);
1226         } ],
1227
1228         # IRC welcome
1229         [ irc => q{:[^ ]* 001 .*} => sub {
1230                 $store{irc_seen_welcome} = 1;
1231                 $store{irc_nick} = $store{irc_nick_requested};
1232                 return irc_joinstage(0);
1233         } ],
1234
1235         # IRC my nickname changed
1236         [ irc => q{:(?i:(??{$store{irc_nick}}))![^ ]* (?i:NICK) :(.*)} => sub {
1237                 my ($n) = @_;
1238                 $store{irc_nick} = $n;
1239                 return irc_joinstage(0);
1240         } ],
1241
1242         # Quakenet: challenge from Q
1243         [ irc => q{(??{$config{irc_quakenet_challengeprefix}}) (.*)} => sub {
1244                 $store{irc_quakenet_challenge} = $1;
1245                 return irc_joinstage(0);
1246         } ],
1247
1248         # shut down everything on SIGINT
1249         [ system => q{quit (.*)} => sub {
1250                 my ($cause) = @_;
1251                 out irc => 1, "QUIT :$cause";
1252                 $store{quitcookie} = int rand 1000000000;
1253                 out dp => 0, "rcon2irc_quit $store{quitcookie}";
1254         } ],
1255
1256         # remove myself from the log destinations and exit everything
1257         [ dp => q{quitting rcon2irc (??{$store{quitcookie}}): log_dest_udp is (.*) *} => sub {
1258                 my ($dest) = @_;
1259                 my @dests = grep { $_ ne $config{dp_listen} } split ' ', $dest;
1260                 out dp => 0, 'log_dest_udp "' . join(" ", @dests) . '"';
1261                 exit 0;
1262                 return 0;
1263         } ],
1264
1265         # IRC PING
1266         [ irc => q{PING (.*)} => sub {
1267                 my ($data) = @_;
1268                 out irc => 1, "PONG $data";
1269                 return 1;
1270         } ],
1271
1272         # IRC PONG
1273         [ irc => q{:[^ ]* PONG .* :(.*)} => sub {
1274                 my ($data) = @_;
1275                 return 0
1276                         if not defined $store{irc_pingtime};
1277                 return 0
1278                         if $data ne $store{irc_pingtime};
1279                 print "* measured IRC line delay: @{[time() - $store{irc_pingtime}]}\n";
1280                 undef $store{irc_pingtime};
1281                 return 0;
1282         } ],
1283
1284         # detect channel join message and note hostname length to get the maximum allowed line length
1285         [ irc => q{(:(?i:(??{$store{irc_nick}}))![^ ]* )(?i:JOIN) :(?i:(??{$config{irc_channel}}))} => sub {
1286                 $store{irc_maxlen} = 510 - length($1);
1287                 $store{irc_joined_channel} = 1;
1288                 print "* detected maximum line length for channel messages: $store{irc_maxlen}\n";
1289                 return 0;
1290         } ],
1291
1292         # chat: Nexuiz server -> IRC channel
1293         [ dp => q{\001(.*?)\^7: (.*)} => sub {
1294                 my ($nick, $message) = map { color_dp2irc $_ } @_;
1295                 out irc => 0, "PRIVMSG $config{irc_channel} :<$nick\017> $message";
1296                 return 0;
1297         } ],
1298
1299         # chat: Nexuiz server -> IRC channel, nick set
1300         [ dp => q{:join:(\d+):(\d+):([^:]*):(.*)} => sub {
1301                 my ($id, $slot, $ip, $nick) = @_;
1302                 $store{"playernickraw_byid_$id"} = $nick;
1303                 $nick = color_dp2irc $nick;
1304                 $store{"playernick_byid_$id"} = $nick;
1305                 $store{"playerip_byid_$id"} = $ip;
1306                 $store{"playerslot_byid_$id"} = $slot;
1307                 $store{"playerid_byslot_$slot"} = $id;
1308                 return 0;
1309         } ],
1310
1311         # chat: Nexuiz server -> IRC channel, nick change/set
1312         [ dp => q{:name:(\d+):(.*)} => sub {
1313                 my ($id, $nick) = @_;
1314                 $store{"playernickraw_byid_$id"} = $nick;
1315                 $nick = color_dp2irc $nick;
1316                 my $oldnick = $store{"playernick_byid_$id"};
1317                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 is now known as $nick";
1318                 $store{"playernick_byid_$id"} = $nick;
1319                 return 0;
1320         } ],
1321
1322         # chat: Nexuiz server -> IRC channel, vote call
1323         [ dp => q{:vote:vcall:(\d+):(.*)} => sub {
1324                 my ($id, $command) = @_;
1325                 $command = color_dp2irc $command;
1326                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1327                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 calls a vote for \"$command\017\"";
1328                 return 0;
1329         } ],
1330
1331         # chat: Nexuiz server -> IRC channel, vote stop
1332         [ dp => q{:vote:vstop:(\d+)} => sub {
1333                 my ($id) = @_;
1334                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1335                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 stopped the vote";
1336                 return 0;
1337         } ],
1338
1339         # chat: Nexuiz server -> IRC channel, master login
1340         [ dp => q{:vote:vlogin:(\d+)} => sub {
1341                 my ($id) = @_;
1342                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1343                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 logged in as master";
1344                 return 0;
1345         } ],
1346
1347         # chat: Nexuiz server -> IRC channel, master do
1348         [ dp => q{:vote:vdo:(\d+):(.*)} => sub {
1349                 my ($id, $command) = @_;
1350                 $command = color_dp2irc $command;
1351                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1352                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 used his master status to do \"$command\017\"";
1353                 return 0;
1354         } ],
1355
1356         # chat: Nexuiz server -> IRC channel, result
1357         [ dp => q{:vote:v(yes|no|timeout):(\d+):(\d+):(\d+):(\d+):(-?\d+)} => sub {
1358                 my ($result, $yes, $no, $abstain, $not, $min) = @_;
1359                 my $spam = "$yes:$no" . (($min >= 0) ? " ($min needed)" : "") . ", $abstain didn't care, $not didn't vote";
1360                 out irc => 0, "PRIVMSG $config{irc_channel} :* the vote ended with $result: $spam";
1361                 return 0;
1362         } ],
1363
1364         # chat: IRC channel -> Nexuiz server
1365         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$store{irc_nick}}))(?: |: ?|, ?)(.*)} => sub {
1366                 my ($nick, $message) = @_;
1367                 $nick = color_dpfix $nick;
1368                         # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1369                 $message = color_irc2dp $message;
1370                 $message =~ s/(["\\])/\\$1/g;
1371                 out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1372                 return 0;
1373         } ],
1374
1375         (
1376                 length $config{irc_trigger}
1377                         ?
1378                                 [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$config{irc_trigger}}))(?: |: ?|, ?)(.*)} => sub {
1379                                         my ($nick, $message) = @_;
1380                                         $nick = color_dpfix $nick;
1381                                                 # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1382                                         $message = color_irc2dp $message;
1383                                         $message =~ s/(["\\])/\\$1/g;
1384                                         out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1385                                         return 0;
1386                                 } ]
1387                         :
1388                                 ()
1389         ),
1390
1391         # irc: CTCP VERSION reply
1392         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$store{irc_nick}})) :\001VERSION( .*)?\001} => sub {
1393                 my ($nick) = @_;
1394                 my $ver = $store{dp_version} or return 0;
1395                 $ver .= ", rcon2irc $VERSION";
1396                 out irc => 0, "NOTICE $nick :\001VERSION $ver\001";
1397         } ],
1398
1399         # on game start, notify the channel
1400         [ dp => q{:gamestart:(.*):[0-9.]*} => sub {
1401                 my ($map) = @_;
1402                 $store{playing} = 1;
1403                 $store{map} = $map;
1404                 $store{map_starttime} = time();
1405                 my $slotsstr = nex_slotsstring();
1406                 out irc => 0, "PRIVMSG $config{irc_channel} :\00304" . $map . "\017 has begun$slotsstr";
1407                 delete $store{lms_blocked};
1408                 return 0;
1409         } ],
1410
1411         # on game over, clear the current map
1412         [ dp => q{:gameover} => sub {
1413                 $store{playing} = 0;
1414                 return 0;
1415         } ],
1416
1417         # scores: Nexuiz server -> IRC channel (start)
1418         [ dp => q{:scores:(.*):(\d+)} => sub {
1419                 my ($map, $time) = @_;
1420                 $store{scores} = {};
1421                 $store{scores}{map} = $map;
1422                 $store{scores}{time} = $time;
1423                 $store{scores}{players} = [];
1424                 delete $store{lms_blocked};
1425                 return 0;
1426         } ],
1427
1428         # scores: Nexuiz server -> IRC channel, legacy format
1429         [ dp => q{:player:(-?\d+):(\d+):(\d+):(\d+):(\d+):(.*)} => sub {
1430                 my ($frags, $deaths, $time, $team, $id, $name) = @_;
1431                 return if not exists $store{scores};
1432                 push @{$store{scores}{players}}, [$frags, $team, $name]
1433                         unless $frags <= -666; # no spectators
1434                 return 0;
1435         } ],
1436
1437         # scores: Nexuiz server -> IRC channel (CTF), legacy format
1438         [ dp => q{:teamscores:(\d+:-?\d*(?::\d+:-?\d*)*)} => sub {
1439                 my ($teams) = @_;
1440                 return if not exists $store{scores};
1441                 $store{scores}{teams} = {split /:/, $teams};
1442                 return 0;
1443         } ],
1444
1445         # scores: Nexuiz server -> IRC channel, new format
1446         [ dp => q{:player:see-labels:(-?\d+)[-0-9,]*:(\d+):(\d+):(\d+):(.*)} => sub {
1447                 my ($frags, $time, $team, $id, $name) = @_;
1448                 return if not exists $store{scores};
1449                 push @{$store{scores}{players}}, [$frags, $team, $name];
1450                 return 0;
1451         } ],
1452
1453         # scores: Nexuiz server -> IRC channel (CTF), new format
1454         [ dp => q{:teamscores:see-labels:(-?\d+)[-0-9,]*:(\d+)} => sub {
1455                 my ($frags, $team) = @_;
1456                 return if not exists $store{scores};
1457                 $store{scores}{teams}{$team} = $frags;
1458                 return 0;
1459         } ],
1460
1461         # scores: Nexuiz server -> IRC channel
1462         [ dp => q{:end} => sub {
1463                 return if not exists $store{scores};
1464                 my $s = $store{scores};
1465                 delete $store{scores};
1466                 my $teams_matter = defined $s->{teams};
1467
1468                 my @t = ();
1469                 my @p = ();
1470
1471                 if($teams_matter)
1472                 {
1473                         # put players into teams
1474                         my %t = ();
1475                         for(@{$s->{players}})
1476                         {
1477                                 my $thisteam = ($t{$_->[1]} ||= {score => 0, team => $_->[1], players => []});
1478                                 push @{$thisteam->{players}}, [$_->[0], $_->[1], $_->[2]];
1479                                 if($s->{teams})
1480                                 {
1481                                         $thisteam->{score} = $s->{teams}{$_->[1]};
1482                                 }
1483                                 else
1484                                 {
1485                                         $thisteam->{score} += $_->[0];
1486                                 }
1487                         }
1488
1489                         # sort by team score
1490                         @t = sort { $b->{score} <=> $a->{score} } values %t;
1491
1492                         # sort by player score
1493                         @p = ();
1494                         for(@t)
1495                         {
1496                                 @{$_->{players}} = sort { $b->[0] <=> $a->[0] } @{$_->{players}};
1497                                 push @p, @{$_->{players}};
1498                         }
1499                 }
1500                 else
1501                 {
1502                         @p = sort { $b->[0] <=> $a->[0] } @{$s->{players}};
1503                 }
1504
1505                 # no display for empty server
1506                 return 0
1507                         if !@p;
1508
1509                 # make message fit somehow
1510                 for my $maxnamelen(reverse 3..64)
1511                 {
1512                         my $scores_string = "PRIVMSG $config{irc_channel} :\00304" . $s->{map} . "\017 ended:";
1513                         if($teams_matter)
1514                         {
1515                                 my $sep = ' ';
1516                                 for(@t)
1517                                 {
1518                                         $scores_string .= $sep . sprintf "\003%02d\%d\017", $color_team2irc_table{$_->{team}}, $_->{score};
1519                                         $sep = ':';
1520                                 }
1521                         }
1522                         my $sep = '';
1523                         for(@p)
1524                         {
1525                                 my ($frags, $team, $name) = @$_;
1526                                 $name = color_dpfix substr($name, 0, $maxnamelen);
1527                                 if($teams_matter)
1528                                 {
1529                                         $name = "\003" . $color_team2irc_table{$team} . " " . color_dp2none $name;
1530                                 }
1531                                 else
1532                                 {
1533                                         $name = " " . color_dp2irc $name;
1534                                 }
1535                                 $scores_string .= "$sep$name\017 $frags";
1536                                 $sep = ',';
1537                         }
1538                         if(length($scores_string) <= ($store{irc_maxlen} || 256))
1539                         {
1540                                 out irc => 0, $scores_string;
1541                                 return 0;
1542                         }
1543                 }
1544                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION would have LIKED to put the scores here, but they wouldn't fit :(\001";
1545                 return 0;
1546         } ],
1547
1548         # complain when system load gets too high
1549         [ dp => q{timing:   (([0-9.]*)% CPU, ([0-9.]*)% lost, offset avg ([0-9.]*)ms, max ([0-9.]*)ms, sdev ([0-9.]*)ms)} => sub {
1550                 my ($all, $cpu, $lost, $avg, $max, $sdev) = @_;
1551                 return 0 # don't complain when just on the voting screen
1552                         if !$store{playing};
1553                 return 0 # don't complain if it was less than 0.5%
1554                         if $lost < 0.5;
1555                 return 0 # don't complain if nobody is looking
1556                         if $store{slots_active} == 0;
1557                 return 0 # don't complain in the first two minutes
1558                         if time() - $store{map_starttime} < 120;
1559                 return 0 # don't complain if it was already at least half as bad in this round
1560                         if $store{map_starttime} == $store{timingerror_map_starttime} and $lost <= 2 * $store{timingerror_lost};
1561                 $store{timingerror_map_starttime} = $store{map_starttime};
1562                 $store{timingerror_lost} = $lost;
1563                 out dp => 0, 'rcon2irc_say_as server "There are currently some severe system load problems. The admins have been notified."';
1564                 out irc => 1, "PRIVMSG $config{irc_channel} :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1565                 #out irc => 1, "PRIVMSG OpBaI :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1566                 return 0;
1567         } ],
1568 );
1569
1570
1571
1572 # Load plugins and add them to the handler list in the front.
1573 for my $p(split ' ', $config{plugins})
1574 {
1575         my @h = eval { do $p; }
1576                 or die "Invalid plugin $p: $@";
1577         for(reverse @h)
1578         {
1579                 ref $_ eq 'ARRAY' or die "Invalid plugin $p: did not return a list of arrays";
1580                 @$_ == 3 or die "Invalid plugin $p: did not return a list of three-element arrays";
1581                 !ref $_->[0] && !ref $_->[1] && ref $_->[2] eq 'CODE' or die "Invalid plugin $p: did not return a list of string-string-sub arrays";
1582                 unshift @handlers, $_;
1583         }
1584 }
1585
1586
1587
1588 # verify that the server is up by letting it echo back a string that causes
1589 # re-initialization of the required aliases
1590 out dp => 0, 'echo "Unknown command \"rcon2irc_eval\""'; # assume the server has been restarted
1591
1592
1593
1594 # regularily, query the server status and if it still is connected to us using
1595 # the log_dest_udp feature. If not, we will detect the response to this rcon
1596 # command and re-initialize the server's connection to us (either by log_dest_udp
1597 # not containing our own IP:port, or by rcon2irc_eval not being a defined command).
1598 schedule sub {
1599         my ($timer) = @_;
1600         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp', 'rcon2irc_eval set dummy 1';
1601         $store{status_waiting} = -1;
1602         schedule $timer => (exists $store{dp_hostname} ? $config{dp_status_delay} : 1);;
1603 } => 1;
1604
1605
1606
1607 # Continue with connecting to IRC as soon as we get our first status reply from
1608 # the DP server (which contains the server's hostname that we'll use as
1609 # realname for IRC).
1610 schedule sub {
1611         my ($timer) = @_;
1612
1613         # log on to IRC when needed
1614         if(exists $store{dp_hostname} && !exists $store{irc_logged_in})
1615         {
1616                 $store{irc_nick_requested} = $config{irc_nick};
1617                 out irc => 1, "NICK $config{irc_nick}", "USER $config{irc_user} localhost localhost :$store{dp_hostname}";
1618                 $store{irc_logged_in} = 1;
1619                 undef $store{irc_maxlen};
1620                 undef $store{irc_pingtime};
1621         }
1622
1623         schedule $timer => 1;;
1624 } => 1;
1625
1626
1627
1628 # Regularily ping the IRC server to detect if the connection is down. If it is,
1629 # schedule an IRC error that will cause reconnection later.
1630 schedule sub {
1631         my ($timer) = @_;
1632
1633         if($store{irc_logged_in})
1634         {
1635                 if(defined $store{irc_pingtime})
1636                 {
1637                         # IRC connection apparently broke
1638                         # so... KILL IT WITH FIRE
1639                         $channels{system}->send("error irc", 0);
1640                 }
1641                 else
1642                 {
1643                         # everything is fine, send a new ping
1644                         $store{irc_pingtime} = time();
1645                         out irc => 1, "PING $store{irc_pingtime}";
1646                 }
1647         }
1648
1649         schedule $timer => $config{irc_ping_delay};;
1650 } => 1;
1651
1652
1653
1654 # Main loop.
1655 for(;;)
1656 {
1657         # Build up an IO::Select object for all our channels.
1658         my $s = IO::Select->new();
1659         for my $chan(values %channels)
1660         {
1661                 $s->add($_) for $chan->fds();
1662         }
1663
1664         # wait for something to happen on our sockets, or wait 2 seconds without anything happening there
1665         $s->can_read(2);
1666         my @errors = $s->has_exception(0);
1667
1668         # on every channel, look for incoming messages
1669         CHANNEL:
1670         for my $chanstr(keys %channels)
1671         {
1672                 my $chan = $channels{$chanstr};
1673                 my @chanfds = $chan->fds();
1674
1675                 for my $chanfd(@chanfds)
1676                 {
1677                         if(grep { $_ == $chanfd } @errors)
1678                         {
1679                                 # STOP! This channel errored!
1680                                 $channels{system}->send("error $chanstr", 0);
1681                                 next CHANNEL;
1682                         }
1683                 }
1684
1685                 eval
1686                 {
1687                         for my $line($chan->recv())
1688                         {
1689                                 # found one! Check if it matches the regular expression of one of
1690                                 # our handlers...
1691                                 my $handled = 0;
1692                                 my $private = 0;
1693                                 for my $h(@handlers)
1694                                 {
1695                                         my ($chanstr_wanted, $re, $sub) = @$h;
1696                                         next
1697                                                 if $chanstr_wanted ne $chanstr;
1698                                         use re 'eval';
1699                                         my @matches = ($line =~ /^$re$/s);
1700                                         no re 'eval';
1701                                         next
1702                                                 unless @matches;
1703                                         # and if it is a match, handle it.
1704                                         ++$handled;
1705                                         my $result = $sub->(@matches);
1706                                         $private = 1
1707                                                 if $result < 0;
1708                                         last
1709                                                 if $result;
1710                                 }
1711                                 # print the message, together with info on whether it has been handled or not
1712                                 if($private)
1713                                 {
1714                                         print "           $chanstr >> (private)\n";
1715                                 }
1716                                 elsif($handled)
1717                                 {
1718                                         print "           $chanstr >> $line\n";
1719                                 }
1720                                 else
1721                                 {
1722                                         print "unhandled: $chanstr >> $line\n";
1723                                 }
1724                         }
1725                         1;
1726                 } or do {
1727                         if($@ eq "read error\n")
1728                         {
1729                                 $channels{system}->send("error $chanstr", 0);
1730                                 next CHANNEL;
1731                         }
1732                         else
1733                         {
1734                                 # re-throw
1735                                 die $@;
1736                         }
1737                 };
1738         }
1739
1740         # handle scheduled tasks...
1741         my @t = @tasks;
1742         my $t = time();
1743         # by emptying the list of tasks...
1744         @tasks = ();
1745         for(@t)
1746         {
1747                 my ($time, $sub) = @$_;
1748                 if($t >= $time)
1749                 {
1750                         # calling them if they are schedled for the "past"...
1751                         $sub->($sub);
1752                 }
1753                 else
1754                 {
1755                         # or re-adding them to the task list if they still are scheduled for the "future"
1756                         push @tasks, [$time, $sub];
1757                 }
1758         }
1759 }