data/qcsrc/server/w_rocketlauncher.qc

   1
   2 .float rl_sound;
   3
   4 void W_Rocket_Explode (void)
   5 {
   6         vector  org2;
   7         sound (self, CHAN_BODY, "weapons/rocket_impact.ogg", 1, ATTN_NORM);
   8         org2 = findbetterlocation (self.origin, 16);
   9
  10         //te_explosion (org2);
  11         // LordHavoc: TE_TEI_BIGEXPLOSION
  12         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  13         WriteByte (MSG_BROADCAST, 78);
  14         WriteCoord (MSG_BROADCAST, org2_x);
  15         WriteCoord (MSG_BROADCAST, org2_y);
  16         WriteCoord (MSG_BROADCAST, org2_z);
  17
  18         //effect (org2, "models/sprites/rockexpl.spr", 0, 12, 35);
  19         self.event_damage = SUB_Null;
  20         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), IT_ROCKET_LAUNCHER);
  21
  22         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  23         {
  24                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  25                 {
  26                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  27                         self.owner.attack_finished = time;
  28                         self.owner.switchweapon = w_getbestweapon(self.owner);
  29                 }
  30                 if(cvar("g_laserguided_missile"))
  31                                   self.owner.attack_finished = time + cvar("g_balance_rocketlauncher_refire");
  32         }
  33         remove (self);
  34 }
  35
  36 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  37 {
  38         entity head, selected;
  39         vector dir;
  40         float dist, maxdist,// bestdist,
  41                 dot,// bestdot,
  42                 points, bestpoints;
  43         //bestdist = 9999;
  44         //bestdot = -2;
  45         bestpoints = 0;
  46         maxdist = 800;
  47         selected = world;
  48
  49         makevectors(e.angles);
  50
  51         head = find(world, classname, "laser_target");
  52         while(head)
  53         {
  54                 points = 0;
  55                 dir = normalize(head.origin - self.origin);
  56                 dot = dir * v_forward;
  57                 dist = vlen(head.origin - self.origin);
  58                 if(dist > maxdist)
  59                         dist = maxdist;
  60
  61                 // gain points for being in front
  62                 points = points + ((dot+1)*0.5) * 500
  63                         * (1 + crandom()*dot_variance);
  64                 // gain points for being close away
  65                 points = points + (1 - dist/maxdist) * 1000
  66                         * (1 + crandom()*dot_variance);
  67
  68                 traceline(e.origin, head.origin, TRUE, self);
  69                 if(trace_fraction < 1)
  70                 {
  71                         points = 0;
  72                 }
  73
  74                 if(points > bestpoints)//random() > 0.5)//
  75                 {
  76                         bestpoints = points;
  77                         selected = head;
  78                 }
  79
  80                 head = find(head, classname, "laser_target");
  81         }
  82
  83         //bprint(selected.owner.netname);
  84         //bprint("\n");
  85         return selected;
  86 }
  87
  88 void W_Rocket_Think (void)
  89 {
  90         entity e;
  91         vector desireddir, olddir, newdir;
  92         float turnrate, velspeed;
  93         self.nextthink = time;
  94         if (time > self.cnt)
  95         {
  96                 W_Rocket_Explode ();
  97                 return;
  98         }
  99
 100         if(cvar("g_laserguided_missile"))
 101         {
 102                 // accelerate
 103                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 104                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 105                 if (velspeed > 0)
 106                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 107         }
 108         else
 109         {
 110                 // accelerate
 111                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 112                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 113                 if (velspeed > 0)
 114                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 115         }
 116
 117         // laser guided, or remote detonation
 118         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 119         {
 120                 if(cvar("g_laserguided_missile"))
 121                 {
 122                         if(!self.owner.button0)
 123                                 self.ltime = -1; // indicate that the player has let go of the button
 124
 125
 126                         if(self.owner.deadflag == DEAD_NO)
 127                         if (self.owner.button0 && self.ltime < 0) // if the player let go of the button and then pushed it again
 128                         {
 129                                   W_Rocket_Explode ();
 130                                   return;
 131                         }
 132
 133                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 134                         {
 135                                 if(self.owner.laser_on)
 136                                 {
 137                                         if(self.attack_finished < time)
 138                                         {
 139                                                 self.attack_finished = time + 0.2 + random()*0.3;
 140                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 141                                         }
 142
 143                                         if(!self.enemy)
 144                                                 self.enemy = self.owner.weaponentity.lasertarget;
 145                                 }
 146                                 else self.enemy = world;
 147                         }
 148                         else // don't allow stealing: always target my owner's laser (if it exists)
 149                                 self.enemy = self.owner.weaponentity.lasertarget;
 150
 151                         if(self.enemy != world)
 152                         {
 153                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 154                                 velspeed = vlen(self.velocity);
 155                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 156                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 157                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 158                                 olddir = normalize(self.velocity);                                      // get my current direction
 159                                 newdir = normalize((olddir + desireddir * turnrate) * 0.5);     // take the average of the 2 directions; not the best method but simple & easy
 160                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 161                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 162
 163                                 self.owner.attack_finished = time + 0.2;
 164                         }
 165                 }
 166                 else
 167                 {
 168                         if(self.owner.deadflag == DEAD_NO)
 169                         if (self.owner.button3)
 170                                   W_Rocket_Explode ();
 171                 }
 172         }
 173 }
 174
 175 void W_Rocket_Touch (void)
 176 {
 177         if(self.owner && self.owner.lastrocket == self)
 178                 self.owner.lastrocket = world;
 179         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 180         {
 181                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
 182                 remove(self);
 183                 return;
 184         }
 185         W_Rocket_Explode ();
 186 }
 187
 188 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 189 {
 190         self.health = self.health - damage;
 191         if (self.health <= 0)
 192         {
 193                 self.owner = attacker;
 194                 W_Rocket_Explode();
 195         }
 196 }
 197
 198 void W_Rocket_Attack (void)
 199 {
 200         local entity missile;
 201         local entity flash;
 202
 203         if (cvar("g_use_ammunition") && !cvar("g_rocketarena"))
 204                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 205
 206         W_SetupShot (self, '15 3 -8', FALSE, 5, "weapons/rocket_fire.ogg");
 207         te_smallflash(w_shotorg);
 208
 209         missile = spawn ();
 210         missile.owner = self;
 211         self.lastrocket = missile;
 212         missile.classname = "missile";
 213         missile.bot_dodge = TRUE;
 214         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 215
 216         missile.takedamage = DAMAGE_YES;
 217         missile.damageforcescale = 4;
 218         missile.health = 30;
 219         missile.event_damage = W_Rocket_Damage;
 220
 221         missile.movetype = MOVETYPE_FLY;
 222         missile.solid = SOLID_BBOX;
 223         setmodel (missile, "models/rocket.md3"); // precision set below
 224         setsize (missile, '0 0 0', '0 0 0');
 225
 226         setorigin (missile, w_shotorg);
 227         if(cvar("g_laserguided_missile") && self.laser_on)
 228                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 229         else
 230                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 231         W_SetupProjectileVelocity(missile);
 232         missile.angles = vectoangles (missile.velocity);
 233
 234         missile.touch = W_Rocket_Touch;
 235         missile.think = W_Rocket_Think;
 236         missile.nextthink = time;
 237         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 238         missile.effects = EF_NOSHADOW | EF_LOWPRECISION;
 239         sound (missile, CHAN_BODY, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);
 240         missile.flags = FL_PROJECTILE;
 241
 242         flash = spawn ();
 243         setorigin (flash, w_shotorg);
 244         setmodel (flash, "models/flash.md3"); // precision set below
 245         flash.angles = vectoangles (w_shotdir);
 246         SUB_SetFade (flash, time, 0.4);
 247         flash.effects = flash.effects | EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 248 }
 249
 250 float(float req) w_rlauncher =
 251 {
 252         if (req == WR_AIM)
 253         {
 254                 // aim and decide to fire if appropriate
 255                 self.button0 = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 256                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 257                 {
 258                         // decide whether to detonate rockets
 259                         local entity missile, targetlist, targ;
 260                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 261                         local float selfdamage, teamdamage, enemydamage;
 262                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 263                         coredamage = cvar("g_balance_rocketlauncher_damage");
 264                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 265                         recipricoledgeradius = 1 / edgeradius;
 266                         selfdamage = 0;
 267                         teamdamage = 0;
 268                         enemydamage = 0;
 269                         targetlist = findchainfloat(bot_attack, TRUE);
 270                         missile = find(world, classname, "missile");
 271                         while (missile)
 272                         {
 273                                 if (missile.owner != self)
 274                                 {
 275                                         missile = find(missile, classname, "missile");
 276                                         continue;
 277                                 }
 278                                 targ = targetlist;
 279                                 while (targ)
 280                                 {
 281                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 282                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 283                                         // count potential damage according to type of target
 284                                         if (targ == self)
 285                                                 selfdamage = selfdamage + d;
 286                                         else if (targ.team == self.team && teamplay)
 287                                                 teamdamage = teamdamage + d;
 288                                         else if (bot_shouldattack(targ))
 289                                                 enemydamage = enemydamage + d;
 290                                         targ = targ.chain;
 291                                 }
 292                                 missile = find(missile, classname, "missile");
 293                         }
 294                         local float desirabledamage;
 295                         desirabledamage = enemydamage;
 296                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 297                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 298                         if (self.team && teamplay == 2)
 299                                 desirabledamage = desirabledamage - teamdamage;
 300
 301                         missile = find(world, classname, "missile");
 302                         while (missile)
 303                         {
 304                                 if (missile.owner != self)
 305                                 {
 306                                         missile = find(missile, classname, "missile");
 307                                         continue;
 308                                 }
 309                                 makevectors(missile.v_angle);
 310                                 targ = targetlist;
 311                                 if (skill > 9) // normal players only do this for the target they are tracking
 312                                 {
 313                                         targ = targetlist;
 314                                         while (targ)
 315                                         {
 316                                                 if (
 317                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 318                                                         && desirabledamage > 0.1*coredamage
 319                                                 )self.button3 = TRUE;
 320                                                 targ = targ.chain;
 321                                         }
 322                                 }else{
 323                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 324                                         //As the distance gets larger, a correct detonation gets near imposible
 325                                         //Bots are assumed to use the rocket light to see if the rocket gets near a player
 326                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 327                                                 if(self.enemy.classname == "player")
 328                                                         if(desirabledamage >= 0.1*coredamage)
 329                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 330                                                                         self.button3 = TRUE;
 331                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 332                                 }
 333
 334                                 missile = find(missile, classname, "missile");
 335                         }
 336                         // if we would be doing at X percent of the core damage, detonate it
 337                         // but don't fire a new shot at the same time!
 338                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 339                                 self.button3 = TRUE;
 340                         if ((skill > 6.5) && (selfdamage > self.health))
 341                                 self.button3 = FALSE;
 342                         //if(self.button3 == TRUE)
 343                         //      dprint(ftos(desirabledamage),"\n");
 344                         if (self.button3 == TRUE) self.button0 = FALSE;
 345                 }
 346         }
 347         else if (req == WR_THINK)
 348         {
 349                 if (self.button0)
 350                 if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 351                 {
 352                         W_Rocket_Attack();
 353                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 354                 }
 355                 if (self.button3)
 356                 if(time > self.rl_sound)
 357                 {
 358                         self.rl_sound = time + 1;
 359                         sound (self, CHAN_BODY, "weapons/rocket_det.ogg", 0.5, ATTN_NORM);
 360                 }
 361                 if (self.button3)
 362                 if(cvar("g_laserguided_missile"))
 363                 if(self.exteriorweaponentity.attack_finished < time)
 364                 {
 365                         self.exteriorweaponentity.attack_finished = time + 0.4;
 366                         self.laser_on = !self.laser_on;
 367                         sound (self, CHAN_AUTO, "weapons/tink1.ogg", 1, ATTN_NORM);
 368                 }
 369         }
 370         else if (req == WR_SETUP)
 371                 weapon_setup(WEP_ROCKET_LAUNCHER, "rl", IT_ROCKETS);
 372         else if (req == WR_CHECKAMMO1)
 373         {
 374                 // don't switch while guiding a missile
 375                 if ((self.attack_finished <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 376                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 377                         return FALSE;
 378         }
 379         else if (req == WR_CHECKAMMO2)
 380                 return FALSE;
 381         return TRUE;
 382 };