data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  11
  12         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  13         self.event_damage = SUB_Null;
  14         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  15
  16         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  17         {
  18                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  19                 {
  20                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  21                         ATTACK_FINISHED(self.owner) = time;
  22                         self.owner.switchweapon = w_getbestweapon(self.owner);
  23                 }
  24                 if(g_laserguided_missile)
  25                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  26         }
  27         remove (self);
  28 }
  29
  30 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  31 {
  32         entity head, selected;
  33         vector dir;
  34         float dist, maxdist,// bestdist,
  35                 dot,// bestdot,
  36                 points, bestpoints;
  37         //bestdist = 9999;
  38         //bestdot = -2;
  39         bestpoints = 0;
  40         maxdist = 800;
  41         selected = world;
  42
  43         makevectors(e.angles);
  44
  45         head = find(world, classname, "laser_target");
  46         while(head)
  47         {
  48                 points = 0;
  49                 dir = normalize(head.origin - self.origin);
  50                 dot = dir * v_forward;
  51                 dist = vlen(head.origin - self.origin);
  52                 if(dist > maxdist)
  53                         dist = maxdist;
  54
  55                 // gain points for being in front
  56                 points = points + ((dot+1)*0.5) * 500
  57                         * (1 + crandom()*dot_variance);
  58                 // gain points for being close away
  59                 points = points + (1 - dist/maxdist) * 1000
  60                         * (1 + crandom()*dot_variance);
  61
  62                 traceline(e.origin, head.origin, TRUE, self);
  63                 if(trace_fraction < 1)
  64                 {
  65                         points = 0;
  66                 }
  67
  68                 if(points > bestpoints)//random() > 0.5)//
  69                 {
  70                         bestpoints = points;
  71                         selected = head;
  72                 }
  73
  74                 head = find(head, classname, "laser_target");
  75         }
  76
  77         //bprint(selected.owner.netname);
  78         //bprint("\n");
  79         return selected;
  80 }
  81
  82 void W_Rocket_RemoteExplode()
  83 {
  84         if(self.owner.deadflag == DEAD_NO)
  85         {
  86                 if((self.spawnshieldtime >= 0)
  87                         ? (time >= self.spawnshieldtime) // timer
  88                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  89                 )
  90                 {
  91                         other = world;
  92                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  93                         W_Rocket_Explode ();
  94                 }
  95                 else
  96                 {
  97                 }
  98         }
  99 }
 100
 101 void W_Rocket_Think (void)
 102 {
 103         entity e;
 104         vector desireddir, olddir, newdir;
 105         float turnrate, velspeed;
 106         self.nextthink = time;
 107         if (time > self.cnt)
 108         {
 109                 other = world;
 110                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 111                 W_Rocket_Explode ();
 112                 return;
 113         }
 114
 115         if(g_laserguided_missile)
 116         {
 117                 // accelerate
 118                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 119                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 120                 if (velspeed > 0)
 121                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 122         }
 123         else
 124         {
 125                 // accelerate
 126                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 127                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 128                 if (velspeed > 0)
 129                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 130         }
 131
 132         // laser guided, or remote detonation
 133         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 134         {
 135                 if(g_laserguided_missile)
 136                 {
 137                         if(self.rl_detonate_later)
 138                                 W_Rocket_RemoteExplode();
 139
 140                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 141                         {
 142                                 if(self.owner.laser_on)
 143                                 {
 144                                         if(self.attack_finished_single < time)
 145                                         {
 146                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 147                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 148                                         }
 149
 150                                         if(!self.enemy)
 151                                                 self.enemy = self.owner.weaponentity.lasertarget;
 152                                 }
 153                                 else self.enemy = world;
 154                         }
 155                         else // don't allow stealing: always target my owner's laser (if it exists)
 156                                 self.enemy = self.owner.weaponentity.lasertarget;
 157
 158                         if(self.enemy != world)
 159                         {
 160                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 161                                 velspeed = vlen(self.velocity);
 162                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 163                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 164                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 165                                 olddir = normalize(self.velocity);                                      // get my current direction
 166                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 167                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 168                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 169
 170                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 171                         }
 172                 }
 173                 else
 174                 {
 175                         if(self.rl_detonate_later)
 176                                 W_Rocket_RemoteExplode();
 177                 }
 178         }
 179 }
 180
 181 void W_Rocket_Touch (void)
 182 {
 183         if(self.owner && self.owner.lastrocket == self)
 184                 self.owner.lastrocket = world;
 185         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 186         {
 187                 sound (self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 188                 remove(self);
 189                 return;
 190         }
 191         W_Rocket_Explode ();
 192 }
 193
 194 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 195 {
 196         self.health = self.health - damage;
 197         self.angles = vectoangles(self.velocity);
 198         if (self.health <= 0)
 199         {
 200                 self.owner = attacker;
 201                 W_Rocket_Explode();
 202         }
 203 }
 204
 205 void W_Rocket_Attack (void)
 206 {
 207         local entity missile;
 208         local entity flash, flash2;
 209
 210         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 211                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 212
 213         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 214         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 215         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 216
 217         missile = spawn ();
 218         missile.owner = self;
 219         self.lastrocket = missile;
 220         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 221                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 222         else
 223                 missile.spawnshieldtime = -1;
 224         missile.classname = "rocket";
 225         missile.bot_dodge = TRUE;
 226         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 227
 228         missile.takedamage = DAMAGE_YES;
 229         missile.damageforcescale = 4;
 230         missile.health = cvar("g_balance_rocketlauncher_health");
 231         missile.event_damage = W_Rocket_Damage;
 232
 233         missile.movetype = MOVETYPE_FLY;
 234         missile.solid = SOLID_BBOX;
 235         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 236         setmodel (missile, "models/rocket.md3"); // precision set below
 237         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 238
 239         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 240         if(g_laserguided_missile && self.laser_on)
 241                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 242         else
 243                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 244         W_SetupProjectileVelocity(missile);
 245         missile.angles = vectoangles (missile.velocity);
 246
 247         missile.touch = W_Rocket_Touch;
 248         missile.think = W_Rocket_Think;
 249         missile.nextthink = time;
 250         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 251         missile.effects = EF_LOWPRECISION;
 252         sound (missile, CHAN_PROJECTILE, "weapons/rocket_fly.wav", 0.4 * VOL_BASE, ATTN_NORM);
 253         missile.flags = FL_PROJECTILE;
 254
 255         // muzzle flash for 1st person view
 256         flash = spawn ();
 257         flash.scale = 1.2;
 258         flash.angles_z = 180;
 259         flash.owner = self;
 260         flash.viewmodelforclient = self;
 261         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 262         setorigin (flash, '35 8 0');
 263         setmodel (flash, "models/flash.md3"); // precision set below
 264         setattachment(flash, self.weaponentity, "bone01");
 265         SUB_SetFade (flash, time, 0.4);
 266
 267         // muzzle flash for 3rd person view
 268         flash2 = spawn ();
 269         flash2.scale = 0.8;
 270         flash2.angles_y = 180;
 271         flash2.angles_z = 90;
 272         setorigin (flash2, '42 0 5');
 273         setmodel (flash2, "models/flash.md3"); // precision set below
 274         setattachment(flash2, self.exteriorweaponentity, "");
 275         SUB_SetFade (flash2, time, 0.4);
 276
 277         // common properties
 278         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 279 }
 280
 281 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 282
 283 float w_rlauncher(float req)
 284 {
 285         entity rock;
 286         float rockfound;
 287         if (req == WR_AIM)
 288         {
 289                 // aim and decide to fire if appropriate
 290                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 291                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 292                 {
 293                         // decide whether to detonate rockets
 294                         local entity missile, targetlist, targ;
 295                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 296                         local float selfdamage, teamdamage, enemydamage;
 297                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 298                         coredamage = cvar("g_balance_rocketlauncher_damage");
 299                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 300                         recipricoledgeradius = 1 / edgeradius;
 301                         selfdamage = 0;
 302                         teamdamage = 0;
 303                         enemydamage = 0;
 304                         targetlist = findchainfloat(bot_attack, TRUE);
 305                         missile = find(world, classname, "rocket");
 306                         while (missile)
 307                         {
 308                                 if (missile.owner != self)
 309                                 {
 310                                         missile = find(missile, classname, "rocket");
 311                                         continue;
 312                                 }
 313                                 targ = targetlist;
 314                                 while (targ)
 315                                 {
 316                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 317                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 318                                         // count potential damage according to type of target
 319                                         if (targ == self)
 320                                                 selfdamage = selfdamage + d;
 321                                         else if (targ.team == self.team && teamplay)
 322                                                 teamdamage = teamdamage + d;
 323                                         else if (bot_shouldattack(targ))
 324                                                 enemydamage = enemydamage + d;
 325                                         targ = targ.chain;
 326                                 }
 327                                 missile = find(missile, classname, "rocket");
 328                         }
 329                         local float desirabledamage;
 330                         desirabledamage = enemydamage;
 331                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 332                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 333                         if (self.team && teamplay == 2)
 334                                 desirabledamage = desirabledamage - teamdamage;
 335
 336                         missile = find(world, classname, "rocket");
 337                         while (missile)
 338                         {
 339                                 if (missile.owner != self)
 340                                 {
 341                                         missile = find(missile, classname, "rocket");
 342                                         continue;
 343                                 }
 344                                 makevectors(missile.v_angle);
 345                                 targ = targetlist;
 346                                 if (skill > 9) // normal players only do this for the target they are tracking
 347                                 {
 348                                         targ = targetlist;
 349                                         while (targ)
 350                                         {
 351                                                 if (
 352                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 353                                                         && desirabledamage > 0.1*coredamage
 354                                                 )self.BUTTON_ATCK2 = TRUE;
 355                                                 targ = targ.chain;
 356                                         }
 357                                 }else{
 358                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 359                                         //As the distance gets larger, a correct detonation gets near imposible
 360                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 361                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 362                                                 if(self.enemy.classname == "player")
 363                                                         if(desirabledamage >= 0.1*coredamage)
 364                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 365                                                                         self.BUTTON_ATCK2 = TRUE;
 366                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 367                                 }
 368
 369                                 missile = find(missile, classname, "rocket");
 370                         }
 371                         // if we would be doing at X percent of the core damage, detonate it
 372                         // but don't fire a new shot at the same time!
 373                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 374                                 self.BUTTON_ATCK2 = TRUE;
 375                         if ((skill > 6.5) && (selfdamage > self.health))
 376                                 self.BUTTON_ATCK2 = FALSE;
 377                         //if(self.BUTTON_ATCK2 == TRUE)
 378                         //      dprint(ftos(desirabledamage),"\n");
 379                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 380                 }
 381         }
 382         else if (req == WR_THINK)
 383         {
 384                 if(g_laserguided_missile)
 385                 {
 386                         if (self.BUTTON_ATCK && self.rl_release)
 387                         {
 388                                 rockfound = 0;
 389                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 390                                 {
 391                                         rock.rl_detonate_later = TRUE;
 392                                         rockfound = 1;
 393                                 }
 394                                 if(rockfound)
 395                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", 0.5 * VOL_BASE, ATTN_NORM);
 396                                 else
 397                                 {
 398                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 399                                         {
 400                                                 W_Rocket_Attack();
 401                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 402                                         }
 403                                 }
 404                                 self.rl_release = 0;
 405                         }
 406                         if (!self.BUTTON_ATCK)
 407                                 self.rl_release = 1;
 408                         if (self.BUTTON_ATCK2)
 409                         if(self.exteriorweaponentity.attack_finished_single < time)
 410                         {
 411                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 412                                 self.laser_on = !self.laser_on;
 413                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 414                                 sound (self, CHAN_WEAPON2, "weapons/tink1.wav", VOL_BASE, ATTN_NORM);
 415                         }
 416                 }
 417                 else
 418                 {
 419                         if (self.BUTTON_ATCK)
 420                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 421                         {
 422                                 W_Rocket_Attack();
 423                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 424                         }
 425                         if (self.BUTTON_ATCK2 && self.rl_release)
 426                         {
 427                                 rockfound = 0;
 428                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 429                                 {
 430                                         rock.rl_detonate_later = TRUE;
 431                                         rockfound = 1;
 432                                 }
 433                                 if(rockfound)
 434                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", 0.5 * VOL_BASE, ATTN_NORM);
 435                                 self.rl_release = 0;
 436                         }
 437                         if (!self.BUTTON_ATCK2)
 438                                 self.rl_release = 1;
 439                 }
 440         }
 441         else if (req == WR_PRECACHE)
 442         {
 443                 precache_model ("models/flash.md3");
 444                 precache_model ("models/rocket.md3");
 445                 precache_model ("models/weapons/g_rl.md3");
 446                 precache_model ("models/weapons/v_rl.md3");
 447                 precache_model ("models/weapons/w_rl.zym");
 448                 precache_sound ("weapons/rocket_det.wav");
 449                 precache_sound ("weapons/rocket_fire.wav");
 450                 precache_sound ("weapons/rocket_fly.wav");
 451                 precache_sound ("weapons/rocket_impact.wav");
 452                 if (g_laserguided_missile)
 453                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 454         }
 455         else if (req == WR_SETUP)
 456         {
 457                 weapon_setup(WEP_ROCKET_LAUNCHER);
 458                 self.rl_release = 1;
 459         }
 460         else if (req == WR_CHECKAMMO1)
 461         {
 462                 // don't switch while guiding a missile
 463                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 464                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 465                         return FALSE;
 466         }
 467         else if (req == WR_CHECKAMMO2)
 468                 return FALSE;
 469         else if (req == WR_SUICIDEMESSAGE)
 470                 w_deathtypestring = "exploded";
 471         else if (req == WR_KILLMESSAGE)
 472         {
 473                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 474                         w_deathtypestring = "got too close to #'s rocket";
 475                 else if(w_deathtype & HITTYPE_SPLASH)
 476                         w_deathtypestring = "almost dodged #'s rocket";
 477                 else
 478                         w_deathtypestring = "ate #'s rocket";
 479         }
 480         return TRUE;
 481 };