data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .entity porto_current;
   3 .vector porto_v_angle; // holds "held" view angles
   4 .float porto_v_angle_held;
   5 .vector right_vector;
   6
   7 void W_Porto_Success (void)
   8 {
   9         if(self.owner == world)
  10         {
  11                 objerror("Cannot succeed successfully: no owner\n");
  12                 return;
  13         }
  14
  15         self.owner.porto_current = world;
  16         remove(self);
  17 }
  18
  19 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  20 void W_Porto_Fail (float failhard)
  21 {
  22         if(self.owner == world)
  23         {
  24                 objerror("Cannot fail successfully: no owner\n");
  25                 return;
  26         }
  27
  28         // no portals here!
  29         Portal_ClearWithID(self.owner, self.portal_id);
  30         self.owner.porto_current = world;
  31
  32         if(!failhard && !(self.owner.weapons & WEPBIT_PORTO))
  33         {
  34                 setsize (self, '-16 -16 0', '16 16 32');
  35                 setorigin(self, self.origin + trace_plane_normal);
  36                 if(move_out_of_solid(self))
  37                 {
  38                         self.flags = FL_ITEM;
  39                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  40                         tracetoss(self, self);
  41                         if(vlen(trace_endpos - self.owner.origin) < 128)
  42                         {
  43                                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  44                                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  45                         }
  46                 }
  47         }
  48         remove(self);
  49 }
  50
  51 void W_Porto_Think (void)
  52 {
  53         trace_plane_normal = '0 0 0';
  54         if(self.owner.playerid != self.playerid)
  55                 remove(self);
  56         else
  57                 W_Porto_Fail(0);
  58 }
  59
  60 void W_Porto_Touch (void)
  61 {
  62         vector norm;
  63
  64         if(other.classname == "portal")
  65                 return; // handled by the portal
  66
  67         norm = trace_plane_normal;
  68         if(trace_ent.movetype == MOVETYPE_WALK)
  69         {
  70                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_NORMAL, self);
  71                 if(trace_fraction >= 1)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         return;
  75                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  76                         return;
  77         }
  78
  79         if(self.owner.playerid != self.playerid)
  80         {
  81                 sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
  82                 remove(self);
  83         }
  84         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  85         {
  86                 sound(self, CHAN_PROJECTILE, "porto/bounce.ogg", VOL_BASE, ATTN_NORM);
  87                 // just reflect
  88                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  89                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  90         }
  91         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  92         {
  93                 sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
  94                 W_Porto_Fail(0);
  95         }
  96         else if(self.effects & EF_RED)
  97         {
  98                 self.effects += EF_BLUE - EF_RED;
  99                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 100                 {
 101                         sound(self, CHAN_PROJECTILE, "porto/create.ogg", VOL_BASE, ATTN_NORM);
 102                         trace_plane_normal = norm;
 103                         centerprint(self.owner, "^1In^7-portal created.\n");
 104                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 105                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 106                 }
 107                 else
 108                 {
 109                         sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
 110                         trace_plane_normal = norm;
 111                         W_Porto_Fail(0);
 112                 }
 113         }
 114         else
 115         {
 116                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
 117                 {
 118                         sound(self, CHAN_PROJECTILE, "porto/create.ogg", VOL_BASE, ATTN_NORM);
 119                         trace_plane_normal = norm;
 120                         centerprint(self.owner, "^4Out^7-portal created.\n");
 121                         W_Porto_Success();
 122                 }
 123                 else
 124                 {
 125                         sound(self, CHAN_PROJECTILE, "porto/unsupported.ogg", VOL_BASE, ATTN_NORM);
 126                         W_Porto_Fail(0);
 127                 }
 128         }
 129
 130 }
 131
 132 void W_Porto_Attack (void)
 133 {
 134         local entity gren;
 135
 136         if not(self.items & IT_UNLIMITED_AMMO)
 137                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 138         W_SetupShot (self, '0 0 0', FALSE, 4, "porto/fire.ogg");
 139
 140         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 141
 142         gren = spawn ();
 143         gren.owner = self;
 144         gren.classname = "porto";
 145         gren.bot_dodge = TRUE;
 146         gren.bot_dodgerating = 200;
 147         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 148         gren.solid = SOLID_BBOX;
 149         gren.effects = EF_LOWPRECISION | EF_RED | EF_ADDITIVE;
 150         gren.scale = 4;
 151         gren.modelflags = MF_GRENADE;
 152         setmodel(gren, "models/grenademodel.md3"); // precision set above
 153         setsize(gren, '0 0 0', '0 0 0');
 154         setorigin(gren, w_shotorg);
 155
 156         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 157         gren.think = W_Porto_Think;
 158         gren.touch = W_Porto_Touch;
 159         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 160         if(self.items & IT_STRENGTH)
 161                 gren.velocity = gren.velocity * cvar("g_balance_powerup_strength_force");
 162         W_SetupProjectileVelocity(gren);
 163
 164         gren.angles = vectoangles (gren.velocity);
 165         gren.flags = FL_PROJECTILE;
 166
 167         gren.portal_id = time;
 168         self.porto_current = gren;
 169         gren.playerid = self.playerid;
 170         fixedmakevectors(vectoangles(gren.velocity));
 171         gren.right_vector = v_right;
 172
 173         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 174 }
 175
 176 void spawnfunc_weapon_porto (void)
 177 {
 178         weapon_defaultspawnfunc(WEP_PORTO);
 179 }
 180
 181 float w_porto(float req)
 182 {
 183         vector v_angle_save;
 184
 185         if (req == WR_AIM)
 186         {
 187                 self.BUTTON_ATCK = FALSE;
 188                 self.BUTTON_ATCK2 = FALSE;
 189                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 190                         self.BUTTON_ATCK = TRUE;
 191         }
 192         else if (req == WR_THINK)
 193         {
 194                 if(self.porto_v_angle_held)
 195                 {
 196                         if(!self.BUTTON_ATCK2)
 197                         {
 198                                 msg_entity = self;
 199                                 WRITESPECTATABLE_MSG_ONE_VARNAME(dummy1, {
 200                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 201                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 202                                         WriteByte(MSG_ONE, WEP_PORTO);
 203                                         WriteByte(MSG_ONE, 0);
 204                                 });
 205                                 self.porto_v_angle_held = 0;
 206                         }
 207                 }
 208                 else
 209                 {
 210                         if(self.BUTTON_ATCK2)
 211                         {
 212                                 self.porto_v_angle = self.v_angle;
 213                                 msg_entity = self;
 214                                 WRITESPECTATABLE_MSG_ONE_VARNAME(dummy2, {
 215                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 216                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 217                                         WriteByte(MSG_ONE, WEP_PORTO);
 218                                         WriteByte(MSG_ONE, 1);
 219                                         WriteCoord(MSG_ONE, self.v_angle_x);
 220                                         WriteCoord(MSG_ONE, self.v_angle_y);
 221                                 });
 222                                 self.porto_v_angle_held = 1;
 223                         }
 224                 }
 225                 v_angle_save = self.v_angle;
 226                 if(self.porto_v_angle_held)
 227                         makevectors(self.porto_v_angle); // override the previously set angles
 228
 229                 if (self.BUTTON_ATCK)
 230                 if (!self.porto_current)
 231                 if (!self.porto_forbidden)
 232                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 233                 {
 234                         W_Porto_Attack();
 235                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 236                 }
 237         }
 238         else if (req == WR_PRECACHE)
 239         {
 240                 precache_model ("models/grenademodel.md3");
 241                 precache_model ("models/weapons/g_porto.md3");
 242                 precache_model ("models/weapons/v_porto.md3");
 243                 precache_model ("models/weapons/w_porto.zym");
 244                 precache_model ("models/portal.md3");
 245                 precache_sound ("porto/bounce.ogg");
 246                 precache_sound ("porto/create.ogg");
 247                 precache_sound ("porto/expire.ogg");
 248                 precache_sound ("porto/explode.ogg");
 249                 precache_sound ("porto/fire.ogg");
 250                 precache_sound ("porto/unsupported.ogg");
 251         }
 252         else if (req == WR_SETUP)
 253                 weapon_setup(WEP_PORTO);
 254         else if (req == WR_SUICIDEMESSAGE)
 255                 w_deathtypestring = "did the impossible";
 256         else if (req == WR_KILLMESSAGE)
 257                 w_deathtypestring = "felt # doing the impossible";
 258         return TRUE;
 259 };