data/qcsrc/server/w_uzi.qc

   1 // leilei's fancy muzzleflash stuff
   2 void W_Uzi_Flash_Go() {
   3         if (self.frame > 10){
   4                 SUB_Remove();
   5                 return;
   6         }
   7         self.frame = self.frame + 2;
   8         self.alpha = self.alpha - 0.2;
   9         self.think = W_Uzi_Flash_Go;
  10         self.nextthink = time + 0.02;
  11 };
  12
  13 .float uzi_bulletcounter;
  14 void W_Uzi_Attack (void)
  15 {
  16         local entity flash, flash2;
  17
  18         if (cvar("g_use_ammunition"))
  19         {
  20                 if (self.uzi_bulletcounter == 1)
  21                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  22                 else
  23                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  24         }
  25         W_SetupShot (self, '25 5.5 -8', TRUE, 0, "weapons/uzi_fire.wav");
  26         //W_SetupShot (self, '25 8 -8', TRUE, 0, "weapons/uzi_fire.wav"); // TODO: move model to the right a little
  27         if (!g_norecoil)
  28         {
  29                 self.punchangle_x = random () - 0.5;
  30                 self.punchangle_y = random () - 0.5;
  31         }
  32
  33         // this attack_finished just enforces a cooldown at the end of a burst
  34         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
  35
  36         if (self.uzi_bulletcounter == 1)
  37                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_first_damage"), cvar("g_balance_uzi_first_force"), WEP_UZI, TRUE);
  38         else
  39                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_sustained_damage"), cvar("g_balance_uzi_sustained_force"), WEP_UZI, (self.uzi_bulletcounter & 3) == 0);
  40
  41         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  42
  43         // muzzle flash for 1st person view
  44         flash = spawn();
  45         setorigin(flash, '53 5 0');
  46         setmodel(flash, "models/uziflash.md3"); // precision set below
  47         setattachment(flash, self.weaponentity, "bone01");
  48         flash.owner = self;
  49         flash.viewmodelforclient = self;
  50         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
  51         flash.scale = 1.2;
  52         //SUB_SetFade(flash, time + 0.06, 0);
  53         flash.think = W_Uzi_Flash_Go;
  54         flash.nextthink = time + 0.02;
  55         flash.frame = 2;
  56
  57         // muzzle flash for 3rd person view
  58         flash2 = spawn();
  59         setorigin(flash2, '43 1 8');
  60         setmodel(flash2, "models/uziflash.md3"); // precision set below
  61         setattachment(flash2, self.exteriorweaponentity, "");
  62         //SUB_SetFade(flash2, time + 0.06, 0);
  63         flash2.think = W_Uzi_Flash_Go;
  64         flash2.nextthink = time + 0.02;
  65         flash2.frame = 2;
  66         // common properties
  67         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  68         flash.alpha = flash2.alpha = 1;
  69         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  70
  71         // casing code
  72         if (cvar("g_casings") >= 2)
  73                 SpawnCasing (w_shotorg + v_forward * 10, ((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  74 }
  75
  76 // weapon frames
  77 void uzi_fire1_02()
  78 {
  79         if(self.weapon != self.switchweapon) // abort immediately if switching
  80         {
  81                 w_ready();
  82                 return;
  83         }
  84         if (self.BUTTON_ATCK)
  85         {
  86                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  87                 {
  88                         self.switchweapon = w_getbestweapon(self);
  89                         if (self.switchweapon != self.weapon)
  90                                 self.cnt = self.weapon;
  91                         w_ready();
  92                         return;
  93                 }
  94                 ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_refire");
  95                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  96                 W_Uzi_Attack();
  97                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  98         }
  99         else
 100                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
 101 };
 102
 103 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
 104
 105 float w_uzi(float req)
 106 {
 107         if (req == WR_AIM)
 108                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 109                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 110                 else
 111                 {
 112                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 113                 }
 114         else if (req == WR_THINK)
 115         {
 116                 if (self.BUTTON_ATCK)
 117                 if (weapon_prepareattack(0, cvar("g_balance_uzi_refire")))
 118                 {
 119                         self.uzi_bulletcounter = 1;
 120                         W_Uzi_Attack();
 121                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 122                 }
 123                 if (self.BUTTON_ATCK2)
 124                 if (weapon_prepareattack(1, cvar("g_balance_uzi_refire")))
 125                 {
 126                         self.uzi_bulletcounter = 1;
 127                         W_Uzi_Attack();
 128                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
 129                 }
 130         }
 131         else if (req == WR_PRECACHE)
 132         {
 133                 precache_model ("models/tracer.mdl");
 134                 precache_model ("models/uziflash.md3");
 135                 precache_model ("models/weapons/g_uzi.md3");
 136                 precache_model ("models/weapons/v_uzi.md3");
 137                 precache_model ("models/weapons/w_uzi.zym");
 138                 precache_sound ("weapons/ric1.wav");
 139                 precache_sound ("weapons/ric2.wav");
 140                 precache_sound ("weapons/ric3.wav");
 141                 precache_sound ("weapons/tink1.wav");
 142                 precache_sound ("weapons/uzi_fire.wav");
 143                 if (cvar("g_casings") >= 2)
 144                         precache_model ("models/casing_bronze.mdl");
 145         }
 146         else if (req == WR_SETUP)
 147                 weapon_setup(WEP_UZI, "uzi");
 148         else if (req == WR_CHECKAMMO1)
 149                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 150         else if (req == WR_CHECKAMMO2)
 151                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 152         else if (req == WR_SUICIDEMESSAGE)
 153                 w_deathtypestring = "did the impossible";
 154         else if (req == WR_KILLMESSAGE)
 155                 w_deathtypestring = "was riddled full of holes by";
 156         else if (req == WR_SPAWNFUNC)
 157                 spawnfunc_weapon_machinegun();
 158         return TRUE;
 159 };