data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  11
  12         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  13         self.event_damage = SUB_Null;
  14         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  15
  16         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  17         {
  18                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  19                 {
  20                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  21                         ATTACK_FINISHED(self.owner) = time;
  22                         self.owner.switchweapon = w_getbestweapon(self.owner);
  23                 }
  24                 if(g_laserguided_missile)
  25                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  26         }
  27         remove (self);
  28 }
  29
  30 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  31 {
  32         entity head, selected;
  33         vector dir;
  34         float dist, maxdist,// bestdist,
  35                 dot,// bestdot,
  36                 points, bestpoints;
  37         //bestdist = 9999;
  38         //bestdot = -2;
  39         bestpoints = 0;
  40         maxdist = 800;
  41         selected = world;
  42
  43         makevectors(e.angles);
  44
  45         head = find(world, classname, "laser_target");
  46         while(head)
  47         {
  48                 points = 0;
  49                 dir = normalize(head.origin - self.origin);
  50                 dot = dir * v_forward;
  51                 dist = vlen(head.origin - self.origin);
  52                 if(dist > maxdist)
  53                         dist = maxdist;
  54
  55                 // gain points for being in front
  56                 points = points + ((dot+1)*0.5) * 500
  57                         * (1 + crandom()*dot_variance);
  58                 // gain points for being close away
  59                 points = points + (1 - dist/maxdist) * 1000
  60                         * (1 + crandom()*dot_variance);
  61
  62                 traceline(e.origin, head.origin, TRUE, self);
  63                 if(trace_fraction < 1)
  64                 {
  65                         points = 0;
  66                 }
  67
  68                 if(points > bestpoints)//random() > 0.5)//
  69                 {
  70                         bestpoints = points;
  71                         selected = head;
  72                 }
  73
  74                 head = find(head, classname, "laser_target");
  75         }
  76
  77         //bprint(selected.owner.netname);
  78         //bprint("\n");
  79         return selected;
  80 }
  81
  82 void W_Rocket_RemoteExplode()
  83 {
  84         if(self.owner.deadflag == DEAD_NO)
  85         {
  86                 if((self.spawnshieldtime >= 0)
  87                         ? (time >= self.spawnshieldtime) // timer
  88                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  89                 )
  90                 {
  91                         other = world;
  92                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  93                         W_Rocket_Explode ();
  94                 }
  95                 else
  96                 {
  97                 }
  98         }
  99 }
 100
 101 void W_Rocket_Think (void)
 102 {
 103         entity e;
 104         vector desireddir, olddir, newdir;
 105         float turnrate, velspeed;
 106         self.nextthink = time;
 107         if (time > self.cnt)
 108         {
 109                 other = world;
 110                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 111                 W_Rocket_Explode ();
 112                 return;
 113         }
 114
 115         if(g_laserguided_missile)
 116         {
 117                 // accelerate
 118                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 119                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 120                 if (velspeed > 0)
 121                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 122         }
 123         else
 124         {
 125                 // accelerate
 126                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 127                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 128                 if (velspeed > 0)
 129                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 130         }
 131
 132         // laser guided, or remote detonation
 133         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 134         {
 135                 if(g_laserguided_missile)
 136                 {
 137                         if(self.rl_detonate_later)
 138                                 W_Rocket_RemoteExplode();
 139
 140                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 141                         {
 142                                 if(self.owner.laser_on)
 143                                 {
 144                                         if(self.attack_finished_single < time)
 145                                         {
 146                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 147                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 148                                         }
 149
 150                                         if(!self.enemy)
 151                                                 self.enemy = self.owner.weaponentity.lasertarget;
 152                                 }
 153                                 else self.enemy = world;
 154                         }
 155                         else // don't allow stealing: always target my owner's laser (if it exists)
 156                                 self.enemy = self.owner.weaponentity.lasertarget;
 157
 158                         if(self.enemy != world)
 159                         {
 160                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 161                                 velspeed = vlen(self.velocity);
 162                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 163                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 164                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 165                                 olddir = normalize(self.velocity);                                      // get my current direction
 166                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 167                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 168                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 169
 170                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 171                         }
 172                 }
 173                 else
 174                 {
 175                         if(self.rl_detonate_later)
 176                                 W_Rocket_RemoteExplode();
 177                 }
 178         }
 179 }
 180
 181 void W_Rocket_Touch (void)
 182 {
 183         if(self.owner && self.owner.lastrocket == self)
 184                 self.owner.lastrocket = world;
 185         PROJECTILE_TOUCH_NOSOUND;
 186         W_Rocket_Explode ();
 187 }
 188
 189 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 190 {
 191         self.health = self.health - damage;
 192         self.angles = vectoangles(self.velocity);
 193         if (self.health <= 0)
 194                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 195 }
 196
 197 void W_Rocket_Attack (void)
 198 {
 199         local entity missile;
 200         local entity flash, flash2;
 201
 202         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 203                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 204
 205         W_SetupShot (self, '25 3 -4', FALSE, 5, "weapons/rocket_fire.wav");
 206         //W_SetupShot (self, '25 8 -8', FALSE, 5, "weapons/rocket_fire.wav"); // TODO: move model to the right a little
 207         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 208
 209         missile = spawn ();
 210         missile.owner = self;
 211         self.lastrocket = missile;
 212         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 213                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 214         else
 215                 missile.spawnshieldtime = -1;
 216         missile.classname = "rocket";
 217         missile.bot_dodge = TRUE;
 218         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 219
 220         missile.takedamage = DAMAGE_YES;
 221         missile.damageforcescale = 4;
 222         missile.health = cvar("g_balance_rocketlauncher_health");
 223         missile.event_damage = W_Rocket_Damage;
 224
 225         missile.movetype = MOVETYPE_FLY;
 226         missile.solid = SOLID_BBOX;
 227         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 228         setmodel (missile, "models/rocket.md3"); // precision set below
 229         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 230
 231         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 232         if(g_laserguided_missile && self.laser_on)
 233                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 234         else
 235                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 236         W_SetupProjectileVelocity(missile);
 237         missile.angles = vectoangles (missile.velocity);
 238
 239         missile.touch = W_Rocket_Touch;
 240         missile.think = W_Rocket_Think;
 241         missile.nextthink = time;
 242         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 243         missile.effects = EF_LOWPRECISION;
 244         sound (missile, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 245         missile.flags = FL_PROJECTILE;
 246
 247         // muzzle flash for 1st person view
 248         flash = spawn ();
 249         flash.scale = 1.2;
 250         flash.angles_z = 180;
 251         flash.owner = self;
 252         flash.viewmodelforclient = self;
 253         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 254         setorigin (flash, '35 8 0');
 255         setmodel (flash, "models/flash.md3"); // precision set below
 256         setattachment(flash, self.weaponentity, "bone01");
 257         SUB_SetFade (flash, time, 0.4);
 258
 259         // muzzle flash for 3rd person view
 260         flash2 = spawn ();
 261         flash2.scale = 0.8;
 262         flash2.angles_y = 180;
 263         flash2.angles_z = 90;
 264         setorigin (flash2, '42 0 5');
 265         setmodel (flash2, "models/flash.md3"); // precision set below
 266         setattachment(flash2, self.exteriorweaponentity, "");
 267         SUB_SetFade (flash2, time, 0.4);
 268
 269         // common properties
 270         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 271 }
 272
 273 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 274
 275 float w_rlauncher(float req)
 276 {
 277         entity rock;
 278         float rockfound;
 279         if (req == WR_AIM)
 280         {
 281                 // aim and decide to fire if appropriate
 282                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 283                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 284                 {
 285                         // decide whether to detonate rockets
 286                         local entity missile, targetlist, targ;
 287                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 288                         local float selfdamage, teamdamage, enemydamage;
 289                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 290                         coredamage = cvar("g_balance_rocketlauncher_damage");
 291                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 292                         recipricoledgeradius = 1 / edgeradius;
 293                         selfdamage = 0;
 294                         teamdamage = 0;
 295                         enemydamage = 0;
 296                         targetlist = findchainfloat(bot_attack, TRUE);
 297                         missile = find(world, classname, "rocket");
 298                         while (missile)
 299                         {
 300                                 if (missile.owner != self)
 301                                 {
 302                                         missile = find(missile, classname, "rocket");
 303                                         continue;
 304                                 }
 305                                 targ = targetlist;
 306                                 while (targ)
 307                                 {
 308                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 309                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 310                                         // count potential damage according to type of target
 311                                         if (targ == self)
 312                                                 selfdamage = selfdamage + d;
 313                                         else if (targ.team == self.team && teamplay)
 314                                                 teamdamage = teamdamage + d;
 315                                         else if (bot_shouldattack(targ))
 316                                                 enemydamage = enemydamage + d;
 317                                         targ = targ.chain;
 318                                 }
 319                                 missile = find(missile, classname, "rocket");
 320                         }
 321                         local float desirabledamage;
 322                         desirabledamage = enemydamage;
 323                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 324                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 325                         if (self.team && teamplay == 2)
 326                                 desirabledamage = desirabledamage - teamdamage;
 327
 328                         missile = find(world, classname, "rocket");
 329                         while (missile)
 330                         {
 331                                 if (missile.owner != self)
 332                                 {
 333                                         missile = find(missile, classname, "rocket");
 334                                         continue;
 335                                 }
 336                                 makevectors(missile.v_angle);
 337                                 targ = targetlist;
 338                                 if (skill > 9) // normal players only do this for the target they are tracking
 339                                 {
 340                                         targ = targetlist;
 341                                         while (targ)
 342                                         {
 343                                                 if (
 344                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 345                                                         && desirabledamage > 0.1*coredamage
 346                                                 )self.BUTTON_ATCK2 = TRUE;
 347                                                 targ = targ.chain;
 348                                         }
 349                                 }else{
 350                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 351                                         //As the distance gets larger, a correct detonation gets near imposible
 352                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 353                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 354                                                 if(self.enemy.classname == "player")
 355                                                         if(desirabledamage >= 0.1*coredamage)
 356                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 357                                                                         self.BUTTON_ATCK2 = TRUE;
 358                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 359                                 }
 360
 361                                 missile = find(missile, classname, "rocket");
 362                         }
 363                         // if we would be doing at X percent of the core damage, detonate it
 364                         // but don't fire a new shot at the same time!
 365                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 366                                 self.BUTTON_ATCK2 = TRUE;
 367                         if ((skill > 6.5) && (selfdamage > self.health))
 368                                 self.BUTTON_ATCK2 = FALSE;
 369                         //if(self.BUTTON_ATCK2 == TRUE)
 370                         //      dprint(ftos(desirabledamage),"\n");
 371                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 372                 }
 373         }
 374         else if (req == WR_THINK)
 375         {
 376                 if(g_laserguided_missile)
 377                 {
 378                         if (self.BUTTON_ATCK && self.rl_release)
 379                         {
 380                                 rockfound = 0;
 381                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 382                                 {
 383                                         if(!rock.rl_detonate_later)
 384                                         {
 385                                                 rock.rl_detonate_later = TRUE;
 386                                                 rockfound = 1;
 387                                         }
 388                                 }
 389                                 if(rockfound)
 390                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 391                                 else
 392                                 {
 393                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 394                                         {
 395                                                 W_Rocket_Attack();
 396                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 397                                         }
 398                                 }
 399                                 self.rl_release = 0;
 400                         }
 401                         if (!self.BUTTON_ATCK)
 402                                 self.rl_release = 1;
 403                         if (self.BUTTON_ATCK2)
 404                         if(self.exteriorweaponentity.attack_finished_single < time)
 405                         {
 406                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 407                                 self.laser_on = !self.laser_on;
 408                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 409                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 410                         }
 411                 }
 412                 else
 413                 {
 414                         if (self.BUTTON_ATCK)
 415                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 416                         {
 417                                 W_Rocket_Attack();
 418                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 419                         }
 420                         if (self.BUTTON_ATCK2)
 421                         {
 422                                 rockfound = 0;
 423                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 424                                 {
 425                                         if(!rock.rl_detonate_later)
 426                                         {
 427                                                 rock.rl_detonate_later = TRUE;
 428                                                 rockfound = 1;
 429                                         }
 430                                 }
 431                                 if(rockfound)
 432                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 433                         }
 434                 }
 435         }
 436         else if (req == WR_PRECACHE)
 437         {
 438                 precache_model ("models/flash.md3");
 439                 precache_model ("models/rocket.md3");
 440                 precache_model ("models/weapons/g_rl.md3");
 441                 precache_model ("models/weapons/v_rl.md3");
 442                 precache_model ("models/weapons/w_rl.zym");
 443                 precache_sound ("weapons/rocket_det.wav");
 444                 precache_sound ("weapons/rocket_fire.wav");
 445                 precache_sound ("weapons/rocket_fly.wav");
 446                 precache_sound ("weapons/rocket_impact.wav");
 447                 if (g_laserguided_missile)
 448                 {
 449                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 450                         precache_sound ("weapons/tink1.wav");
 451                 }
 452         }
 453         else if (req == WR_SETUP)
 454         {
 455                 weapon_setup(WEP_ROCKET_LAUNCHER);
 456                 self.rl_release = 1;
 457         }
 458         else if (req == WR_CHECKAMMO1)
 459         {
 460                 // don't switch while guiding a missile
 461                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 462                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 463                         return FALSE;
 464         }
 465         else if (req == WR_CHECKAMMO2)
 466                 return FALSE;
 467         else if (req == WR_SUICIDEMESSAGE)
 468                 w_deathtypestring = "exploded";
 469         else if (req == WR_KILLMESSAGE)
 470         {
 471                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 472                         w_deathtypestring = "got too close to #'s rocket";
 473                 else if(w_deathtype & HITTYPE_SPLASH)
 474                         w_deathtypestring = "almost dodged #'s rocket";
 475                 else
 476                         w_deathtypestring = "ate #'s rocket";
 477         }
 478         return TRUE;
 479 };