data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister()
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         if(other.takedamage == DAMAGE_AIM)
  18                 if(other.classname == "player")
  19                         if(IsDifferentTeam(self.owner, other))
  20                                 if(IsFlying(other))
  21                                         announce(self.owner, "announcer/male/airshot.wav");
  22
  23         self.event_damage = SUB_Null;
  24         self.takedamage = DAMAGE_NO;
  25         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  26
  27         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  28         {
  29                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  30                 {
  31                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  32                         ATTACK_FINISHED(self.owner) = time;
  33                         self.owner.switchweapon = w_getbestweapon(self.owner);
  34                 }
  35                 if(g_laserguided_missile)
  36                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  37         }
  38         remove (self);
  39 }
  40
  41 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  42 {
  43         entity head, selected;
  44         vector dir;
  45         float dist, maxdist,// bestdist,
  46                 dot,// bestdot,
  47                 points, bestpoints;
  48         //bestdist = 9999;
  49         //bestdot = -2;
  50         bestpoints = 0;
  51         maxdist = 800;
  52         selected = world;
  53
  54         makevectors(e.angles);
  55
  56         head = find(world, classname, "laser_target");
  57         while(head)
  58         {
  59                 points = 0;
  60                 dir = normalize(head.origin - self.origin);
  61                 dot = dir * v_forward;
  62                 dist = vlen(head.origin - self.origin);
  63                 if(dist > maxdist)
  64                         dist = maxdist;
  65
  66                 // gain points for being in front
  67                 points = points + ((dot+1)*0.5) * 500
  68                         * (1 + crandom()*dot_variance);
  69                 // gain points for being close away
  70                 points = points + (1 - dist/maxdist) * 1000
  71                         * (1 + crandom()*dot_variance);
  72
  73                 traceline(e.origin, head.origin, TRUE, self);
  74                 if(trace_fraction < 1)
  75                 {
  76                         points = 0;
  77                 }
  78
  79                 if(points > bestpoints)//random() > 0.5)//
  80                 {
  81                         bestpoints = points;
  82                         selected = head;
  83                 }
  84
  85                 head = find(head, classname, "laser_target");
  86         }
  87
  88         //bprint(selected.owner.netname);
  89         //bprint("\n");
  90         return selected;
  91 }
  92
  93 void W_Rocket_RemoteExplode()
  94 {
  95         if(self.owner.deadflag == DEAD_NO)
  96         if(self.owner.lastrocket)
  97         {
  98                 if((self.spawnshieldtime >= 0)
  99                         ? (time >= self.spawnshieldtime) // timer
 100                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
 101                 )
 102                 {
 103                         other = world;
 104                         self.projectiledeathtype |= HITTYPE_BOUNCE;
 105                         W_Rocket_Explode ();
 106                 }
 107                 else
 108                 {
 109                 }
 110         }
 111 }
 112
 113 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 114 {
 115         if(thisdir * goaldir > maxturn_cos)
 116                 return goaldir;
 117         float f, m2;
 118         vector v;
 119         // solve:
 120         //   g = normalize(thisdir + goaldir * X)
 121         //   thisdir * g = maxturn
 122         //
 123         //   gg = thisdir + goaldir * X
 124         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 125         //
 126         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 127         f = thisdir * goaldir;
 128         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 129         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 130         m2 = maxturn_cos * maxturn_cos;
 131         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 132         return normalize(thisdir + goaldir * v_y); // the larger solution!
 133 }
 134
 135 void W_Rocket_Think (void)
 136 {
 137         entity e;
 138         vector desireddir, olddir, newdir, desiredorigin, goal;
 139         float turnrate, velspeed, f;
 140         self.nextthink = time;
 141         if (time > self.cnt)
 142         {
 143                 other = world;
 144                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 145                 W_Rocket_Explode ();
 146                 return;
 147         }
 148
 149         if(g_laserguided_missile)
 150         {
 151                 // accelerate
 152                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 153                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 154                 if (velspeed > 0)
 155                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 156         }
 157         else
 158         {
 159                 // accelerate
 160                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 161                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 162                 if (velspeed > 0)
 163                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 164         }
 165
 166         // laser guided, or remote detonation
 167         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 168         {
 169                 if(g_laserguided_missile)
 170                 {
 171                         if(self.rl_detonate_later)
 172                                 W_Rocket_RemoteExplode();
 173
 174                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 175                         {
 176                                 if(self.owner.laser_on)
 177                                 {
 178                                         if(self.attack_finished_single < time)
 179                                         {
 180                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 181                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 182                                         }
 183
 184                                         if(!self.enemy)
 185                                                 self.enemy = self.owner.weaponentity.lasertarget;
 186                                 }
 187                                 else self.enemy = world;
 188                         }
 189                         else // don't allow stealing: always target my owner's laser (if it exists)
 190                                 self.enemy = self.owner.weaponentity.lasertarget;
 191
 192                         if(self.enemy != world)
 193                         {
 194                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 195                                 velspeed = vlen(self.velocity);
 196                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 197                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 198                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 199                                 olddir = normalize(self.velocity);                                      // get my current direction
 200                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 201                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 202                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 203
 204                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 205                         }
 206                 }
 207                 else
 208                 {
 209                         if(self == self.owner.lastrocket)
 210                         if(!self.owner.rl_release)
 211                         if(cvar("g_balance_rocketlauncher_guiderate"))
 212                         if(time > self.pushltime)
 213                         if(self.owner.deadflag == DEAD_NO)
 214                         {
 215                                 f = min(1, (time - self.pushltime) / cvar("g_balance_rocketlauncher_guideratedelay"));
 216                                 velspeed = vlen(self.velocity);
 217
 218                                 makevectors(self.owner.v_angle);
 219                                 desireddir = v_forward;
 220                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 221                                 olddir = normalize(self.velocity);
 222
 223                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 224                                 // but we are limiting the rate at which we can turn!
 225                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 226                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * PI / 180));
 227
 228                                 self.velocity = newdir * velspeed;
 229                         }
 230
 231                         if(self.rl_detonate_later)
 232                                 W_Rocket_RemoteExplode();
 233                 }
 234         }
 235
 236         if(self.csqcprojectile_clientanimate == 0)
 237                 UpdateCSQCProjectile(self);
 238 }
 239
 240 void W_Rocket_Touch (void)
 241 {
 242         W_Rocket_Unregister();
 243
 244         PROJECTILE_TOUCH;
 245         W_Rocket_Explode ();
 246 }
 247
 248 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 249 {
 250         if (self.health <= 0)
 251                 return;
 252         self.health = self.health - damage;
 253         self.angles = vectoangles(self.velocity);
 254         if (self.health <= 0)
 255                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 256 }
 257
 258 void W_Rocket_Attack (void)
 259 {
 260         local entity missile;
 261         local entity flash;
 262
 263         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 264                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 265
 266         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 267         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 268
 269         missile = spawn ();
 270         missile.owner = self;
 271         self.lastrocket = missile;
 272         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 273                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 274         else
 275                 missile.spawnshieldtime = -1;
 276         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 277         missile.classname = "rocket";
 278         missile.bot_dodge = TRUE;
 279         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 280
 281         missile.takedamage = DAMAGE_YES;
 282         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 283         missile.health = cvar("g_balance_rocketlauncher_health");
 284         missile.event_damage = W_Rocket_Damage;
 285
 286         missile.movetype = MOVETYPE_FLY;
 287         PROJECTILE_MAKETRIGGER(missile);
 288         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 289         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 290
 291         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 292         if(g_laserguided_missile && self.laser_on)
 293                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart") * g_weaponspeedfactor;
 294         else
 295                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart") * g_weaponspeedfactor;
 296         W_SetupProjectileVelocity(missile);
 297         missile.angles = vectoangles (missile.velocity);
 298
 299         missile.touch = W_Rocket_Touch;
 300         missile.think = W_Rocket_Think;
 301         missile.nextthink = time;
 302         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 303         missile.flags = FL_PROJECTILE;
 304
 305         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 306
 307         // muzzle flash for 1st person view
 308         flash = spawn ();
 309         setmodel (flash, "models/flash.md3"); // precision set below
 310         SUB_SetFade (flash, time, 0.1);
 311         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 312         W_AttachToShotorg(flash, '5 0 0');
 313
 314         // common properties
 315 }
 316
 317 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 318
 319 float w_rlauncher(float req)
 320 {
 321         entity rock;
 322         float rockfound;
 323         if (req == WR_AIM)
 324         {
 325                 // aim and decide to fire if appropriate
 326                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 327                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 328                 {
 329                         // decide whether to detonate rockets
 330                         local entity missile, targetlist, targ;
 331                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 332                         local float selfdamage, teamdamage, enemydamage;
 333                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 334                         coredamage = cvar("g_balance_rocketlauncher_damage");
 335                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 336                         recipricoledgeradius = 1 / edgeradius;
 337                         selfdamage = 0;
 338                         teamdamage = 0;
 339                         enemydamage = 0;
 340                         targetlist = findchainfloat(bot_attack, TRUE);
 341                         missile = find(world, classname, "rocket");
 342                         while (missile)
 343                         {
 344                                 if (missile.owner != self)
 345                                 {
 346                                         missile = find(missile, classname, "rocket");
 347                                         continue;
 348                                 }
 349                                 targ = targetlist;
 350                                 while (targ)
 351                                 {
 352                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 353                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 354                                         // count potential damage according to type of target
 355                                         if (targ == self)
 356                                                 selfdamage = selfdamage + d;
 357                                         else if (targ.team == self.team && teams_matter)
 358                                                 teamdamage = teamdamage + d;
 359                                         else if (bot_shouldattack(targ))
 360                                                 enemydamage = enemydamage + d;
 361                                         targ = targ.chain;
 362                                 }
 363                                 missile = find(missile, classname, "rocket");
 364                         }
 365                         local float desirabledamage;
 366                         desirabledamage = enemydamage;
 367                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 368                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 369                         if (self.team && teamplay != 1)
 370                                 desirabledamage = desirabledamage - teamdamage;
 371
 372                         missile = find(world, classname, "rocket");
 373                         while (missile)
 374                         {
 375                                 if (missile.owner != self)
 376                                 {
 377                                         missile = find(missile, classname, "rocket");
 378                                         continue;
 379                                 }
 380                                 makevectors(missile.v_angle);
 381                                 targ = targetlist;
 382                                 if (skill > 9) // normal players only do this for the target they are tracking
 383                                 {
 384                                         targ = targetlist;
 385                                         while (targ)
 386                                         {
 387                                                 if (
 388                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 389                                                         && desirabledamage > 0.1*coredamage
 390                                                 )self.BUTTON_ATCK2 = TRUE;
 391                                                 targ = targ.chain;
 392                                         }
 393                                 }else{
 394                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 395                                         //As the distance gets larger, a correct detonation gets near imposible
 396                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 397                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 398                                                 if(self.enemy.classname == "player")
 399                                                         if(desirabledamage >= 0.1*coredamage)
 400                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 401                                                                         self.BUTTON_ATCK2 = TRUE;
 402                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 403                                 }
 404
 405                                 missile = find(missile, classname, "rocket");
 406                         }
 407                         // if we would be doing at X percent of the core damage, detonate it
 408                         // but don't fire a new shot at the same time!
 409                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 410                                 self.BUTTON_ATCK2 = TRUE;
 411                         if ((skill > 6.5) && (selfdamage > self.health))
 412                                 self.BUTTON_ATCK2 = FALSE;
 413                         //if(self.BUTTON_ATCK2 == TRUE)
 414                         //      dprint(ftos(desirabledamage),"\n");
 415                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 416                 }
 417         }
 418         else if (req == WR_THINK)
 419         {
 420                 if(g_laserguided_missile)
 421                 {
 422                         if (self.BUTTON_ATCK && self.rl_release)
 423                         {
 424                                 rockfound = 0;
 425                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 426                                 {
 427                                         if(!rock.rl_detonate_later)
 428                                         {
 429                                                 rock.rl_detonate_later = TRUE;
 430                                                 rockfound = 1;
 431                                         }
 432                                 }
 433                                 if(rockfound)
 434                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 435                                 else
 436                                 {
 437                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 438                                         {
 439                                                 W_Rocket_Attack();
 440                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 441                                         }
 442                                 }
 443                                 self.rl_release = 0;
 444                         }
 445                         if (!self.BUTTON_ATCK)
 446                                 self.rl_release = 1;
 447                         if (self.BUTTON_ATCK2)
 448                         if(self.exteriorweaponentity.attack_finished_single < time)
 449                         {
 450                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 451                                 self.laser_on = !self.laser_on;
 452                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 453                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 454                         }
 455                 }
 456                 else
 457                 {
 458                         if (self.BUTTON_ATCK)
 459                         {
 460                                 if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 461                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 462                                 {
 463                                         W_Rocket_Attack();
 464                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 465                                         self.rl_release = 0;
 466                                 }
 467                         }
 468                         else
 469                                 self.rl_release = 1;
 470
 471                         if (self.BUTTON_ATCK2)
 472                         {
 473                                 rockfound = 0;
 474                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 475                                 {
 476                                         if(!rock.rl_detonate_later)
 477                                         {
 478                                                 rock.rl_detonate_later = TRUE;
 479                                                 rockfound = 1;
 480                                         }
 481                                 }
 482                                 if(rockfound)
 483                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 484                         }
 485                 }
 486         }
 487         else if (req == WR_PRECACHE)
 488         {
 489                 precache_model ("models/flash.md3");
 490                 precache_model ("models/weapons/g_rl.md3");
 491                 precache_model ("models/weapons/v_rl.md3");
 492                 precache_model ("models/weapons/h_rl.dpm");
 493                 precache_sound ("weapons/rocket_det.wav");
 494                 precache_sound ("weapons/rocket_fire.wav");
 495                 if (g_laserguided_missile)
 496                 {
 497                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 498                         precache_sound ("weapons/rocket_mode.wav");
 499                 }
 500         }
 501         else if (req == WR_SETUP)
 502         {
 503                 weapon_setup(WEP_ROCKET_LAUNCHER);
 504                 self.rl_release = 1;
 505         }
 506         else if (req == WR_CHECKAMMO1)
 507         {
 508                 // don't switch while guiding a missile
 509                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 510                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 511                         return FALSE;
 512         }
 513         else if (req == WR_CHECKAMMO2)
 514                 return FALSE;
 515         else if (req == WR_SUICIDEMESSAGE)
 516                 w_deathtypestring = "exploded";
 517         else if (req == WR_KILLMESSAGE)
 518         {
 519                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 520                         w_deathtypestring = "got too close to #'s rocket";
 521                 else if(w_deathtype & HITTYPE_SPLASH)
 522                         w_deathtypestring = "almost dodged #'s rocket";
 523                 else
 524                         w_deathtypestring = "ate #'s rocket";
 525         }
 526         return TRUE;
 527 };