data/qcsrc/server/w_hagar.qc

   1 // NO bounce protection, as bounces are limited!
   2 void W_Hagar_Explode (void)
   3 {
   4         self.event_damage = SUB_Null;
   5         RadiusDamage (self, self.realowner, cvar("g_balance_hagar_primary_damage"), cvar("g_balance_hagar_primary_edgedamage"), cvar("g_balance_hagar_primary_radius"), world, cvar("g_balance_hagar_primary_force"), self.projectiledeathtype, other);
   6
   7         remove (self);
   8 }
   9
  10 void W_Hagar_Explode2 (void)
  11 {
  12         self.event_damage = SUB_Null;
  13         RadiusDamage (self, self.realowner, cvar("g_balance_hagar_secondary_damage"), cvar("g_balance_hagar_secondary_edgedamage"), cvar("g_balance_hagar_secondary_radius"), world, cvar("g_balance_hagar_secondary_force"), self.projectiledeathtype, other);
  14
  15         remove (self);
  16 }
  17
  18 void W_Hagar_Touch (void)
  19 {
  20         PROJECTILE_TOUCH;
  21         self.use ();
  22 }
  23
  24 void W_Hagar_Touch2 (void)
  25 {
  26         PROJECTILE_TOUCH;
  27
  28         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  29                 self.use();
  30         } else {
  31                 self.cnt++;
  32                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  33                 self.angles = vectoangles (self.velocity);
  34                 self.owner = world;
  35                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  36         }
  37 }
  38
  39 void W_Hagar_Attack (void)
  40 {
  41         local entity missile;
  42
  43         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  44                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_hagar_primary_ammo");
  45         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", cvar("g_balance_hagar_primary_damage"));
  46
  47         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  48
  49         missile = spawn ();
  50         missile.owner = missile.realowner = self;
  51         missile.classname = "missile";
  52         missile.bot_dodge = TRUE;
  53         missile.bot_dodgerating = cvar("g_balance_hagar_primary_damage");
  54         missile.touch = W_Hagar_Touch;
  55         missile.use = W_Hagar_Explode;
  56         missile.think = adaptor_think2use;
  57         missile.nextthink = time + cvar("g_balance_hagar_primary_lifetime");
  58         PROJECTILE_MAKETRIGGER(missile);
  59         missile.projectiledeathtype = WEP_HAGAR;
  60         setorigin (missile, w_shotorg);
  61         setsize(missile, '0 0 0', '0 0 0');
  62
  63         missile.movetype = MOVETYPE_FLY;
  64         missile.velocity = (w_shotdir + randomvec() * cvar("g_balance_hagar_primary_spread")) * cvar("g_balance_hagar_primary_speed");
  65         W_SetupProjectileVelocity(missile);
  66
  67         missile.angles = vectoangles (missile.velocity);
  68         missile.flags = FL_PROJECTILE;
  69
  70         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  71 }
  72
  73 void W_Hagar_Attack2 (void)
  74 {
  75         local entity missile;
  76
  77         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  78                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_hagar_secondary_ammo");
  79         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", cvar("g_balance_hagar_secondary_damage"));
  80         //W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav"); // TODO: move model a little to the right
  81
  82         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  83
  84         missile = spawn ();
  85         missile.owner = missile.realowner = self;
  86         missile.classname = "missile";
  87         missile.bot_dodge = TRUE;
  88         missile.bot_dodgerating = cvar("g_balance_hagar_secondary_damage");
  89         missile.touch = W_Hagar_Touch2;
  90         missile.cnt = 0;
  91         missile.use = W_Hagar_Explode;
  92         missile.think = adaptor_think2use;
  93         missile.nextthink = time + cvar("g_balance_hagar_secondary_lifetime_min") + random() * cvar("g_balance_hagar_secondary_lifetime_rand");
  94         PROJECTILE_MAKETRIGGER(missile);
  95         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
  96         setorigin (missile, w_shotorg);
  97         setsize(missile, '0 0 0', '0 0 0');
  98
  99         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 100         missile.velocity = (w_shotdir + randomvec() * cvar("g_balance_hagar_secondary_spread")) * cvar("g_balance_hagar_secondary_speed");
 101         W_SetupProjectileVelocity(missile);
 102         missile.avelocity = '100 10 10';
 103
 104         missile.angles = vectoangles (missile.velocity);
 105         missile.flags = FL_PROJECTILE;
 106
 107         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 108 }
 109
 110 void spawnfunc_weapon_hagar (void)
 111 {
 112         weapon_defaultspawnfunc(WEP_HAGAR);
 113 }
 114
 115 float w_hagar(float req)
 116 {
 117         if (req == WR_AIM)
 118                 if (random()>0.15)
 119                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_hagar_primary_speed"), 0, cvar("g_balance_hagar_primary_lifetime"), FALSE);
 120                 else
 121                 {
 122                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 123                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_hagar_primary_speed"), 0, cvar("g_balance_hagar_primary_lifetime"), FALSE);
 124                 }
 125         else if (req == WR_THINK)
 126         {
 127                 if (self.BUTTON_ATCK)
 128                 if (weapon_prepareattack(0, cvar("g_balance_hagar_primary_refire")))
 129                 {
 130                         W_Hagar_Attack();
 131                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hagar_primary_refire"), w_ready);
 132                 }
 133                 if (self.BUTTON_ATCK2)
 134                 if (weapon_prepareattack(1, cvar("g_balance_hagar_secondary_refire")))
 135                 {
 136                         W_Hagar_Attack2();
 137                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_hagar_secondary_refire"), w_ready);
 138                 }
 139         }
 140         else if (req == WR_PRECACHE)
 141         {
 142                 precache_model ("models/weapons/g_hagar.md3");
 143                 precache_model ("models/weapons/v_hagar.md3");
 144                 precache_model ("models/weapons/h_hagar.dpm");
 145                 precache_sound ("weapons/hagar_fire.wav");
 146         }
 147         else if (req == WR_SETUP)
 148                 weapon_setup(WEP_HAGAR);
 149         else if (req == WR_CHECKAMMO1)
 150                 return self.ammo_rockets >= cvar("g_balance_hagar_primary_ammo");
 151         else if (req == WR_CHECKAMMO2)
 152                 return self.ammo_rockets >= cvar("g_balance_hagar_secondary_ammo");
 153         else if (req == WR_SUICIDEMESSAGE)
 154                 w_deathtypestring = "played with tiny rockets";
 155         else if (req == WR_KILLMESSAGE)
 156         {
 157                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 158                         w_deathtypestring = "hoped #'s missiles wouldn't bounce";
 159                 else // unchecked: SPLASH, SECONDARY
 160                         w_deathtypestring = "was pummeled by";
 161         }
 162         return TRUE;
 163 };