data/qcsrc/server/w_nex.qc

   1 void W_Nex_Attack (void)
   2 {
   3         float flying;
   4         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
   5
   6         W_SetupShot (self, '25 4 -4', TRUE, 5, "weapons/nexfire.wav");
   7
   8         yoda = 0;
   9         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, cvar("g_balance_nex_damage"), cvar("g_balance_nex_force"), WEP_NEX);
  10
  11         if(yoda && flying)
  12                 announce(self, "announcer/male/yoda.ogg");
  13
  14         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  15
  16         // beam effect
  17         trailparticles(world, particleeffectnum("nex_beam"), w_shotorg, trace_endpos);
  18         // flash and burn the wall
  19         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  20                 pointparticles(particleeffectnum("nex_impact"), trace_endpos - w_shotdir * 6, '0 0 0', 1);
  21         // play a sound
  22         soundat (self, trace_endpos, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
  23
  24         if not(self.items & IT_UNLIMITED_AMMO)
  25         {
  26                 self.ammo_cells = self.ammo_cells - cvar("g_balance_nex_ammo");
  27         }
  28 }
  29
  30 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  31
  32 float w_nex(float req)
  33 {
  34         if (req == WR_AIM)
  35                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  36         else if (req == WR_THINK)
  37         {
  38                 if (self.BUTTON_ATCK)
  39                 {
  40                         if (weapon_prepareattack(0, cvar("g_balance_nex_refire")))
  41                         {
  42                                 W_Nex_Attack();
  43                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_animtime"), w_ready);
  44                         }
  45                 }
  46         }
  47         else if (req == WR_PRECACHE)
  48         {
  49                 precache_model ("models/nexflash.md3");
  50                 precache_model ("models/weapons/g_nex.md3");
  51                 precache_model ("models/weapons/v_nex.md3");
  52                 precache_model ("models/weapons/w_nex.zym");
  53                 precache_sound ("weapons/nexfire.wav");
  54                 precache_sound ("weapons/neximpact.wav");
  55         }
  56         else if (req == WR_SETUP)
  57                 weapon_setup(WEP_NEX);
  58         else if (req == WR_CHECKAMMO1)
  59                 return self.ammo_cells >= cvar("g_balance_nex_ammo");
  60         else if (req == WR_CHECKAMMO2)
  61                 return FALSE;
  62         else if (req == WR_SUICIDEMESSAGE)
  63                 w_deathtypestring = "did the impossible";
  64         else if (req == WR_KILLMESSAGE)
  65                 w_deathtypestring = "has been vaporized by";
  66         return TRUE;
  67 };