data/qcsrc/server/w_grenadelauncher.qc

   1
   2 void W_Grenade_Explode (void)
   3 {
   4         vector  org2;
   5         org2 = findbetterlocation (self.origin, 12);
   6         te_explosion (org2);
   7         //effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
   8         sound (self, CHAN_BODY, "weapons/grenade_impact.wav", 1, ATTN_NORM);
   9
  10         self.event_damage = SUB_Null;
  11         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), IT_GRENADE_LAUNCHER);
  12
  13         remove (self);
  14 }
  15
  16 void W_Grenade_Explode2 (void)
  17 {
  18         vector  org2;
  19         org2 = findbetterlocation (self.origin, 12);
  20         te_explosion (org2);
  21         //effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
  22         sound (self, CHAN_BODY, "weapons/grenade_impact.wav", 1, ATTN_NORM);
  23
  24         self.event_damage = SUB_Null;
  25         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), IT_GRENADE_LAUNCHER);
  26
  27         remove (self);
  28 }
  29
  30 void W_Grenade_Touch1 (void)
  31 {
  32         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  33         {
  34                 remove(self);
  35                 return;
  36         }
  37         W_Grenade_Explode ();
  38 }
  39
  40 void W_Grenade_Touch2 (void)
  41 {
  42         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  43         {
  44                 remove(self);
  45                 return;
  46         }
  47         if (other.takedamage == DAMAGE_AIM)
  48                 self.think ();
  49         else
  50         {
  51                 float r;
  52                 r = random() * 6;
  53                 if(r < 1)
  54                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce1.wav", 1, ATTN_NORM);
  55                 else if(r < 2)
  56                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce2.wav", 1, ATTN_NORM);
  57                 else if(r < 3)
  58                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce3.wav", 1, ATTN_NORM);
  59                 else if(r < 4)
  60                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce4.wav", 1, ATTN_NORM);
  61                 else if(r < 5)
  62                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce5.wav", 1, ATTN_NORM);
  63                 else
  64                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce6.wav", 1, ATTN_NORM);
  65         }
  66 }
  67
  68 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  69 {
  70         self.health = self.health - damage;
  71         if (self.health <= 0)
  72         {
  73                 self.owner = attacker;
  74                 self.think ();
  75         }
  76 }
  77
  78 void W_Grenade_Attack (void)
  79 {
  80         local entity gren;
  81
  82         if (cvar("g_use_ammunition"))
  83                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  84         W_SetupShot (self, '11 8 -8', FALSE, 4, "weapons/grenade_fire.wav");
  85
  86         gren = spawn ();
  87         gren.owner = self;
  88         gren.classname = "grenade";
  89         gren.bot_dodge = TRUE;
  90         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  91         gren.movetype = MOVETYPE_BOUNCE;
  92         gren.solid = SOLID_BBOX;
  93         gren.effects = EF_LOWPRECISION;
  94         setmodel(gren, "models/grenademodel.md3"); // precision set above
  95         setsize(gren, '0 0 0', '0 0 0');
  96         setorigin(gren, w_shotorg);
  97
  98         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
  99         gren.think = W_Grenade_Explode;
 100         gren.touch = W_Grenade_Touch1;
 101         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 102         W_SetupProjectileVelocity(gren);
 103         gren.avelocity_x = random () * -500 - 500;
 104
 105         gren.angles = vectoangles (gren.velocity);
 106         gren.flags = FL_PROJECTILE;
 107 }
 108
 109 void W_Grenade_Attack2 (void)
 110 {
 111         local entity gren;
 112
 113         if (cvar("g_use_ammunition"))
 114                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 115         W_SetupShot (self, '11 8 -8', FALSE, 4, "weapons/grenade_fire.wav");
 116
 117         gren = spawn ();
 118         gren.owner = self;
 119         gren.classname = "grenade";
 120         gren.bot_dodge = TRUE;
 121         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 122         gren.movetype = MOVETYPE_BOUNCE;
 123         gren.solid = SOLID_BBOX;
 124         gren.effects = EF_LOWPRECISION;
 125         setmodel(gren, "models/grenademodel.md3"); // precision set above
 126         setsize(gren, '0 0 -3', '0 0 -3');
 127         setorigin(gren, w_shotorg);
 128
 129         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 130         gren.think = W_Grenade_Explode2;
 131         gren.touch = W_Grenade_Touch2;
 132         gren.takedamage = DAMAGE_YES;
 133         gren.health = 10;
 134         gren.damageforcescale = 4;
 135         gren.event_damage = W_Grenade_Damage;
 136         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 137         W_SetupProjectileVelocity(gren);
 138         gren.avelocity = '100 150 100';
 139
 140         gren.angles = vectoangles (gren.velocity);
 141         gren.flags = FL_PROJECTILE;
 142 }
 143
 144 .float bot_secondary_grenademooth;
 145 float(float req) w_glauncher =
 146 {
 147         if (req == WR_AIM)
 148         {
 149                 self.button0 = FALSE;
 150                 self.button3 = FALSE;
 151                 if (self.bot_secondary_grenademooth == 0)
 152                 {
 153                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 154                         {
 155                                 self.button0 = TRUE;
 156                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 157                         }
 158                 }
 159                 else
 160                 {
 161                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 162                         {
 163                                 self.button3 = TRUE;
 164                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 165                         }
 166                 }
 167         }
 168         else if (req == WR_THINK)
 169         {
 170                 if (self.button0)
 171                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 172                 {
 173                         W_Grenade_Attack();
 174                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 175                 }
 176                 if (self.button3)
 177                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 178                 {
 179                         W_Grenade_Attack2();
 180                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 181                 }
 182         }
 183         else if (req == WR_PRECACHE)
 184         {
 185                 precache_model ("models/grenademodel.md3");
 186                 precache_model ("models/weapons/g_gl.md3");
 187                 precache_model ("models/weapons/v_gl.md3");
 188                 precache_model ("models/weapons/w_gl.zym");
 189                 precache_sound ("weapons/grenade_bounce1.wav");
 190                 precache_sound ("weapons/grenade_bounce2.wav");
 191                 precache_sound ("weapons/grenade_bounce3.wav");
 192                 precache_sound ("weapons/grenade_bounce4.wav");
 193                 precache_sound ("weapons/grenade_bounce5.wav");
 194                 precache_sound ("weapons/grenade_bounce6.wav");
 195                 precache_sound ("weapons/grenade_fire.wav");
 196                 precache_sound ("weapons/grenade_impact.wav");
 197         }
 198         else if (req == WR_SETUP)
 199                 weapon_setup(WEP_GRENADE_LAUNCHER, "gl", IT_ROCKETS);
 200         else if (req == WR_CHECKAMMO1)
 201                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 202         else if (req == WR_CHECKAMMO2)
 203                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 204         else if (req == WR_REGISTER)
 205                 weapon_register(WEP_GRENADE_LAUNCHER, min(cvar("g_balance_grenadelauncher_primary_ammo"), cvar("g_balance_grenadelauncher_secondary_ammo")));
 206         return TRUE;
 207 };