data/qcsrc/server/w_uzi.qc

   1 // leilei's fancy muzzleflash stuff
   2 void W_Uzi_Flash_Go() {
   3         if (self.frame > 10){
   4                 SUB_Remove();
   5                 return;
   6         }
   7         self.frame = self.frame + 2;
   8         self.alpha = self.alpha - 0.2;
   9         self.think = W_Uzi_Flash_Go;
  10         self.nextthink = time + 0.02;
  11 };
  12
  13 .float uzi_bulletcounter;
  14 void W_Uzi_Attack (float deathtype)
  15 {
  16         local entity flash;
  17
  18         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  19         {
  20                 if (self.uzi_bulletcounter == 1)
  21                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  22                 else
  23                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  24         }
  25         W_SetupShot (self, cvar("g_antilag_bullets") && cvar("g_balance_uzi_speed") >= cvar("g_antilag_bullets"), 0, "weapons/uzi_fire.wav", cvar("g_balance_uzi_first_damage"));
  26         if (!g_norecoil)
  27         {
  28                 self.punchangle_x = random () - 0.5;
  29                 self.punchangle_y = random () - 0.5;
  30         }
  31
  32         // this attack_finished just enforces a cooldown at the end of a burst
  33         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire") * W_WeaponRateFactor();
  34
  35         if (self.uzi_bulletcounter == 1)
  36                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_first_damage"), 0, cvar("g_balance_uzi_first_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  37         else
  38                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_sustained_damage"), 0, cvar("g_balance_uzi_sustained_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  39         endFireBallisticBullet();
  40
  41         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  42
  43         // muzzle flash for 1st person view
  44         flash = spawn();
  45         setmodel(flash, "models/uziflash.md3"); // precision set below
  46         //SUB_SetFade(flash, time + 0.06, 0);
  47         flash.think = W_Uzi_Flash_Go;
  48         flash.nextthink = time + 0.02;
  49         flash.frame = 2;
  50         flash.alpha = 1;
  51         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  52         W_AttachToShotorg(flash, '5 0 0');
  53
  54         // casing code
  55         if (cvar("g_casings") >= 2)
  56                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  57 }
  58
  59 // weapon frames
  60 void uzi_fire1_02()
  61 {
  62         if(self.weapon != self.switchweapon) // abort immediately if switching
  63         {
  64                 w_ready();
  65                 return;
  66         }
  67         if (self.BUTTON_ATCK)
  68         {
  69                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  70                 {
  71                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  72                         w_ready();
  73                         return;
  74                 }
  75                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  76                 W_Uzi_Attack(WEP_UZI);
  77                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  78         }
  79         else
  80                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
  81 };
  82
  83 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
  84
  85 float w_uzi(float req)
  86 {
  87         if (req == WR_AIM)
  88                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
  89                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
  90                 else
  91                 {
  92                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
  93                 }
  94         else if (req == WR_THINK)
  95         {
  96                 if (self.BUTTON_ATCK)
  97                 if (weapon_prepareattack(0, 0))
  98                 {
  99                         self.uzi_bulletcounter = 1;
 100                         W_Uzi_Attack(WEP_UZI); // sets attack_finished
 101                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 102                 }
 103                 if (self.BUTTON_ATCK2)
 104                 if (weapon_prepareattack(1, 0))
 105                 {
 106                         self.uzi_bulletcounter = 1;
 107                         W_Uzi_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 108                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_uzi_first_refire"), w_ready);
 109                 }
 110         }
 111         else if (req == WR_PRECACHE)
 112         {
 113                 precache_model ("models/uziflash.md3");
 114                 precache_model ("models/weapons/g_uzi.md3");
 115                 precache_model ("models/weapons/v_uzi.md3");
 116                 precache_model ("models/weapons/h_uzi.dpm");
 117                 precache_sound ("weapons/uzi_fire.wav");
 118         }
 119         else if (req == WR_SETUP)
 120                 weapon_setup(WEP_UZI);
 121         else if (req == WR_CHECKAMMO1)
 122                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 123         else if (req == WR_CHECKAMMO2)
 124                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 125         else if (req == WR_SUICIDEMESSAGE)
 126                 w_deathtypestring = "did the impossible";
 127         else if (req == WR_KILLMESSAGE)
 128         {
 129                 if(w_deathtype & HITTYPE_SECONDARY)
 130                         w_deathtypestring = "was sniped by";
 131                 else
 132                         w_deathtypestring = "was riddled full of holes by";
 133         }
 134         return TRUE;
 135 };