data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister()
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  19
  20         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  21         {
  22                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  23                 {
  24                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  25                         ATTACK_FINISHED(self.owner) = time;
  26                         self.owner.switchweapon = w_getbestweapon(self.owner);
  27                 }
  28                 if(g_laserguided_missile)
  29                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponSpeedFactor();
  30         }
  31         remove (self);
  32 }
  33
  34 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  35 {
  36         entity head, selected;
  37         vector dir;
  38         float dist, maxdist,// bestdist,
  39                 dot,// bestdot,
  40                 points, bestpoints;
  41         //bestdist = 9999;
  42         //bestdot = -2;
  43         bestpoints = 0;
  44         maxdist = 800;
  45         selected = world;
  46
  47         makevectors(e.angles);
  48
  49         head = find(world, classname, "laser_target");
  50         while(head)
  51         {
  52                 points = 0;
  53                 dir = normalize(head.origin - self.origin);
  54                 dot = dir * v_forward;
  55                 dist = vlen(head.origin - self.origin);
  56                 if(dist > maxdist)
  57                         dist = maxdist;
  58
  59                 // gain points for being in front
  60                 points = points + ((dot+1)*0.5) * 500
  61                         * (1 + crandom()*dot_variance);
  62                 // gain points for being close away
  63                 points = points + (1 - dist/maxdist) * 1000
  64                         * (1 + crandom()*dot_variance);
  65
  66                 traceline(e.origin, head.origin, TRUE, self);
  67                 if(trace_fraction < 1)
  68                 {
  69                         points = 0;
  70                 }
  71
  72                 if(points > bestpoints)//random() > 0.5)//
  73                 {
  74                         bestpoints = points;
  75                         selected = head;
  76                 }
  77
  78                 head = find(head, classname, "laser_target");
  79         }
  80
  81         //bprint(selected.owner.netname);
  82         //bprint("\n");
  83         return selected;
  84 }
  85
  86 void W_Rocket_RemoteExplode()
  87 {
  88         if(self.owner.deadflag == DEAD_NO)
  89         if(self.owner.lastrocket)
  90         {
  91                 if((self.spawnshieldtime >= 0)
  92                         ? (time >= self.spawnshieldtime) // timer
  93                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  94                 )
  95                 {
  96                         other = world;
  97                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  98                         W_Rocket_Explode ();
  99                 }
 100                 else
 101                 {
 102                 }
 103         }
 104 }
 105
 106 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 107 {
 108         if(thisdir * goaldir > maxturn_cos)
 109                 return goaldir;
 110         float f, m2;
 111         vector v;
 112         // solve:
 113         //   g = normalize(thisdir + goaldir * X)
 114         //   thisdir * g = maxturn
 115         //
 116         //   gg = thisdir + goaldir * X
 117         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 118         //
 119         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 120         f = thisdir * goaldir;
 121         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 122         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 123         m2 = maxturn_cos * maxturn_cos;
 124         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 125         return normalize(thisdir + goaldir * v_y); // the larger solution!
 126 }
 127
 128 void W_Rocket_Think (void)
 129 {
 130         entity e;
 131         vector desireddir, olddir, newdir, desiredorigin, goal;
 132         float turnrate, velspeed;
 133         self.nextthink = time;
 134         if (time > self.cnt)
 135         {
 136                 other = world;
 137                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 138                 W_Rocket_Explode ();
 139                 return;
 140         }
 141
 142         if(g_laserguided_missile)
 143         {
 144                 // accelerate
 145                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 146                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 147                 if (velspeed > 0)
 148                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 149         }
 150         else
 151         {
 152                 // accelerate
 153                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 154                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 155                 if (velspeed > 0)
 156                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 157         }
 158
 159         // laser guided, or remote detonation
 160         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 161         {
 162                 if(g_laserguided_missile)
 163                 {
 164                         if(self.rl_detonate_later)
 165                                 W_Rocket_RemoteExplode();
 166
 167                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 168                         {
 169                                 if(self.owner.laser_on)
 170                                 {
 171                                         if(self.attack_finished_single < time)
 172                                         {
 173                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 174                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 175                                         }
 176
 177                                         if(!self.enemy)
 178                                                 self.enemy = self.owner.weaponentity.lasertarget;
 179                                 }
 180                                 else self.enemy = world;
 181                         }
 182                         else // don't allow stealing: always target my owner's laser (if it exists)
 183                                 self.enemy = self.owner.weaponentity.lasertarget;
 184
 185                         if(self.enemy != world)
 186                         {
 187                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 188                                 velspeed = vlen(self.velocity);
 189                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 190                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 191                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 192                                 olddir = normalize(self.velocity);                                      // get my current direction
 193                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 194                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 195                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 196
 197                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponSpeedFactor();
 198                         }
 199                 }
 200                 else
 201                 {
 202                         if(self == self.owner.lastrocket)
 203                         if(!self.owner.rl_release)
 204                         if(cvar("g_balance_rocketlauncher_guiderate"))
 205                         if(time > self.pushltime)
 206                         if(self.owner.deadflag == DEAD_NO)
 207                         {
 208                                 velspeed = vlen(self.velocity);
 209
 210                                 makevectors(self.owner.v_angle);
 211                                 desireddir = v_forward;
 212                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 213                                 olddir = normalize(self.velocity);
 214
 215                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 216                                 // but we are limiting the rate at which we can turn!
 217                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 218                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * frametime * PI / 180));
 219
 220                                 self.velocity = newdir * velspeed;
 221                         }
 222
 223                         if(self.rl_detonate_later)
 224                                 W_Rocket_RemoteExplode();
 225                 }
 226         }
 227
 228         if(self.csqcprojectile_clientanimate == 0)
 229                 UpdateCSQCProjectile(self);
 230 }
 231
 232 void W_Rocket_Touch (void)
 233 {
 234         W_Rocket_Unregister();
 235
 236         PROJECTILE_TOUCH;
 237         W_Rocket_Explode ();
 238 }
 239
 240 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 241 {
 242         if (self.health <= 0)
 243                 return;
 244         self.health = self.health - damage;
 245         self.angles = vectoangles(self.velocity);
 246         if (self.health <= 0)
 247                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 248 }
 249
 250 void W_Rocket_Attack (void)
 251 {
 252         local entity missile;
 253         local entity flash;
 254
 255         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 256                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 257
 258         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav");
 259         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 260
 261         missile = spawn ();
 262         missile.owner = self;
 263         self.lastrocket = missile;
 264         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 265                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 266         else
 267                 missile.spawnshieldtime = -1;
 268         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 269         missile.classname = "rocket";
 270         missile.bot_dodge = TRUE;
 271         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 272
 273         missile.takedamage = DAMAGE_YES;
 274         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 275         missile.health = cvar("g_balance_rocketlauncher_health");
 276         missile.event_damage = W_Rocket_Damage;
 277
 278         missile.movetype = MOVETYPE_FLY;
 279         missile.solid = SOLID_BBOX;
 280         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 281         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 282
 283         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 284         if(g_laserguided_missile && self.laser_on)
 285                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 286         else
 287                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 288         W_SetupProjectileVelocity(missile);
 289         missile.angles = vectoangles (missile.velocity);
 290
 291         missile.touch = W_Rocket_Touch;
 292         missile.think = W_Rocket_Think;
 293         missile.nextthink = time;
 294         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 295         missile.flags = FL_PROJECTILE;
 296
 297         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 298
 299         // muzzle flash for 1st person view
 300         flash = spawn ();
 301         setmodel (flash, "models/flash.md3"); // precision set below
 302         SUB_SetFade (flash, time, 0.1);
 303         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 304         W_AttachToShotorg(flash, '5 0 0');
 305
 306         // common properties
 307 }
 308
 309 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 310
 311 float w_rlauncher(float req)
 312 {
 313         entity rock;
 314         float rockfound;
 315         if (req == WR_AIM)
 316         {
 317                 // aim and decide to fire if appropriate
 318                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 319                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 320                 {
 321                         // decide whether to detonate rockets
 322                         local entity missile, targetlist, targ;
 323                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 324                         local float selfdamage, teamdamage, enemydamage;
 325                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 326                         coredamage = cvar("g_balance_rocketlauncher_damage");
 327                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 328                         recipricoledgeradius = 1 / edgeradius;
 329                         selfdamage = 0;
 330                         teamdamage = 0;
 331                         enemydamage = 0;
 332                         targetlist = findchainfloat(bot_attack, TRUE);
 333                         missile = find(world, classname, "rocket");
 334                         while (missile)
 335                         {
 336                                 if (missile.owner != self)
 337                                 {
 338                                         missile = find(missile, classname, "rocket");
 339                                         continue;
 340                                 }
 341                                 targ = targetlist;
 342                                 while (targ)
 343                                 {
 344                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 345                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 346                                         // count potential damage according to type of target
 347                                         if (targ == self)
 348                                                 selfdamage = selfdamage + d;
 349                                         else if (targ.team == self.team && teams_matter)
 350                                                 teamdamage = teamdamage + d;
 351                                         else if (bot_shouldattack(targ))
 352                                                 enemydamage = enemydamage + d;
 353                                         targ = targ.chain;
 354                                 }
 355                                 missile = find(missile, classname, "rocket");
 356                         }
 357                         local float desirabledamage;
 358                         desirabledamage = enemydamage;
 359                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 360                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 361                         if (self.team && teamplay != 1)
 362                                 desirabledamage = desirabledamage - teamdamage;
 363
 364                         missile = find(world, classname, "rocket");
 365                         while (missile)
 366                         {
 367                                 if (missile.owner != self)
 368                                 {
 369                                         missile = find(missile, classname, "rocket");
 370                                         continue;
 371                                 }
 372                                 makevectors(missile.v_angle);
 373                                 targ = targetlist;
 374                                 if (skill > 9) // normal players only do this for the target they are tracking
 375                                 {
 376                                         targ = targetlist;
 377                                         while (targ)
 378                                         {
 379                                                 if (
 380                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 381                                                         && desirabledamage > 0.1*coredamage
 382                                                 )self.BUTTON_ATCK2 = TRUE;
 383                                                 targ = targ.chain;
 384                                         }
 385                                 }else{
 386                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 387                                         //As the distance gets larger, a correct detonation gets near imposible
 388                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 389                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 390                                                 if(self.enemy.classname == "player")
 391                                                         if(desirabledamage >= 0.1*coredamage)
 392                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 393                                                                         self.BUTTON_ATCK2 = TRUE;
 394                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 395                                 }
 396
 397                                 missile = find(missile, classname, "rocket");
 398                         }
 399                         // if we would be doing at X percent of the core damage, detonate it
 400                         // but don't fire a new shot at the same time!
 401                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 402                                 self.BUTTON_ATCK2 = TRUE;
 403                         if ((skill > 6.5) && (selfdamage > self.health))
 404                                 self.BUTTON_ATCK2 = FALSE;
 405                         //if(self.BUTTON_ATCK2 == TRUE)
 406                         //      dprint(ftos(desirabledamage),"\n");
 407                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 408                 }
 409         }
 410         else if (req == WR_THINK)
 411         {
 412                 if(g_laserguided_missile)
 413                 {
 414                         if (self.BUTTON_ATCK && self.rl_release)
 415                         {
 416                                 rockfound = 0;
 417                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 418                                 {
 419                                         if(!rock.rl_detonate_later)
 420                                         {
 421                                                 rock.rl_detonate_later = TRUE;
 422                                                 rockfound = 1;
 423                                         }
 424                                 }
 425                                 if(rockfound)
 426                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 427                                 else
 428                                 {
 429                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 430                                         {
 431                                                 W_Rocket_Attack();
 432                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 433                                         }
 434                                 }
 435                                 self.rl_release = 0;
 436                         }
 437                         if (!self.BUTTON_ATCK)
 438                                 self.rl_release = 1;
 439                         if (self.BUTTON_ATCK2)
 440                         if(self.exteriorweaponentity.attack_finished_single < time)
 441                         {
 442                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 443                                 self.laser_on = !self.laser_on;
 444                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 445                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 446                         }
 447                 }
 448                 else
 449                 {
 450                         if (self.BUTTON_ATCK)
 451                         {
 452                                 if(self.rl_release)
 453                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 454                                 {
 455                                         W_Rocket_Attack();
 456                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 457                                         self.rl_release = 0;
 458                                 }
 459                         }
 460                         else
 461                                 self.rl_release = 1;
 462
 463                         if (self.BUTTON_ATCK2)
 464                         {
 465                                 rockfound = 0;
 466                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 467                                 {
 468                                         if(!rock.rl_detonate_later)
 469                                         {
 470                                                 rock.rl_detonate_later = TRUE;
 471                                                 rockfound = 1;
 472                                         }
 473                                 }
 474                                 if(rockfound)
 475                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 476                         }
 477                 }
 478         }
 479         else if (req == WR_PRECACHE)
 480         {
 481                 precache_model ("models/flash.md3");
 482                 precache_model ("models/weapons/g_rl.md3");
 483                 precache_model ("models/weapons/v_rl.md3");
 484                 precache_model ("models/weapons/h_rl.dpm");
 485                 precache_sound ("weapons/rocket_det.wav");
 486                 precache_sound ("weapons/rocket_fire.wav");
 487                 if (g_laserguided_missile)
 488                 {
 489                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 490                         precache_sound ("weapons/rocket_mode.wav");
 491                 }
 492         }
 493         else if (req == WR_SETUP)
 494         {
 495                 weapon_setup(WEP_ROCKET_LAUNCHER);
 496                 self.rl_release = 1;
 497         }
 498         else if (req == WR_CHECKAMMO1)
 499         {
 500                 // don't switch while guiding a missile
 501                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 502                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 503                         return FALSE;
 504         }
 505         else if (req == WR_CHECKAMMO2)
 506                 return FALSE;
 507         else if (req == WR_SUICIDEMESSAGE)
 508                 w_deathtypestring = "exploded";
 509         else if (req == WR_KILLMESSAGE)
 510         {
 511                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 512                         w_deathtypestring = "got too close to #'s rocket";
 513                 else if(w_deathtype & HITTYPE_SPLASH)
 514                         w_deathtypestring = "almost dodged #'s rocket";
 515                 else
 516                         w_deathtypestring = "ate #'s rocket";
 517         }
 518         return TRUE;
 519 };