data/qcsrc/server/w_tuba.qc

   1 #define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   2 .float tuba_notecount;
   3
   4 float Tuba_GetNote(entity pl, float hittype)
   5 {
   6         float note;
   7         float movestate;
   8         movestate = 5;
   9         if(pl.movement_x < 0) movestate -= 3;
  10         if(pl.movement_x > 0) movestate += 3;
  11         if(pl.movement_y < 0) movestate -= 1;
  12         if(pl.movement_y > 0) movestate += 1;
  13         switch(movestate)
  14         {
  15         // layout: originally I wanted
  16         //   eb e  e#=f
  17         //   B  c  d
  18         //   Gb G  G#
  19         // but then you only use forward and right key. So to make things more
  20         // interesting, I swapped B with e#. Har har har...
  21         //   eb e  B
  22         // f=e# c  d
  23         //   Gb G  G#
  24                 case 1: note = -6; break; // Gb
  25                 case 2: note = -5; break; // G
  26                 case 3: note = -4; break; // G#
  27                 case 4: note = +5; break; // e#
  28                 case 5: note =  0; break; // c
  29                 case 6: note = +2; break; // d
  30                 case 7: note = +3; break; // eb
  31                 case 8: note = +4; break; // e
  32                 case 9: note = -1; break; // B
  33         }
  34         if(pl.BUTTON_CROUCH)
  35                 note -= 12;
  36         if(pl.BUTTON_JUMP)
  37                 note += 12;
  38         if(hittype & HITTYPE_SECONDARY)
  39                 note += 7;
  40
  41         // we support two kinds of tubas, those tuned in Eb and those tuned in C
  42         // kind of tuba currently is player slot number, or team number if in
  43         // teamplay
  44         // that way, holes in the range of notes are "plugged"
  45         if(teams_matter)
  46         {
  47                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
  48                         note += 3;
  49         }
  50         else
  51         {
  52                 if(pl.clientcolors & 1)
  53                         note += 3;
  54         }
  55
  56         // total range of notes:
  57         //                       0
  58         //                 ***  ** ****
  59         //                        ***  ** ****
  60         //     ***  ** ****
  61         //            ***  ** ****
  62         //     ***  ********************* ****
  63         //     -18.........................+12
  64         //        ***  ********************* ****
  65         //     -18............................+15
  66         //     with jump: ... +24
  67         //     ... +27
  68         return note;
  69 }
  70
  71 void W_Tuba_Attack(float hittype)
  72 {
  73         vector o;
  74         float c;
  75         W_SetupShot(self, FALSE, 2, "", cvar("g_balance_tuba_damage"));
  76         if(self.tuba_notecount)
  77         {
  78                 self.tuba_notecount = FALSE;
  79                 c = CHAN_WEAPON;
  80         }
  81         else
  82         {
  83                 self.tuba_notecount = TRUE;
  84                 c = CHAN_WEAPON2;
  85         }
  86         sound(self, c, TUBA_NOTE(Tuba_GetNote(self, hittype)), bound(0, VOL_BASE * cvar("g_balance_tuba_volume"), 1), cvar("g_balance_tuba_attenuation"));
  87         RadiusDamage(self, self, cvar("g_balance_tuba_damage"), cvar("g_balance_tuba_edgedamage"), cvar("g_balance_tuba_radius"), world, cvar("g_balance_tuba_force"), hittype | WEP_TUBA, world);
  88
  89         o = gettaginfo(self.exteriorweaponentity, 0);
  90         pointparticles(particleeffectnum("smoke_ring"), o + v_up * 45 + v_right * -6 + v_forward * 8, v_up * 100, 1);
  91 }
  92
  93 void spawnfunc_weapon_tuba (void)
  94 {
  95         if(!sv_cheats && !cvar("developer"))
  96         {
  97                 print("The @!#%'n Tuba awaits you... not.\n");
  98                 remove(self);
  99                 return;
 100         }
 101         weapon_defaultspawnfunc(WEP_TUBA);
 102 }
 103
 104 float w_tuba(float req)
 105 {
 106         if (req == WR_AIM)
 107         {
 108                 // bots cannot play the Tuba well yet
 109                 // I think they should start with the recorder first
 110                 if(vlen(self.origin - self.enemy.origin) < cvar("g_balance_tuba_radius"))
 111                 {
 112                         if(random() > 0.5)
 113                                 self.BUTTON_ATCK = 1;
 114                         else
 115                                 self.BUTTON_ATCK2 = 1;
 116                 }
 117         }
 118         else if (req == WR_THINK)
 119         {
 120                 if (self.BUTTON_ATCK)
 121                 if (weapon_prepareattack(0, cvar("g_balance_tuba_refire")))
 122                 {
 123                         W_Tuba_Attack(0);
 124                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_tuba_animtime"), w_ready);
 125                 }
 126                 if (self.BUTTON_ATCK2)
 127                 if (weapon_prepareattack(1, cvar("g_balance_tuba_refire")))
 128                 {
 129                         W_Tuba_Attack(HITTYPE_SECONDARY);
 130                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_tuba_animtime"), w_ready);
 131                 }
 132         }
 133         else if (req == WR_PRECACHE)
 134         {
 135                 precache_model ("models/weapons/g_tuba.md3");
 136                 precache_model ("models/weapons/v_tuba.md3");
 137                 precache_model ("models/weapons/h_tuba.dpm");
 138
 139                 float i;
 140                 for(i = -18; i <= +27; ++i)
 141                         precache_sound(TUBA_NOTE(i));
 142         }
 143         else if (req == WR_SETUP)
 144                 weapon_setup(WEP_TUBA);
 145         else if (req == WR_CHECKAMMO1)
 146                 return TRUE; // TODO use fuel?
 147         else if (req == WR_CHECKAMMO2)
 148                 return TRUE; // TODO use fuel?
 149         else if (req == WR_SUICIDEMESSAGE)
 150         {
 151                 w_deathtypestring = "hurt his own ears with the @!#%'n Tuba";
 152         }
 153         else if (req == WR_KILLMESSAGE)
 154         {
 155                 w_deathtypestring = "died of #'s great playing on the @!#%'n Tuba";
 156         }
 157         return TRUE;
 158 };