data/qcsrc/server/w_rocketlauncher.qc

   1
   2 .float rl_sound;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_BODY, "weapons/rocket_impact.wav", 1, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         //te_explosion (org2);
  11         // LordHavoc: TE_TEI_BIGEXPLOSION
  12         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  13         WriteByte (MSG_BROADCAST, 78);
  14         WriteCoord (MSG_BROADCAST, org2_x);
  15         WriteCoord (MSG_BROADCAST, org2_y);
  16         WriteCoord (MSG_BROADCAST, org2_z);
  17
  18         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  19         self.event_damage = SUB_Null;
  20         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  21
  22         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  23         {
  24                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  25                 {
  26                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  27                         ATTACK_FINISHED(self.owner) = time;
  28                         self.owner.switchweapon = w_getbestweapon(self.owner);
  29                 }
  30                 if(cvar("g_laserguided_missile"))
  31                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  32         }
  33         remove (self);
  34 }
  35
  36 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  37 {
  38         entity head, selected;
  39         vector dir;
  40         float dist, maxdist,// bestdist,
  41                 dot,// bestdot,
  42                 points, bestpoints;
  43         //bestdist = 9999;
  44         //bestdot = -2;
  45         bestpoints = 0;
  46         maxdist = 800;
  47         selected = world;
  48
  49         makevectors(e.angles);
  50
  51         head = find(world, classname, "laser_target");
  52         while(head)
  53         {
  54                 points = 0;
  55                 dir = normalize(head.origin - self.origin);
  56                 dot = dir * v_forward;
  57                 dist = vlen(head.origin - self.origin);
  58                 if(dist > maxdist)
  59                         dist = maxdist;
  60
  61                 // gain points for being in front
  62                 points = points + ((dot+1)*0.5) * 500
  63                         * (1 + crandom()*dot_variance);
  64                 // gain points for being close away
  65                 points = points + (1 - dist/maxdist) * 1000
  66                         * (1 + crandom()*dot_variance);
  67
  68                 traceline(e.origin, head.origin, TRUE, self);
  69                 if(trace_fraction < 1)
  70                 {
  71                         points = 0;
  72                 }
  73
  74                 if(points > bestpoints)//random() > 0.5)//
  75                 {
  76                         bestpoints = points;
  77                         selected = head;
  78                 }
  79
  80                 head = find(head, classname, "laser_target");
  81         }
  82
  83         //bprint(selected.owner.netname);
  84         //bprint("\n");
  85         return selected;
  86 }
  87
  88 void W_Rocket_Think (void)
  89 {
  90         entity e;
  91         vector desireddir, olddir, newdir;
  92         float turnrate, velspeed;
  93         self.nextthink = time;
  94         if (time > self.cnt)
  95         {
  96                 W_Rocket_Explode ();
  97                 return;
  98         }
  99
 100         if(cvar("g_laserguided_missile"))
 101         {
 102                 // accelerate
 103                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 104                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 105                 if (velspeed > 0)
 106                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 107         }
 108         else
 109         {
 110                 // accelerate
 111                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 112                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 113                 if (velspeed > 0)
 114                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 115         }
 116
 117         // laser guided, or remote detonation
 118         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 119         {
 120                 if(cvar("g_laserguided_missile"))
 121                 {
 122                         if(!self.owner.button0)
 123                                 self.ltime = -1; // indicate that the player has let go of the button
 124
 125
 126                         if(self.owner.deadflag == DEAD_NO)
 127                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 128                         {
 129                                   W_Rocket_Explode ();
 130                                   return;
 131                         }
 132
 133                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 134                         {
 135                                 if(self.owner.laser_on)
 136                                 {
 137                                         if(self.attack_finished_single < time)
 138                                         {
 139                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 140                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 141                                         }
 142
 143                                         if(!self.enemy)
 144                                                 self.enemy = self.owner.weaponentity.lasertarget;
 145                                 }
 146                                 else self.enemy = world;
 147                         }
 148                         else // don't allow stealing: always target my owner's laser (if it exists)
 149                                 self.enemy = self.owner.weaponentity.lasertarget;
 150
 151                         if(self.enemy != world)
 152                         {
 153                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 154                                 velspeed = vlen(self.velocity);
 155                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 156                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 157                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 158                                 olddir = normalize(self.velocity);                                      // get my current direction
 159                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 160                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 161                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 162
 163                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 164                         }
 165                 }
 166                 else
 167                 {
 168                         if(self.owner.deadflag == DEAD_NO)
 169                         if (self.owner.button3)
 170                                   W_Rocket_Explode ();
 171                 }
 172         }
 173 }
 174
 175 void W_Rocket_Touch (void)
 176 {
 177         if(self.owner && self.owner.lastrocket == self)
 178                 self.owner.lastrocket = world;
 179         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 180         {
 181                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 182                 remove(self);
 183                 return;
 184         }
 185         W_Rocket_Explode ();
 186 }
 187
 188 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 189 {
 190         self.health = self.health - damage;
 191         self.angles = vectoangles(self.velocity);
 192         if (self.health <= 0)
 193         {
 194                 self.owner = attacker;
 195                 W_Rocket_Explode();
 196         }
 197 }
 198
 199 void W_Rocket_Attack (void)
 200 {
 201         local entity missile;
 202         local entity flash, flash2;
 203
 204         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 205                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 206
 207         W_SetupShot (self, '8 3 -8', FALSE, 5, "weapons/rocket_fire.wav");
 208         te_smallflash(w_shotorg);
 209
 210         missile = spawn ();
 211         missile.owner = self;
 212         self.lastrocket = missile;
 213         missile.classname = "missile";
 214         missile.bot_dodge = TRUE;
 215         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 216
 217         missile.takedamage = DAMAGE_YES;
 218         missile.damageforcescale = 4;
 219         missile.health = 30;
 220         missile.event_damage = W_Rocket_Damage;
 221
 222         missile.movetype = MOVETYPE_FLY;
 223         missile.solid = SOLID_BBOX;
 224         setmodel (missile, "models/rocket.md3"); // precision set below
 225         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 226
 227         setorigin (missile, w_shotorg);
 228         if(cvar("g_laserguided_missile") && self.laser_on)
 229                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 230         else
 231                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 232         W_SetupProjectileVelocity(missile);
 233         missile.angles = vectoangles (missile.velocity);
 234
 235         missile.touch = W_Rocket_Touch;
 236         missile.think = W_Rocket_Think;
 237         missile.nextthink = time;
 238         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 239         missile.effects = EF_LOWPRECISION;
 240         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 241         missile.flags = FL_PROJECTILE;
 242
 243         // muzzle flash for 1st person view
 244         flash = spawn ();
 245         flash.scale = 1.2;
 246         flash.angles_z = 180;
 247         flash.owner = self;
 248         flash.viewmodelforclient = self;
 249         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 250         setorigin (flash, '35 5 -12');
 251         setmodel (flash, "models/flash.md3"); // precision set below
 252         setattachment(flash, self.weaponentity, "bone01");
 253         SUB_SetFade (flash, time, 0.4);
 254
 255         // muzzle flash for 3rd person view
 256         flash2 = spawn ();
 257         flash2.scale = 0.8;
 258         flash2.angles_y = 180;
 259         flash2.angles_z = 90;
 260         setorigin (flash2, '42 0 5');
 261         setmodel (flash2, "models/flash.md3"); // precision set below
 262         setattachment(flash2, self.exteriorweaponentity, "");
 263         SUB_SetFade (flash2, time, 0.4);
 264
 265         // common properties
 266         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 267 }
 268
 269 float(float req) w_rlauncher =
 270 {
 271         if (req == WR_AIM)
 272         {
 273                 // aim and decide to fire if appropriate
 274                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 275                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 276                 {
 277                         // decide whether to detonate rockets
 278                         local entity missile, targetlist, targ;
 279                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 280                         local float selfdamage, teamdamage, enemydamage;
 281                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 282                         coredamage = cvar("g_balance_rocketlauncher_damage");
 283                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 284                         recipricoledgeradius = 1 / edgeradius;
 285                         selfdamage = 0;
 286                         teamdamage = 0;
 287                         enemydamage = 0;
 288                         targetlist = findchainfloat(bot_attack, TRUE);
 289                         missile = find(world, classname, "missile");
 290                         while (missile)
 291                         {
 292                                 if (missile.owner != self)
 293                                 {
 294                                         missile = find(missile, classname, "missile");
 295                                         continue;
 296                                 }
 297                                 targ = targetlist;
 298                                 while (targ)
 299                                 {
 300                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 301                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 302                                         // count potential damage according to type of target
 303                                         if (targ == self)
 304                                                 selfdamage = selfdamage + d;
 305                                         else if (targ.team == self.team && teamplay)
 306                                                 teamdamage = teamdamage + d;
 307                                         else if (bot_shouldattack(targ))
 308                                                 enemydamage = enemydamage + d;
 309                                         targ = targ.chain;
 310                                 }
 311                                 missile = find(missile, classname, "missile");
 312                         }
 313                         local float desirabledamage;
 314                         desirabledamage = enemydamage;
 315                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 316                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 317                         if (self.team && teamplay == 2)
 318                                 desirabledamage = desirabledamage - teamdamage;
 319
 320                         missile = find(world, classname, "missile");
 321                         while (missile)
 322                         {
 323                                 if (missile.owner != self)
 324                                 {
 325                                         missile = find(missile, classname, "missile");
 326                                         continue;
 327                                 }
 328                                 makevectors(missile.v_angle);
 329                                 targ = targetlist;
 330                                 if (skill > 9) // normal players only do this for the target they are tracking
 331                                 {
 332                                         targ = targetlist;
 333                                         while (targ)
 334                                         {
 335                                                 if (
 336                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 337                                                         && desirabledamage > 0.1*coredamage
 338                                                 )self.button3 = TRUE;
 339                                                 targ = targ.chain;
 340                                         }
 341                                 }else{
 342                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 343                                         //As the distance gets larger, a correct detonation gets near imposible
 344                                         //Bots are assumed to use the rocket light to see if the rocket gets near a player
 345                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 346                                                 if(self.enemy.classname == "player")
 347                                                         if(desirabledamage >= 0.1*coredamage)
 348                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 349                                                                         self.button3 = TRUE;
 350                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 351                                 }
 352
 353                                 missile = find(missile, classname, "missile");
 354                         }
 355                         // if we would be doing at X percent of the core damage, detonate it
 356                         // but don't fire a new shot at the same time!
 357                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 358                                 self.button3 = TRUE;
 359                         if ((skill > 6.5) && (selfdamage > self.health))
 360                                 self.button3 = FALSE;
 361                         //if(self.button3 == TRUE)
 362                         //      dprint(ftos(desirabledamage),"\n");
 363                         if (self.button3 == TRUE) self.button0 = FALSE;
 364                 }
 365         }
 366         else if (req == WR_THINK)
 367         {
 368                 if (self.button0)
 369                 if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 370                 {
 371                         W_Rocket_Attack();
 372                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 373                 }
 374                 if (self.button3)
 375                 if(time > self.rl_sound)
 376                 {
 377                         self.rl_sound = time + 1;
 378                         sound (self, CHAN_BODY, "weapons/rocket_det.wav", 0.5, ATTN_NORM);
 379                 }
 380                 if (self.button3)
 381                 if(cvar("g_laserguided_missile"))
 382                 if(self.exteriorweaponentity.attack_finished_single < time)
 383                 {
 384                         self.exteriorweaponentity.attack_finished_single = time + 0.4;
 385                         self.laser_on = !self.laser_on;
 386                         sound (self, CHAN_AUTO, "weapons/tink1.wav", 1, ATTN_NORM);
 387                 }
 388         }
 389         else if (req == WR_PRECACHE)
 390         {
 391                 precache_model ("models/flash.md3");
 392                 precache_model ("models/rocket.md3");
 393                 precache_model ("models/weapons/g_rl.md3");
 394                 precache_model ("models/weapons/v_rl.md3");
 395                 precache_model ("models/weapons/w_rl.zym");
 396                 precache_sound ("weapons/rocket_det.wav");
 397                 precache_sound ("weapons/rocket_fire.wav");
 398                 precache_sound ("weapons/rocket_fly.wav");
 399                 precache_sound ("weapons/rocket_impact.wav");
 400                 if (cvar("g_laserguided_missile"))
 401                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 402         }
 403         else if (req == WR_SETUP)
 404                 weapon_setup(WEP_ROCKET_LAUNCHER, "rl", IT_ROCKETS);
 405         else if (req == WR_CHECKAMMO1)
 406         {
 407                 // don't switch while guiding a missile
 408                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 409                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 410                         return FALSE;
 411         }
 412         else if (req == WR_CHECKAMMO2)
 413                 return FALSE;
 414         return TRUE;
 415 };